b0bb90543a7294e8162eec52013f82db1651d1e8
[kopensolaris-gnu/glibc.git] / configure.in
1 Dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45
46 AC_ARG_ENABLE(libio, dnl
47 [  --enable-libio          build in GNU libio instead of GNU stdio],
48               [if test $enableval = yes; then
49                  stdio=libio
50                else
51                  stdio=stdio
52                fi],
53               stdio=default)
54
55 AC_ARG_ENABLE(sanity-checks, dnl
56 [  --disable-sanity-checks really do not use threads (should not be used
57                           except in special situations) [default=yes]],
58               enable_sanity=$enableval, enable_sanity=yes)
59
60 dnl Arguments to enable or disable building the static, shared, profiled,
61 dnl and -fomit-frame-pointer libraries.
62 AC_ARG_ENABLE(static, dnl
63 [  --enable-static         build static library [default=yes]],
64               static=$enableval, static=yes)
65 AC_ARG_ENABLE(shared, dnl
66 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
67               shared=$enableval, shared=default)
68 AC_ARG_ENABLE(profile, dnl
69 [  --enable-profile        build profiled library [default=yes]],
70               profile=$enableval, profile=yes)
71 AC_ARG_ENABLE(omitfp, dnl
72 [  --enable-omitfp         build undebuggable optimized library [default=no]],
73               omitfp=$enableval, omitfp=no)
74 AC_ARG_ENABLE(bounded, dnl
75 [  --enable-bounded        build with runtime bounds checking [default=no]],
76               bounded=$enableval, bounded=no)
77 AC_ARG_ENABLE(versioning, dnl
78 [  --disable-versioning    do not include versioning information in the
79                           library objects [default=yes if supported]],
80              enable_versioning=$enableval, enable_versioning=yes)
81
82 dnl Generic infrastructure for drop-in additions to libc.
83 AC_ARG_ENABLE(add-ons, dnl
84 [  --enable-add-ons=DIR... configure and build named extra directories],
85               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
86               [add_ons=])
87 AC_CONFIG_SUBDIRS($add_ons)
88 add_ons_pfx=
89 if test x"$add_ons" != x; then
90   for f in $add_ons; do
91     add_ons_pfx="$add_ons_pfx $f/"
92   done
93 fi
94
95 dnl On some platforms we cannot use dynamic loading.  We must provide
96 dnl static NSS modules.
97 AC_ARG_ENABLE(static-nss, dnl
98 [  --enable-static-nss     build static NSS modules [default=no]],
99               static_nss=$enableval, static_nss=no)
100 if test x"$static_nss" = xyes; then
101   AC_DEFINE(DO_STATIC_NSS)
102 fi
103
104 AC_CANONICAL_HOST
105
106 # The way shlib-versions is used to generate soversions.mk uses a
107 # fairly simplistic model for name recognition that can't distinguish
108 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
109 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
110 # tell.  This doesn't get used much beyond that, so it's fairly safe.
111 case "$host_os" in
112 linux*)
113   ;;
114 gnu*)
115   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
116   ;;
117 esac
118
119 ###
120 ### I put this here to prevent those annoying emails from people who cannot
121 ### read and try to compile glibc on unsupported platforms.  --drepper
122 ###
123 ### By using the undocumented --enable-hacker-mode option for configure
124 ### one can skip this test to make the configuration not fail for unsupported
125 ### platforms.
126 ###
127 if test -z "$enable_hacker_mode"; then
128   case "$host_os" in
129   linux* | gnu*)
130     ;;
131   *)
132     echo "*** The GNU C library is currently not available for this platform."
133     echo "*** So far nobody cared to port it and if there is no volunteer it"
134     echo "*** might never happen.  So, if you have interest to see glibc on"
135     echo "*** this platform visit"
136     echo "***   http://www.gnu.ai.mit.edu/software/libc/porting.html"
137     echo "*** and join the group of porters"
138     exit 1
139     ;;
140   esac
141 fi
142
143 # We keep the original values in `$config_*' and never modify them, so we
144 # can write them unchanged into config.make.  Everything else uses
145 # $machine, $vendor, and $os, and changes them whenever convenient.
146 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
147
148 # Some configurations imply other options.
149 case "$host_os" in
150 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
151   # These systems always use GNU tools.
152   gnu_ld=yes gnu_as=yes ;;
153 esac
154 case "$host_os" in
155 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
156 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
157   ;;
158 gnu* | linux* | sysv4* | solaris2*)
159   # These systems (almost) always use the ELF format.
160   elf=yes
161   ;;
162 esac
163
164 machine=$config_machine
165 vendor=$config_vendor
166 os=$config_os
167
168 dnl We need to use [ and ] for other purposes for a while now.
169 changequote(,)dnl
170 # Expand the configuration machine name into a subdirectory by architecture
171 # type and particular chip.
172 case "$machine" in
173 a29k | am29000) base_machine=a29k machine=a29k ;;
174 alpha*)         base_machine=alpha machine=alpha/$machine ;;
175 arm*)           base_machine=arm machine=arm/$machine ;;
176 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
177 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
178 hppa*)          base_machine=hppa machine=hppa/$machine ;;
179 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
180 m680?0)         base_machine=m68k machine=m68k/$machine ;;
181 m68k)           base_machine=m68k machine=m68k/m68020 ;;
182 m88???)         base_machine=m88k machine=m88k/$machine ;;
183 m88k)           base_machine=m88k machine=m88k/m88100 ;;
184 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
185 mips*)          base_machine=mips machine=mips/$machine ;;
186 sparc | sparcv[67])
187                 base_machine=sparc machine=sparc/sparc32 ;;
188 sparcv8 | supersparc | hypersparc)
189                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
190 sparc64 | ultrasparc)
191                 base_machine=sparc machine=sparc/sparc64 ;;
192 esac
193 changequote([,])dnl
194 AC_SUBST(base_machine)
195
196 # Compute the list of sysdep directories for this configuration.
197 # This can take a while to compute.
198 sysdep_dir=$srcdir/sysdeps
199 AC_MSG_CHECKING(sysdep dirs)
200 dnl We need to use [ and ] for other purposes for a while now.
201 changequote(,)dnl
202 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
203 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
204
205 case "$os" in
206 gnu*)
207   base_os=mach/hurd ;;
208 netbsd* | 386bsd* | freebsd* | bsdi*)
209   base_os=unix/bsd/bsd4.4 ;;
210 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
211   base_os=unix/bsd ;;
212 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
213   base_os=unix/sysv ;;
214 solaris[2-9]*)
215   base_os=unix/sysv/sysv4 ;;
216 none)
217   base_os=standalone ;;
218 *)
219   base_os='' ;;
220 esac
221
222 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
223 tail=$os
224 ostry=$os
225 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
226   ostry="$ostry /$o"
227   tail=$o
228 done
229 o=`echo $tail | sed 's/[0-9]*$//'`
230 if test $o != $tail; then
231   ostry="$ostry /$o"
232 fi
233 # For linux-gnu, try linux-gnu, then linux.
234 o=`echo $tail | sed 's/-.*$//'`
235 if test $o != $tail; then
236   ostry="$ostry /$o"
237 fi
238
239 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
240 base=
241 tail=$base_os
242 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
243   set $b
244   base="$base /$1"
245   tail="$2"
246 done
247
248 # For sparc/sparc9, try sparc/sparc9 and then sparc.
249 mach=
250 tail=$machine
251 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
252   set $m
253   # Prepend the machine's FPU directory unless --without-fp.
254   if test "$with_fp" = yes; then
255     mach="$mach /$1/fpu"
256   fi
257   mach="$mach /$1"
258   tail="$2"
259 done
260
261 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
262 changequote([,])dnl
263
264 # Find what sysdep directories exist.
265 sysnames=
266 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
267 for d in $add_ons_pfx ''; do
268   for b in $base ''; do
269     for m0 in $mach ''; do
270       for v in /$vendor ''; do
271         for o in /$ostry ''; do
272           for m in $mach ''; do
273             if test "$m0$b$v$o$m"; then
274               try="${d}sysdeps$m0$b$v$o$m"
275               test -n "$enable_debug_configure" &&
276               echo "$0 [DEBUG]: try $try" >&2
277               case $try in
278                 /*) dest=$try ;;
279                 *)  dest=$srcdir/$try ;;
280               esac
281               if test -d $dest; then
282                 sysnames="$sysnames $try"
283                 { test -n "$o" || test -n "$b"; } && os_used=t
284                 { test -n "$m" || test -n "$m0"; } && machine_used=t
285               fi
286             fi
287           done
288         done
289       done
290     done
291   done
292 done
293 IFS="$ac_save_ifs"
294
295 if test -z "$os_used" && test "$os" != none; then
296   AC_MSG_ERROR(Operating system $os is not supported.)
297 fi
298 if test -z "$machine_used" && test "$machine" != none; then
299   AC_MSG_ERROR(The $machine is not supported.)
300 fi
301
302 # We have now validated the configuration.
303
304
305 # If using ELF, look for an `elf' subdirectory of each machine directory.
306 # We prepend these rather than inserting them whereever the machine appears
307 # because things specified by the machine's ELF ABI should override
308 # OS-specific things, and should always be the same for any OS on the
309 # machine (otherwise what's the point of an ABI?).
310 if test "$elf" = yes; then
311   elf_dirs=
312   for d in $add_ons_pfx ''; do
313     case $d in
314       /*) xsrcdir= ;;
315       *)  xsrcdir=$srcdir/ ;;
316     esac
317     for m in $mach; do
318       if test -d $xsrcdir${d}sysdeps$m/elf; then
319         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
320       fi
321     done
322   done
323   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
324 fi
325
326
327 # Expand the list of system names into a full list of directories
328 # from each element's parent name and Implies file (if present).
329 set $sysnames
330 names=
331 while test $# -gt 0; do
332   name=$1
333   shift
334
335   case " $names " in *" $name "*)
336     # Already in the list.
337     continue
338   esac
339
340   # Report each name as we discover it, so there is no long pause in output.
341   echo $ac_n "$name $ac_c" >&AC_FD_MSG
342
343   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
344
345   case $name in
346     /*) xsrcdir= ;;
347     *)  xsrcdir=$srcdir/ ;;
348   esac
349   test -n "$enable_debug_configure" &&
350   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
351
352   if test -f $xsrcdir$name/Implies; then
353     # Collect more names from the `Implies' file (removing comments).
354     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
355     implied=
356     for x in $implied_candidate; do
357       if test -d $xsrcdir$name_base/$x; then
358         implied="$implied $name_base/$x";
359       else
360         AC_MSG_WARN($name/Implies specifies nonexistent $x)
361       fi
362     done
363   else
364     implied=
365   fi
366
367   # Add NAME to the list of names.
368   names="$names $name"
369
370   # Find the parent of NAME, using the empty string if it has none.
371 changequote(,)dnl
372   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
373 changequote([,])dnl
374
375   # Add the names implied by NAME, and NAME's parent (if it has one), to
376   # the list of names to be processed (the argument list).  We prepend the
377   # implied names to the list and append the parent.  We want implied
378   # directories to come before further directories inferred from the
379   # configuration components; this ensures that for sysv4, unix/common
380   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
381   # after sysv4).
382   sysnames="`echo $implied $* $parent`"
383   test -n "$sysnames" && set $sysnames
384 done
385
386 # Add the default directories.
387 sysnames="$names sysdeps/generic sysdeps/stub"
388 AC_SUBST(sysnames)
389 # The other names were emitted during the scan.
390 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
391
392
393 ### Locate tools.
394
395 AC_PROG_INSTALL
396 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
397   # The makefiles need to use a different form to find it in $srcdir.
398   INSTALL='\$(..)./install-sh -c'
399 fi
400 AC_PROG_LN_S
401 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
402
403 AC_PROG_CC_LOCAL
404 AC_CANONICAL_BUILD
405 if test $host != $build; then
406   AC_CHECK_PROGS(BUILD_CC, gcc cc)
407 fi
408 AC_SUBST(cross_compiling)
409 AC_PROG_CPP
410 LIBC_PROG_BINUTILS
411 AC_CHECK_TOOL(AR, ar)
412 AC_CHECK_TOOL(RANLIB, ranlib, :)
413
414 AC_PATH_PROG(BASH, bash, no)
415 if test "$BASH" != no &&
416    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
417   libc_cv_have_bash2=yes
418 else
419   libc_cv_have_bash2=no
420 fi
421 AC_SUBST(libc_cv_have_bash2)
422
423 dnl We need a ksh compatible shell for tzselect.
424 if test "$BASH" = no; then
425   AC_PATH_PROG(KSH, ksh, no)
426   if test "$KSH" = no; then
427     libc_cv_have_ksh=no
428   else
429     libc_cv_have_ksh=yes
430   fi
431 else
432   KSH="$BASH"
433   AC_SUBST(KSH)
434   libc_cv_have_ksh=yes
435 fi
436 AC_SUBST(libc_cv_have_ksh)
437
438 AC_PATH_PROGS(PERL, perl, no)
439 AC_SUBST(PERL)
440
441 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
442 echo '#include <stddef.h>
443 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
444 if eval "$ac_cpp conftest.c 2>/dev/null" \
445 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
446   libc_cv_signed_size_t=no
447 else
448   libc_cv_signed_size_t=yes
449 fi
450 rm -f conftest*])
451 if test $libc_cv_signed_size_t = yes; then
452   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
453   cat >> confdefs.h <<\EOF
454 #undef __SIZE_TYPE__
455 #define __SIZE_TYPE__ unsigned
456 EOF
457 fi
458
459 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
460 AC_TRY_COMPILE(dnl
461 [#define __need_size_t
462 #define __need_wchar_t
463 #include <stddef.h>
464 #define __need_NULL
465 #include <stddef.h>], [size_t size; wchar_t wchar;
466 #ifdef offsetof
467 #error stddef.h ignored __need_*
468 #endif
469 if (&size == NULL || &wchar == NULL) abort ();],
470                libc_cv_friendly_stddef=yes,
471                libc_cv_friendly_stddef=no)])
472 if test $libc_cv_friendly_stddef = yes; then
473   config_vars="$config_vars
474 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
475 fi
476
477 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
478                libc_cv_need_minus_P, [dnl
479 cat > conftest.S <<EOF
480 #include "confdefs.h"
481 /* Nothing whatsoever.  */
482 EOF
483 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
484   libc_cv_need_minus_P=no
485 else
486   libc_cv_need_minus_P=yes
487 fi
488 rm -f conftest*])
489 if test $libc_cv_need_minus_P = yes; then
490   config_vars="$config_vars
491 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
492 fi
493
494 AC_CACHE_CHECK(for assembler global-symbol directive,
495                libc_cv_asm_global_directive, [dnl
496 libc_cv_asm_global_directive=UNKNOWN
497 for ac_globl in .globl .global; do
498   cat > conftest.s <<EOF
499 .text
500 ${ac_globl} foo
501 foo:
502 EOF
503   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
504     libc_cv_asm_global_directive=${ac_globl}
505   fi
506   rm -f conftest*
507   test $libc_cv_asm_global_directive != UNKNOWN && break
508 done])
509 if test $libc_cv_asm_global_directive = UNKNOWN; then
510   AC_MSG_ERROR(cannot determine asm global directive)
511 else
512   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
513 fi
514
515 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
516 cat > conftest.s <<EOF
517 .text
518 foo:
519 .set glibc_conftest_frobozz,foo
520 $libc_cv_asm_global_directive glibc_conftest_frobozz
521 EOF
522 # The alpha-dec-osf1 assembler gives only a warning for `.set'
523 # (but it doesn't work), so we must do a linking check to be sure.
524 cat > conftest1.c <<\EOF
525 extern int glibc_conftest_frobozz;
526 main () { printf ("%d\n", glibc_conftest_frobozz); }
527 EOF
528 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
529             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
530   libc_cv_asm_set_directive=yes
531 else
532   libc_cv_asm_set_directive=no
533 fi
534 rm -f conftest*])
535 if test $libc_cv_asm_set_directive = yes; then
536   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
537 fi
538
539 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
540 [cat > conftest.s <<EOF
541 .text
542 _sym:
543 .symver _sym,sym@VERS
544 EOF
545 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
546   libc_cv_asm_symver_directive=yes
547 else
548   libc_cv_asm_symver_directive=no
549 fi
550 rm -f conftest*])
551 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
552 if test $libc_cv_asm_symver_directive = yes; then
553   cat > conftest.s <<EOF
554 .text
555 _sym:
556 .symver _sym,sym@VERS
557 EOF
558   cat > conftest.map <<EOF
559 VERS {
560         global: sym;
561 };
562 EOF
563   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
564     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
565                                         -nostartfiles -nostdlib
566                                         -Wl,--version-script,conftest.map
567                        1>&AC_FD_CC]);
568     then
569       libc_cv_ld_version_script_option=yes
570     else
571       libc_cv_ld_version_script_option=no
572     fi
573   else
574     libc_cv_ld_version_script_option=no
575   fi
576 else
577   libc_cv_ld_version_script_option=no
578 fi
579 rm -f conftest*])
580 if test $libc_cv_asm_symver_directive = yes &&
581    test $libc_cv_ld_version_script_option = yes &&
582    test $enable_versioning = yes; then
583   VERSIONING=yes
584   AC_DEFINE(DO_VERSIONING)
585 else
586   VERSIONING=no
587 fi
588 AC_SUBST(VERSIONING)
589
590 if test $elf = yes; then
591   AC_CACHE_CHECK(for .previous assembler directive,
592                  libc_cv_asm_previous_directive, [dnl
593   cat > conftest.s <<EOF
594 .section foo_section
595 .previous
596 EOF
597   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
598     libc_cv_asm_previous_directive=yes
599   else
600     libc_cv_asm_previous_directive=no
601   fi
602   rm -f conftest*])
603   if test $libc_cv_asm_previous_directive = yes; then
604     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
605   else
606     AC_CACHE_CHECK(for .popsection assembler directive,
607                    libc_cv_asm_popsection_directive, [dnl
608     cat > conftest.s <<EOF
609 .pushsection foo_section
610 .popsection
611 EOF
612     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
613       libc_cv_asm_popsection_directive=yes
614     else
615       libc_cv_asm_popsection_directive=no
616     fi
617     rm -f conftest*])
618     if test $libc_cv_asm_popsection_directive = yes; then
619       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
620     fi
621   fi
622 fi
623
624 if test $elf != yes; then
625   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
626                  [AC_TRY_COMPILE(, [asm (".section .init");
627                                     asm (".section .fini");
628                                     asm (".text");],
629                                  libc_cv_have_initfini=yes,
630                                  libc_cv_have_initfini=no)])
631   AC_SUBST(libc_cv_have_initfini)dnl
632   if test $libc_cv_have_initfini = yes; then
633     AC_DEFINE(HAVE_INITFINI)
634   fi
635 fi
636
637 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
638 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
639 [cat > conftest.$ac_ext <<EOF
640 dnl This sometimes fails to find confdefs.h, for some reason.
641 dnl [#]line __oline__ "[$]0"
642 [#]line __oline__ "configure"
643 #include "confdefs.h"
644 void underscore_test(void) {
645 return; }
646 EOF
647 if AC_TRY_EVAL(ac_compile); then
648   if grep _underscore_test conftest* >/dev/null; then
649     ifelse([$1], , :, [rm -f conftest*
650     $1])
651   else
652     ifelse([$2], , , [rm -f conftest*
653     $2])
654   fi
655 else
656   echo "configure: failed program was:" >&AC_FD_CC
657   cat conftest.$ac_ext >&AC_FD_CC
658   ifelse([$2], , , [rm -f conftest*
659   $2])
660 fi
661 rm -f conftest*])
662
663 if test $elf = yes; then
664   libc_cv_asm_underscores=no
665 else
666   if test $ac_cv_prog_cc_works = yes; then
667     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
668                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
669                                 libc_cv_asm_underscores=yes,
670                                 libc_cv_asm_underscores=no)])
671   else
672     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
673                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
674                                             libc_cv_asm_underscores=no)])
675   fi
676 fi
677 if test $libc_cv_asm_underscores = no; then
678   AC_DEFINE(NO_UNDERSCORES)
679 fi
680
681 if test $elf = yes; then
682   libc_cv_weak_symbols=yes
683   libc_cv_asm_weak_directive=yes
684   libc_cv_asm_weakext_directive=no
685 else
686   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
687                  [dnl
688 cat > conftest.s <<EOF
689 .text
690 ${libc_cv_asm_global_directive} foo
691 foo:
692 .weak foo
693 .weak bar; bar = foo
694 EOF
695   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
696     libc_cv_asm_weak_directive=yes
697   else
698     libc_cv_asm_weak_directive=no
699   fi
700   rm -f conftest*])
701
702 if test $libc_cv_asm_weak_directive = no; then
703   AC_CACHE_CHECK(for assembler .weakext directive,
704                  libc_cv_asm_weakext_directive,
705                  [dnl
706 cat > conftest.s <<EOF
707 .text
708 ${libc_cv_asm_global_directive} foo
709 foo:
710 .weakext foo
711 .weakext foo, bar
712 EOF
713   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
714     libc_cv_asm_weakext_directive=yes
715   else
716     libc_cv_asm_weakext_directive=no
717   fi
718   rm -f conftest*])
719
720   fi # no .weak
721 fi # not ELF
722
723 if test $libc_cv_asm_weak_directive = yes; then
724   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
725 elif test $libc_cv_asm_weakext_directive = yes; then
726   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
727 fi
728
729 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
730 cat > conftest.c <<\EOF
731 _start () {}
732 int __eh_pc;
733 __throw () {}
734 EOF
735 dnl No \ in command here because it ends up inside ''.
736 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
737                             -nostdlib -nostartfiles -Wl,--no-whole-archive
738                             -o conftest conftest.c 1>&AC_FD_CC]); then
739   libc_cv_ld_no_whole_archive=yes
740 else
741   libc_cv_ld_no_whole_archive=no
742 fi
743 rm -f conftest*])
744 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
745
746 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
747 cat > conftest.c <<\EOF
748 _start () {}
749 int __eh_pc;
750 __throw () {}
751 EOF
752 dnl No \ in command here because it ends up inside ''.
753 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
754                             -nostdlib -nostartfiles -fno-exceptions
755                             -o conftest conftest.c 1>&AC_FD_CC]); then
756   libc_cv_gcc_no_exceptions=yes
757 else
758   libc_cv_gcc_no_exceptions=no
759 fi
760 rm -f conftest*])
761 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
762
763 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
764 [cat > conftest.c <<EOF
765 #line __oline__ "configure"
766 static char __EH_FRAME_BEGIN__[];
767 _start ()
768 {
769   __register_frame (__EH_FRAME_BEGIN__);
770   __deregister_frame (__EH_FRAME_BEGIN__);
771 }
772 int __eh_pc;
773 __throw () {}
774 /* FIXME: this is fragile.  */
775 malloc () {}
776 strcmp () {}
777 strlen () {}
778 memcpy () {}
779 memset () {}
780 free () {}
781 abort () {}
782 EOF
783 dnl No \ in command here because it ends up inside ''.
784 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
785                             -nostdlib -nostartfiles
786                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
787   libc_cv_gcc_dwarf2_unwind_info=yes
788 else
789   libc_cv_gcc_dwarf2_unwind_info=no
790 fi
791 rm -f conftest*])
792 if test $libc_cv_gcc_dwarf2_unwind_info = yes; then
793   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
794 fi
795
796 ### End of automated tests.
797 ### Now run sysdeps configure fragments.
798
799 # sysdeps configure fragments may set these with files to be linked below.
800 libc_link_dests=
801 libc_link_sources=
802
803 # Iterate over all the sysdep directories we will use, running their
804 # configure fragments, and looking for a uname implementation.
805 uname=
806 for dir in $sysnames; do
807   case $dir in
808     /*) dest=$dir ;;
809     *)  dest=$srcdir/$dir ;;
810   esac
811   if test -r $dest/configure; then
812     AC_MSG_RESULT(running configure fragment for $dest)
813     . $dest/configure
814   fi
815 [
816   if test -z "$uname"; then
817     if test -r $dest/uname.c ||
818        test -r $dest/uname.S ||
819        { test -r $dest/syscalls.list &&
820          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
821       uname=$dir
822     fi
823   fi
824 ]dnl
825 done
826
827 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
828
829 # If we will use the generic uname implementation, we must figure out what
830 # it will say by examining the system, and write the results in config-name.h.
831 if test "$uname" = "sysdeps/generic"; then
832
833 changequote(,)dnl
834   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
835 changequote([,])dnl
836   if test $uname_sysname != $config_os; then
837     config_release=`echo $config_os | sed s/$uname_sysname//`
838   fi
839 dnl
840 AC_DEFUN(LIBC_KERNEL_ID, [dnl
841     if test -r /vmunix; then
842       kernel_id=`strings /vmunix | grep UNIX`
843     elif test -r /dynix; then
844       kernel_id=`strings /dynix | grep DYNIX`
845     else
846       kernel_id=
847     fi
848 ])dnl
849
850   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
851 AC_REQUIRE([LIBC_KERNEL_ID])dnl
852 changequote(,)dnl
853   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
854 changequote([,])dnl
855   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
856          != x$config_release; then
857     # The configuration release is a substring of the kernel release.
858     libc_cv_uname_release=$kernel_release
859   elif test x$config_release != x; then
860     libc_cv_uname_release=$config_release
861   elif test x$kernel_release != x; then
862     libc_cv_uname_release=$kernel_release
863   else
864     libc_cv_uname_release=unknown
865   fi])
866   uname_release="$libc_cv_uname_release"
867
868   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
869 AC_REQUIRE([LIBC_KERNEL_ID])dnl
870 changequote(,)dnl
871   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
872 changequote([,])dnl
873   if test -n "$kernel_version"; then
874     libc_cv_uname_version="$kernel_version"
875   else
876     libc_cv_uname_version=unknown
877   fi])
878   uname_version="$libc_cv_uname_version"
879
880 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
881   config_uname=config-name.h:config-name.in
882 else
883   # For non-generic uname, we don't need to create config-name.h at all.
884   config_uname=
885 fi
886
887 AC_MSG_CHECKING(stdio selection)
888 AC_SUBST(stdio)
889 case $stdio in
890 libio) AC_DEFINE(USE_IN_LIBIO) ;;
891 default) stdio=stdio ;;
892 esac
893 AC_MSG_RESULT($stdio)
894
895 AC_MSG_CHECKING(ldap selection)
896 AC_SUBST(LDAP)
897 case $add_ons in
898 *ldap*)
899    ldap=yes
900    LDAP=ldap ;;
901 *) ldap=no
902    LDAP= ;;
903 esac
904 AC_MSG_RESULT($ldap)
905
906 AC_SUBST(libc_cv_slibdir)
907 AC_SUBST(libc_cv_sysconfdir)
908 AC_SUBST(libc_cv_rootsbindir)
909
910 AC_SUBST(has_ldconfig)
911
912 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
913 if test $gnu_ld = yes; then
914   AC_DEFINE(HAVE_GNU_LD)
915 fi
916 if test $gnu_as = yes; then
917   AC_DEFINE(HAVE_GNU_AS)
918 fi
919 if test $elf = yes; then
920   AC_DEFINE(HAVE_ELF)
921 fi
922
923 AC_SUBST(static)
924 AC_SUBST(shared)
925 if test $shared = default; then
926   if test $gnu_ld = yes; then
927     shared=$elf
928   else
929     # For now we do not assume shared libs are available.  In future more
930     # tests might become available.
931     shared=no
932   fi
933 fi
934 AC_SUBST(profile)
935 AC_SUBST(omitfp)
936 AC_SUBST(bounded)
937 AC_SUBST(static_nss)
938 AC_SUBST(nopic_initfini)
939
940 AC_SUBST(DEFINES)
941
942 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
943   config_makefile=
944 else
945   config_makefile=Makefile
946 fi
947
948 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
949 AC_SUBST(VERSION)
950
951 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
952           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])