ce626ca35261038616fb71f2cafbf0149605bfdc
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45 AC_ARG_WITH(cvs, dnl
46 [  --without-cvs          if CVS should not be used],
47             with_cvs=$withval, with_cvs=yes)
48 AC_SUBST(with_cvs)
49
50 AC_ARG_ENABLE(libio, dnl
51 [  --enable-libio          build in GNU libio instead of GNU stdio],
52               [if test $enableval = yes; then
53                  stdio=libio
54                else
55                  stdio=stdio
56                fi],
57               stdio=default)
58
59 AC_ARG_ENABLE(sanity-checks, dnl
60 [  --disable-sanity-checks really do not use threads (should not be used
61                           except in special situations) [default=yes]],
62               enable_sanity=$enableval, enable_sanity=yes)
63
64 dnl Arguments to enable or disable building the static, shared, profiled,
65 dnl and -fomit-frame-pointer libraries.
66 AC_ARG_ENABLE(static, dnl
67 [  --enable-static         build static library [default=yes]],
68               static=$enableval, static=yes)
69 AC_ARG_ENABLE(shared, dnl
70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
71               shared=$enableval, shared=default)
72 AC_ARG_ENABLE(profile, dnl
73 [  --enable-profile        build profiled library [default=yes]],
74               profile=$enableval, profile=yes)
75 AC_ARG_ENABLE(omitfp, dnl
76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
77               omitfp=$enableval, omitfp=no)
78 AC_ARG_ENABLE(bounded, dnl
79 [  --enable-bounded        build with runtime bounds checking [default=no]],
80               bounded=$enableval, bounded=no)
81 AC_ARG_ENABLE(versioning, dnl
82 [  --disable-versioning    do not include versioning information in the
83                           library objects [default=yes if supported]],
84              enable_versioning=$enableval, enable_versioning=yes)
85
86 dnl Generic infrastructure for drop-in additions to libc.
87 AC_ARG_ENABLE(add-ons, dnl
88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
89                                   search for add-ons if no parameter given],
90   [case "$enableval" in
91     yes) if test "$srcdir" = "."; then
92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
93          else
94            add_ons=`echo $srcdir/*/configure | \
95                     sed -e "s!$srcdir/!!g" -e 's!/configure!!g'`
96          fi;;
97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
98    esac],
99   [add_ons=])
100
101 AC_CONFIG_SUBDIRS($add_ons)
102 add_ons_pfx=
103 if test x"$add_ons" != x; then
104   for f in $add_ons; do
105     # Test whether such a subdir really exists.
106     if test -d $srcdir/$f; then
107       add_ons_pfx="$add_ons_pfx $f/"
108     else
109       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
110     fi
111   done
112 fi
113
114 dnl On some platforms we cannot use dynamic loading.  We must provide
115 dnl static NSS modules.
116 AC_ARG_ENABLE(static-nss, dnl
117 [  --enable-static-nss     build static NSS modules [default=no]],
118               static_nss=$enableval, static_nss=no)
119 if test x"$static_nss" = xyes; then
120   AC_DEFINE(DO_STATIC_NSS)
121 fi
122
123 AC_CANONICAL_HOST
124
125 # The way shlib-versions is used to generate soversions.mk uses a
126 # fairly simplistic model for name recognition that can't distinguish
127 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
128 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
129 # tell.  This doesn't get used much beyond that, so it's fairly safe.
130 case "$host_os" in
131 linux*)
132   ;;
133 gnu*)
134   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
135   ;;
136 esac
137
138 ###
139 ### I put this here to prevent those annoying emails from people who cannot
140 ### read and try to compile glibc on unsupported platforms.  --drepper
141 ###
142 ### By using the undocumented --enable-hacker-mode option for configure
143 ### one can skip this test to make the configuration not fail for unsupported
144 ### platforms.
145 ###
146 if test -z "$enable_hacker_mode"; then
147   case "$machine-$host_os" in
148   *-linux* | *-gnu* | arm*-none*)
149     ;;
150   *)
151     echo "*** The GNU C library is currently not available for this platform."
152     echo "*** So far nobody cared to port it and if there is no volunteer it"
153     echo "*** might never happen.  So, if you have interest to see glibc on"
154     echo "*** this platform visit"
155     echo "***   http://www.gnu.org/software/libc/porting.html"
156     echo "*** and join the group of porters"
157     exit 1
158     ;;
159   esac
160 fi
161
162 # We keep the original values in `$config_*' and never modify them, so we
163 # can write them unchanged into config.make.  Everything else uses
164 # $machine, $vendor, and $os, and changes them whenever convenient.
165 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
166
167 # Some configurations imply other options.
168 case "$host_os" in
169 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
170   # These systems always use GNU tools.
171   gnu_ld=yes gnu_as=yes ;;
172 esac
173 case "$host_os" in
174 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
175 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
176   ;;
177 gnu* | linux* | sysv4* | solaris2*)
178   # These systems (almost) always use the ELF format.
179   elf=yes
180   ;;
181 esac
182
183 machine=$config_machine
184 vendor=$config_vendor
185 os=$config_os
186
187 dnl We need to use [ and ] for other purposes for a while now.
188 changequote(,)dnl
189 # Expand the configuration machine name into a subdirectory by architecture
190 # type and particular chip.
191 case "$machine" in
192 a29k | am29000) base_machine=a29k machine=a29k ;;
193 alpha*)         base_machine=alpha machine=alpha/$machine ;;
194 arm*)           base_machine=arm machine=arm/$machine ;;
195 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
196 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
197 hppa*)          base_machine=hppa machine=hppa/$machine ;;
198 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
199 m680?0)         base_machine=m68k machine=m68k/$machine ;;
200 m68k)           base_machine=m68k machine=m68k/m68020 ;;
201 m88???)         base_machine=m88k machine=m88k/$machine ;;
202 m88k)           base_machine=m88k machine=m88k/m88100 ;;
203 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
204 mips*)          base_machine=mips machine=mips/$machine ;;
205 sparc | sparcv[67])
206                 base_machine=sparc machine=sparc/sparc32 ;;
207 sparcv8 | supersparc | hypersparc)
208                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
209 sparc64 | ultrasparc)
210                 base_machine=sparc machine=sparc/sparc64 ;;
211 esac
212 changequote([,])dnl
213 AC_SUBST(base_machine)
214
215 if test "$base_machine" = "i386"; then
216   AC_DEFINE(USE_REGPARMS)
217 fi
218
219 # Compute the list of sysdep directories for this configuration.
220 # This can take a while to compute.
221 sysdep_dir=$srcdir/sysdeps
222 AC_MSG_CHECKING(sysdep dirs)
223 dnl We need to use [ and ] for other purposes for a while now.
224 changequote(,)dnl
225 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
226 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
227
228 case "$os" in
229 gnu*)
230   base_os=mach/hurd ;;
231 netbsd* | 386bsd* | freebsd* | bsdi*)
232   base_os=unix/bsd/bsd4.4 ;;
233 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
234   base_os=unix/bsd ;;
235 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
236   base_os=unix/sysv ;;
237 solaris[2-9]*)
238   base_os=unix/sysv/sysv4 ;;
239 none)
240   base_os=standalone ;;
241 *)
242   base_os='' ;;
243 esac
244
245 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
246 tail=$os
247 ostry=$os
248 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
249   ostry="$ostry /$o"
250   tail=$o
251 done
252 o=`echo $tail | sed 's/[0-9]*$//'`
253 if test $o != $tail; then
254   ostry="$ostry /$o"
255 fi
256 # For linux-gnu, try linux-gnu, then linux.
257 o=`echo $tail | sed 's/-.*$//'`
258 if test $o != $tail; then
259   ostry="$ostry /$o"
260 fi
261
262 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
263 base=
264 tail=$base_os
265 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
266   set $b
267   base="$base /$1"
268   tail="$2"
269 done
270
271 # For sparc/sparc9, try sparc/sparc9 and then sparc.
272 mach=
273 tail=$machine
274 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
275   set $m
276   # Prepend the machine's FPU directory unless --without-fp.
277   if test "$with_fp" = yes; then
278     mach="$mach /$1/fpu"
279   fi
280   mach="$mach /$1"
281   tail="$2"
282 done
283
284 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
285 changequote([,])dnl
286
287 # Find what sysdep directories exist.
288 sysnames=
289 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
290 for d in $add_ons_pfx ''; do
291   for b in $base ''; do
292     for m0 in $mach ''; do
293       for v in /$vendor ''; do
294         for o in /$ostry ''; do
295           for m in $mach ''; do
296             if test "$m0$b$v$o$m"; then
297               try="${d}sysdeps$m0$b$v$o$m"
298               test -n "$enable_debug_configure" &&
299               echo "$0 [DEBUG]: try $try" >&2
300               case $try in
301                 /*) dest=$try ;;
302                 *)  dest=$srcdir/$try ;;
303               esac
304               if test -d $dest; then
305                 sysnames="$sysnames $try"
306                 { test -n "$o" || test -n "$b"; } && os_used=t
307                 { test -n "$m" || test -n "$m0"; } && machine_used=t
308               fi
309             fi
310           done
311         done
312       done
313     done
314   done
315 done
316 IFS="$ac_save_ifs"
317
318 if test -z "$os_used" && test "$os" != none; then
319   AC_MSG_ERROR(Operating system $os is not supported.)
320 fi
321 if test -z "$machine_used" && test "$machine" != none; then
322   AC_MSG_ERROR(The $machine is not supported.)
323 fi
324
325 # We have now validated the configuration.
326
327
328 # If using ELF, look for an `elf' subdirectory of each machine directory.
329 # We prepend these rather than inserting them whereever the machine appears
330 # because things specified by the machine's ELF ABI should override
331 # OS-specific things, and should always be the same for any OS on the
332 # machine (otherwise what's the point of an ABI?).
333 if test "$elf" = yes; then
334   elf_dirs=
335   for d in $add_ons_pfx ''; do
336     case $d in
337       /*) xsrcdir= ;;
338       *)  xsrcdir=$srcdir/ ;;
339     esac
340     for m in $mach; do
341       if test -d $xsrcdir${d}sysdeps$m/elf; then
342         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
343       fi
344     done
345   done
346   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
347 fi
348
349
350 # Expand the list of system names into a full list of directories
351 # from each element's parent name and Implies file (if present).
352 set $sysnames
353 names=
354 while test $# -gt 0; do
355   name=$1
356   shift
357
358   case " $names " in *" $name "*)
359     # Already in the list.
360     continue
361   esac
362
363   # Report each name as we discover it, so there is no long pause in output.
364   echo $ac_n "$name $ac_c" >&AC_FD_MSG
365
366   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
367
368   case $name in
369     /*) xsrcdir= ;;
370     *)  xsrcdir=$srcdir/ ;;
371   esac
372   test -n "$enable_debug_configure" &&
373   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
374
375   if test -f $xsrcdir$name/Implies; then
376     # Collect more names from the `Implies' file (removing comments).
377     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
378     implied=
379     for x in $implied_candidate; do
380       if test -d $xsrcdir$name_base/$x; then
381         implied="$implied $name_base/$x";
382       else
383         AC_MSG_WARN($name/Implies specifies nonexistent $x)
384       fi
385     done
386   else
387     implied=
388   fi
389
390   # Add NAME to the list of names.
391   names="$names $name"
392
393   # Find the parent of NAME, using the empty string if it has none.
394 changequote(,)dnl
395   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
396 changequote([,])dnl
397
398   # Add the names implied by NAME, and NAME's parent (if it has one), to
399   # the list of names to be processed (the argument list).  We prepend the
400   # implied names to the list and append the parent.  We want implied
401   # directories to come before further directories inferred from the
402   # configuration components; this ensures that for sysv4, unix/common
403   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
404   # after sysv4).
405   sysnames="`echo $implied $* $parent`"
406   test -n "$sysnames" && set $sysnames
407 done
408
409 # Add the default directories.
410 sysnames="$names sysdeps/generic"
411 AC_SUBST(sysnames)
412 # The other names were emitted during the scan.
413 AC_MSG_RESULT(sysdeps/generic)
414
415
416 ### Locate tools.
417
418 AC_PROG_INSTALL
419 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
420   # The makefiles need to use a different form to find it in $srcdir.
421   INSTALL='\$(..)./install-sh -c'
422 fi
423 AC_PROG_LN_S
424 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
425 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
426 if test "$MAKEINFO"; then
427 changequote(,)dnl Need [] for regexps.
428   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
429 changequote([,])dnl
430   then : # Makeinfo 3.11 or greater, works.
431   else
432     AC_MSG_WARN([
433 *** makeinfo is too old (need version 3.11 or better).
434 *** You should install the needed version and re-configure since otherwise
435 *** you won't get the info pages installed.])
436     MAKEINFO=
437   fi
438 fi
439
440 AC_PROG_CC_LOCAL
441 AC_CANONICAL_BUILD
442 if test $host != $build; then
443   AC_CHECK_PROGS(BUILD_CC, gcc cc)
444 fi
445 AC_SUBST(cross_compiling)
446 AC_PROG_CPP
447 LIBC_PROG_BINUTILS
448 AC_CHECK_TOOL(AR, ar)
449 AC_CHECK_TOOL(RANLIB, ranlib, :)
450
451 AC_PATH_PROG(BASH, bash, no)
452 if test "$BASH" != no &&
453    $BASH -c 'test "$BASH_VERSINFO" \
454              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
455   libc_cv_have_bash2=yes
456 else
457   libc_cv_have_bash2=no
458 fi
459 AC_SUBST(libc_cv_have_bash2)
460
461 dnl We need a ksh compatible shell for tzselect.
462 if test "$BASH" = no; then
463   AC_PATH_PROG(KSH, ksh, no)
464   if test "$KSH" = no; then
465     libc_cv_have_ksh=no
466   else
467     libc_cv_have_ksh=yes
468   fi
469 else
470   KSH="$BASH"
471   AC_SUBST(KSH)
472   libc_cv_have_ksh=yes
473 fi
474 AC_SUBST(libc_cv_have_ksh)
475
476 AC_PATH_PROGS(PERL, perl, no)
477 AC_SUBST(PERL)
478
479 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
480 echo '#include <stddef.h>
481 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
482 if eval "$ac_cpp conftest.c 2>/dev/null" \
483 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
484   libc_cv_signed_size_t=no
485 else
486   libc_cv_signed_size_t=yes
487 fi
488 rm -f conftest*])
489 if test $libc_cv_signed_size_t = yes; then
490   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
491   cat >> confdefs.h <<\EOF
492 #undef __SIZE_TYPE__
493 #define __SIZE_TYPE__ unsigned
494 EOF
495 fi
496
497 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
498 AC_TRY_COMPILE(dnl
499 [#define __need_size_t
500 #define __need_wchar_t
501 #include <stddef.h>
502 #define __need_NULL
503 #include <stddef.h>], [size_t size; wchar_t wchar;
504 #ifdef offsetof
505 #error stddef.h ignored __need_*
506 #endif
507 if (&size == NULL || &wchar == NULL) abort ();],
508                libc_cv_friendly_stddef=yes,
509                libc_cv_friendly_stddef=no)])
510 if test $libc_cv_friendly_stddef = yes; then
511   config_vars="$config_vars
512 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
513 fi
514
515 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
516                libc_cv_need_minus_P, [dnl
517 cat > conftest.S <<EOF
518 #include "confdefs.h"
519 /* Nothing whatsoever.  */
520 EOF
521 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
522   libc_cv_need_minus_P=no
523 else
524   libc_cv_need_minus_P=yes
525 fi
526 rm -f conftest*])
527 if test $libc_cv_need_minus_P = yes; then
528   config_vars="$config_vars
529 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
530 fi
531
532 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
533 # be told to read stdin.  This causes the compiler to hang when fed an
534 # .s file.
535 if test $ac_cv_prog_gcc = yes; then
536  case `${CC-cc} -v 2>&1` in
537   *2.7*)
538   # We must check this even if -pipe is not given here, because the user
539   # might do `make CFLAGS=-pipe'.
540   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
541    cp /dev/null conftest.s
542    cat >conftest1.s <<EOF
543 .nosuchdirective
544 EOF
545    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
546     libc_cv_gcc_pipe_bug=no
547    else
548     libc_cv_gcc_pipe_bug=yes
549    fi
550    rm -f conftest*])
551   if test $libc_cv_gcc_pipe_bug = yes; then
552    makeCC="${CC-cc} -B\$(common-objpfx)"
553    makeCFLAGS=$CFLAGS
554    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
555   fi;;
556  *) libc_cv_gcc_pipe_bug=no;;
557  esac
558 else
559  libc_cv_gcc_pipe_bug=no
560 fi
561
562 AC_CACHE_CHECK(for assembler global-symbol directive,
563                libc_cv_asm_global_directive, [dnl
564 libc_cv_asm_global_directive=UNKNOWN
565 for ac_globl in .globl .global; do
566   cat > conftest.s <<EOF
567 .text
568 ${ac_globl} foo
569 foo:
570 EOF
571   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
572     libc_cv_asm_global_directive=${ac_globl}
573   fi
574   rm -f conftest*
575   test $libc_cv_asm_global_directive != UNKNOWN && break
576 done])
577 if test $libc_cv_asm_global_directive = UNKNOWN; then
578   AC_MSG_ERROR(cannot determine asm global directive)
579 else
580   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
581 fi
582
583 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
584 cat > conftest.s <<EOF
585 .text
586 foo:
587 .set glibc_conftest_frobozz,foo
588 $libc_cv_asm_global_directive glibc_conftest_frobozz
589 EOF
590 # The alpha-dec-osf1 assembler gives only a warning for `.set'
591 # (but it doesn't work), so we must do a linking check to be sure.
592 cat > conftest1.c <<\EOF
593 extern int glibc_conftest_frobozz;
594 main () { printf ("%d\n", glibc_conftest_frobozz); }
595 EOF
596 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
597             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
598   libc_cv_asm_set_directive=yes
599 else
600   libc_cv_asm_set_directive=no
601 fi
602 rm -f conftest*])
603 if test $libc_cv_asm_set_directive = yes; then
604   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
605 fi
606
607 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
608 [cat > conftest.s <<EOF
609 .text
610 _sym:
611 .symver _sym,sym@VERS
612 EOF
613 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
614   libc_cv_asm_symver_directive=yes
615 else
616   libc_cv_asm_symver_directive=no
617 fi
618 rm -f conftest*])
619 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
620 if test $libc_cv_asm_symver_directive = yes; then
621   cat > conftest.s <<EOF
622 .text
623 _sym:
624 .symver _sym,sym@VERS
625 EOF
626   cat > conftest.map <<EOF
627 VERS_1 {
628         global: sym;
629 };
630
631 VERS_2 {
632         global: sym;
633 } VERS_1;
634 EOF
635   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
636     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
637                                         -nostartfiles -nostdlib
638                                         -Wl,--version-script,conftest.map
639                        1>&AC_FD_CC]);
640     then
641       libc_cv_ld_version_script_option=yes
642     else
643       libc_cv_ld_version_script_option=no
644     fi
645   else
646     libc_cv_ld_version_script_option=no
647   fi
648 else
649   libc_cv_ld_version_script_option=no
650 fi
651 rm -f conftest*])
652 if test $libc_cv_asm_symver_directive = yes &&
653    test $libc_cv_ld_version_script_option = yes &&
654    test $enable_versioning = yes; then
655   VERSIONING=yes
656   AC_DEFINE(DO_VERSIONING)
657 else
658   VERSIONING=no
659 fi
660 AC_SUBST(VERSIONING)
661
662 if test $VERSIONING = no; then
663   echo "\
664 *** WARNING: You should not compile GNU libc without versioning. Not using
665 *** versioning will introduce incompatibilities so that old binaries
666 *** will not run anymore.
667 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
668 fi
669 if test $elf = yes; then
670   AC_CACHE_CHECK(for .previous assembler directive,
671                  libc_cv_asm_previous_directive, [dnl
672   cat > conftest.s <<EOF
673 .section foo_section
674 .previous
675 EOF
676   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
677     libc_cv_asm_previous_directive=yes
678   else
679     libc_cv_asm_previous_directive=no
680   fi
681   rm -f conftest*])
682   if test $libc_cv_asm_previous_directive = yes; then
683     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
684   else
685     AC_CACHE_CHECK(for .popsection assembler directive,
686                    libc_cv_asm_popsection_directive, [dnl
687     cat > conftest.s <<EOF
688 .pushsection foo_section
689 .popsection
690 EOF
691     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
692       libc_cv_asm_popsection_directive=yes
693     else
694       libc_cv_asm_popsection_directive=no
695     fi
696     rm -f conftest*])
697     if test $libc_cv_asm_popsection_directive = yes; then
698       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
699     fi
700   fi
701 fi
702
703 if test $elf != yes; then
704   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
705                  [AC_TRY_COMPILE(, [asm (".section .init");
706                                     asm (".section .fini");
707                                     asm (".text");],
708                                  libc_cv_have_initfini=yes,
709                                  libc_cv_have_initfini=no)])
710   AC_SUBST(libc_cv_have_initfini)dnl
711   if test $libc_cv_have_initfini = yes; then
712     AC_DEFINE(HAVE_INITFINI)
713   fi
714 fi
715
716 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
717 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
718 [cat > conftest.$ac_ext <<EOF
719 dnl This sometimes fails to find confdefs.h, for some reason.
720 dnl [#]line __oline__ "[$]0"
721 [#]line __oline__ "configure"
722 #include "confdefs.h"
723 void underscore_test(void) {
724 return; }
725 EOF
726 if AC_TRY_EVAL(ac_compile); then
727   if grep _underscore_test conftest* >/dev/null; then
728     ifelse([$1], , :, [rm -f conftest*
729     $1])
730   else
731     ifelse([$2], , , [rm -f conftest*
732     $2])
733   fi
734 else
735   echo "configure: failed program was:" >&AC_FD_CC
736   cat conftest.$ac_ext >&AC_FD_CC
737   ifelse([$2], , , [rm -f conftest*
738   $2])
739 fi
740 rm -f conftest*])
741
742 if test $elf = yes; then
743   libc_cv_asm_underscores=no
744 else
745   if test $ac_cv_prog_cc_works = yes; then
746     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
747                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
748                                 libc_cv_asm_underscores=yes,
749                                 libc_cv_asm_underscores=no)])
750   else
751     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
752                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
753                                             libc_cv_asm_underscores=no)])
754   fi
755 fi
756 if test $libc_cv_asm_underscores = no; then
757   AC_DEFINE(NO_UNDERSCORES)
758 fi
759
760 if test $elf = yes; then
761   libc_cv_weak_symbols=yes
762   libc_cv_asm_weak_directive=yes
763   libc_cv_asm_weakext_directive=no
764 else
765   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
766                  [dnl
767 cat > conftest.s <<EOF
768 .text
769 ${libc_cv_asm_global_directive} foo
770 foo:
771 .weak foo
772 .weak bar; bar = foo
773 EOF
774   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
775     libc_cv_asm_weak_directive=yes
776   else
777     libc_cv_asm_weak_directive=no
778   fi
779   rm -f conftest*])
780
781 if test $libc_cv_asm_weak_directive = no; then
782   AC_CACHE_CHECK(for assembler .weakext directive,
783                  libc_cv_asm_weakext_directive,
784                  [dnl
785 cat > conftest.s <<EOF
786 .text
787 ${libc_cv_asm_global_directive} foo
788 foo:
789 .weakext foo
790 .weakext foo, bar
791 EOF
792   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
793     libc_cv_asm_weakext_directive=yes
794   else
795     libc_cv_asm_weakext_directive=no
796   fi
797   rm -f conftest*])
798
799   fi # no .weak
800 fi # not ELF
801
802 if test $libc_cv_asm_weak_directive = yes; then
803   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
804 elif test $libc_cv_asm_weakext_directive = yes; then
805   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
806 fi
807
808 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
809 cat > conftest.c <<\EOF
810 _start () {}
811 int __eh_pc;
812 __throw () {}
813 EOF
814 dnl No \ in command here because it ends up inside ''.
815 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
816                             -nostdlib -nostartfiles -Wl,--no-whole-archive
817                             -o conftest conftest.c 1>&AC_FD_CC]); then
818   libc_cv_ld_no_whole_archive=yes
819 else
820   libc_cv_ld_no_whole_archive=no
821 fi
822 rm -f conftest*])
823 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
824
825 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
826 cat > conftest.c <<\EOF
827 _start () {}
828 int __eh_pc;
829 __throw () {}
830 EOF
831 dnl No \ in command here because it ends up inside ''.
832 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
833                             -nostdlib -nostartfiles -fno-exceptions
834                             -o conftest conftest.c 1>&AC_FD_CC]); then
835   libc_cv_gcc_no_exceptions=yes
836 else
837   libc_cv_gcc_no_exceptions=no
838 fi
839 rm -f conftest*])
840 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
841
842 if test "$base_machine" = alpha ; then
843 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
844 cat > conftest.c <<\EOF
845 foo () { }
846 EOF
847 dnl
848 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
849 then
850   libc_cv_gcc_alpha_ng_prefix=yes
851 else
852   libc_cv_gcc_alpha_ng_prefix=no
853 fi
854 rm -f conftest* ])
855 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
856   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
857 else
858   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
859 fi
860 fi
861
862 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
863 [cat > conftest.c <<EOF
864 #line __oline__ "configure"
865 static char __EH_FRAME_BEGIN__[];
866 _start ()
867 {
868 #ifdef CHECK__register_frame
869   __register_frame (__EH_FRAME_BEGIN__);
870   __deregister_frame (__EH_FRAME_BEGIN__);
871 #endif
872 #ifdef CHECK__register_frame_info
873   __register_frame_info (__EH_FRAME_BEGIN__);
874   __deregister_frame_info (__EH_FRAME_BEGIN__);
875 #endif
876 }
877 int __eh_pc;
878 __throw () {}
879 /* FIXME: this is fragile.  */
880 malloc () {}
881 strcmp () {}
882 strlen () {}
883 memcpy () {}
884 memset () {}
885 free () {}
886 abort () {}
887 __bzero () {}
888 EOF
889 dnl No \ in command here because it ends up inside ''.
890 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
891                             -nostdlib -nostartfiles
892                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
893   libc_cv_gcc_dwarf2_unwind_info=static
894 else
895   libc_cv_gcc_dwarf2_unwind_info=no
896 fi
897 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
898   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
899                               -nostdlib -nostartfiles
900                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
901     libc_cv_gcc_dwarf2_unwind_info=yes
902   else
903     libc_cv_gcc_dwarf2_unwind_info=no
904   fi
905 fi
906 rm -f conftest*])
907 case $libc_cv_gcc_dwarf2_unwind_info in
908 yes)
909   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
910   ;;
911 static)
912   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
913   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
914   ;;
915 esac
916
917 ### End of automated tests.
918 ### Now run sysdeps configure fragments.
919
920 # sysdeps configure fragments may set these with files to be linked below.
921 libc_link_dests=
922 libc_link_sources=
923
924 # Iterate over all the sysdep directories we will use, running their
925 # configure fragments, and looking for a uname implementation.
926 uname=
927 for dir in $sysnames; do
928   case $dir in
929     /*) dest=$dir ;;
930     *)  dest=$srcdir/$dir ;;
931   esac
932   if test -r $dest/configure; then
933     AC_MSG_RESULT(running configure fragment for $dest)
934     . $dest/configure
935   fi
936 [
937   if test -z "$uname"; then
938     if test -r $dest/uname.c ||
939        test -r $dest/uname.S ||
940        { test -r $dest/syscalls.list &&
941          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
942       uname=$dir
943     fi
944   fi
945 ]dnl
946 done
947
948 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
949
950 # If we will use the generic uname implementation, we must figure out what
951 # it will say by examining the system, and write the results in config-name.h.
952 if test "$uname" = "sysdeps/generic"; then
953
954 changequote(,)dnl
955   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
956 changequote([,])dnl
957   if test $uname_sysname != $config_os; then
958     config_release=`echo $config_os | sed s/$uname_sysname//`
959   fi
960 dnl
961 AC_DEFUN(LIBC_KERNEL_ID, [dnl
962     if test -r /vmunix; then
963       kernel_id=`strings /vmunix | grep UNIX`
964     elif test -r /dynix; then
965       kernel_id=`strings /dynix | grep DYNIX`
966     else
967       kernel_id=
968     fi
969 ])dnl
970
971   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
972 AC_REQUIRE([LIBC_KERNEL_ID])dnl
973 changequote(,)dnl
974   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
975 changequote([,])dnl
976   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
977          != x$config_release; then
978     # The configuration release is a substring of the kernel release.
979     libc_cv_uname_release=$kernel_release
980   elif test x$config_release != x; then
981     libc_cv_uname_release=$config_release
982   elif test x$kernel_release != x; then
983     libc_cv_uname_release=$kernel_release
984   else
985     libc_cv_uname_release=unknown
986   fi])
987   uname_release="$libc_cv_uname_release"
988
989   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
990 AC_REQUIRE([LIBC_KERNEL_ID])dnl
991 changequote(,)dnl
992   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
993 changequote([,])dnl
994   if test -n "$kernel_version"; then
995     libc_cv_uname_version="$kernel_version"
996   else
997     libc_cv_uname_version=unknown
998   fi])
999   uname_version="$libc_cv_uname_version"
1000
1001 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1002   config_uname=config-name.h:config-name.in
1003 else
1004   # For non-generic uname, we don't need to create config-name.h at all.
1005   config_uname=
1006 fi
1007
1008 AC_MSG_CHECKING(stdio selection)
1009 AC_SUBST(stdio)
1010 case $stdio in
1011 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1012 default) stdio=stdio ;;
1013 esac
1014 AC_MSG_RESULT($stdio)
1015
1016 AC_MSG_CHECKING(ldap selection)
1017 AC_SUBST(LDAP)
1018 case $add_ons in
1019 *ldap*)
1020    ldap=yes
1021    LDAP=ldap ;;
1022 *) ldap=no
1023    LDAP= ;;
1024 esac
1025 AC_MSG_RESULT($ldap)
1026
1027 AC_SUBST(libc_cv_slibdir)
1028 AC_SUBST(libc_cv_sysconfdir)
1029 AC_SUBST(libc_cv_rootsbindir)
1030
1031 AC_SUBST(has_ldconfig)
1032
1033 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1034 if test $gnu_ld = yes; then
1035   AC_DEFINE(HAVE_GNU_LD)
1036 fi
1037 if test $gnu_as = yes; then
1038   AC_DEFINE(HAVE_GNU_AS)
1039 fi
1040 if test $elf = yes; then
1041   AC_DEFINE(HAVE_ELF)
1042 fi
1043
1044 AC_SUBST(static)
1045 AC_SUBST(shared)
1046 if test $shared = default; then
1047   if test $gnu_ld = yes; then
1048     shared=$elf
1049   else
1050     # For now we do not assume shared libs are available.  In future more
1051     # tests might become available.
1052     shared=no
1053   fi
1054 fi
1055
1056 dnl We must not allow compilation without static library on some platforms.
1057 if test $static = no && test $shared = yes; then
1058   case "$host_os" in
1059   linux* | gnu*)
1060     AC_MSG_ERROR([
1061 *** You must compile with support for the static library since the shared
1062 *** library uses it.  Restart configure without \`--disable-static'.])
1063     ;;
1064   *)
1065     ;;
1066   esac
1067 fi
1068
1069 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1070 [pic_default=yes
1071 cat > conftest.c <<EOF
1072 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1073 # error PIC is default.
1074 #endif
1075 EOF
1076 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1077   pic_default=no
1078 fi
1079 rm -f conftest.*])
1080 AC_SUBST(pic_default)
1081
1082 AC_SUBST(profile)
1083 AC_SUBST(omitfp)
1084 AC_SUBST(bounded)
1085 AC_SUBST(static_nss)
1086 AC_SUBST(nopic_initfini)
1087
1088 AC_SUBST(DEFINES)
1089
1090 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1091   config_makefile=
1092 else
1093   config_makefile=Makefile
1094 fi
1095
1096 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1097 AC_SUBST(VERSION)
1098
1099 if test $libc_cv_gcc_pipe_bug = yes; then
1100  realCC=$CC
1101  CC=$makeCC
1102  CFLAGS=$makeCFLAGS
1103 fi
1104 AC_OUTPUT_COMMANDS([
1105 if test "$realCC"; then
1106  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1107  mv specsT specs
1108 fi], [realCC=$realCC])
1109
1110 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1111           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])