update from main archive 970121
[kopensolaris-gnu/glibc.git] / configure.in
1 Dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(gnu-binutils, dnl
40   --with-gnu-binutils     if using GNU binutils (as and ld),
41             gnu_binutils=$withval, gnu_binutils=no)
42 AC_ARG_WITH(gnu-ld, dnl
43   --with-gnu-ld           if using GNU ld (in the binutils package),
44             gnu_ld=$withval, gnu_ld=no)
45 AC_ARG_WITH(gnu-as, dnl
46   --with-gnu-as           if using GNU as (in the binutils package),
47             gnu_as=$withval, gnu_as=no)
48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
49 AC_ARG_WITH(elf, dnl
50   --with-elf              if using the ELF object format,
51             elf=$withval, elf=no)
52
53 AC_ARG_ENABLE(libio, dnl
54 [  --enable-libio          build in GNU libio instead of GNU stdio],
55               [if test $enableval = yes; then
56                  stdio=libio
57                else
58                  stdio=stdio
59                fi],
60               stdio=default)
61
62 AC_ARG_ENABLE(new-malloc, dnl
63 [  --enable-new-malloc    use the new malloc implementation.  This is the
64                           default for Linux, others use the old malloc.],
65               [if test $enableval = yes; then
66                  malloc=new-malloc
67                else
68                  malloc=malloc
69                fi],
70               malloc=default)
71
72 AC_ARG_ENABLE(sanity-checks, dnl
73 [  --disable-sanity-checks really do not use threads (should not be used
74                           except in special situations) [default=yes]],
75               enable_sanity=$enableval, enable_sanity=yes)
76
77 dnl Arguments to enable or disable building the shared, profiled, and
78 dnl -fomit-frame-pointer libraries.
79 AC_ARG_ENABLE(shared, dnl
80 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
81               shared=$enableval, shared=default)
82 AC_ARG_ENABLE(profile, dnl
83 [  --enable-profile        build profiled library [default=yes]],
84               profile=$enableval, profile=yes)
85 AC_ARG_ENABLE(omitfp, dnl
86 [  --enable-omitfp         build undebuggable optimized library [default=no]],
87               omitfp=$enableval, omitfp=no)
88
89 dnl Generic infrastructure for drop-in additions to libc.
90 AC_ARG_ENABLE(add-ons, dnl
91 [  --enable-add-ons=DIR... configure and build named extra directories],
92               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
93               [add_ons=])
94 AC_CONFIG_SUBDIRS($add_ons)
95 add_ons_pfx=
96 if test x"$add_ons" != x; then
97   for f in $add_ons; do
98     add_ons_pfx="$add_ons_pfx $f/"
99   done
100 fi
101
102 AC_CANONICAL_HOST
103
104 # The way shlib-versions is used to generate soversions.mk uses a
105 # fairly simplistic model for name recognition that can't distinguish
106 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
107 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
108 # tell.  This doesn't get used much beyond that, so it's fairly safe.
109 case "$host_os" in
110 linux*)
111   ;;
112 gnu*)
113   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
114   ;;
115 esac
116
117 # We keep the original values in `$config_*' and never modify them, so we
118 # can write them unchanged into config.make.  Everything else uses
119 # $machine, $vendor, and $os, and changes them whenever convenient.
120 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
121
122 # Some configurations imply other options.
123 case "$host_os" in
124 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
125   # These systems always use GNU tools.
126   gnu_ld=yes gnu_as=yes ;;
127 esac
128 case "$host_os" in
129 linux*ecoff*)
130   ;;
131 gnu* | linux* | sysv4* | solaris2*)
132   # These systems (almost) always use the ELF format.
133   elf=yes
134   ;;
135 esac
136
137 machine=$config_machine
138 vendor=$config_vendor
139 os=$config_os
140
141 dnl We need to use [ and ] for other purposes for a while now.
142 changequote(,)dnl
143 # Expand the configuration machine name into a subdirectory by architecture
144 # type and particular chip.
145 case "$machine" in
146 a29k | am29000) base_machine=a29k machine=a29k ;;
147 alpha*)         base_machine=alpha machine=alpha/$machine ;;
148 hppa*)          base_machine=hppa machine=hppa/$machine ;;
149 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
150 m680?0)         base_machine=m68k machine=m68k/$machine ;;
151 m68k)           base_machine=m68k machine=m68k/m68020 ;;
152 m88???)         base_machine=m88k machine=m88k/$machine ;;
153 m88k)           base_machine=m88k machine=m88k/m88100 ;;
154 mips*)          base_machine=mips machine=mips/$machine ;;
155 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
156 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
157 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
158 esac
159 changequote([,])dnl
160 AC_SUBST(base_machine)
161
162 # Compute the list of sysdep directories for this configuration.
163 # This can take a while to compute.
164 sysdep_dir=$srcdir/sysdeps
165 AC_MSG_CHECKING(sysdep dirs)
166 dnl We need to use [ and ] for other purposes for a while now.
167 changequote(,)dnl
168 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
169 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
170
171 case "$os" in
172 gnu*)
173   base_os=mach/hurd ;;
174 netbsd* | 386bsd* | freebsd* | bsdi*)
175   base_os=unix/bsd/bsd4.4 ;;
176 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
177   base_os=unix/bsd ;;
178 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
179   base_os=unix/sysv ;;
180 solaris[2-9]*)
181   base_os=unix/sysv/sysv4 ;;
182 none)
183   base_os=standalone ;;
184 *)
185   base_os='' ;;
186 esac
187
188 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
189 tail=$os
190 ostry=$os
191 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
192   ostry="$ostry /$o"
193   tail=$o
194 done
195 o=`echo $tail | sed 's/[0-9]*$//'`
196 if test $o != $tail; then
197   ostry="$ostry /$o"
198 fi
199 # For linux-gnu, try linux-gnu, then linux.
200 o=`echo $tail | sed 's/-.*$//'`
201 if test $o != $tail; then
202   ostry="$ostry /$o"
203 fi
204
205 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
206 base=
207 tail=$base_os
208 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
209   set $b
210   base="$base /$1"
211   tail="$2"
212 done
213
214 # For sparc/sparc9, try sparc/sparc9 and then sparc.
215 mach=
216 tail=$machine
217 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
218   set $m
219   # Prepend the machine's FPU directory unless --without-fp.
220   if test "$with_fp" = yes; then
221     mach="$mach /$1/fpu"
222   fi
223   mach="$mach /$1"
224   tail="$2"
225 done
226
227 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
228 changequote([,])dnl
229
230 # Find what sysdep directories exist.
231 sysnames=
232 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
233 for d in $add_ons_pfx ''; do
234   for b in $base ''; do
235     for m0 in $mach ''; do
236       for v in /$vendor ''; do
237         for o in /$ostry ''; do
238           for m in $mach ''; do
239             if test "$m0$b$v$o$m"; then
240               try="${d}sysdeps$m0$b$v$o$m"
241               test -n "$enable_debug_configure" &&
242               echo "$0 [DEBUG]: try $try" >&2
243               case $try in
244                 /*) dest=$try ;;
245                 *)  dest=$srcdir/$try ;;
246               esac
247               if test -d $dest; then
248                 sysnames="$sysnames $try"
249                 { test -n "$o" || test -n "$b"; } && os_used=t
250                 { test -n "$m" || test -n "$m0"; } && machine_used=t
251               fi
252             fi
253           done
254         done
255       done
256     done
257   done
258 done
259 IFS="$ac_save_ifs"
260
261 if test -z "$os_used" && test "$os" != none; then
262   AC_MSG_ERROR(Operating system $os is not supported.)
263 fi
264 if test -z "$machine_used" && test "$machine" != none; then
265   AC_MSG_ERROR(The $machine is not supported.)
266 fi
267
268 # We have now validated the configuration.
269
270
271 # If using ELF, look for an `elf' subdirectory of each machine directory.
272 # We prepend these rather than inserting them whereever the machine appears
273 # because things specified by the machine's ELF ABI should override
274 # OS-specific things, and should always be the same for any OS on the
275 # machine (otherwise what's the point of an ABI?).
276 if test "$elf" = yes; then
277   elf_dirs=
278   for d in $add_ons_pfx ''; do
279     case $d in
280       /*) xsrcdir= ;;
281       *)  xsrcdir=$srcdir/ ;;
282     esac
283     for m in $mach; do
284       if test -d $xsrcdir${d}sysdeps$m/elf; then
285         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
286       fi
287     done
288   done
289   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
290 fi
291
292
293 # Expand the list of system names into a full list of directories
294 # from each element's parent name and Implies file (if present).
295 set $sysnames
296 names=
297 while test $# -gt 0; do
298   name=$1
299   shift
300
301   case " $names " in *" $name "*)
302     # Already in the list.
303     continue
304   esac
305
306   # Report each name as we discover it, so there is no long pause in output.
307   echo $ac_n "$name $ac_c" >&AC_FD_MSG
308
309   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
310
311   case $name in
312     /*) xsrcdir= ;;
313     *)  xsrcdir=$srcdir/ ;;
314   esac
315   test -n "$enable_debug_configure" &&
316   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
317
318   if test -f $xsrcdir$name/Implies; then
319     # Collect more names from the `Implies' file (removing comments).
320     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
321     implied=
322     for x in $implied_candidate; do
323       if test -d $xsrcdir$name_base/$x; then
324         implied="$implied $name_base/$x";
325       else
326         AC_MSG_WARN($name/Implies specifies nonexistent $x)
327       fi
328     done
329   else
330     implied=
331   fi
332
333   # Add NAME to the list of names.
334   names="$names $name"
335
336   # Find the parent of NAME, using the empty string if it has none.
337 changequote(,)dnl
338   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
339 changequote([,])dnl
340
341   # Add the names implied by NAME, and NAME's parent (if it has one), to
342   # the list of names to be processed (the argument list).  We prepend the
343   # implied names to the list and append the parent.  We want implied
344   # directories to come before further directories inferred from the
345   # configuration components; this ensures that for sysv4, unix/common
346   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
347   # after sysv4).
348   sysnames="`echo $implied $* $parent`"
349   test -n "$sysnames" && set $sysnames
350 done
351
352 # Add the default directories.
353 sysnames="$names sysdeps/generic sysdeps/stub"
354 AC_SUBST(sysnames)
355 # The other names were emitted during the scan.
356 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
357
358
359 ### Locate tools.
360
361 AC_PROG_INSTALL
362 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
363   # The makefiles need to use a different form to find it in $srcdir.
364   INSTALL='$(..)./install-sh -c'
365 fi
366 AC_PROG_LN_S
367 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
368
369 AC_CHECK_TOOL(CC, gcc)
370 if test $host != $build; then
371   AC_CHECK_PROG(BUILD_CC, gcc cc)
372 fi
373 AC_PROG_CPP
374 AC_CHECK_TOOL(AR, ar)
375 AC_CHECK_TOOL(RANLIB, ranlib, :)
376
377 AC_PATH_PROG(BASH, bash, no)
378 if test "$BASH" != no &&
379    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
380   libc_cv_have_bash2=yes
381 else
382   libc_cv_have_bash2=no
383 fi
384 AC_SUBST(libc_cv_have_bash2)
385
386 dnl We need a ksh compatible shell for tzselect.
387 if test "$BASH" = no; then
388   AC_PATH_PROG(KSH, ksh, no)
389   if test "$KSH" = no; then
390     libc_cv_have_ksh=no
391   else
392     libc_cv_have_ksh=yes
393   fi
394 else
395   KSH="$BASH"
396   AC_SUBST(KSH)
397   libc_cv_have_ksh=yes
398 fi
399 AC_SUBST(libc_cv_have_ksh)
400
401 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
402 echo '#include <stddef.h>
403 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
404 if eval "$ac_cpp conftest.c 2>/dev/null" \
405 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
406   libc_cv_signed_size_t=no
407 else
408   libc_cv_signed_size_t=yes
409 fi
410 rm -f conftest*])
411 if test $libc_cv_signed_size_t = yes; then
412   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
413   cat >> confdefs.h <<\EOF
414 #undef __SIZE_TYPE__
415 #define __SIZE_TYPE__ unsigned
416 EOF
417 fi
418
419 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
420 AC_TRY_COMPILE(dnl
421 [#define __need_size_t
422 #define __need_wchar_t
423 #include <stddef.h>
424 #define __need_NULL
425 #include <stddef.h>], [size_t size; wchar_t wchar;
426 #ifdef offsetof
427 #error stddef.h ignored __need_*
428 #endif
429 if (&size == NULL || &wchar == NULL) abort ();],
430                libc_cv_friendly_stddef=yes,
431                libc_cv_friendly_stddef=no)])
432 if test $libc_cv_friendly_stddef = yes; then
433   config_vars="$config_vars
434 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
435 fi
436
437 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
438                libc_cv_need_minus_P, [dnl
439 cat > conftest.S <<EOF
440 #include "confdefs.h"
441 /* Nothing whatsoever.  */
442 EOF
443 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
444   libc_cv_need_minus_P=no
445 else
446   libc_cv_need_minus_P=yes
447 fi
448 rm -f conftest*])
449 if test $libc_cv_need_minus_P = yes; then
450   config_vars="$config_vars
451 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
452 fi
453
454 AC_CACHE_CHECK(for assembler global-symbol directive,
455                libc_cv_asm_global_directive, [dnl
456 libc_cv_asm_global_directive=UNKNOWN
457 for ac_globl in .globl .global; do
458   cat > conftest.s <<EOF
459 .text
460 ${ac_globl} foo
461 foo: .long 0
462 EOF
463   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
464     libc_cv_asm_global_directive=${ac_globl}
465   fi
466   rm -f conftest*
467   test $libc_cv_asm_global_directive != UNKNOWN && break
468 done])
469 if test $libc_cv_asm_global_directive = UNKNOWN; then
470   AC_MSG_ERROR(cannot determine asm global directive)
471 else
472   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
473 fi
474
475 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
476 cat > conftest.s <<EOF
477 .text
478 foo: .long 0
479 .set glibc_conftest_frobozz,foo
480 $libc_cv_asm_global_directive glibc_conftest_frobozz
481 EOF
482 # The alpha-dec-osf1 assembler gives only a warning for `.set'
483 # (but it doesn't work), so we must do a linking check to be sure.
484 cat > conftest1.c <<\EOF
485 extern int glibc_conftest_frobozz;
486 main () { printf ("%d\n", glibc_conftest_frobozz); }
487 EOF
488 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
489             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
490   libc_cv_asm_set_directive=yes
491 else
492   libc_cv_asm_set_directive=no
493 fi
494 rm -f conftest*])
495 if test $libc_cv_asm_set_directive = yes; then
496   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
497 fi
498
499 if test $elf = yes; then
500   AC_CACHE_CHECK(for .previous assembler directive,
501                  libc_cv_asm_previous_directive, [dnl
502   cat > conftest.s <<EOF
503 .section foo_section
504 .previous
505 EOF
506   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
507     libc_cv_asm_previous_directive=yes
508   else
509     libc_cv_asm_previous_directive=no
510   fi
511   rm -f conftest*])
512   if test $libc_cv_asm_previous_directive = yes; then
513     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
514   else
515     AC_CACHE_CHECK(for .popsection assembler directive,
516                    libc_cv_asm_popsection_directive, [dnl
517     cat > conftest.s <<EOF
518 .pushsection foo_section
519 .popsection
520 EOF
521     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
522       libc_cv_asm_popsection_directive=yes
523     else
524       libc_cv_asm_popsection_directive=no
525     fi
526     rm -f conftest*])
527     if test $libc_cv_asm_popsection_directive = yes; then
528       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
529     fi
530   fi
531 fi
532
533 if test $elf != yes; then
534   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
535                  [AC_TRY_COMPILE(, [asm (".section .init");
536                                     asm (".section .fini");
537                                     asm (".text");],
538                                  libc_cv_have_initfini=yes,
539                                  libc_cv_have_initfini=no)])
540   AC_SUBST(libc_cv_have_initfini)dnl
541   if test $libc_cv_have_initfini = yes; then
542     AC_DEFINE(HAVE_INITFINI)
543   fi
544 fi
545
546 if test $elf = yes; then
547   libc_cv_asm_underscores=no
548 else
549   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
550                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
551                               libc_cv_asm_underscores=yes,
552                               libc_cv_asm_underscores=no)])
553 fi
554 if test $libc_cv_asm_underscores = no; then
555   AC_DEFINE(NO_UNDERSCORES)
556 fi
557
558 if test $elf = yes; then
559   libc_cv_weak_symbols=yes
560   libc_cv_asm_weak_directive=yes
561   libc_cv_asm_weakext_directive=no
562 else
563   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
564                  [dnl
565 cat > conftest.s <<EOF
566 .text
567 ${libc_cv_asm_global_directive} foo
568 foo: .long 0
569 .weak foo
570 .weak bar; bar = foo
571 EOF
572   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
573     libc_cv_asm_weak_directive=yes
574   else
575     libc_cv_asm_weak_directive=no
576   fi
577   rm -f conftest*])
578
579 if test $libc_cv_asm_weak_directive = no; then
580   AC_CACHE_CHECK(for assembler .weakext directive,
581                  libc_cv_asm_weakext_directive,
582                  [dnl
583 cat > conftest.s <<EOF
584 .text
585 ${libc_cv_asm_global_directive} foo
586 foo: .long 0
587 .weakext foo
588 .weakext foo, bar
589 EOF
590   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
591     libc_cv_asm_weakext_directive=yes
592   else
593     libc_cv_asm_weakext_directive=no
594   fi
595   rm -f conftest*])
596
597   fi # no .weak
598 fi # not ELF
599
600 if test $libc_cv_asm_weak_directive = yes; then
601   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
602 elif test $libc_cv_asm_weakext_directive = yes; then
603   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
604 fi
605
606 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
607 cat > conftest.c <<\EOF
608 _start () {}
609 int __eh_pc;
610 __throw () {}
611 EOF
612 dnl No \ in command here because it ends up inside ''.
613 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
614                             -nostdlib -nostartfiles -Wl,--no-whole-archive
615                             -o conftest conftest.c]); then
616   libc_cv_ld_no_whole_archive=yes
617 else
618   libc_cv_ld_no_whole_archive=no
619 fi
620 rm -f conftest*])
621 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
622
623 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
624 cat > conftest.c <<\EOF
625 _start () {}
626 int __eh_pc;
627 __throw () {}
628 EOF
629 dnl No \ in command here because it ends up inside ''.
630 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
631                             -nostdlib -nostartfiles -fno-exceptions
632                             -o conftest conftest.c]); then
633   libc_cv_gcc_no_exceptions=yes
634 else
635   libc_cv_gcc_no_exceptions=no
636 fi
637 rm -f conftest*])
638 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
639
640 ### End of automated tests.
641 ### Now run sysdeps configure fragments.
642
643 # sysdeps configure fragments may set these with files to be linked below.
644 libc_link_dests=
645 libc_link_sources=
646
647 # Iterate over all the sysdep directories we will use, running their
648 # configure fragments, and looking for a uname implementation.
649 uname=
650 for dir in $sysnames; do
651   case $dir in
652     /*) dest=$dir ;;
653     *)  dest=$srcdir/$dir ;;
654   esac
655   if test -r $dest/configure; then
656     AC_MSG_RESULT(running configure fragment for $dest)
657     . $dest/configure
658   fi
659 [
660   if test -z "$uname"; then
661     if test -r $sysdep_dir/$dir/uname.c ||
662        test -r $sysdep_dir/$dir/uname.S ||
663        { test -r $sysdep_dir/$dir/syscalls.list &&
664          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
665       uname=$dir
666     fi
667   fi
668 ]dnl
669 done
670
671 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
672
673 # If we will use the generic uname implementation, we must figure out what
674 # it will say by examining the system, and write the results in config-name.h.
675 if test "$uname" = generic; then
676
677 changequote(,)dnl
678   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
679 changequote([,])dnl
680   if test $uname_sysname != $config_os; then
681     config_release=`echo $config_os | sed s/$uname_sysname//`
682   fi
683 dnl
684 AC_DEFUN(LIBC_KERNEL_ID, [dnl
685     if test -r /vmunix; then
686       kernel_id=`strings /vmunix | grep UNIX`
687     elif test -r /dynix; then
688       kernel_id=`strings /dynix | grep DYNIX`
689     else
690       kernel_id=
691     fi
692 ])dnl
693
694   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
695 AC_REQUIRE([LIBC_KERNEL_ID])dnl
696 changequote(,)dnl
697   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
698 changequote([,])dnl
699   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
700          != x$config_release; then
701     # The configuration release is a substring of the kernel release.
702     libc_cv_uname_release=$kernel_release
703   elif test x$config_release != x; then
704     libc_cv_uname_release=$config_release
705   elif test x$kernel_release != x; then
706     libc_cv_uname_release=$kernel_release
707   else
708     libc_cv_uname_release=unknown
709   fi])
710   uname_release="$libc_cv_uname_release"
711
712   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
713 AC_REQUIRE([LIBC_KERNEL_ID])dnl
714 changequote(,)dnl
715   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
716 changequote([,])dnl
717   if test -n "$kernel_version"; then
718     libc_cv_uname_version="$kernel_version"
719   else
720     libc_cv_uname_version=unknown
721   fi])
722   uname_version="$libc_cv_uname_version"
723
724 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
725   config_uname=config-name.h:config-name.in
726 else
727   # For non-generic uname, we don't need to create config-name.h at all.
728   config_uname=
729 fi
730
731 AC_MSG_CHECKING(stdio selection)
732 AC_SUBST(stdio)
733 case $stdio in
734 libio) AC_DEFINE(USE_IN_LIBIO) ;;
735 default) stdio=stdio ;;
736 esac
737 AC_MSG_RESULT($stdio)
738
739 AC_MSG_CHECKING(malloc selection)
740 AC_SUBST(malloc)
741 case $malloc in
742 new-malloc) USE_NEW_MALLOC=-DUSE_NEW_MALLOC ;;
743 default) malloc=malloc ;;
744 esac
745 AC_SUBST(USE_NEW_MALLOC)
746 AC_MSG_RESULT($malloc)
747
748 AC_SUBST(libc_cv_slibdir)
749 AC_SUBST(libc_cv_sysconfdir)
750 AC_SUBST(libc_cv_rootsbindir)
751
752 AC_SUBST(has_ldconfig)
753
754 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
755 if test $gnu_ld = yes; then
756   AC_DEFINE(HAVE_GNU_LD)
757 fi
758 if test $gnu_as = yes; then
759   AC_DEFINE(HAVE_GNU_AS)
760 fi
761 if test $elf = yes; then
762   AC_DEFINE(HAVE_ELF)
763 fi
764
765 AC_SUBST(shared)
766 if test $shared = default; then
767   if test $gnu_ld = yes; then
768     shared=$elf
769   else
770     # For now we do not assume shared libs are available.  In future more
771     # tests might become available.
772     shared=no
773   fi
774 fi
775 AC_SUBST(profile)
776 AC_SUBST(omitfp)
777
778 AC_SUBST(DEFINES)
779
780 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
781   config_makefile=
782 else
783   config_makefile=Makefile
784 fi
785
786 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
787 AC_SUBST(VERSION)
788
789 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
790           [echo '$config_vars' >> config.make])