Sat Jun 15 18:13:43 1996 Roland McGrath <roland@delasyd.gnu.ai.mit.edu>
[kopensolaris-gnu/glibc.git] / configure.in
1 Dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.10)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37   --with-fp               if using floating-point hardware [default=yes],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(gnu-binutils, dnl
40   --with-gnu-binutils     if using GNU binutils (as and ld),
41             gnu_binutils=$withval, gnu_binutils=no)
42 AC_ARG_WITH(gnu-ld, dnl
43   --with-gnu-ld           if using GNU ld (in the binutils package),
44             gnu_ld=$withval, gnu_ld=no)
45 AC_ARG_WITH(gnu-as, dnl
46   --with-gnu-as           if using GNU as (in the binutils package),
47             gnu_as=$withval, gnu_as=no)
48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
49 AC_ARG_WITH(elf, dnl
50   --with-elf              if using the ELF object format,
51             elf=$withval, elf=no)
52
53 AC_ARG_ENABLE(libio, dnl
54 [  --enable-libio          build in GNU libio instead of GNU stdio],
55               [if test $enableval = yes; then
56                  stdio=libio
57                else
58                  stdio=stdio
59                fi],
60               stdio=default)
61
62 dnl Arguments to enable or disable building the shared, profiled, and
63 dnl -fomit-frame-pointer libraries.
64 AC_ARG_ENABLE(shared, dnl
65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
66             shared=$enableval, shared=default)
67 AC_ARG_ENABLE(profile, dnl
68 [  --enable-profile        build profiled library [default=yes]],
69             profile=$enableval, profile=yes)
70 AC_ARG_ENABLE(omitfp, dnl
71 [  --enable-omitfp       build undebuggable optimized library [default=no]],
72             omitfp=$enableval, omitfp=no)
73
74 AC_CANONICAL_HOST
75 # We keep the original values in `$config_*' and never modify them, so we
76 # can write them unchanged into config.make.  Everything else uses
77 # $machine, $vendor, and $os, and changes them whenever convenient.
78 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
79
80 # Some configurations imply other options.
81 case "$host_os" in
82 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
83   # These systems always use GNU tools.
84   gnu_ld=yes gnu_as=yes ;;
85 esac
86 case "$host_os" in
87 gnu* | linux* | sysv4* | solaris2*)
88   # These systems always use the ELF format.
89   if test "$host_cpu" != alpha; then    # Linux/Alpha is not fully ELF yet
90     elf=yes
91   fi
92   ;;
93 esac
94
95 machine=$config_machine
96 vendor=$config_vendor
97 os=$config_os
98
99 dnl We need to use [ and ] for other purposes for a while now.
100 changequote(,)dnl
101 # Expand the configuration machine name into a subdirectory by architecture
102 # type and particular chip.
103 case "$machine" in
104 a29k | am29000) base_machine=a29k machine=a29k ;;
105 alpha*)         base_machine=alpha machine=alpha/$machine ;;
106 hppa*)          base_machine=hppa machine=hppa/$machine ;;
107 i[345]86)       base_machine=i386 machine=i386/$machine ;;
108 m680?0)         base_machine=m68k machine=m68k/$machine ;;
109 m68k)           base_machine=m68k machine=m68k/m68020 ;;
110 m88???)         base_machine=m88k machine=m88k/$machine ;;
111 m88k)           base_machine=m88k machine=m88k/m88100 ;;
112 mips*)          base_machine=mips machine=mips/$machine ;;
113 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
114 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
115 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
116 esac
117 changequote([,])dnl
118 AC_SUBST(base_machine)
119
120 # Compute the list of sysdep directories for this configuration.
121 # This can take a while to compute.
122 sysdep_dir=$srcdir/sysdeps
123 AC_MSG_CHECKING(sysdep dirs)
124 dnl We need to use [ and ] for other purposes for a while now.
125 changequote(,)dnl
126 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
127 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
128
129 case "$os" in
130 gnu*)
131   base_os=mach/hurd ;;
132 netbsd* | 386bsd* | freebsd* | bsdi*)
133   base_os=unix/bsd/bsd4.4 ;;
134 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
135   base_os=unix/bsd ;;
136 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
137   base_os=unix/sysv ;;
138 solaris[2-9]*)
139   base_os=unix/sysv/sysv4 ;;
140 none)
141   base_os=standalone ;;
142 *)
143   base_os='' ;;
144 esac
145
146 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
147 tail=$os
148 ostry=$os
149 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
150   ostry="$ostry /$o"
151   tail=$o
152 done
153 o=`echo $tail | sed 's/[0-9]*$//'`
154 if test $o != $tail; then
155   ostry="$ostry /$o"
156 fi
157
158 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
159 base=
160 tail=$base_os
161 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
162   set $b
163   base="$base /$1"
164   tail="$2"
165 done
166
167 # For sparc/sparc9, try sparc/sparc9 and then sparc.
168 mach=
169 tail=$machine
170 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
171   set $m
172   # Prepend the machine's FPU directory unless --without-fp.
173   if test "$with_fp" = yes; then
174     mach="$mach /$1/fpu"
175   fi
176   mach="$mach /$1"
177   tail="$2"
178 done
179
180 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
181 changequote([,])dnl
182
183 # Find what sysdep directories exist.
184 sysnames=
185 for b in $base ''; do
186   for m0 in $mach ''; do
187     for v in /$vendor ''; do
188       for o in /$ostry ''; do
189         for m in $mach ''; do
190           try="$m0$b$v$o$m"
191           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
192           if test -d $sysdep_dir$try; then
193             sysnames="$sysnames $try"
194             { test -n "$o" || test -n "$b"; } && os_used=t
195             { test -n "$m" || test -n "$m0"; } && machine_used=t
196           fi
197         done
198       done
199     done
200   done
201 done
202
203 if test -z "$os_used" && test "$os" != none; then
204   AC_MSG_ERROR(Operating system $os is not supported.)
205 fi
206 if test -z "$machine_used" && test "$machine" != none; then
207   AC_MSG_ERROR(The $machine is not supported.)
208 fi
209
210 # We have now validated the configuration.
211
212
213 # If using ELF, look for an `elf' subdirectory of each machine directory.
214 # We prepend these rather than inserting them whereever the machine appears
215 # because things specified by the machine's ELF ABI should override
216 # OS-specific things, and should always be the same for any OS on the
217 # machine (otherwise what's the point of an ABI?).
218 if test "$elf" = yes; then
219   elf_dirs=
220   for m in $mach; do
221     if test -d $sysdep_dir$m/elf; then
222       elf_dirs="$elf_dirs $m/elf"
223     fi
224   done
225   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
226 fi
227
228
229 # Remove the leading slashes.
230 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
231
232
233 # Expand the list of system names into a full list of directories
234 # from each element's parent name and Implies file (if present).
235 set $sysnames
236 names= seen=
237 while test $# -gt 0; do
238   name=$1
239   shift
240
241   if echo "$seen" | fgrep -x $name >/dev/null; then
242     # Already in the list.
243     continue
244   fi
245
246   # Report each name as we discover it, so there is no long pause in output.
247   echo $ac_n "$name $ac_c" >&AC_FD_MSG
248
249   if test -f $sysdep_dir/$name/Implies; then
250     # Collect more names from the `Implies' file (removing comments).
251     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
252     for x in $implied; do
253       test -d $sysdep_dir/$x || {
254         AC_MSG_WARN(sysdeps/$name/Implies specifies nonexistent $x)
255       }
256     done
257   else
258     implied=
259   fi
260
261   # Add NAME to the list of names.
262   names="$names $name"
263   # We maintain a parallel newline-separated list for the fgrep check above.
264   seen="$seen
265 $name"
266
267   # Find the parent of NAME, using the empty string if it has none.
268 changequote(,)dnl
269   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
270 changequote([,])dnl
271
272   # Add the names implied by NAME, and NAME's parent (if it has one), to
273   # the list of names to be processed (the argument list).  We prepend the
274   # implied names to the list and append the parent.  We want implied
275   # directories to come before further directories inferred from the
276   # configuration components; this ensures that for sysv4, unix/common
277   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
278   # after sysv4).
279   sysnames="`echo $implied $* $parent`"
280   test -n "$sysnames" && set $sysnames
281 done
282
283 # Add the default directories.
284 sysnames="$names generic stub"
285 AC_SUBST(sysnames)
286 # The other names were emitted during the scan.
287 AC_MSG_RESULT(generic stub)
288
289
290 ### Locate tools.
291
292 AC_PROG_INSTALL
293 if test "$INSTALL" = "${srcdir}/install-sh"; then
294   # The makefiles need to use a different form to find it in $srcdir.
295   INSTALL='$(..)./install-sh'
296 fi
297 AC_PROG_LN_S
298 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
299
300 AC_CHECK_TOOL(CC, gcc)
301 AC_PROG_CPP
302 AC_CHECK_TOOL(AR, ar)
303 AC_CHECK_TOOL(RANLIB, ranlib, :)
304
305 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
306 echo '#include <stddef.h>
307 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
308 if eval "$ac_cpp conftest.c 2>/dev/null" \
309 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
310   libc_cv_signed_size_t=no
311 else
312   libc_cv_signed_size_t=yes
313 fi
314 rm -f conftest*])
315 if test $libc_cv_signed_size_t = yes; then
316   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
317   cat >> confdefs.h <<\EOF
318 #undef __SIZE_TYPE__
319 #define __SIZE_TYPE__ unsigned
320 EOF
321 fi
322
323 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
324 AC_TRY_COMPILE(dnl
325 [#define __need_size_t
326 #define __need_wchar_t
327 #include <stddef.h>
328 #define __need_NULL
329 #include <stddef.h>], [size_t size; wchar_t wchar;
330 #ifdef offsetof
331 #error stddef.h ignored __need_*
332 #endif
333 if (&size == NULL || &wchar == NULL) abort ();],
334                libc_cv_friendly_stddef=yes,
335                libc_cv_friendly_stddef=no)])
336 if test $libc_cv_friendly_stddef = yes; then
337   config_vars="$config_vars
338 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
339 fi
340
341 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
342                libc_cv_need_minus_P, [dnl
343 cat > conftest.S <<EOF
344 #include "confdefs.h"
345 /* Nothing whatsoever.  */
346 EOF
347 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
348   libc_cv_need_minus_P=no
349 else
350   libc_cv_need_minus_P=yes
351 fi
352 rm -f conftest*])
353 if test $libc_cv_need_minus_P = yes; then
354   config_vars="$config_vars
355 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
356 fi
357
358 AC_CACHE_CHECK(for assembler global-symbol directive,
359                libc_cv_asm_global_directive, [dnl
360 libc_cv_asm_global_directive=UNKNOWN
361 for ac_globl in .globl .global; do
362   cat > conftest.s <<EOF
363 .text
364 ${ac_globl} foo
365 foo: .long 0
366 EOF
367   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
368     libc_cv_asm_global_directive=${ac_globl}
369   fi
370   rm -f conftest*
371   test $libc_cv_asm_global_directive != UNKNOWN && break
372 done])
373 if test $libc_cv_asm_global_directive = UNKNOWN; then
374   AC_MSG_ERROR(cannot determine asm global directive)
375 else
376   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
377 fi
378
379 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
380 cat > conftest.s <<EOF
381 .text
382 foo: .long 0
383 .set glibc_conftest_frobozz,foo
384 $libc_cv_asm_global_directive glibc_conftest_frobozz
385 EOF
386 # The alpha-dec-osf1 assembler gives only a warning for `.set'
387 # (but it doesn't work), so we must do a linking check to be sure.
388 cat > conftest1.c <<\EOF
389 extern int glibc_conftest_frobozz;
390 main () { printf ("%d\n", glibc_conftest_frobozz); }
391 EOF
392 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
393             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
394   libc_cv_asm_set_directive=yes
395 else
396   libc_cv_asm_set_directive=no
397 fi
398 rm -f conftest*])
399 if test $libc_cv_asm_set_directive = yes; then
400   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
401 fi
402
403 if test $elf != yes; then
404   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
405                  [AC_TRY_COMPILE(, [asm (".section .init");
406                                     asm (".section .fini");
407                                     asm (".text");],
408                                  libc_cv_have_initfini=yes,
409                                  libc_cv_have_initfini=no)])
410   AC_SUBST(libc_cv_have_initfini)dnl
411   if test $libc_cv_have_initfini = yes; then
412     AC_DEFINE(HAVE_INITFINI)
413   fi
414 fi
415
416 if test $elf = yes; then
417   libc_cv_asm_underscores=no
418 else
419   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
420                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
421                               libc_cv_asm_underscores=yes,
422                               libc_cv_asm_underscores=no)])
423 fi
424 if test $libc_cv_asm_underscores = no; then
425   AC_DEFINE(NO_UNDERSCORES)
426 fi
427
428 if test $elf = yes; then
429   libc_cv_weak_symbols=yes
430   libc_cv_asm_weak_directive=yes
431   libc_cv_asm_weakext_directive=no
432 else
433   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
434                  [dnl
435 cat > conftest.s <<EOF
436 .text
437 ${libc_cv_asm_global_directive} foo
438 foo: .long 0
439 .weak foo
440 .weak bar; bar = foo
441 EOF
442   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
443     libc_cv_asm_weak_directive=yes
444   else
445     libc_cv_asm_weak_directive=no
446   fi
447   rm -f conftest*])
448
449 if test $libc_cv_asm_weak_directive = no; then
450   AC_CACHE_CHECK(for assembler .weakext directive,
451                  libc_cv_asm_weakext_directive,
452                  [dnl
453 cat > conftest.s <<EOF
454 .text
455 ${libc_cv_asm_global_directive} foo
456 foo: .long 0
457 .weakext foo
458 .weakext bar, foo
459 EOF
460   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
461     libc_cv_asm_weakext_directive=yes
462   else
463     libc_cv_asm_weakext_directive=no
464   fi
465   rm -f conftest*])
466
467   fi # no .weak
468 fi # not ELF
469
470 if test $libc_cv_asm_weak_directive = yes; then
471   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
472 elif test $libc_cv_asm_weakext_directive = yes; then
473   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
474 fi
475
476 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
477 cat > conftest.c <<\EOF
478 main () { exit (0); }
479 EOF
480 if ${CC-cc} $CFLAGS -Wl,--no-whole-archive \
481             -o conftest conftest.c 2>/dev/null; then
482   libc_cv_ld_no_whole_archive=yes
483 else
484   libc_cv_ld_no_whole_archive=no
485 fi
486 rm -f conftest*])
487 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
488
489 ### End of automated tests.
490 ### Now run sysdeps configure fragments.
491
492 # sysdeps configure fragments may set these with files to be linked below.
493 libc_link_dests=
494 libc_link_sources=
495
496 # Iterate over all the sysdep directories we will use, running their
497 # configure fragments, and looking for a uname implementation.
498 uname=
499 for dir in $sysnames; do
500   if test -r $sysdep_dir/$dir/configure; then
501     AC_MSG_RESULT(running configure fragment for $dir)
502     . $sysdep_dir/$dir/configure
503   fi
504 [
505   if test -z "$uname"; then
506     if test -r $sysdep_dir/$dir/uname.c ||
507        test -r $sysdep_dir/$dir/uname.S ||
508        { test -r $sysdep_dir/$dir/syscalls.list &&
509          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
510       uname=$dir
511     fi
512   fi
513 ]dnl
514 done
515
516 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
517
518 # If we will use the generic uname implementation, we must figure out what
519 # it will say by examining the system, and write the results in config-name.h.
520 if test "$uname" = generic; then
521
522 changequote(,)dnl
523   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
524 changequote([,])dnl
525   if test $uname_sysname != $config_os; then
526     config_release=`echo $config_os | sed s/$uname_sysname//`
527   fi
528 dnl
529 AC_DEFUN(LIBC_KERNEL_ID, [dnl
530     if test -r /vmunix; then
531       kernel_id=`strings /vmunix | grep UNIX`
532     elif test -r /dynix; then
533       kernel_id=`strings /dynix | grep DYNIX`
534     else
535       kernel_id=
536     fi
537 ])dnl
538
539   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
540 AC_REQUIRE([LIBC_KERNEL_ID])dnl
541 changequote(,)dnl
542   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
543 changequote([,])dnl
544   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
545          != x$config_release; then
546     # The configuration release is a substring of the kernel release.
547     libc_cv_uname_release=$kernel_release
548   elif test x$config_release != x; then
549     libc_cv_uname_release=$config_release
550   elif test x$kernel_release != x; then
551     libc_cv_uname_release=$kernel_release
552   else
553     libc_cv_uname_release=unknown
554   fi])
555   uname_release="$libc_cv_uname_release"
556
557   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
558 AC_REQUIRE([LIBC_KERNEL_ID])dnl
559 changequote(,)dnl
560   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
561 changequote([,])dnl
562   if test -n "$kernel_version"; then
563     libc_cv_uname_version="$kernel_version"
564   else
565     libc_cv_uname_version=unknown
566   fi])
567   uname_version="$libc_cv_uname_version"
568
569 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
570   config_uname=config-name.h:config-name.in
571 else
572   # For non-generic uname, we don't need to create config-name.h at all.
573   config_uname=
574 fi
575
576 AC_MSG_CHECKING(stdio selection)
577 AC_SUBST(stdio)
578 case $stdio in
579 libio) AC_DEFINE(USE_IN_LIBIO) ;;
580 default) stdio=stdio ;;
581 esac
582 AC_MSG_RESULT($stdio)
583
584 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
585 if test $gnu_ld = yes; then
586   AC_DEFINE(HAVE_GNU_LD)
587 fi
588 if test $gnu_as = yes; then
589   AC_DEFINE(HAVE_GNU_AS)
590 fi
591 if test $elf = yes; then
592   AC_DEFINE(HAVE_ELF)
593 fi
594
595 AC_SUBST(shared)
596 if test $shared = default; then
597   if test $gnu_ld = yes; then
598     shared=$elf
599   fi
600 fi
601 AC_SUBST(profile)
602 AC_SUBST(omitfp)
603
604 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
605   config_makefile=
606 else
607   config_makefile=Makefile
608 fi
609
610 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
611           [echo '$config_vars' >> config.make])