(with_cvs): Test for pserver access.
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6 AC_CONFIG_AUX_DIR(scripts)
7
8 # This will get text that should go into config.make.
9 config_vars=
10
11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
12 AC_ARG_WITH(gmp, dnl
13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
14             [dnl
15 case "$with_gmp" in
16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
17 ''|no) ;;
18 *) config_vars="$config_vars
19 gmp-srcdir = $withval" ;;
20 esac
21 ])
22 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
23 AC_ARG_WITH(gd, dnl
24   --with-gd=DIR           find libgd include dir and library with prefix DIR,
25             [dnl
26 case "$with_gd" in
27 yes|''|no) ;;
28 *) libgd_include="-I$withval/include"
29    libgd_ldflags="-L$withval/lib" ;;
30 esac
31 ])
32 AC_ARG_WITH(gd-include, dnl
33   --with-gd-include=DIR   find libgd include files in DIR,
34             [dnl
35 case "$with_gd_include" in
36 ''|no) ;;
37 *) libgd_include="-I$withval" ;;
38 esac
39 ])
40 AC_ARG_WITH(gd-lib, dnl
41   --with-gd-lib=DIR       find libgd library files in DIR,
42             [dnl
43 case "$with_gd_lib" in
44 ''|no) ;;
45 *) libgd_ldflags="-L$withval" ;;
46 esac
47 ])
48
49 if test -n "$libgd_include"; then
50   config_vars="$config_vars
51 CFLAGS-memusagestat.c = $libgd_include"
52 fi
53 if test -n "$libgd_ldflags"; then
54   config_vars="$config_vars
55 libgd-LDFLAGS = $libgd_ldflags"
56 fi
57
58 dnl Arguments to specify presence of other packages/features.
59 AC_ARG_WITH(fp, dnl
60 [  --with-fp              if using floating-point hardware [default=yes]],
61             with_fp=$withval, with_fp=yes)
62 AC_ARG_WITH(binutils, dnl
63   --with-binutils=PATH    specify location of binutils (as and ld),
64             path_binutils=$withval, path_binutils='')
65 AC_ARG_WITH(elf, dnl
66   --with-elf              if using the ELF object format,
67             elf=$withval, elf=no)
68 AC_ARG_WITH(cvs, dnl
69 [  --without-cvs           if CVS should not be used],
70             with_cvs=$withval, with_cvs=yes)
71 if test "$with_cvs" = yes && test -d CVS && grep :pserver: CVS/Root > /dev/null
72 then
73   with_cvs=no
74 fi
75 AC_SUBST(with_cvs)
76
77 AC_ARG_WITH(headers, dnl
78 [  --with-headers=PATH     location of system headers to use
79                           [e.g. /usr/src/linux/include]
80                           [default=compiler default]],
81             sysheaders=$withval, sysheaders='')
82
83 AC_ARG_ENABLE(libio, dnl
84 [  --enable-libio          build in GNU libio instead of GNU stdio],
85               [if test $enableval = yes; then
86                  stdio=libio
87                else
88                  stdio=stdio
89                fi],
90               stdio=default)
91
92 AC_ARG_ENABLE(sanity-checks, dnl
93 [  --disable-sanity-checks really do not use threads (should not be used
94                           except in special situations) [default=yes]],
95               enable_sanity=$enableval, enable_sanity=yes)
96
97 dnl Arguments to enable or disable building the static, shared, profiled,
98 dnl and -fomit-frame-pointer libraries.
99 dnl I've disabled this for now since we cannot build glibc without static
100 dnl libraries built in the moment.
101 dnl AC_ARG_ENABLE(static, dnl
102 dnl [  --enable-static         build static library [default=yes]],
103 dnl           static=$enableval, static=yes)
104 static=yes
105 AC_ARG_ENABLE(shared, dnl
106 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
107               shared=$enableval, shared=default)
108 AC_ARG_ENABLE(profile, dnl
109 [  --enable-profile        build profiled library [default=yes]],
110               profile=$enableval, profile=yes)
111 AC_ARG_ENABLE(omitfp, dnl
112 [  --enable-omitfp         build undebuggable optimized library [default=no]],
113               omitfp=$enableval, omitfp=no)
114 AC_ARG_ENABLE(bounded, dnl
115 [  --enable-bounded        build with runtime bounds checking [default=no]],
116               bounded=$enableval, bounded=no)
117 AC_ARG_ENABLE(versioning, dnl
118 [  --disable-versioning    do not include versioning information in the
119                           library objects [default=yes if supported]],
120              enable_versioning=$enableval, enable_versioning=yes)
121
122 dnl Generic infrastructure for drop-in additions to libc.
123 AC_ARG_ENABLE(add-ons, dnl
124 [  --enable-add-ons[=DIR1,DIR2]...
125                           configure and build add-ons in DIR1,DIR2,...
126                           search for add-ons if no parameter given],
127   [case "$enableval" in
128     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
129          test "$add_ons" = "*" && add_ons= ;;
130     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
131    esac],
132   [add_ons=])
133
134 AC_CONFIG_SUBDIRS($add_ons)
135 add_ons_pfx=
136 if test x"$add_ons" != x; then
137   for f in $add_ons; do
138     # Test whether such a subdir really exists.
139     if test -d $srcdir/$f; then
140       add_ons_pfx="$add_ons_pfx $f/"
141     else
142       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
143     fi
144   done
145 fi
146
147 dnl On some platforms we cannot use dynamic loading.  We must provide
148 dnl static NSS modules.
149 AC_ARG_ENABLE(static-nss, dnl
150 [  --enable-static-nss     build static NSS modules [default=no]],
151               static_nss=$enableval, static_nss=no)
152 if test x"$static_nss" = xyes; then
153   AC_DEFINE(DO_STATIC_NSS)
154 fi
155
156 AC_ARG_ENABLE(force-install,
157 [  --disable-force-install don't force installation of files from this package,
158                           even if they are older than the installed files],
159               force_install=$enableval, force_install=yes)
160 AC_SUBST(force_install)
161
162 dnl On some platforms we allow dropping compatibility with all kernel
163 dnl versions.
164 AC_ARG_ENABLE(kernel,
165 [  --enable-kernel=VERSION compile for compatibility with kernel not older
166                            than VERSION],
167               minimum_kernel=$enableval)
168 dnl Prevent unreasonable values.
169 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
170   # Better nothing than this.
171   minimum_kernel=""
172 else
173   if test "$minimum_kernel" = current; then
174     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
175   fi
176 fi
177
178 AC_CANONICAL_HOST
179
180 # The way shlib-versions is used to generate soversions.mk uses a
181 # fairly simplistic model for name recognition that can't distinguish
182 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
183 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
184 # tell.  This doesn't get used much beyond that, so it's fairly safe.
185 case "$host_os" in
186 linux*)
187   ;;
188 gnu*)
189   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
190   ;;
191 esac
192
193 # We keep the original values in `$config_*' and never modify them, so we
194 # can write them unchanged into config.make.  Everything else uses
195 # $machine, $vendor, and $os, and changes them whenever convenient.
196 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
197
198 # Don't allow vendor == "unknown"
199 test "$config_vendor" = unknown && config_vendor=
200 config_os="`echo $config_os | sed 's/^unknown-//'`"
201
202 # Some configurations imply other options.
203 case "$host_os" in
204 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
205   # These systems always use GNU tools.
206   gnu_ld=yes gnu_as=yes ;;
207 esac
208 case "$host_os" in
209 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
210 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
211   ;;
212 gnu* | linux* | sysv4* | solaris2* | irix6*)
213   # These systems (almost) always use the ELF format.
214   elf=yes
215   ;;
216 esac
217
218 machine=$config_machine
219 vendor=$config_vendor
220 os=$config_os
221
222 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
223 # Unify this here.
224 if test "$machine" = rs6000; then
225   machine="powerpc"
226 fi
227
228 ###
229 ### I put this here to prevent those annoying emails from people who cannot
230 ### read and try to compile glibc on unsupported platforms.  --drepper
231 ###
232 ### By using the undocumented --enable-hacker-mode option for configure
233 ### one can skip this test to make the configuration not fail for unsupported
234 ### platforms.
235 ###
236 if test -z "$enable_hacker_mode"; then
237   case "$machine-$host_os" in
238   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
239     ;;
240   *)
241     echo "*** The GNU C library is currently not available for this platform."
242     echo "*** So far nobody cared to port it and if there is no volunteer it"
243     echo "*** might never happen.  So, if you have interest to see glibc on"
244     echo "*** this platform visit"
245     echo "***   http://www.gnu.org/software/libc/porting.html"
246     echo "*** and join the group of porters"
247     exit 1
248     ;;
249   esac
250 fi
251
252 dnl We need to use [ and ] for other purposes for a while now.
253 changequote(,)dnl
254 # Expand the configuration machine name into a subdirectory by architecture
255 # type and particular chip.
256 case "$machine" in
257 a29k | am29000) base_machine=a29k machine=a29k ;;
258 alpha*)         base_machine=alpha machine=alpha/$machine ;;
259 arm*)           base_machine=arm machine=arm/$machine ;;
260 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
261 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
262 hppa*64*)       base_machine=hppa machine=hppa/hppa64 ;;
263 hppa*)          base_machine=hppa machine=hppa/hppa1.1 ;;
264 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
265 ia64)           base_machine=ia64 machine=ia64 ;;
266 m680?0)         base_machine=m68k machine=m68k/$machine ;;
267 m68k)           base_machine=m68k machine=m68k/m68020 ;;
268 m88???)         base_machine=m88k machine=m88k/$machine ;;
269 m88k)           base_machine=m88k machine=m88k/m88100 ;;
270 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
271 mips*)          base_machine=mips
272                 case "`uname -m`" in
273                 IP22) machine=mips/mips3 ;;
274                 *)    machine=mips/$machine ;;
275                 esac ;;
276 sh3*)           base_machine=sh machine=sh/sh3 ;;
277 sh4*)           base_machine=sh machine=sh/sh4 ;;
278 sparc | sparcv[67])
279                 base_machine=sparc machine=sparc/sparc32 ;;
280 sparcv8 | supersparc | hypersparc)
281                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
282 sparcv8plus | sparcv8plusa | sparcv9)
283                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
284 sparc64 | ultrasparc)
285                 base_machine=sparc machine=sparc/sparc64 ;;
286 esac
287 changequote([,])dnl
288 AC_SUBST(base_machine)
289
290 if test "$base_machine" = "i386"; then
291   AC_DEFINE(USE_REGPARMS)
292 fi
293
294 # Compute the list of sysdep directories for this configuration.
295 # This can take a while to compute.
296 sysdep_dir=$srcdir/sysdeps
297 AC_MSG_CHECKING(sysdep dirs)
298 dnl We need to use [ and ] for other purposes for a while now.
299 changequote(,)dnl
300 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
301 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
302
303 case "$os" in
304 gnu*)
305   base_os=mach/hurd ;;
306 netbsd* | 386bsd* | freebsd* | bsdi*)
307   base_os=unix/bsd/bsd4.4 ;;
308 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
309   base_os=unix/bsd ;;
310 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
311   base_os=unix/sysv ;;
312 irix6*)
313   base_os=unix/sysv/irix6/$os ;;
314 solaris[2-9]*)
315   base_os=unix/sysv/sysv4 ;;
316 hpux*)
317   base_os=unix/sysv/hpux/$os ;;
318 aix4.3*)
319   base_os=unix/sysv/aix/aix4.3 ;;
320 none)
321   base_os=standalone ;;
322 *)
323   base_os='' ;;
324 esac
325
326 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
327 tail=$os
328 ostry=$os
329 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
330   ostry="$ostry /$o"
331   tail=$o
332 done
333 o=`echo $tail | sed 's/[0-9]*$//'`
334 if test $o != $tail; then
335   ostry="$ostry /$o"
336 fi
337 # For linux-gnu, try linux-gnu, then linux.
338 o=`echo $tail | sed 's/-.*$//'`
339 if test $o != $tail; then
340   ostry="$ostry /$o"
341 fi
342
343 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
344 base=
345 tail=$base_os
346 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
347   set $b
348   base="$base /$1"
349   tail="$2"
350 done
351
352 # For sparc/sparc32, try sparc/sparc32 and then sparc.
353 mach=
354 tail=$machine
355 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
356   set $m
357   # Prepend the machine's FPU directory unless --without-fp.
358   if test "$with_fp" = yes; then
359     mach="$mach /$1/fpu"
360   fi
361   mach="$mach /$1"
362   tail="$2"
363 done
364
365 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
366 changequote([,])dnl
367
368 # Find what sysdep directories exist.
369 sysnames=
370 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
371 for d in $add_ons_pfx ''; do
372   for b in $base ''; do
373     for m0 in $mach ''; do
374       for v in /$vendor ''; do
375         test "$v" = / && continue
376         for o in /$ostry ''; do
377           test "$o" = / && continue
378           for m in $mach ''; do
379             if test "$m0$b$v$o$m"; then
380               try="${d}sysdeps$m0$b$v$o$m"
381               test -n "$enable_debug_configure" &&
382               echo "$0 [DEBUG]: try $try" >&2
383               if test -d $srcdir/$try; then
384                 sysnames="$sysnames $try"
385                 { test -n "$o" || test -n "$b"; } && os_used=t
386                 { test -n "$m" || test -n "$m0"; } && machine_used=t
387               fi
388             fi
389           done
390         done
391       done
392     done
393   done
394 done
395 IFS="$ac_save_ifs"
396
397 if test -z "$os_used" && test "$os" != none; then
398   AC_MSG_ERROR(Operating system $os is not supported.)
399 fi
400 if test -z "$machine_used" && test "$machine" != none; then
401   AC_MSG_ERROR(The $machine is not supported.)
402 fi
403
404 # We have now validated the configuration.
405
406
407 # If using ELF, look for an `elf' subdirectory of each machine directory.
408 # We prepend these rather than inserting them whereever the machine appears
409 # because things specified by the machine's ELF ABI should override
410 # OS-specific things, and should always be the same for any OS on the
411 # machine (otherwise what's the point of an ABI?).
412 if test "$elf" = yes; then
413   elf_dirs=
414   for d in $add_ons_pfx ''; do
415     for m in $mach; do
416       if test -d $srcdir/${d}sysdeps$m/elf; then
417         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
418       fi
419     done
420   done
421   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
422 fi
423
424
425 # Expand the list of system names into a full list of directories
426 # from each element's parent name and Implies file (if present).
427 set $sysnames
428 names=
429 while test $# -gt 0; do
430   name=$1
431   shift
432
433   case " $names " in *" $name "*)
434     # Already in the list.
435     continue
436   esac
437
438   # Report each name as we discover it, so there is no long pause in output.
439   echo $ac_n "$name $ac_c" >&AC_FD_MSG
440
441   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
442
443   case $name in
444     /*) xsrcdir= ;;
445     *)  xsrcdir=$srcdir/ ;;
446   esac
447   test -n "$enable_debug_configure" &&
448   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
449
450   if test -f $xsrcdir$name/Implies; then
451     # Collect more names from the `Implies' file (removing comments).
452     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
453     implied=
454     for x in $implied_candidate; do
455       if test -d $xsrcdir$name_base/$x; then
456         implied="$implied $name_base/$x";
457       else
458         AC_MSG_WARN($name/Implies specifies nonexistent $x)
459       fi
460     done
461   else
462     implied=
463   fi
464
465   # Add NAME to the list of names.
466   names="$names $name"
467
468   # Find the parent of NAME, using the empty string if it has none.
469 changequote(,)dnl
470   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
471 changequote([,])dnl
472
473   # Add the names implied by NAME, and NAME's parent (if it has one), to
474   # the list of names to be processed (the argument list).  We prepend the
475   # implied names to the list and append the parent.  We want implied
476   # directories to come before further directories inferred from the
477   # configuration components; this ensures that for sysv4, unix/common
478   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
479   # after sysv4).
480   sysnames="`echo $implied $* $parent`"
481   test -n "$sysnames" && set $sysnames
482 done
483
484 # Add the default directories.
485 default_sysnames=sysdeps/generic
486 if test "$elf" = yes; then
487   default_sysnames="sysdeps/generic/elf $default_sysnames"
488 fi
489 sysnames="$names $default_sysnames"
490 AC_SUBST(sysnames)
491 # The other names were emitted during the scan.
492 AC_MSG_RESULT($default_sysnames)
493
494
495 ### Locate tools.
496
497 AC_PROG_INSTALL
498 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
499   # The makefiles need to use a different form to find it in $srcdir.
500   INSTALL='\$(..)./scripts/install-sh -c'
501 fi
502 AC_PROG_LN_S
503
504 # We need the physical current working directory.  We cannot use the
505 # "pwd -P" shell builtin since that's not portable.  Instead we try to
506 # find a pwd binary.  Note that assigning to the PWD environment
507 # variable might have some interesting side effects, so we don't do
508 # that.
509 AC_PATH_PROG(PWD_P, pwd, no)
510 if test "$PWD_P" = no; then
511   AC_MSG_ERROR(*** A pwd binary could not be found.)
512 fi
513
514 # These programs are version sensitive.
515 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
516 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
517   [version \([egcygnustpi-]*[0-9.]*\)],
518   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
519   critic_missing=t)
520 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
521   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
522   [3.79* | 3.[89]*], critic_missing=t)
523
524 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
525   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
526   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
527 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
528   [GNU texinfo.* \([0-9][0-9.]*\)],
529   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
530 AC_CHECK_PROG_VER(SED, gsed sed, --version,
531   [GNU sed version \([0-9]*\.[0-9.]*\)],
532   [3.0[2-9]*|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
533
534 if test -n "$critic_missing"; then
535 AC_MSG_ERROR([
536 *** Some critical program is missing or too old.
537 *** Check the INSTALL file for required versions.])
538 fi
539
540 test -n "$aux_missing" && AC_MSG_WARN([
541 *** An auxiliary program is missing or too old;
542 *** some features will be disabled.
543 *** Check the INSTALL file for required versions.])
544
545 # glibcbug.in wants to know the compiler version.
546 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
547 AC_SUBST(CCVERSION)
548
549 AC_PROG_CC_LOCAL
550 AC_CANONICAL_BUILD
551 if test $host != $build; then
552   AC_CHECK_PROGS(BUILD_CC, gcc cc)
553 fi
554 AC_SUBST(cross_compiling)
555 AC_PROG_CPP
556 LIBC_PROG_BINUTILS
557 AC_CHECK_TOOL(MIG, mig)
558
559 # if using special system headers, find out the compiler's sekrit
560 # header directory and add that to the list.  NOTE: Only does the right
561 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
562 if test -n "$sysheaders"; then
563   ccheaders=`$CC -print-file-name=include`
564   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
565 fi
566 AC_SUBST(SYSINCLUDES)
567
568 # check if ranlib is necessary
569 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
570 cat > conftest.c <<EOF
571 int a;
572 char b;
573 void c(void) {}
574 EOF
575 $CC $CFLAGS -c conftest.c
576 $AR cr conftest.a conftest.c
577 cp conftest.a conftest2.a
578 $RANLIB conftest.a
579 if cmp -s conftest.a conftest2.a; then
580   libc_cv_ranlib_necessary=no
581 else
582   libc_cv_ranlib_necessary=yes
583 fi
584 rm -rf conftest*])
585 if test "$libc_cv_ranlib_necessary" = no; then
586  RANLIB=:
587 fi
588
589 # Test if LD_LIBRARY_PATH contains the notation for the current directory
590 # since this would lead to problems installing/building glibc.
591 # LD_LIBRARY_PATH contains the current directory if one of the following
592 # is true:
593 # - one of the terminals (":" and ";") is the first or last sign
594 # - two terminals occur directly after each other
595 # - the path contains an element with a dot in it
596 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
597 changequote(,)dnl
598 case ${LD_LIBRARY_PATH} in
599   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
600     ld_library_path_setting="contains current directory"
601     ;;
602   *)
603     ld_library_path_setting="ok"
604     ;;
605 esac
606 changequote([,])dnl
607 AC_MSG_RESULT($ld_library_path_setting)
608 if test "$ld_library_path_setting" != "ok"; then
609 AC_MSG_ERROR([
610 *** LD_LIBRARY_PATH shouldn't contain the current directory when
611 *** building glibc. Please change the environment variable
612 *** and run configure again.])
613 fi
614
615 AC_PATH_PROG(BASH, bash, no)
616 if test "$BASH" != no &&
617    $BASH -c 'test "$BASH_VERSINFO" \
618              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
619   libc_cv_have_bash2=yes
620 else
621   libc_cv_have_bash2=no
622 fi
623 AC_SUBST(libc_cv_have_bash2)
624
625 dnl We need a ksh compatible shell for tzselect.
626 if test "$BASH" = no; then
627   AC_PATH_PROG(KSH, ksh, no)
628   if test "$KSH" = no; then
629     libc_cv_have_ksh=no
630   else
631     libc_cv_have_ksh=yes
632   fi
633 else
634   KSH="$BASH"
635   AC_SUBST(KSH)
636   libc_cv_have_ksh=yes
637 fi
638 AC_SUBST(libc_cv_have_ksh)
639
640 AC_PROG_AWK
641 AC_PATH_PROG(PERL, perl, no)
642 if test "$PERL" != no &&
643    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
644   PERL=no
645 fi
646 AC_PATH_PROG(INSTALL_INFO, install-info, no,
647              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
648 if test "$INSTALL_INFO" != "no"; then
649 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
650  [mkdir conftest.d
651   # There is a hard ^_ on the next line.  I am open to better ideas.
652   (echo '\1f'
653   echo 'File: dir       Node: Top       This is the top of the INFO tree'
654   echo '* Menu:') >conftest.d/dir
655   (echo 'INFO-DIR-SECTION i-d-s works'
656   echo 'START-INFO-DIR-ENTRY'
657   echo '* Prog: (prog).   Program.'
658   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
659   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
660   then
661     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
662     then libc_cv_old_debian_install_info=no
663     else libc_cv_old_debian_install_info=yes
664     fi
665   else libc_cv_old_debian_install_info=no testfailed=t
666   fi
667   rm -fr conftest.d])
668 if test -n "$testfailed"
669 then AC_MSG_WARN([install-info errored out, check config.log])
670 fi
671 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
672 fi
673 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
674
675 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
676 echo '#include <stddef.h>
677 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
678 if eval "$ac_cpp conftest.c 2>/dev/null" \
679 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
680   libc_cv_signed_size_t=no
681 else
682   libc_cv_signed_size_t=yes
683 fi
684 rm -f conftest*])
685 if test $libc_cv_signed_size_t = yes; then
686   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
687   cat >> confdefs.h <<\EOF
688 #undef __SIZE_TYPE__
689 #define __SIZE_TYPE__ unsigned
690 EOF
691 fi
692
693 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
694 AC_TRY_COMPILE(dnl
695 [#define __need_size_t
696 #define __need_wchar_t
697 #include <stddef.h>
698 #define __need_NULL
699 #include <stddef.h>], [size_t size; wchar_t wchar;
700 #ifdef offsetof
701 #error stddef.h ignored __need_*
702 #endif
703 if (&size == NULL || &wchar == NULL) abort ();],
704                libc_cv_friendly_stddef=yes,
705                libc_cv_friendly_stddef=no)])
706 if test $libc_cv_friendly_stddef = yes; then
707   config_vars="$config_vars
708 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
709 fi
710
711 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
712                libc_cv_need_minus_P, [dnl
713 cat > conftest.S <<EOF
714 #include "confdefs.h"
715 /* Nothing whatsoever.  */
716 EOF
717 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
718   libc_cv_need_minus_P=no
719 else
720   libc_cv_need_minus_P=yes
721 fi
722 rm -f conftest*])
723 if test $libc_cv_need_minus_P = yes; then
724   config_vars="$config_vars
725 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
726 fi
727
728 AC_MSG_CHECKING(whether .text pseudo-op must be used)
729 AC_CACHE_VAL(libc_cv_dot_text, [dnl
730 cat > conftest.s <<EOF
731 .text
732 EOF
733 libc_cv_dot_text=
734 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
735   libc_cv_dot_text=.text
736 fi
737 rm -f conftest*])
738 if test -z "$libc_cv_dot_text"; then
739   AC_MSG_RESULT(no)
740 else
741   AC_MSG_RESULT(yes)
742 fi
743
744 AC_CACHE_CHECK(for assembler global-symbol directive,
745                libc_cv_asm_global_directive, [dnl
746 libc_cv_asm_global_directive=UNKNOWN
747 for ac_globl in .globl .global .EXPORT; do
748   cat > conftest.s <<EOF
749         ${libc_cv_dot_text}
750         ${ac_globl} foo
751 foo:
752 EOF
753   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
754     libc_cv_asm_global_directive=${ac_globl}
755   fi
756   rm -f conftest*
757   test $libc_cv_asm_global_directive != UNKNOWN && break
758 done])
759 if test $libc_cv_asm_global_directive = UNKNOWN; then
760   AC_MSG_ERROR(cannot determine asm global directive)
761 else
762   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
763 fi
764
765 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
766 cat > conftest.s <<EOF
767 ${libc_cv_dot_text}
768 foo:
769 .set glibc_conftest_frobozz,foo
770 $libc_cv_asm_global_directive glibc_conftest_frobozz
771 EOF
772 # The alpha-dec-osf1 assembler gives only a warning for `.set'
773 # (but it doesn't work), so we must do a linking check to be sure.
774 cat > conftest1.c <<\EOF
775 extern int glibc_conftest_frobozz;
776 main () { printf ("%d\n", glibc_conftest_frobozz); }
777 EOF
778 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
779             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
780   libc_cv_asm_set_directive=yes
781 else
782   libc_cv_asm_set_directive=no
783 fi
784 rm -f conftest*])
785 if test $libc_cv_asm_set_directive = yes; then
786   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
787 fi
788
789 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
790 [cat > conftest.s <<EOF
791 ${libc_cv_dot_text}
792 _sym:
793 .symver _sym,sym@VERS
794 EOF
795 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
796   libc_cv_asm_symver_directive=yes
797 else
798   libc_cv_asm_symver_directive=no
799 fi
800 rm -f conftest*])
801 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
802 if test $libc_cv_asm_symver_directive = yes; then
803   cat > conftest.s <<EOF
804 ${libc_cv_dot_text}
805 _sym:
806 .symver _sym,sym@VERS
807 EOF
808   cat > conftest.map <<EOF
809 VERS_1 {
810         global: sym;
811 };
812
813 VERS_2 {
814         global: sym;
815 } VERS_1;
816 EOF
817   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
818     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
819                                         -nostartfiles -nostdlib
820                                         -Wl,--version-script,conftest.map
821                        1>&AC_FD_CC]);
822     then
823       libc_cv_ld_version_script_option=yes
824     else
825       libc_cv_ld_version_script_option=no
826     fi
827   else
828     libc_cv_ld_version_script_option=no
829   fi
830 else
831   libc_cv_ld_version_script_option=no
832 fi
833 rm -f conftest*])
834 if test $shared != no &&
835    test $libc_cv_asm_symver_directive = yes &&
836    test $libc_cv_ld_version_script_option = yes &&
837    test $enable_versioning = yes; then
838   VERSIONING=yes
839   AC_DEFINE(DO_VERSIONING)
840 else
841   VERSIONING=no
842 fi
843 AC_SUBST(VERSIONING)
844
845 if test $shared != no && test $VERSIONING = no; then
846   echo "\
847 *** WARNING: You should not compile GNU libc without versioning. Not using
848 *** versioning will introduce incompatibilities so that old binaries
849 *** will not run anymore.
850 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
851 fi
852 if test $elf = yes; then
853   AC_CACHE_CHECK(for .previous assembler directive,
854                  libc_cv_asm_previous_directive, [dnl
855   cat > conftest.s <<EOF
856 .section foo_section
857 .previous
858 EOF
859   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
860     libc_cv_asm_previous_directive=yes
861   else
862     libc_cv_asm_previous_directive=no
863   fi
864   rm -f conftest*])
865   if test $libc_cv_asm_previous_directive = yes; then
866     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
867   else
868     AC_CACHE_CHECK(for .popsection assembler directive,
869                    libc_cv_asm_popsection_directive, [dnl
870     cat > conftest.s <<EOF
871 .pushsection foo_section
872 .popsection
873 EOF
874     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
875       libc_cv_asm_popsection_directive=yes
876     else
877       libc_cv_asm_popsection_directive=no
878     fi
879     rm -f conftest*])
880     if test $libc_cv_asm_popsection_directive = yes; then
881       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
882     fi
883   fi
884   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
885                  libc_cv_asm_protected_directive, [dnl
886   cat > conftest.s <<EOF
887 .protected foo
888 foo:
889 .hidden bar
890 bar:
891 EOF
892   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
893     libc_cv_asm_protected_directive=yes
894   else
895     libc_cv_asm_protected_directive=no
896   fi
897   rm -f conftest*])
898   AC_SUBST(libc_cv_asm_protected_directive)
899
900   AC_CACHE_CHECK(for -z nodelete option,
901                  libc_cv_z_nodelete, [dnl
902   cat > conftest.c <<EOF
903 int _start (void) { return 42; }
904 EOF
905   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodelete 1>&AC_FD_CC])
906   then
907     libc_cv_z_nodelete=yes
908   else
909     libc_cv_z_nodelete=no
910   fi
911   rm -f conftest*])
912   AC_SUBST(libc_cv_z_nodelete)
913
914   AC_CACHE_CHECK(for -z nodlopen option,
915                  libc_cv_z_nodlopen, [dnl
916   cat > conftest.c <<EOF
917 int _start (void) { return 42; }
918 EOF
919   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodlopen 1>&AC_FD_CC])
920   then
921     libc_cv_z_nodlopen=yes
922   else
923     libc_cv_z_nodlopen=no
924   fi
925   rm -f conftest*])
926   AC_SUBST(libc_cv_z_nodlopen)
927 fi
928
929 if test $elf != yes; then
930   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
931                  [AC_TRY_COMPILE(, [asm (".section .init");
932                                     asm (".section .fini");
933                                     asm ("${libc_cv_dot_text}");],
934                                  libc_cv_have_initfini=yes,
935                                  libc_cv_have_initfini=no)])
936   AC_SUBST(libc_cv_have_initfini)dnl
937   if test $libc_cv_have_initfini = yes; then
938     AC_DEFINE(HAVE_INITFINI)
939   fi
940 fi
941
942 if test $elf = yes -a $gnu_ld = yes; then
943   AC_CACHE_CHECK(whether cc puts quotes around section names,
944                  libc_cv_have_section_quotes,
945                  [cat > conftest.c <<EOF
946                   static const int foo
947                   __attribute__ ((section ("bar"))) = 1;
948 EOF
949                   if ${CC-cc} -S conftest.c -o conftest.s; then
950                     if grep '\.section.*"bar"' conftest.s >/dev/null; then
951                       libc_cv_have_section_quotes=yes
952                     else
953                       libc_cv_have_section_quotes=no
954                     fi
955                   else
956                     libc_cv_have_section_quotes=unknown
957                   fi
958                   rm -f conftest.[cs]
959                  ])
960   if test $libc_cv_have_section_quotes = yes; then
961     AC_DEFINE(HAVE_SECTION_QUOTES)
962   fi
963 fi
964
965 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
966 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
967 [cat > conftest.$ac_ext <<EOF
968 dnl This sometimes fails to find confdefs.h, for some reason.
969 dnl [#]line __oline__ "[$]0"
970 [#]line __oline__ "configure"
971 #include "confdefs.h"
972 void underscore_test(void) {
973 return; }
974 EOF
975 if AC_TRY_EVAL(ac_compile); then
976   if grep _underscore_test conftest* >/dev/null; then
977     ifelse([$1], , :, [rm -f conftest*
978     $1])
979   else
980     ifelse([$2], , , [rm -f conftest*
981     $2])
982   fi
983 else
984   echo "configure: failed program was:" >&AC_FD_CC
985   cat conftest.$ac_ext >&AC_FD_CC
986   ifelse([$2], , , [rm -f conftest*
987   $2])
988 fi
989 rm -f conftest*])
990
991 if test $elf = yes; then
992   libc_cv_asm_underscores=no
993 else
994   if test $ac_cv_prog_cc_works = yes; then
995     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
996                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
997                                 libc_cv_asm_underscores=yes,
998                                 libc_cv_asm_underscores=no)])
999   else
1000     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1001                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
1002                                             libc_cv_asm_underscores=no)])
1003   fi
1004 fi
1005 if test $libc_cv_asm_underscores = no; then
1006   AC_DEFINE(NO_UNDERSCORES)
1007 fi
1008
1009 if test $elf = yes; then
1010   libc_cv_weak_symbols=yes
1011 fi
1012
1013 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1014                [dnl
1015 cat > conftest.s <<EOF
1016 ${libc_cv_dot_text}
1017 ${libc_cv_asm_global_directive} foo
1018 foo:
1019 .weak foo
1020 .weak bar; bar = foo
1021 EOF
1022 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1023   libc_cv_asm_weak_directive=yes
1024 else
1025   libc_cv_asm_weak_directive=no
1026 fi
1027 rm -f conftest*])
1028
1029 if test $libc_cv_asm_weak_directive = no; then
1030   AC_CACHE_CHECK(for assembler .weakext directive,
1031                  libc_cv_asm_weakext_directive,
1032                  [dnl
1033 cat > conftest.s <<EOF
1034 ${libc_cv_dot_text}
1035 ${libc_cv_asm_global_directive} foo
1036 foo:
1037 .weakext bar foo
1038 .weakext baz
1039 ${libc_cv_asm_global_directive} baz
1040 baz:
1041 EOF
1042   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1043     libc_cv_asm_weakext_directive=yes
1044   else
1045     libc_cv_asm_weakext_directive=no
1046   fi
1047   rm -f conftest*])
1048
1049 fi # no .weak
1050
1051 if test $libc_cv_asm_weak_directive = yes; then
1052   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1053 elif test $libc_cv_asm_weakext_directive = yes; then
1054   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1055 fi
1056
1057 dnl The standard hppa assembler uses `;' to start comments and `!'
1058 dnl as a line separator.
1059 case "${host_cpu}-${host_os}" in
1060   hppa*linux*)
1061   AC_CACHE_CHECK(for assembler line separator,
1062                  libc_cv_asm_line_sep, [dnl
1063   cat > conftest.s <<EOF
1064  nop ; is_old_puffin
1065 EOF
1066   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
1067     libc_cv_asm_line_sep='!'
1068   else
1069     if test -z "$enable_hacker_mode"; then
1070       echo "*** You need a newer assembler to compile glibc"
1071       rm -f conftest*
1072       exit 1
1073     fi
1074     libc_cv_asm_line_sep=';'
1075   fi
1076   rm -f conftest*])
1077   AC_DEFINE_UNQUOTED(ASM_LINE_SEP, $libc_cv_asm_line_sep)
1078   ;;
1079 esac
1080
1081 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1082 cat > conftest.c <<\EOF
1083 _start () {}
1084 int __eh_pc;
1085 __throw () {}
1086 EOF
1087 dnl No \ in command here because it ends up inside ''.
1088 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1089                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1090                             -o conftest conftest.c 1>&AC_FD_CC]); then
1091   libc_cv_ld_no_whole_archive=yes
1092 else
1093   libc_cv_ld_no_whole_archive=no
1094 fi
1095 rm -f conftest*])
1096 if test $libc_cv_ld_no_whole_archive = yes; then
1097   no_whole_archive=-Wl,--no-whole-archive
1098 fi
1099 AC_SUBST(no_whole_archive)dnl
1100
1101 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1102 cat > conftest.c <<\EOF
1103 _start () {}
1104 int __eh_pc;
1105 __throw () {}
1106 EOF
1107 dnl No \ in command here because it ends up inside ''.
1108 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1109                             -nostdlib -nostartfiles -fexceptions
1110                             -o conftest conftest.c 1>&AC_FD_CC]); then
1111   libc_cv_gcc_exceptions=yes
1112 else
1113   libc_cv_gcc_exceptions=no
1114 fi
1115 rm -f conftest*])
1116 if test $libc_cv_gcc_exceptions = yes; then
1117   exceptions=-fexceptions
1118 fi
1119 AC_SUBST(exceptions)dnl
1120
1121 if test "$base_machine" = alpha ; then
1122 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1123 cat > conftest.c <<\EOF
1124 foo () { }
1125 EOF
1126 dnl
1127 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1128 then
1129   libc_cv_gcc_alpha_ng_prefix=yes
1130 else
1131   libc_cv_gcc_alpha_ng_prefix=no
1132 fi
1133 rm -f conftest* ])
1134 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1135   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1136 else
1137   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1138 fi
1139 fi
1140
1141 if test "$host_cpu" = powerpc ; then
1142 # Check for a bug present in at least versions 2.8.x of GCC
1143 # and versions 1.0.x of EGCS.
1144 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1145 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1146                libc_cv_c_asmcr0_bug='no',
1147                libc_cv_c_asmcr0_bug='yes')])
1148 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1149   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1150 fi
1151 fi
1152
1153 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1154 [cat > conftest.c <<EOF
1155 #line __oline__ "configure"
1156 static char __EH_FRAME_BEGIN__[];
1157 _start ()
1158 {
1159 #ifdef CHECK__register_frame
1160   __register_frame (__EH_FRAME_BEGIN__);
1161   __deregister_frame (__EH_FRAME_BEGIN__);
1162 #endif
1163 #ifdef CHECK__register_frame_info
1164   __register_frame_info (__EH_FRAME_BEGIN__);
1165   __deregister_frame_info (__EH_FRAME_BEGIN__);
1166 #endif
1167 }
1168 int __eh_pc;
1169 __throw () {}
1170 /* FIXME: this is fragile.  */
1171 malloc () {}
1172 strcmp () {}
1173 strlen () {}
1174 memcpy () {}
1175 memset () {}
1176 free () {}
1177 abort () {}
1178 __bzero () {}
1179 EOF
1180 dnl No \ in command here because it ends up inside ''.
1181 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1182                             -nostdlib -nostartfiles
1183                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1184   libc_cv_gcc_dwarf2_unwind_info=static
1185 else
1186   libc_cv_gcc_dwarf2_unwind_info=no
1187 fi
1188 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1189   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1190                               -nostdlib -nostartfiles
1191                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1192     libc_cv_gcc_dwarf2_unwind_info=yes
1193   else
1194     libc_cv_gcc_dwarf2_unwind_info=no
1195   fi
1196 fi
1197 rm -f conftest*])
1198 case $libc_cv_gcc_dwarf2_unwind_info in
1199 yes)
1200   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1201   ;;
1202 static)
1203   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1204   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1205   ;;
1206 esac
1207
1208 dnl Check whether compiler understands __builtin_expect.
1209 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1210 [cat > conftest.c <<EOF
1211 #line __oline__ "configure"
1212 int foo (int a)
1213 {
1214   a = __builtin_expect (a, 10);
1215   return a == 10 ? 0 : 1;
1216 }
1217 EOF
1218 dnl No \ in command here because it ends up inside ''.
1219 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1220                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1221   libc_cv_gcc_builtin_expect=yes
1222 else
1223   libc_cv_gcc_builtin_expect=no
1224 fi
1225 rm -f conftest*])
1226 if test "$libc_cv_gcc_builtin_expect" = yes; then
1227   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1228 fi
1229
1230 dnl Check whether the compiler supports subtraction of local labels.
1231 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1232 [cat > conftest.c <<EOF
1233 changequote(,)dnl
1234 #line __oline__ "configure"
1235 int foo (int a)
1236 {
1237   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1238   void *p = &&l1 + ar[a];
1239   goto *p;
1240  l1:
1241   return 1;
1242  l2:
1243   return 2;
1244 }
1245 changequote([,])dnl
1246 EOF
1247 dnl No \ in command here because it ends up inside ''.
1248 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1249                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1250   libc_cv_gcc_subtract_local_labels=yes
1251 else
1252   libc_cv_gcc_subtract_local_labels=no
1253 fi
1254 rm -f conftest*])
1255 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1256   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1257 fi
1258
1259 dnl Check whether we have the gd library available.
1260 AC_MSG_CHECKING(for libgd)
1261 old_CFLAGS="$CFLAGS"
1262 CFLAGS="$CFLAGS $libgd_include"
1263 old_LDFLAGS="$LDFLAGS"
1264 LDFLAGS="$LDFLAGS $libgd_ldflags"
1265 old_LIBS="$LIBS"
1266 LIBS="$LIBS -lgd -lpng -lz -lm"
1267 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1268 CFLAGS="$old_CFLAGS"
1269 LDFLAGS="$old_LDFLAGS"
1270 LIBS="$old_LIBS"
1271 AC_MSG_RESULT($LIBGD)
1272 AC_SUBST(LIBGD)
1273
1274 dnl check for the size of 'long double'.
1275 AC_CHECK_SIZEOF(long double, 0)
1276 sizeof_long_double=$ac_cv_sizeof_long_double
1277 AC_SUBST(sizeof_long_double)
1278
1279 ### End of automated tests.
1280 ### Now run sysdeps configure fragments.
1281
1282 # sysdeps configure fragments may set these with files to be linked below.
1283 libc_link_dests=
1284 libc_link_sources=
1285
1286 # They also can set these variables.
1287 use_ldconfig=no
1288 ldd_rewrite_script=no
1289
1290 # Iterate over all the sysdep directories we will use, running their
1291 # configure fragments, and looking for a uname implementation.
1292 uname=
1293 for dir in $sysnames; do
1294   case $dir in
1295     /*) dest=$dir ;;
1296     *)  dest=$srcdir/$dir ;;
1297   esac
1298   if test -r $dest/configure; then
1299     AC_MSG_RESULT(running configure fragment for $dest)
1300     . $dest/configure
1301   fi
1302 [
1303   if test -z "$uname"; then
1304     if test -r $dest/uname.c ||
1305        test -r $dest/uname.S ||
1306        { test -r $dest/syscalls.list &&
1307          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1308       uname=$dir
1309     fi
1310   fi
1311 ]dnl
1312 done
1313
1314 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1315
1316 # If we will use the generic uname implementation, we must figure out what
1317 # it will say by examining the system, and write the results in config-name.h.
1318 if test "$uname" = "sysdeps/generic"; then
1319
1320 changequote(,)dnl
1321   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1322 changequote([,])dnl
1323   if test $uname_sysname != $config_os; then
1324     config_release=`echo $config_os | sed s/$uname_sysname//`
1325   fi
1326 dnl
1327 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1328     if test -r /vmunix; then
1329       kernel_id=`strings /vmunix | grep UNIX`
1330     elif test -r /dynix; then
1331       kernel_id=`strings /dynix | grep DYNIX`
1332     else
1333       kernel_id=
1334     fi
1335 ])dnl
1336
1337   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1338 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1339 changequote(,)dnl
1340   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1341 changequote([,])dnl
1342   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1343          != x$config_release; then
1344     # The configuration release is a substring of the kernel release.
1345     libc_cv_uname_release=$kernel_release
1346   elif test x$config_release != x; then
1347     libc_cv_uname_release=$config_release
1348   elif test x$kernel_release != x; then
1349     libc_cv_uname_release=$kernel_release
1350   else
1351     libc_cv_uname_release=unknown
1352   fi])
1353   uname_release="$libc_cv_uname_release"
1354
1355   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1356 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1357 changequote(,)dnl
1358   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1359 changequote([,])dnl
1360   if test -n "$kernel_version"; then
1361     libc_cv_uname_version="$kernel_version"
1362   else
1363     libc_cv_uname_version=unknown
1364   fi])
1365   uname_version="$libc_cv_uname_version"
1366
1367 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1368   config_uname=config-name.h:config-name.in
1369 else
1370   # For non-generic uname, we don't need to create config-name.h at all.
1371   config_uname=
1372 fi
1373
1374 AC_MSG_CHECKING(stdio selection)
1375 AC_SUBST(stdio)
1376 case $stdio in
1377 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1378 default) stdio=stdio ;;
1379 esac
1380 AC_MSG_RESULT($stdio)
1381
1382 # Test for old glibc 2.0.x headers so that they can be removed properly
1383 # Search only in includedir.
1384 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1385 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1386 then
1387   old_glibc_headers=yes
1388 else
1389   old_glibc_headers=no
1390 fi
1391 AC_MSG_RESULT($old_glibc_headers)
1392 if test ${old_glibc_headers} = yes; then
1393   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1394   AC_MSG_WARN(*** be removed.)
1395 fi
1396 AC_SUBST(old_glibc_headers)
1397
1398 AC_SUBST(libc_cv_slibdir)
1399 AC_SUBST(libc_cv_localedir)
1400 AC_SUBST(libc_cv_sysconfdir)
1401 AC_SUBST(libc_cv_rootsbindir)
1402
1403 AC_SUBST(use_ldconfig)
1404 AC_SUBST(ldd_rewrite_script)
1405
1406 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1407 if test $gnu_ld = yes; then
1408   AC_DEFINE(HAVE_GNU_LD)
1409 fi
1410 if test $gnu_as = yes; then
1411   AC_DEFINE(HAVE_GNU_AS)
1412 fi
1413 if test $elf = yes; then
1414   AC_DEFINE(HAVE_ELF)
1415 fi
1416
1417 AC_SUBST(static)
1418 AC_SUBST(shared)
1419 if test $shared = default; then
1420   if test $gnu_ld = yes; then
1421     shared=$elf
1422   else
1423     # For now we do not assume shared libs are available.  In future more
1424     # tests might become available.
1425     shared=no
1426   fi
1427 fi
1428
1429 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1430 [pic_default=yes
1431 cat > conftest.c <<EOF
1432 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1433 # error PIC is default.
1434 #endif
1435 EOF
1436 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1437   pic_default=no
1438 fi
1439 rm -f conftest.*])
1440 AC_SUBST(pic_default)
1441
1442 AC_SUBST(profile)
1443 AC_SUBST(omitfp)
1444 AC_SUBST(bounded)
1445 AC_SUBST(static_nss)
1446 AC_SUBST(nopic_initfini)
1447
1448 AC_SUBST(DEFINES)
1449
1450 case "$add_ons" in
1451   *door*) linux_doors=yes ;;
1452   *) linux_doors=no ;;
1453 esac
1454 AC_SUBST(linux_doors)
1455
1456 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1457   config_makefile=
1458 else
1459   config_makefile=Makefile
1460 fi
1461
1462 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1463 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1464 AC_SUBST(VERSION)
1465 AC_SUBST(RELEASE)
1466
1467 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1468 case $CONFIG_FILES in *config.make*)
1469 echo "$config_vars" >> config.make;;
1470 esac
1471 test -d bits || mkdir bits], [config_vars='$config_vars'])