Check for a working makeinfo (3.11 or better).
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45
46 AC_ARG_ENABLE(libio, dnl
47 [  --enable-libio          build in GNU libio instead of GNU stdio],
48               [if test $enableval = yes; then
49                  stdio=libio
50                else
51                  stdio=stdio
52                fi],
53               stdio=default)
54
55 AC_ARG_ENABLE(sanity-checks, dnl
56 [  --disable-sanity-checks really do not use threads (should not be used
57                           except in special situations) [default=yes]],
58               enable_sanity=$enableval, enable_sanity=yes)
59
60 dnl Arguments to enable or disable building the static, shared, profiled,
61 dnl and -fomit-frame-pointer libraries.
62 AC_ARG_ENABLE(static, dnl
63 [  --enable-static         build static library [default=yes]],
64               static=$enableval, static=yes)
65 AC_ARG_ENABLE(shared, dnl
66 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
67               shared=$enableval, shared=default)
68 AC_ARG_ENABLE(profile, dnl
69 [  --enable-profile        build profiled library [default=yes]],
70               profile=$enableval, profile=yes)
71 AC_ARG_ENABLE(omitfp, dnl
72 [  --enable-omitfp         build undebuggable optimized library [default=no]],
73               omitfp=$enableval, omitfp=no)
74 AC_ARG_ENABLE(bounded, dnl
75 [  --enable-bounded        build with runtime bounds checking [default=no]],
76               bounded=$enableval, bounded=no)
77 AC_ARG_ENABLE(versioning, dnl
78 [  --disable-versioning    do not include versioning information in the
79                           library objects [default=yes if supported]],
80              enable_versioning=$enableval, enable_versioning=yes)
81
82 dnl Generic infrastructure for drop-in additions to libc.
83 AC_ARG_ENABLE(add-ons, dnl
84 [  --enable-add-ons=DIR1,DIR2... configure and build named extra directories],
85               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
86               [add_ons=])
87 AC_CONFIG_SUBDIRS($add_ons)
88 add_ons_pfx=
89 if test x"$add_ons" != x; then
90   for f in $add_ons; do
91     # Test whether such a subdir really exists.
92     if test -d $srcdir/$f; then
93       add_ons_pfx="$add_ons_pfx $f/"
94     else
95       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
96     fi
97   done
98 fi
99
100 dnl On some platforms we cannot use dynamic loading.  We must provide
101 dnl static NSS modules.
102 AC_ARG_ENABLE(static-nss, dnl
103 [  --enable-static-nss     build static NSS modules [default=no]],
104               static_nss=$enableval, static_nss=no)
105 if test x"$static_nss" = xyes; then
106   AC_DEFINE(DO_STATIC_NSS)
107 fi
108
109 AC_CANONICAL_HOST
110
111 # The way shlib-versions is used to generate soversions.mk uses a
112 # fairly simplistic model for name recognition that can't distinguish
113 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
114 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
115 # tell.  This doesn't get used much beyond that, so it's fairly safe.
116 case "$host_os" in
117 linux*)
118   ;;
119 gnu*)
120   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
121   ;;
122 esac
123
124 ###
125 ### I put this here to prevent those annoying emails from people who cannot
126 ### read and try to compile glibc on unsupported platforms.  --drepper
127 ###
128 ### By using the undocumented --enable-hacker-mode option for configure
129 ### one can skip this test to make the configuration not fail for unsupported
130 ### platforms.
131 ###
132 if test -z "$enable_hacker_mode"; then
133   case "$host_os" in
134   linux* | gnu*)
135     ;;
136   *)
137     echo "*** The GNU C library is currently not available for this platform."
138     echo "*** So far nobody cared to port it and if there is no volunteer it"
139     echo "*** might never happen.  So, if you have interest to see glibc on"
140     echo "*** this platform visit"
141     echo "***   http://www.gnu.ai.mit.edu/software/libc/porting.html"
142     echo "*** and join the group of porters"
143     exit 1
144     ;;
145   esac
146 fi
147
148 # We keep the original values in `$config_*' and never modify them, so we
149 # can write them unchanged into config.make.  Everything else uses
150 # $machine, $vendor, and $os, and changes them whenever convenient.
151 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
152
153 # Some configurations imply other options.
154 case "$host_os" in
155 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
156   # These systems always use GNU tools.
157   gnu_ld=yes gnu_as=yes ;;
158 esac
159 case "$host_os" in
160 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
161 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
162   ;;
163 gnu* | linux* | sysv4* | solaris2*)
164   # These systems (almost) always use the ELF format.
165   elf=yes
166   ;;
167 esac
168
169 machine=$config_machine
170 vendor=$config_vendor
171 os=$config_os
172
173 dnl We need to use [ and ] for other purposes for a while now.
174 changequote(,)dnl
175 # Expand the configuration machine name into a subdirectory by architecture
176 # type and particular chip.
177 case "$machine" in
178 a29k | am29000) base_machine=a29k machine=a29k ;;
179 alpha*)         base_machine=alpha machine=alpha/$machine ;;
180 arm*)           base_machine=arm machine=arm/$machine ;;
181 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
182 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
183 hppa*)          base_machine=hppa machine=hppa/$machine ;;
184 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
185 m680?0)         base_machine=m68k machine=m68k/$machine ;;
186 m68k)           base_machine=m68k machine=m68k/m68020 ;;
187 m88???)         base_machine=m88k machine=m88k/$machine ;;
188 m88k)           base_machine=m88k machine=m88k/m88100 ;;
189 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
190 mips*)          base_machine=mips machine=mips/$machine ;;
191 sparc | sparcv[67])
192                 base_machine=sparc machine=sparc/sparc32 ;;
193 sparcv8 | supersparc | hypersparc)
194                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
195 sparc64 | ultrasparc)
196                 base_machine=sparc machine=sparc/sparc64 ;;
197 esac
198 changequote([,])dnl
199 AC_SUBST(base_machine)
200
201 if test "$base_machine" = "i386"; then
202   AC_DEFINE(USE_REGPARMS)
203 fi
204
205 # Compute the list of sysdep directories for this configuration.
206 # This can take a while to compute.
207 sysdep_dir=$srcdir/sysdeps
208 AC_MSG_CHECKING(sysdep dirs)
209 dnl We need to use [ and ] for other purposes for a while now.
210 changequote(,)dnl
211 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
212 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
213
214 case "$os" in
215 gnu*)
216   base_os=mach/hurd ;;
217 netbsd* | 386bsd* | freebsd* | bsdi*)
218   base_os=unix/bsd/bsd4.4 ;;
219 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
220   base_os=unix/bsd ;;
221 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
222   base_os=unix/sysv ;;
223 solaris[2-9]*)
224   base_os=unix/sysv/sysv4 ;;
225 none)
226   base_os=standalone ;;
227 *)
228   base_os='' ;;
229 esac
230
231 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
232 tail=$os
233 ostry=$os
234 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
235   ostry="$ostry /$o"
236   tail=$o
237 done
238 o=`echo $tail | sed 's/[0-9]*$//'`
239 if test $o != $tail; then
240   ostry="$ostry /$o"
241 fi
242 # For linux-gnu, try linux-gnu, then linux.
243 o=`echo $tail | sed 's/-.*$//'`
244 if test $o != $tail; then
245   ostry="$ostry /$o"
246 fi
247
248 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
249 base=
250 tail=$base_os
251 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
252   set $b
253   base="$base /$1"
254   tail="$2"
255 done
256
257 # For sparc/sparc9, try sparc/sparc9 and then sparc.
258 mach=
259 tail=$machine
260 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
261   set $m
262   # Prepend the machine's FPU directory unless --without-fp.
263   if test "$with_fp" = yes; then
264     mach="$mach /$1/fpu"
265   fi
266   mach="$mach /$1"
267   tail="$2"
268 done
269
270 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
271 changequote([,])dnl
272
273 # Find what sysdep directories exist.
274 sysnames=
275 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
276 for d in $add_ons_pfx ''; do
277   for b in $base ''; do
278     for m0 in $mach ''; do
279       for v in /$vendor ''; do
280         for o in /$ostry ''; do
281           for m in $mach ''; do
282             if test "$m0$b$v$o$m"; then
283               try="${d}sysdeps$m0$b$v$o$m"
284               test -n "$enable_debug_configure" &&
285               echo "$0 [DEBUG]: try $try" >&2
286               case $try in
287                 /*) dest=$try ;;
288                 *)  dest=$srcdir/$try ;;
289               esac
290               if test -d $dest; then
291                 sysnames="$sysnames $try"
292                 { test -n "$o" || test -n "$b"; } && os_used=t
293                 { test -n "$m" || test -n "$m0"; } && machine_used=t
294               fi
295             fi
296           done
297         done
298       done
299     done
300   done
301 done
302 IFS="$ac_save_ifs"
303
304 if test -z "$os_used" && test "$os" != none; then
305   AC_MSG_ERROR(Operating system $os is not supported.)
306 fi
307 if test -z "$machine_used" && test "$machine" != none; then
308   AC_MSG_ERROR(The $machine is not supported.)
309 fi
310
311 # We have now validated the configuration.
312
313
314 # If using ELF, look for an `elf' subdirectory of each machine directory.
315 # We prepend these rather than inserting them whereever the machine appears
316 # because things specified by the machine's ELF ABI should override
317 # OS-specific things, and should always be the same for any OS on the
318 # machine (otherwise what's the point of an ABI?).
319 if test "$elf" = yes; then
320   elf_dirs=
321   for d in $add_ons_pfx ''; do
322     case $d in
323       /*) xsrcdir= ;;
324       *)  xsrcdir=$srcdir/ ;;
325     esac
326     for m in $mach; do
327       if test -d $xsrcdir${d}sysdeps$m/elf; then
328         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
329       fi
330     done
331   done
332   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
333 fi
334
335
336 # Expand the list of system names into a full list of directories
337 # from each element's parent name and Implies file (if present).
338 set $sysnames
339 names=
340 while test $# -gt 0; do
341   name=$1
342   shift
343
344   case " $names " in *" $name "*)
345     # Already in the list.
346     continue
347   esac
348
349   # Report each name as we discover it, so there is no long pause in output.
350   echo $ac_n "$name $ac_c" >&AC_FD_MSG
351
352   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
353
354   case $name in
355     /*) xsrcdir= ;;
356     *)  xsrcdir=$srcdir/ ;;
357   esac
358   test -n "$enable_debug_configure" &&
359   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
360
361   if test -f $xsrcdir$name/Implies; then
362     # Collect more names from the `Implies' file (removing comments).
363     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
364     implied=
365     for x in $implied_candidate; do
366       if test -d $xsrcdir$name_base/$x; then
367         implied="$implied $name_base/$x";
368       else
369         AC_MSG_WARN($name/Implies specifies nonexistent $x)
370       fi
371     done
372   else
373     implied=
374   fi
375
376   # Add NAME to the list of names.
377   names="$names $name"
378
379   # Find the parent of NAME, using the empty string if it has none.
380 changequote(,)dnl
381   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
382 changequote([,])dnl
383
384   # Add the names implied by NAME, and NAME's parent (if it has one), to
385   # the list of names to be processed (the argument list).  We prepend the
386   # implied names to the list and append the parent.  We want implied
387   # directories to come before further directories inferred from the
388   # configuration components; this ensures that for sysv4, unix/common
389   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
390   # after sysv4).
391   sysnames="`echo $implied $* $parent`"
392   test -n "$sysnames" && set $sysnames
393 done
394
395 # Add the default directories.
396 sysnames="$names sysdeps/generic"
397 AC_SUBST(sysnames)
398 # The other names were emitted during the scan.
399 AC_MSG_RESULT(sysdeps/generic)
400
401
402 ### Locate tools.
403
404 AC_PROG_INSTALL
405 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
406   # The makefiles need to use a different form to find it in $srcdir.
407   INSTALL='\$(..)./install-sh -c'
408 fi
409 AC_PROG_LN_S
410 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
411 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
412 if test "$MAKEINFO"; then
413 changequote(,)dnl Need [] for regexps.
414   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
415 changequote([,])dnl
416   then : # Makeinfo 3.11 or greater, works.
417   else
418     AC_MSG_WARN([
419 *** makeinfo is too old (need version 3.11 or better).
420 *** You should install the needed version and re-configure since otherwise
421 *** you won't get the info pages installed.])
422     MAKEINFO=
423   fi
424 fi
425
426 AC_PROG_CC_LOCAL
427 AC_CANONICAL_BUILD
428 if test $host != $build; then
429   AC_CHECK_PROGS(BUILD_CC, gcc cc)
430 fi
431 AC_SUBST(cross_compiling)
432 AC_PROG_CPP
433 LIBC_PROG_BINUTILS
434 AC_CHECK_TOOL(AR, ar)
435 AC_CHECK_TOOL(RANLIB, ranlib, :)
436
437 AC_PATH_PROG(BASH, bash, no)
438 if test "$BASH" != no &&
439    $BASH -c 'test "$BASH_VERSINFO" \
440              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
441   libc_cv_have_bash2=yes
442 else
443   libc_cv_have_bash2=no
444 fi
445 AC_SUBST(libc_cv_have_bash2)
446
447 dnl We need a ksh compatible shell for tzselect.
448 if test "$BASH" = no; then
449   AC_PATH_PROG(KSH, ksh, no)
450   if test "$KSH" = no; then
451     libc_cv_have_ksh=no
452   else
453     libc_cv_have_ksh=yes
454   fi
455 else
456   KSH="$BASH"
457   AC_SUBST(KSH)
458   libc_cv_have_ksh=yes
459 fi
460 AC_SUBST(libc_cv_have_ksh)
461
462 AC_PATH_PROGS(PERL, perl, no)
463 AC_SUBST(PERL)
464
465 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
466 echo '#include <stddef.h>
467 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
468 if eval "$ac_cpp conftest.c 2>/dev/null" \
469 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
470   libc_cv_signed_size_t=no
471 else
472   libc_cv_signed_size_t=yes
473 fi
474 rm -f conftest*])
475 if test $libc_cv_signed_size_t = yes; then
476   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
477   cat >> confdefs.h <<\EOF
478 #undef __SIZE_TYPE__
479 #define __SIZE_TYPE__ unsigned
480 EOF
481 fi
482
483 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
484 AC_TRY_COMPILE(dnl
485 [#define __need_size_t
486 #define __need_wchar_t
487 #include <stddef.h>
488 #define __need_NULL
489 #include <stddef.h>], [size_t size; wchar_t wchar;
490 #ifdef offsetof
491 #error stddef.h ignored __need_*
492 #endif
493 if (&size == NULL || &wchar == NULL) abort ();],
494                libc_cv_friendly_stddef=yes,
495                libc_cv_friendly_stddef=no)])
496 if test $libc_cv_friendly_stddef = yes; then
497   config_vars="$config_vars
498 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
499 fi
500
501 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
502                libc_cv_need_minus_P, [dnl
503 cat > conftest.S <<EOF
504 #include "confdefs.h"
505 /* Nothing whatsoever.  */
506 EOF
507 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
508   libc_cv_need_minus_P=no
509 else
510   libc_cv_need_minus_P=yes
511 fi
512 rm -f conftest*])
513 if test $libc_cv_need_minus_P = yes; then
514   config_vars="$config_vars
515 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
516 fi
517
518 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
519 # be told to read stdin.  This causes the compiler to hang when fed an
520 # .s file.
521 if test $ac_cv_prog_gcc = yes; then
522  case `${CC-cc} -v 2>&1` in
523   *2.7*)
524   # We must check this even if -pipe is not given here, because the user
525   # might do `make CFLAGS=-pipe'.
526   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
527    cp /dev/null conftest.s
528    cat >conftest1.s <<EOF
529 .nosuchdirective
530 EOF
531    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
532     libc_cv_gcc_pipe_bug=no
533    else
534     libc_cv_gcc_pipe_bug=yes
535    fi
536    rm -f conftest*])
537   if test $libc_cv_gcc_pipe_bug = yes; then
538    makeCC="${CC-cc} -B\$(common-objpfx)"
539    makeCFLAGS=$CFLAGS
540    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
541   fi;;
542  *) libc_cv_gcc_pipe_bug=no;;
543  esac
544 else
545  libc_cv_gcc_pipe_bug=no
546 fi
547
548 AC_CACHE_CHECK(for assembler global-symbol directive,
549                libc_cv_asm_global_directive, [dnl
550 libc_cv_asm_global_directive=UNKNOWN
551 for ac_globl in .globl .global; do
552   cat > conftest.s <<EOF
553 .text
554 ${ac_globl} foo
555 foo:
556 EOF
557   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
558     libc_cv_asm_global_directive=${ac_globl}
559   fi
560   rm -f conftest*
561   test $libc_cv_asm_global_directive != UNKNOWN && break
562 done])
563 if test $libc_cv_asm_global_directive = UNKNOWN; then
564   AC_MSG_ERROR(cannot determine asm global directive)
565 else
566   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
567 fi
568
569 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
570 cat > conftest.s <<EOF
571 .text
572 foo:
573 .set glibc_conftest_frobozz,foo
574 $libc_cv_asm_global_directive glibc_conftest_frobozz
575 EOF
576 # The alpha-dec-osf1 assembler gives only a warning for `.set'
577 # (but it doesn't work), so we must do a linking check to be sure.
578 cat > conftest1.c <<\EOF
579 extern int glibc_conftest_frobozz;
580 main () { printf ("%d\n", glibc_conftest_frobozz); }
581 EOF
582 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
583             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
584   libc_cv_asm_set_directive=yes
585 else
586   libc_cv_asm_set_directive=no
587 fi
588 rm -f conftest*])
589 if test $libc_cv_asm_set_directive = yes; then
590   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
591 fi
592
593 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
594 [cat > conftest.s <<EOF
595 .text
596 _sym:
597 .symver _sym,sym@VERS
598 EOF
599 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
600   libc_cv_asm_symver_directive=yes
601 else
602   libc_cv_asm_symver_directive=no
603 fi
604 rm -f conftest*])
605 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
606 if test $libc_cv_asm_symver_directive = yes; then
607   cat > conftest.s <<EOF
608 .text
609 _sym:
610 .symver _sym,sym@VERS
611 EOF
612   cat > conftest.map <<EOF
613 VERS_1 {
614         global: sym;
615 };
616
617 VERS_2 {
618         global: sym;
619 } VERS_1;
620 EOF
621   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
622     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
623                                         -nostartfiles -nostdlib
624                                         -Wl,--version-script,conftest.map
625                        1>&AC_FD_CC]);
626     then
627       libc_cv_ld_version_script_option=yes
628     else
629       libc_cv_ld_version_script_option=no
630     fi
631   else
632     libc_cv_ld_version_script_option=no
633   fi
634 else
635   libc_cv_ld_version_script_option=no
636 fi
637 rm -f conftest*])
638 if test $libc_cv_asm_symver_directive = yes &&
639    test $libc_cv_ld_version_script_option = yes &&
640    test $enable_versioning = yes; then
641   VERSIONING=yes
642   AC_DEFINE(DO_VERSIONING)
643 else
644   VERSIONING=no
645 fi
646 AC_SUBST(VERSIONING)
647
648 if test $VERSIONING = no; then
649   echo "\
650 *** WARNING: You should not compile GNU libc without versioning. Not using
651 *** versioning will introduce incompatibilities so that old binaries
652 *** will not run anymore.
653 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
654 fi
655 if test $elf = yes; then
656   AC_CACHE_CHECK(for .previous assembler directive,
657                  libc_cv_asm_previous_directive, [dnl
658   cat > conftest.s <<EOF
659 .section foo_section
660 .previous
661 EOF
662   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
663     libc_cv_asm_previous_directive=yes
664   else
665     libc_cv_asm_previous_directive=no
666   fi
667   rm -f conftest*])
668   if test $libc_cv_asm_previous_directive = yes; then
669     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
670   else
671     AC_CACHE_CHECK(for .popsection assembler directive,
672                    libc_cv_asm_popsection_directive, [dnl
673     cat > conftest.s <<EOF
674 .pushsection foo_section
675 .popsection
676 EOF
677     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
678       libc_cv_asm_popsection_directive=yes
679     else
680       libc_cv_asm_popsection_directive=no
681     fi
682     rm -f conftest*])
683     if test $libc_cv_asm_popsection_directive = yes; then
684       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
685     fi
686   fi
687 fi
688
689 if test $elf != yes; then
690   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
691                  [AC_TRY_COMPILE(, [asm (".section .init");
692                                     asm (".section .fini");
693                                     asm (".text");],
694                                  libc_cv_have_initfini=yes,
695                                  libc_cv_have_initfini=no)])
696   AC_SUBST(libc_cv_have_initfini)dnl
697   if test $libc_cv_have_initfini = yes; then
698     AC_DEFINE(HAVE_INITFINI)
699   fi
700 fi
701
702 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
703 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
704 [cat > conftest.$ac_ext <<EOF
705 dnl This sometimes fails to find confdefs.h, for some reason.
706 dnl [#]line __oline__ "[$]0"
707 [#]line __oline__ "configure"
708 #include "confdefs.h"
709 void underscore_test(void) {
710 return; }
711 EOF
712 if AC_TRY_EVAL(ac_compile); then
713   if grep _underscore_test conftest* >/dev/null; then
714     ifelse([$1], , :, [rm -f conftest*
715     $1])
716   else
717     ifelse([$2], , , [rm -f conftest*
718     $2])
719   fi
720 else
721   echo "configure: failed program was:" >&AC_FD_CC
722   cat conftest.$ac_ext >&AC_FD_CC
723   ifelse([$2], , , [rm -f conftest*
724   $2])
725 fi
726 rm -f conftest*])
727
728 if test $elf = yes; then
729   libc_cv_asm_underscores=no
730 else
731   if test $ac_cv_prog_cc_works = yes; then
732     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
733                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
734                                 libc_cv_asm_underscores=yes,
735                                 libc_cv_asm_underscores=no)])
736   else
737     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
738                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
739                                             libc_cv_asm_underscores=no)])
740   fi
741 fi
742 if test $libc_cv_asm_underscores = no; then
743   AC_DEFINE(NO_UNDERSCORES)
744 fi
745
746 if test $elf = yes; then
747   libc_cv_weak_symbols=yes
748   libc_cv_asm_weak_directive=yes
749   libc_cv_asm_weakext_directive=no
750 else
751   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
752                  [dnl
753 cat > conftest.s <<EOF
754 .text
755 ${libc_cv_asm_global_directive} foo
756 foo:
757 .weak foo
758 .weak bar; bar = foo
759 EOF
760   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
761     libc_cv_asm_weak_directive=yes
762   else
763     libc_cv_asm_weak_directive=no
764   fi
765   rm -f conftest*])
766
767 if test $libc_cv_asm_weak_directive = no; then
768   AC_CACHE_CHECK(for assembler .weakext directive,
769                  libc_cv_asm_weakext_directive,
770                  [dnl
771 cat > conftest.s <<EOF
772 .text
773 ${libc_cv_asm_global_directive} foo
774 foo:
775 .weakext foo
776 .weakext foo, bar
777 EOF
778   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
779     libc_cv_asm_weakext_directive=yes
780   else
781     libc_cv_asm_weakext_directive=no
782   fi
783   rm -f conftest*])
784
785   fi # no .weak
786 fi # not ELF
787
788 if test $libc_cv_asm_weak_directive = yes; then
789   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
790 elif test $libc_cv_asm_weakext_directive = yes; then
791   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
792 fi
793
794 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
795 cat > conftest.c <<\EOF
796 _start () {}
797 int __eh_pc;
798 __throw () {}
799 EOF
800 dnl No \ in command here because it ends up inside ''.
801 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
802                             -nostdlib -nostartfiles -Wl,--no-whole-archive
803                             -o conftest conftest.c 1>&AC_FD_CC]); then
804   libc_cv_ld_no_whole_archive=yes
805 else
806   libc_cv_ld_no_whole_archive=no
807 fi
808 rm -f conftest*])
809 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
810
811 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
812 cat > conftest.c <<\EOF
813 _start () {}
814 int __eh_pc;
815 __throw () {}
816 EOF
817 dnl No \ in command here because it ends up inside ''.
818 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
819                             -nostdlib -nostartfiles -fno-exceptions
820                             -o conftest conftest.c 1>&AC_FD_CC]); then
821   libc_cv_gcc_no_exceptions=yes
822 else
823   libc_cv_gcc_no_exceptions=no
824 fi
825 rm -f conftest*])
826 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
827
828 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
829 [cat > conftest.c <<EOF
830 #line __oline__ "configure"
831 static char __EH_FRAME_BEGIN__[];
832 _start ()
833 {
834   __register_frame (__EH_FRAME_BEGIN__);
835   __deregister_frame (__EH_FRAME_BEGIN__);
836 }
837 int __eh_pc;
838 __throw () {}
839 /* FIXME: this is fragile.  */
840 malloc () {}
841 strcmp () {}
842 strlen () {}
843 memcpy () {}
844 memset () {}
845 free () {}
846 abort () {}
847 __bzero () {}
848 EOF
849 dnl No \ in command here because it ends up inside ''.
850 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
851                             -nostdlib -nostartfiles
852                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
853   libc_cv_gcc_dwarf2_unwind_info=yes
854 else
855   libc_cv_gcc_dwarf2_unwind_info=no
856 fi
857 rm -f conftest*])
858 if test $libc_cv_gcc_dwarf2_unwind_info = yes; then
859   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
860 fi
861
862 ### End of automated tests.
863 ### Now run sysdeps configure fragments.
864
865 # sysdeps configure fragments may set these with files to be linked below.
866 libc_link_dests=
867 libc_link_sources=
868
869 # Iterate over all the sysdep directories we will use, running their
870 # configure fragments, and looking for a uname implementation.
871 uname=
872 for dir in $sysnames; do
873   case $dir in
874     /*) dest=$dir ;;
875     *)  dest=$srcdir/$dir ;;
876   esac
877   if test -r $dest/configure; then
878     AC_MSG_RESULT(running configure fragment for $dest)
879     . $dest/configure
880   fi
881 [
882   if test -z "$uname"; then
883     if test -r $dest/uname.c ||
884        test -r $dest/uname.S ||
885        { test -r $dest/syscalls.list &&
886          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
887       uname=$dir
888     fi
889   fi
890 ]dnl
891 done
892
893 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
894
895 # If we will use the generic uname implementation, we must figure out what
896 # it will say by examining the system, and write the results in config-name.h.
897 if test "$uname" = "sysdeps/generic"; then
898
899 changequote(,)dnl
900   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
901 changequote([,])dnl
902   if test $uname_sysname != $config_os; then
903     config_release=`echo $config_os | sed s/$uname_sysname//`
904   fi
905 dnl
906 AC_DEFUN(LIBC_KERNEL_ID, [dnl
907     if test -r /vmunix; then
908       kernel_id=`strings /vmunix | grep UNIX`
909     elif test -r /dynix; then
910       kernel_id=`strings /dynix | grep DYNIX`
911     else
912       kernel_id=
913     fi
914 ])dnl
915
916   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
917 AC_REQUIRE([LIBC_KERNEL_ID])dnl
918 changequote(,)dnl
919   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
920 changequote([,])dnl
921   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
922          != x$config_release; then
923     # The configuration release is a substring of the kernel release.
924     libc_cv_uname_release=$kernel_release
925   elif test x$config_release != x; then
926     libc_cv_uname_release=$config_release
927   elif test x$kernel_release != x; then
928     libc_cv_uname_release=$kernel_release
929   else
930     libc_cv_uname_release=unknown
931   fi])
932   uname_release="$libc_cv_uname_release"
933
934   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
935 AC_REQUIRE([LIBC_KERNEL_ID])dnl
936 changequote(,)dnl
937   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
938 changequote([,])dnl
939   if test -n "$kernel_version"; then
940     libc_cv_uname_version="$kernel_version"
941   else
942     libc_cv_uname_version=unknown
943   fi])
944   uname_version="$libc_cv_uname_version"
945
946 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
947   config_uname=config-name.h:config-name.in
948 else
949   # For non-generic uname, we don't need to create config-name.h at all.
950   config_uname=
951 fi
952
953 AC_MSG_CHECKING(stdio selection)
954 AC_SUBST(stdio)
955 case $stdio in
956 libio) AC_DEFINE(USE_IN_LIBIO) ;;
957 default) stdio=stdio ;;
958 esac
959 AC_MSG_RESULT($stdio)
960
961 AC_MSG_CHECKING(ldap selection)
962 AC_SUBST(LDAP)
963 case $add_ons in
964 *ldap*)
965    ldap=yes
966    LDAP=ldap ;;
967 *) ldap=no
968    LDAP= ;;
969 esac
970 AC_MSG_RESULT($ldap)
971
972 AC_SUBST(libc_cv_slibdir)
973 AC_SUBST(libc_cv_sysconfdir)
974 AC_SUBST(libc_cv_rootsbindir)
975
976 AC_SUBST(has_ldconfig)
977
978 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
979 if test $gnu_ld = yes; then
980   AC_DEFINE(HAVE_GNU_LD)
981 fi
982 if test $gnu_as = yes; then
983   AC_DEFINE(HAVE_GNU_AS)
984 fi
985 if test $elf = yes; then
986   AC_DEFINE(HAVE_ELF)
987 fi
988
989 AC_SUBST(static)
990 AC_SUBST(shared)
991 if test $shared = default; then
992   if test $gnu_ld = yes; then
993     shared=$elf
994   else
995     # For now we do not assume shared libs are available.  In future more
996     # tests might become available.
997     shared=no
998   fi
999 fi
1000
1001 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1002 [pic_default=yes
1003 cat > conftest.c <<EOF
1004 #if defined(__PIC__) || defined(__pic__) || defined(PIC) || defined(pic)
1005 # error PIC is default.
1006 #endif
1007 EOF
1008 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1009   pic_default=no
1010 fi
1011 rm -f conftest.*])
1012 AC_SUBST(pic_default)
1013
1014 AC_SUBST(profile)
1015 AC_SUBST(omitfp)
1016 AC_SUBST(bounded)
1017 AC_SUBST(static_nss)
1018 AC_SUBST(nopic_initfini)
1019
1020 AC_SUBST(DEFINES)
1021
1022 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1023   config_makefile=
1024 else
1025   config_makefile=Makefile
1026 fi
1027
1028 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1029 AC_SUBST(VERSION)
1030
1031 if test $libc_cv_gcc_pipe_bug = yes; then
1032  realCC=$CC
1033  CC=$makeCC
1034  CFLAGS=$makeCFLAGS
1035 fi
1036 AC_OUTPUT_COMMANDS([
1037 if test "$realCC"; then
1038  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1039  mv specsT specs
1040 fi], [realCC=$realCC])
1041
1042 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1043           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])