2002-10-17 Roland McGrath <roland@redhat.com>
[kopensolaris-gnu/glibc.git] / aclocal.m4
1 dnl We define the macro GLIBC_PROVIDES to do an AC_PROVIDE for each macro
2 dnl which appears in configure.in before the sysdep configure scripts are run.
3 dnl Each sysdep configure.in does GLIBC_PROVIDES first, to avoid any
4 dnl AC_REQUIREs or AC_BEFOREs duplicating their code.
5 dnl
6 define([GLIBC_PROVIDES], [dnl
7 AC_PROVIDE([_AS_ECHO_N_PREPARE])dnl
8 AC_PROVIDE([_AS_CR_PREPARE])dnl
9 AC_PROVIDE([_AS_TR_SH_PREPARE])dnl
10 AC_PROVIDE([AC_PROG_INSTALL])dnl
11 AC_PROVIDE([AC_PROG_RANLIB])dnl
12 AC_PROVIDE([AC_PROG_CC])dnl
13 AC_PROVIDE([AC_PROG_CPP])dnl
14 define([AS_MESSAGE_LOG_FD],5)dnl
15 define([AS_MESSAGE_FD],6)dnl
16 AS_INIT()dnl
17 m4_divert_text([HEADER-COMMENT],
18 [@%:@ This file is generated from configure.in by Autoconf.  DO NOT EDIT!])
19 define([_AC_LANG], [C])dnl
20 ])dnl
21 dnl
22 dnl Check for a symbol
23 dnl
24 AC_DEFUN([AC_CHECK_SYMBOL], [dnl
25 AC_MSG_CHECKING(for $1)
26 AC_CACHE_VAL(ac_cv_check_symbol_$1, [dnl
27 AC_TRY_LINK(,
28 changequote(,)dnl
29 extern char *$1[]; puts(*$1);,
30 changequote([,])dnl
31             ac_cv_check_symbol_$1=yes, ac_cv_check_symbol_$1=no)])
32 if test "$ac_cv_check_symbol_$1" = yes; then
33 changequote(,)dnl
34   ac_tr_symbol=`echo $1 | tr '[a-z]' '[A-Z]'`
35 changequote([,])dnl
36   AC_DEFINE_UNQUOTED(HAVE_${ac_tr_symbol})
37 fi
38 AC_MSG_RESULT($ac_cv_check_symbol_$1)])dnl
39 dnl
40
41 dnl Locate a program and check that its version is acceptable.
42 dnl AC_PROG_CHECK_VER(var, namelist, version-switch,
43 dnl                   [version-extract-regexp], version-glob [, do-if-fail])
44 AC_DEFUN([AC_CHECK_PROG_VER],
45 [AC_CHECK_PROGS([$1], [$2])
46 if test -z "[$]$1"; then
47   ac_verc_fail=yes
48 else
49   # Found it, now check the version.
50   AC_MSG_CHECKING([version of [$]$1])
51 changequote(<<,>>)dnl
52   ac_prog_version=`<<$>>$1 $3 2>&1 ifelse(<<$4>>,,,
53                    <<| sed -n 's/^.*patsubst(<<$4>>,/,\/).*$/\1/p'>>)`
54   case $ac_prog_version in
55     '') ac_prog_version="v. ?.??, bad"; ac_verc_fail=yes;;
56     <<$5>>)
57 changequote([,])dnl
58        ac_prog_version="$ac_prog_version, ok"; ac_verc_fail=no;;
59     *) ac_prog_version="$ac_prog_version, bad"; ac_verc_fail=yes;;
60
61   esac
62   AC_MSG_RESULT([$ac_prog_version])
63 fi
64 ifelse([$6],,,
65 [if test $ac_verc_fail = yes; then
66   $6
67 fi])
68 ])
69
70 dnl These modifications are to allow for an empty cross compiler tree.
71 define([_AC_COMPILER_EXEEXT], [EXEEXT=
72 ])
73
74 AC_DEFUN([LIBC_PROG_FOO_GNU],
75 [# Most GNU programs take a -v and spit out some text including
76 # the word 'GNU'.  Some try to read stdin, so give them /dev/null.
77 if $1 -o conftest -v </dev/null 2>&1 | grep GNU > /dev/null 2>&1; then
78   $2
79 else
80   $3
81 fi
82 rm -fr contest*])
83
84 AC_DEFUN([LIBC_PROG_BINUTILS],
85 [# Was a --with-binutils option given?
86 if test -n "$path_binutils"; then
87     # Make absolute; ensure a single trailing slash.
88     path_binutils=`(cd $path_binutils; pwd) | sed 's%/*$%/%'`
89     CC="$CC -B$path_binutils"
90 fi
91 AS=`$CC -print-prog-name=as`
92 LD=`$CC -print-prog-name=ld`
93 AR=`$CC -print-prog-name=ar`
94 AC_SUBST(AR)
95
96 # ranlib has to be treated a bit differently since it might not exist at all.
97 ac_ranlib=`$CC -print-prog-name=ranlib`
98 if test "x$ac_ranlib" = xranlib; then
99 # This extra check has to happen since gcc simply echos the parameter in
100 # case it cannot find the value in its own directories.
101 AC_CHECK_TOOL(RANLIB, ranlib, :)
102 else
103   RANLIB=$ac_ranlib
104 fi
105 AC_SUBST(RANLIB)
106
107 # Determine whether we are using GNU binutils.
108 AC_CACHE_CHECK(whether $AS is GNU as, libc_cv_prog_as_gnu,
109 [LIBC_PROG_FOO_GNU($AS, libc_cv_prog_as_gnu=yes, libc_cv_prog_as_gnu=no)])
110 rm -f a.out
111 gnu_as=$libc_cv_prog_as_gnu
112
113 AC_CACHE_CHECK(whether $LD is GNU ld, libc_cv_prog_ld_gnu,
114 [LIBC_PROG_FOO_GNU($LD, libc_cv_prog_ld_gnu=yes, libc_cv_prog_ld_gnu=no)])
115 gnu_ld=$libc_cv_prog_ld_gnu
116 ])