(_hurd_sig_post): __sig_post renamed to __msg_sig_post.
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$Id$])
3 AC_PREREQ(2.1)dnl               dnl Minimum Autoconf version required.
4 AC_INIT(features.h)
5
6 # This will get text that should go into config.make.
7 config_vars=
8
9 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
10 AC_ARG_WITH(gmp, dnl
11   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
12             [dnl
13 case "$with_gmp" in
14 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
15 ''|no) ;;
16 *) config_vars="$config_vars
17 gmp-srcdir = $withval" ;;
18 esac
19 ])
20
21 AC_ARG_WITH(gnu-binutils, dnl
22   --with-gnu-binutils     if using GNU binutils (as and ld),
23             gnu_binutils=yes, gnu_binutils=no)
24 AC_ARG_WITH(gnu-ld, dnl
25   --with-gnu-ld           if using GNU ld (in the binutils package),
26             gnu_ld=yes, gnu_ld=no)
27 AC_ARG_WITH(gnu-as, dnl
28   --with-gnu-as           if using GNU as (in the binutils package),
29             gnu_as=yes, gnu_as=no)
30 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
31
32 AC_CANONICAL_HOST
33 # We keep the original values in `$config_*' and never modify them, so we
34 # can write them unchanged into config.make.  Everything else uses
35 # $machine, $vendor, and $os, and changes them whenever convenient.
36 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
37
38 sysdep_dir=$srcdir/sysdeps
39 AC_MSG_CHECKING(sysdep dirs)
40 AC_CACHE_VAL(libc_cv_sysdirs, [dnl
41 machine=$config_machine
42 vendor=$config_vendor
43 os=$config_os
44
45 dnl We need to use [ and ] for other purposes for a while now.
46 changequote(,)dnl
47 # Expand the configuration machine name into a subdirectory by architecture
48 # type and particular chip.
49 case "$machine" in
50 i[345]86)
51   machine=i386/$machine ;;
52 sparc[6789])
53   machine=sparc/$machine ;;
54 m68k)
55   machine=m68k/m68020 ;;
56 m680?0)
57   machine=m68k/$machine ;;
58 m88k)
59   machine=m88k/m88100 ;;
60 m88???)
61   machine=m88k/$machine ;;
62 mips64*)
63   machine=mips/mips64/$machine ;;
64 mips*)
65   machine=mips/$machine ;;
66 esac
67
68 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
69 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
70
71 case "$os" in
72 gnu*)
73   base_os=mach/hurd ;;
74 netbsd* | 386bsd*)
75   base_os=unix/bsd/bsd4.4 ;;
76 osf1* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
77   base_os=unix/bsd ;;
78 linux* | sysv* | isc* | esix* | sco* | minix* | irix4*)
79   base_os=unix/sysv ;;
80 solaris[2-9]*)
81   base_os=unix/sysv/sysv4 ;;
82 none)
83   base_os=standalone ;;
84 *)
85   base_os='' ;;
86 esac
87
88 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
89 tail=$os
90 ostry=$os
91 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
92   ostry="$ostry /$o"
93   tail=$o
94 done  
95 o=`echo $tail | sed 's/[0-9]*$//'`
96 if test $o != $tail; then
97   ostry="$ostry /$o"
98 fi
99
100 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
101 base=
102 tail=$base_os
103 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
104   set $b
105   base="$base /$1"
106   tail="$2"
107 done
108
109 # For sparc/sparc9, try sparc/sparc9 and then sparc.
110 mach=
111 tail=$machine
112 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
113   set $m
114   mach="$mach /$1"
115   tail="$2"
116 done
117
118 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
119 changequote([,])dnl
120
121 # Find what sysdep directories exist.
122 sysnames=
123 for b in $base ''; do
124   for m0 in $mach ''; do
125     for v in /$vendor ''; do
126       for o in /$ostry ''; do
127         for m in $mach ''; do
128           try="$m0$b$v$o$m"
129           if test -d $sysdep_dir$try; then
130             sysnames="$sysnames $try"
131             { test -n "$o" || test -n "$b"; } && os_used=t
132             { test -n "$m" || test -n "$m0"; } && machine_used=t
133           fi
134         done
135       done
136     done
137   done
138 done
139
140 if test -z "$os_used" && test "$os" != none; then
141   AC_MSG_ERROR(Operating system $os is not supported.)
142 fi
143 if test -z "$machine_used" && test "$machine" != none; then
144   AC_MSG_ERROR(The $machine is not supported.)
145 fi
146
147 # We have now validated the configuration.
148
149 # Remove the leading slashes.
150 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
151
152 # Prepend the machine's FPU directory unless --without-fp.
153 if test "$with_fp" = no; then
154   fpu_dirs=
155   for m in $mach; do
156     if test -d $sysdep_dir$m/fpu; then
157       fpu_dirs="$fpu_dirs $m/fpu"
158     fi
159   done
160   sysnames="`echo $fpu_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
161 fi
162
163 # Expand the list of system names into a full list of directories
164 # from each element's parent name and Implies file (if present).
165 set $sysnames
166 while test $# -gt 0; do
167   name=$1
168   shift
169
170   if test -f $sysdep_dir/$name/Implies; then
171     # Collect more names from the `Implies' file (removing comments).
172     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
173     for x in $implied; do
174       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
175     done
176   else
177     implied=
178   fi
179
180   # Add NAME to the list of names.
181   names="$names $name"
182
183   # Find the parent of NAME, using the empty string if it has none.
184 changequote(,)dnl
185   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
186 changequote([,])dnl
187
188   # Add the names implied by NAME, and NAME's parent (if it has one), to
189   # the list of names to be processed (the argument list).  We prepend the
190   # implied names to the list and append the parent.  We want implied
191   # directories to come before further directories inferred from the
192   # configuration components; this ensures that for sysv4, unix/common
193   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
194   # after sysv4).
195   sysnames="`echo $implied $* $parent`"
196   test -n "$sysnames" && set $sysnames
197 done
198
199 # Add the default directories.
200 names="$names generic stub"
201
202 # Now uniquize the list.
203 seen=
204 sysnames=
205 for name in $names; do
206   if echo "$seen" | fgrep -x $name >/dev/null; then
207     # Already in the list.
208     true;
209   else
210     # A new one.
211     if test -z "$seen"; then
212       seen="$name" sysnames="$name"
213     else
214       seen="$seen
215 $name"
216       sysnames="$sysnames $name"
217     fi
218   fi
219 done
220 libc_cv_sysdirs="$sysnames"])
221 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
222 AC_MSG_RESULT(${sysnames})
223
224 case "$host_os" in
225 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
226   gnu_ld=yes gnu_as=yes
227 esac
228
229 AC_PROG_INSTALL
230 if test "$INSTALL" = "${srcdir}/install-sh"; then
231   # The makefiles need to use a different form to find it in $srcdir.
232   INSTALL='$(..)./install-sh'
233 fi
234
235 AC_PROG_CC
236 AC_PROG_CPP
237 AC_CHECK_PROG(AR, ar, ar, ar)
238 AC_PROG_RANLIB
239
240 AC_MSG_CHECKING(signed size_t type)
241 AC_CACHE_VAL(libc_cv_signed_size_t, [dnl
242 echo '#include <stddef.h>
243 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
244 if eval "$ac_cpp conftest.c 2>/dev/null" \
245 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
246   libc_cv_signed_size_t=no
247 else
248   libc_cv_signed_size_t=yes
249 fi
250 rm -f conftest*])
251 AC_MSG_RESULT($libc_cv_signed_size_t)
252 if test $libc_cv_signed_size_t = yes; then
253   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
254   cat >> confdefs.h <<\EOF
255 #undef __SIZE_TYPE__
256 #define __SIZE_TYPE__ unsigned
257 EOF
258 fi
259
260 AC_MSG_CHECKING(libc-friendly stddef.h)
261 AC_CACHE_VAL(libc_cv_friendly_stddef, [dnl
262 AC_TRY_COMPILE(dnl
263 [#define __need_size_t
264 #define __need_wchar_t
265 #include <stddef.h>
266 #define __need_NULL
267 #include <stddef.h>], [size_t size; wchar_t wchar;
268 #ifdef offsetof
269 #error stddef.h ignored __need_*
270 #endif
271 if (&size == NULL || &wchar == NULL) abort ();],
272                libc_cv_friendly_stddef=yes,
273                libc_cv_friendly_stddef=no)])
274 AC_MSG_RESULT($libc_cv_friendly_stddef)
275 if test $libc_cv_friendly_stddef = yes; then
276   config_vars="$config_vars
277 stddef.h = # The installed <stddef.h> seems to be libc-friendly."
278 fi
279
280 AC_MSG_CHECKING(whether we need to use -P to assemble .S files)
281 AC_CACHE_VAL(libc_cv_need_minus_P, [dnl
282 cat > conftest.S <<EOF
283 #include "confdefs.h"
284 /* Nothing whatsoever.  */
285 EOF
286 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
287   libc_cv_need_minus_P=no
288 else
289   libc_cv_need_minus_P=yes
290 fi
291 rm -f conftest*])
292 AC_MSG_RESULT($libc_cv_need_minus_P)
293 if test $libc_cv_need_minus_P = yes; then
294   config_vars="$config_vars
295 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
296 fi
297
298 # Iterate over all the sysdep directories we will use, running their
299 # configure fragments, and looking for a uname implementation.
300 uname=
301 for dir in $sysnames; do
302   if test -r $sysdep_dir/$dir/configure; then
303     AC_MSG_RESULT(running configure fragment for $dir)
304     . $sysdep_dir/$dir/configure
305   fi
306   if test -z "$uname"; then
307     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
308     && uname=$dir
309   fi
310 done
311
312 # If we will use the generic uname implementation, we must figure out what
313 # it will say by examining the system, and write the results in config-name.h.
314 if test "$uname" = generic; then
315
316 changequote(,)dnl
317   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
318 changequote([,])dnl
319   if test $uname_sysname != $config_os; then
320     config_release=`echo $config_os | sed s/$uname_sysname//`
321   fi
322 dnl
323 AC_DEFUN(LIBC_KERNEL_ID, [dnl
324     if test -r /vmunix; then
325       kernel_id=`strings /vmunix | grep UNIX`
326     elif test -r /dynix; then
327       kernel_id=`strings /dynix | grep DYNIX`
328     else
329       kernel_id=
330     fi
331 ])dnl
332
333   AC_MSG_CHECKING(OS release for uname)
334   AC_CACHE_VAL(libc_cv_uname_release, [dnl
335 AC_REQUIRE([LIBC_KERNEL_ID])dnl
336 changequote(,)dnl
337   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
338 changequote([,])dnl
339   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
340          != x$config_release; then
341     # The configuration release is a substring of the kernel release.
342     libc_cv_uname_release=$kernel_release
343   elif test x$config_release != x; then
344     libc_cv_uname_release=$config_release
345   elif test x$kernel_release != x; then
346     libc_cv_uname_release=$kernel_release
347   else
348     libc_cv_uname_release=unknown
349   fi])
350   AC_MSG_RESULT($libc_cv_uname_release)
351   uname_release="$libc_cv_uname_release"
352
353   AC_MSG_CHECKING(OS version for uname)
354   AC_CACHE_VAL(libc_cv_uname_version, [dnl
355 AC_REQUIRE([LIBC_KERNEL_ID])dnl
356 changequote(,)dnl
357   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
358 changequote([,])dnl
359   if test -n "$kernel_version"; then
360     libc_cv_uname_version="$kernel_version"
361   else
362     libc_cv_uname_version=unknown
363   fi])
364   AC_MSG_RESULT($libc_cv_uname_version)
365   uname_version="$libc_cv_uname_version"
366
367 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
368   config_uname=config-name.h:config-name.in
369 else
370   # For non-generic uname, we don't need to create config-name.h at all.
371   config_uname=
372 fi
373
374 if test $gnu_ld = yes; then
375   AC_DEFINE(HAVE_GNU_LD)
376 fi
377 if test $gnu_as = yes; then
378   AC_DEFINE(HAVE_GNU_AS)
379 fi
380
381 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
382   config_makefile=
383 else
384   config_makefile=Makefile
385 fi
386
387 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
388           [echo '$config_vars' >> config.make])