Remove duplicated `;'.
[kopensolaris-gnu/glibc.git] / configure.in
1 Dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45
46 AC_ARG_ENABLE(libio, dnl
47 [  --enable-libio          build in GNU libio instead of GNU stdio],
48               [if test $enableval = yes; then
49                  stdio=libio
50                else
51                  stdio=stdio
52                fi],
53               stdio=default)
54
55 AC_ARG_ENABLE(sanity-checks, dnl
56 [  --disable-sanity-checks really do not use threads (should not be used
57                           except in special situations) [default=yes]],
58               enable_sanity=$enableval, enable_sanity=yes)
59
60 dnl Arguments to enable or disable building the static, shared, profiled,
61 dnl and -fomit-frame-pointer libraries.
62 AC_ARG_ENABLE(static, dnl
63 [  --enable-static         build static library [default=yes]],
64               static=$enableval, static=yes)
65 AC_ARG_ENABLE(shared, dnl
66 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
67               shared=$enableval, shared=default)
68 AC_ARG_ENABLE(profile, dnl
69 [  --enable-profile        build profiled library [default=yes]],
70               profile=$enableval, profile=yes)
71 AC_ARG_ENABLE(omitfp, dnl
72 [  --enable-omitfp         build undebuggable optimized library [default=no]],
73               omitfp=$enableval, omitfp=no)
74 AC_ARG_ENABLE(bounded, dnl
75 [  --enable-bounded        build with runtime bounds checking [default=no]],
76               bounded=$enableval, bounded=no)
77 AC_ARG_ENABLE(versioning, dnl
78 [  --disable-versioning    do not include versioning information in the
79                           library objects [default=yes if supported]],
80              enable_versioning=$enableval, enable_versioning=yes)
81
82 dnl Generic infrastructure for drop-in additions to libc.
83 AC_ARG_ENABLE(add-ons, dnl
84 [  --enable-add-ons=DIR... configure and build named extra directories],
85               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
86               [add_ons=])
87 AC_CONFIG_SUBDIRS($add_ons)
88 add_ons_pfx=
89 if test x"$add_ons" != x; then
90   for f in $add_ons; do
91     # Test whether such a subdir really exists.
92     if test -d $srcdir/$f; then
93       add_ons_pfx="$add_ons_pfx $f/"
94     else
95       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
96     fi
97   done
98 fi
99
100 dnl On some platforms we cannot use dynamic loading.  We must provide
101 dnl static NSS modules.
102 AC_ARG_ENABLE(static-nss, dnl
103 [  --enable-static-nss     build static NSS modules [default=no]],
104               static_nss=$enableval, static_nss=no)
105 if test x"$static_nss" = xyes; then
106   AC_DEFINE(DO_STATIC_NSS)
107 fi
108
109 AC_CANONICAL_HOST
110
111 # The way shlib-versions is used to generate soversions.mk uses a
112 # fairly simplistic model for name recognition that can't distinguish
113 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
114 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
115 # tell.  This doesn't get used much beyond that, so it's fairly safe.
116 case "$host_os" in
117 linux*)
118   ;;
119 gnu*)
120   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
121   ;;
122 esac
123
124 ###
125 ### I put this here to prevent those annoying emails from people who cannot
126 ### read and try to compile glibc on unsupported platforms.  --drepper
127 ###
128 ### By using the undocumented --enable-hacker-mode option for configure
129 ### one can skip this test to make the configuration not fail for unsupported
130 ### platforms.
131 ###
132 if test -z "$enable_hacker_mode"; then
133   case "$host_os" in
134   linux* | gnu*)
135     ;;
136   *)
137     echo "*** The GNU C library is currently not available for this platform."
138     echo "*** So far nobody cared to port it and if there is no volunteer it"
139     echo "*** might never happen.  So, if you have interest to see glibc on"
140     echo "*** this platform visit"
141     echo "***   http://www.gnu.ai.mit.edu/software/libc/porting.html"
142     echo "*** and join the group of porters"
143     exit 1
144     ;;
145   esac
146 fi
147
148 # We keep the original values in `$config_*' and never modify them, so we
149 # can write them unchanged into config.make.  Everything else uses
150 # $machine, $vendor, and $os, and changes them whenever convenient.
151 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
152
153 # Some configurations imply other options.
154 case "$host_os" in
155 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
156   # These systems always use GNU tools.
157   gnu_ld=yes gnu_as=yes ;;
158 esac
159 case "$host_os" in
160 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
161 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
162   ;;
163 gnu* | linux* | sysv4* | solaris2*)
164   # These systems (almost) always use the ELF format.
165   elf=yes
166   ;;
167 esac
168
169 machine=$config_machine
170 vendor=$config_vendor
171 os=$config_os
172
173 dnl We need to use [ and ] for other purposes for a while now.
174 changequote(,)dnl
175 # Expand the configuration machine name into a subdirectory by architecture
176 # type and particular chip.
177 case "$machine" in
178 a29k | am29000) base_machine=a29k machine=a29k ;;
179 alpha*)         base_machine=alpha machine=alpha/$machine ;;
180 arm*)           base_machine=arm machine=arm/$machine ;;
181 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
182 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
183 hppa*)          base_machine=hppa machine=hppa/$machine ;;
184 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
185 m680?0)         base_machine=m68k machine=m68k/$machine ;;
186 m68k)           base_machine=m68k machine=m68k/m68020 ;;
187 m88???)         base_machine=m88k machine=m88k/$machine ;;
188 m88k)           base_machine=m88k machine=m88k/m88100 ;;
189 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
190 mips*)          base_machine=mips machine=mips/$machine ;;
191 sparc | sparcv[67])
192                 base_machine=sparc machine=sparc/sparc32 ;;
193 sparcv8 | supersparc | hypersparc)
194                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
195 sparc64 | ultrasparc)
196                 base_machine=sparc machine=sparc/sparc64 ;;
197 esac
198 changequote([,])dnl
199 AC_SUBST(base_machine)
200
201 if test "$base_machine" = "i386"; then
202   AC_DEFINE(USE_REGPARMS)
203 fi
204
205 # Compute the list of sysdep directories for this configuration.
206 # This can take a while to compute.
207 sysdep_dir=$srcdir/sysdeps
208 AC_MSG_CHECKING(sysdep dirs)
209 dnl We need to use [ and ] for other purposes for a while now.
210 changequote(,)dnl
211 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
212 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
213
214 case "$os" in
215 gnu*)
216   base_os=mach/hurd ;;
217 netbsd* | 386bsd* | freebsd* | bsdi*)
218   base_os=unix/bsd/bsd4.4 ;;
219 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
220   base_os=unix/bsd ;;
221 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
222   base_os=unix/sysv ;;
223 solaris[2-9]*)
224   base_os=unix/sysv/sysv4 ;;
225 none)
226   base_os=standalone ;;
227 *)
228   base_os='' ;;
229 esac
230
231 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
232 tail=$os
233 ostry=$os
234 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
235   ostry="$ostry /$o"
236   tail=$o
237 done
238 o=`echo $tail | sed 's/[0-9]*$//'`
239 if test $o != $tail; then
240   ostry="$ostry /$o"
241 fi
242 # For linux-gnu, try linux-gnu, then linux.
243 o=`echo $tail | sed 's/-.*$//'`
244 if test $o != $tail; then
245   ostry="$ostry /$o"
246 fi
247
248 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
249 base=
250 tail=$base_os
251 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
252   set $b
253   base="$base /$1"
254   tail="$2"
255 done
256
257 # For sparc/sparc9, try sparc/sparc9 and then sparc.
258 mach=
259 tail=$machine
260 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
261   set $m
262   # Prepend the machine's FPU directory unless --without-fp.
263   if test "$with_fp" = yes; then
264     mach="$mach /$1/fpu"
265   fi
266   mach="$mach /$1"
267   tail="$2"
268 done
269
270 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
271 changequote([,])dnl
272
273 # Find what sysdep directories exist.
274 sysnames=
275 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
276 for d in $add_ons_pfx ''; do
277   for b in $base ''; do
278     for m0 in $mach ''; do
279       for v in /$vendor ''; do
280         for o in /$ostry ''; do
281           for m in $mach ''; do
282             if test "$m0$b$v$o$m"; then
283               try="${d}sysdeps$m0$b$v$o$m"
284               test -n "$enable_debug_configure" &&
285               echo "$0 [DEBUG]: try $try" >&2
286               case $try in
287                 /*) dest=$try ;;
288                 *)  dest=$srcdir/$try ;;
289               esac
290               if test -d $dest; then
291                 sysnames="$sysnames $try"
292                 { test -n "$o" || test -n "$b"; } && os_used=t
293                 { test -n "$m" || test -n "$m0"; } && machine_used=t
294               fi
295             fi
296           done
297         done
298       done
299     done
300   done
301 done
302 IFS="$ac_save_ifs"
303
304 if test -z "$os_used" && test "$os" != none; then
305   AC_MSG_ERROR(Operating system $os is not supported.)
306 fi
307 if test -z "$machine_used" && test "$machine" != none; then
308   AC_MSG_ERROR(The $machine is not supported.)
309 fi
310
311 # We have now validated the configuration.
312
313
314 # If using ELF, look for an `elf' subdirectory of each machine directory.
315 # We prepend these rather than inserting them whereever the machine appears
316 # because things specified by the machine's ELF ABI should override
317 # OS-specific things, and should always be the same for any OS on the
318 # machine (otherwise what's the point of an ABI?).
319 if test "$elf" = yes; then
320   elf_dirs=
321   for d in $add_ons_pfx ''; do
322     case $d in
323       /*) xsrcdir= ;;
324       *)  xsrcdir=$srcdir/ ;;
325     esac
326     for m in $mach; do
327       if test -d $xsrcdir${d}sysdeps$m/elf; then
328         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
329       fi
330     done
331   done
332   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
333 fi
334
335
336 # Expand the list of system names into a full list of directories
337 # from each element's parent name and Implies file (if present).
338 set $sysnames
339 names=
340 while test $# -gt 0; do
341   name=$1
342   shift
343
344   case " $names " in *" $name "*)
345     # Already in the list.
346     continue
347   esac
348
349   # Report each name as we discover it, so there is no long pause in output.
350   echo $ac_n "$name $ac_c" >&AC_FD_MSG
351
352   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
353
354   case $name in
355     /*) xsrcdir= ;;
356     *)  xsrcdir=$srcdir/ ;;
357   esac
358   test -n "$enable_debug_configure" &&
359   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
360
361   if test -f $xsrcdir$name/Implies; then
362     # Collect more names from the `Implies' file (removing comments).
363     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
364     implied=
365     for x in $implied_candidate; do
366       if test -d $xsrcdir$name_base/$x; then
367         implied="$implied $name_base/$x";
368       else
369         AC_MSG_WARN($name/Implies specifies nonexistent $x)
370       fi
371     done
372   else
373     implied=
374   fi
375
376   # Add NAME to the list of names.
377   names="$names $name"
378
379   # Find the parent of NAME, using the empty string if it has none.
380 changequote(,)dnl
381   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
382 changequote([,])dnl
383
384   # Add the names implied by NAME, and NAME's parent (if it has one), to
385   # the list of names to be processed (the argument list).  We prepend the
386   # implied names to the list and append the parent.  We want implied
387   # directories to come before further directories inferred from the
388   # configuration components; this ensures that for sysv4, unix/common
389   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
390   # after sysv4).
391   sysnames="`echo $implied $* $parent`"
392   test -n "$sysnames" && set $sysnames
393 done
394
395 # Add the default directories.
396 sysnames="$names sysdeps/generic"
397 AC_SUBST(sysnames)
398 # The other names were emitted during the scan.
399 AC_MSG_RESULT(sysdeps/generic)
400
401
402 ### Locate tools.
403
404 AC_PROG_INSTALL
405 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
406   # The makefiles need to use a different form to find it in $srcdir.
407   INSTALL='\$(..)./install-sh -c'
408 fi
409 AC_PROG_LN_S
410 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
411
412 AC_PROG_CC_LOCAL
413 AC_CANONICAL_BUILD
414 if test $host != $build; then
415   AC_CHECK_PROGS(BUILD_CC, gcc cc)
416 fi
417 AC_SUBST(cross_compiling)
418 AC_PROG_CPP
419 LIBC_PROG_BINUTILS
420 AC_CHECK_TOOL(AR, ar)
421 AC_CHECK_TOOL(RANLIB, ranlib, :)
422
423 AC_PATH_PROG(BASH, bash, no)
424 if test "$BASH" != no &&
425    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
426   libc_cv_have_bash2=yes
427 else
428   libc_cv_have_bash2=no
429 fi
430 AC_SUBST(libc_cv_have_bash2)
431
432 dnl We need a ksh compatible shell for tzselect.
433 if test "$BASH" = no; then
434   AC_PATH_PROG(KSH, ksh, no)
435   if test "$KSH" = no; then
436     libc_cv_have_ksh=no
437   else
438     libc_cv_have_ksh=yes
439   fi
440 else
441   KSH="$BASH"
442   AC_SUBST(KSH)
443   libc_cv_have_ksh=yes
444 fi
445 AC_SUBST(libc_cv_have_ksh)
446
447 AC_PATH_PROGS(PERL, perl, no)
448 AC_SUBST(PERL)
449
450 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
451 echo '#include <stddef.h>
452 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
453 if eval "$ac_cpp conftest.c 2>/dev/null" \
454 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
455   libc_cv_signed_size_t=no
456 else
457   libc_cv_signed_size_t=yes
458 fi
459 rm -f conftest*])
460 if test $libc_cv_signed_size_t = yes; then
461   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
462   cat >> confdefs.h <<\EOF
463 #undef __SIZE_TYPE__
464 #define __SIZE_TYPE__ unsigned
465 EOF
466 fi
467
468 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
469 AC_TRY_COMPILE(dnl
470 [#define __need_size_t
471 #define __need_wchar_t
472 #include <stddef.h>
473 #define __need_NULL
474 #include <stddef.h>], [size_t size; wchar_t wchar;
475 #ifdef offsetof
476 #error stddef.h ignored __need_*
477 #endif
478 if (&size == NULL || &wchar == NULL) abort ();],
479                libc_cv_friendly_stddef=yes,
480                libc_cv_friendly_stddef=no)])
481 if test $libc_cv_friendly_stddef = yes; then
482   config_vars="$config_vars
483 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
484 fi
485
486 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
487                libc_cv_need_minus_P, [dnl
488 cat > conftest.S <<EOF
489 #include "confdefs.h"
490 /* Nothing whatsoever.  */
491 EOF
492 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
493   libc_cv_need_minus_P=no
494 else
495   libc_cv_need_minus_P=yes
496 fi
497 rm -f conftest*])
498 if test $libc_cv_need_minus_P = yes; then
499   config_vars="$config_vars
500 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
501 fi
502
503 AC_CACHE_CHECK(for assembler global-symbol directive,
504                libc_cv_asm_global_directive, [dnl
505 libc_cv_asm_global_directive=UNKNOWN
506 for ac_globl in .globl .global; do
507   cat > conftest.s <<EOF
508 .text
509 ${ac_globl} foo
510 foo:
511 EOF
512   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
513     libc_cv_asm_global_directive=${ac_globl}
514   fi
515   rm -f conftest*
516   test $libc_cv_asm_global_directive != UNKNOWN && break
517 done])
518 if test $libc_cv_asm_global_directive = UNKNOWN; then
519   AC_MSG_ERROR(cannot determine asm global directive)
520 else
521   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
522 fi
523
524 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
525 cat > conftest.s <<EOF
526 .text
527 foo:
528 .set glibc_conftest_frobozz,foo
529 $libc_cv_asm_global_directive glibc_conftest_frobozz
530 EOF
531 # The alpha-dec-osf1 assembler gives only a warning for `.set'
532 # (but it doesn't work), so we must do a linking check to be sure.
533 cat > conftest1.c <<\EOF
534 extern int glibc_conftest_frobozz;
535 main () { printf ("%d\n", glibc_conftest_frobozz); }
536 EOF
537 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
538             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
539   libc_cv_asm_set_directive=yes
540 else
541   libc_cv_asm_set_directive=no
542 fi
543 rm -f conftest*])
544 if test $libc_cv_asm_set_directive = yes; then
545   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
546 fi
547
548 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
549 [cat > conftest.s <<EOF
550 .text
551 _sym:
552 .symver _sym,sym@VERS
553 EOF
554 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
555   libc_cv_asm_symver_directive=yes
556 else
557   libc_cv_asm_symver_directive=no
558 fi
559 rm -f conftest*])
560 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
561 if test $libc_cv_asm_symver_directive = yes; then
562   cat > conftest.s <<EOF
563 .text
564 _sym:
565 .symver _sym,sym@VERS
566 EOF
567   cat > conftest.map <<EOF
568 VERS {
569         global: sym;
570 };
571 EOF
572   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
573     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
574                                         -nostartfiles -nostdlib
575                                         -Wl,--version-script,conftest.map
576                        1>&AC_FD_CC]);
577     then
578       libc_cv_ld_version_script_option=yes
579     else
580       libc_cv_ld_version_script_option=no
581     fi
582   else
583     libc_cv_ld_version_script_option=no
584   fi
585 else
586   libc_cv_ld_version_script_option=no
587 fi
588 rm -f conftest*])
589 if test $libc_cv_asm_symver_directive = yes &&
590    test $libc_cv_ld_version_script_option = yes &&
591    test $enable_versioning = yes; then
592   VERSIONING=yes
593   AC_DEFINE(DO_VERSIONING)
594 else
595   VERSIONING=no
596 fi
597 AC_SUBST(VERSIONING)
598
599 if test $elf = yes; then
600   AC_CACHE_CHECK(for .previous assembler directive,
601                  libc_cv_asm_previous_directive, [dnl
602   cat > conftest.s <<EOF
603 .section foo_section
604 .previous
605 EOF
606   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
607     libc_cv_asm_previous_directive=yes
608   else
609     libc_cv_asm_previous_directive=no
610   fi
611   rm -f conftest*])
612   if test $libc_cv_asm_previous_directive = yes; then
613     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
614   else
615     AC_CACHE_CHECK(for .popsection assembler directive,
616                    libc_cv_asm_popsection_directive, [dnl
617     cat > conftest.s <<EOF
618 .pushsection foo_section
619 .popsection
620 EOF
621     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
622       libc_cv_asm_popsection_directive=yes
623     else
624       libc_cv_asm_popsection_directive=no
625     fi
626     rm -f conftest*])
627     if test $libc_cv_asm_popsection_directive = yes; then
628       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
629     fi
630   fi
631 fi
632
633 if test $elf != yes; then
634   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
635                  [AC_TRY_COMPILE(, [asm (".section .init");
636                                     asm (".section .fini");
637                                     asm (".text");],
638                                  libc_cv_have_initfini=yes,
639                                  libc_cv_have_initfini=no)])
640   AC_SUBST(libc_cv_have_initfini)dnl
641   if test $libc_cv_have_initfini = yes; then
642     AC_DEFINE(HAVE_INITFINI)
643   fi
644 fi
645
646 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
647 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
648 [cat > conftest.$ac_ext <<EOF
649 dnl This sometimes fails to find confdefs.h, for some reason.
650 dnl [#]line __oline__ "[$]0"
651 [#]line __oline__ "configure"
652 #include "confdefs.h"
653 void underscore_test(void) {
654 return; }
655 EOF
656 if AC_TRY_EVAL(ac_compile); then
657   if grep _underscore_test conftest* >/dev/null; then
658     ifelse([$1], , :, [rm -f conftest*
659     $1])
660   else
661     ifelse([$2], , , [rm -f conftest*
662     $2])
663   fi
664 else
665   echo "configure: failed program was:" >&AC_FD_CC
666   cat conftest.$ac_ext >&AC_FD_CC
667   ifelse([$2], , , [rm -f conftest*
668   $2])
669 fi
670 rm -f conftest*])
671
672 if test $elf = yes; then
673   libc_cv_asm_underscores=no
674 else
675   if test $ac_cv_prog_cc_works = yes; then
676     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
677                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
678                                 libc_cv_asm_underscores=yes,
679                                 libc_cv_asm_underscores=no)])
680   else
681     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
682                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
683                                             libc_cv_asm_underscores=no)])
684   fi
685 fi
686 if test $libc_cv_asm_underscores = no; then
687   AC_DEFINE(NO_UNDERSCORES)
688 fi
689
690 if test $elf = yes; then
691   libc_cv_weak_symbols=yes
692   libc_cv_asm_weak_directive=yes
693   libc_cv_asm_weakext_directive=no
694 else
695   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
696                  [dnl
697 cat > conftest.s <<EOF
698 .text
699 ${libc_cv_asm_global_directive} foo
700 foo:
701 .weak foo
702 .weak bar; bar = foo
703 EOF
704   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
705     libc_cv_asm_weak_directive=yes
706   else
707     libc_cv_asm_weak_directive=no
708   fi
709   rm -f conftest*])
710
711 if test $libc_cv_asm_weak_directive = no; then
712   AC_CACHE_CHECK(for assembler .weakext directive,
713                  libc_cv_asm_weakext_directive,
714                  [dnl
715 cat > conftest.s <<EOF
716 .text
717 ${libc_cv_asm_global_directive} foo
718 foo:
719 .weakext foo
720 .weakext foo, bar
721 EOF
722   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
723     libc_cv_asm_weakext_directive=yes
724   else
725     libc_cv_asm_weakext_directive=no
726   fi
727   rm -f conftest*])
728
729   fi # no .weak
730 fi # not ELF
731
732 if test $libc_cv_asm_weak_directive = yes; then
733   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
734 elif test $libc_cv_asm_weakext_directive = yes; then
735   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
736 fi
737
738 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
739 cat > conftest.c <<\EOF
740 _start () {}
741 int __eh_pc;
742 __throw () {}
743 EOF
744 dnl No \ in command here because it ends up inside ''.
745 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
746                             -nostdlib -nostartfiles -Wl,--no-whole-archive
747                             -o conftest conftest.c 1>&AC_FD_CC]); then
748   libc_cv_ld_no_whole_archive=yes
749 else
750   libc_cv_ld_no_whole_archive=no
751 fi
752 rm -f conftest*])
753 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
754
755 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
756 cat > conftest.c <<\EOF
757 _start () {}
758 int __eh_pc;
759 __throw () {}
760 EOF
761 dnl No \ in command here because it ends up inside ''.
762 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
763                             -nostdlib -nostartfiles -fno-exceptions
764                             -o conftest conftest.c 1>&AC_FD_CC]); then
765   libc_cv_gcc_no_exceptions=yes
766 else
767   libc_cv_gcc_no_exceptions=no
768 fi
769 rm -f conftest*])
770 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
771
772 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
773 [cat > conftest.c <<EOF
774 #line __oline__ "configure"
775 static char __EH_FRAME_BEGIN__[];
776 _start ()
777 {
778   __register_frame (__EH_FRAME_BEGIN__);
779   __deregister_frame (__EH_FRAME_BEGIN__);
780 }
781 int __eh_pc;
782 __throw () {}
783 /* FIXME: this is fragile.  */
784 malloc () {}
785 strcmp () {}
786 strlen () {}
787 memcpy () {}
788 memset () {}
789 free () {}
790 abort () {}
791 __bzero () {}
792 EOF
793 dnl No \ in command here because it ends up inside ''.
794 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
795                             -nostdlib -nostartfiles
796                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
797   libc_cv_gcc_dwarf2_unwind_info=yes
798 else
799   libc_cv_gcc_dwarf2_unwind_info=no
800 fi
801 rm -f conftest*])
802 if test $libc_cv_gcc_dwarf2_unwind_info = yes; then
803   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
804 fi
805
806 ### End of automated tests.
807 ### Now run sysdeps configure fragments.
808
809 # sysdeps configure fragments may set these with files to be linked below.
810 libc_link_dests=
811 libc_link_sources=
812
813 # Iterate over all the sysdep directories we will use, running their
814 # configure fragments, and looking for a uname implementation.
815 uname=
816 for dir in $sysnames; do
817   case $dir in
818     /*) dest=$dir ;;
819     *)  dest=$srcdir/$dir ;;
820   esac
821   if test -r $dest/configure; then
822     AC_MSG_RESULT(running configure fragment for $dest)
823     . $dest/configure
824   fi
825 [
826   if test -z "$uname"; then
827     if test -r $dest/uname.c ||
828        test -r $dest/uname.S ||
829        { test -r $dest/syscalls.list &&
830          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
831       uname=$dir
832     fi
833   fi
834 ]dnl
835 done
836
837 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
838
839 # If we will use the generic uname implementation, we must figure out what
840 # it will say by examining the system, and write the results in config-name.h.
841 if test "$uname" = "sysdeps/generic"; then
842
843 changequote(,)dnl
844   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
845 changequote([,])dnl
846   if test $uname_sysname != $config_os; then
847     config_release=`echo $config_os | sed s/$uname_sysname//`
848   fi
849 dnl
850 AC_DEFUN(LIBC_KERNEL_ID, [dnl
851     if test -r /vmunix; then
852       kernel_id=`strings /vmunix | grep UNIX`
853     elif test -r /dynix; then
854       kernel_id=`strings /dynix | grep DYNIX`
855     else
856       kernel_id=
857     fi
858 ])dnl
859
860   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
861 AC_REQUIRE([LIBC_KERNEL_ID])dnl
862 changequote(,)dnl
863   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
864 changequote([,])dnl
865   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
866          != x$config_release; then
867     # The configuration release is a substring of the kernel release.
868     libc_cv_uname_release=$kernel_release
869   elif test x$config_release != x; then
870     libc_cv_uname_release=$config_release
871   elif test x$kernel_release != x; then
872     libc_cv_uname_release=$kernel_release
873   else
874     libc_cv_uname_release=unknown
875   fi])
876   uname_release="$libc_cv_uname_release"
877
878   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
879 AC_REQUIRE([LIBC_KERNEL_ID])dnl
880 changequote(,)dnl
881   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
882 changequote([,])dnl
883   if test -n "$kernel_version"; then
884     libc_cv_uname_version="$kernel_version"
885   else
886     libc_cv_uname_version=unknown
887   fi])
888   uname_version="$libc_cv_uname_version"
889
890 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
891   config_uname=config-name.h:config-name.in
892 else
893   # For non-generic uname, we don't need to create config-name.h at all.
894   config_uname=
895 fi
896
897 AC_MSG_CHECKING(stdio selection)
898 AC_SUBST(stdio)
899 case $stdio in
900 libio) AC_DEFINE(USE_IN_LIBIO) ;;
901 default) stdio=stdio ;;
902 esac
903 AC_MSG_RESULT($stdio)
904
905 AC_MSG_CHECKING(ldap selection)
906 AC_SUBST(LDAP)
907 case $add_ons in
908 *ldap*)
909    ldap=yes
910    LDAP=ldap ;;
911 *) ldap=no
912    LDAP= ;;
913 esac
914 AC_MSG_RESULT($ldap)
915
916 AC_SUBST(libc_cv_slibdir)
917 AC_SUBST(libc_cv_sysconfdir)
918 AC_SUBST(libc_cv_rootsbindir)
919
920 AC_SUBST(has_ldconfig)
921
922 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
923 if test $gnu_ld = yes; then
924   AC_DEFINE(HAVE_GNU_LD)
925 fi
926 if test $gnu_as = yes; then
927   AC_DEFINE(HAVE_GNU_AS)
928 fi
929 if test $elf = yes; then
930   AC_DEFINE(HAVE_ELF)
931 fi
932
933 AC_SUBST(static)
934 AC_SUBST(shared)
935 if test $shared = default; then
936   if test $gnu_ld = yes; then
937     shared=$elf
938   else
939     # For now we do not assume shared libs are available.  In future more
940     # tests might become available.
941     shared=no
942   fi
943 fi
944 AC_SUBST(profile)
945 AC_SUBST(omitfp)
946 AC_SUBST(bounded)
947 AC_SUBST(static_nss)
948 AC_SUBST(nopic_initfini)
949
950 AC_SUBST(DEFINES)
951
952 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
953   config_makefile=
954 else
955   config_makefile=Makefile
956 fi
957
958 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
959 AC_SUBST(VERSION)
960
961 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
962           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])