Check for recent egcs/gcc.
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45 AC_ARG_WITH(cvs, dnl
46 [  --without-cvs          if CVS should not be used],
47             with_cvs=$withval, with_cvs=yes)
48 AC_SUBST(with_cvs)
49
50 AC_ARG_ENABLE(libio, dnl
51 [  --enable-libio          build in GNU libio instead of GNU stdio],
52               [if test $enableval = yes; then
53                  stdio=libio
54                else
55                  stdio=stdio
56                fi],
57               stdio=default)
58
59 AC_ARG_ENABLE(sanity-checks, dnl
60 [  --disable-sanity-checks really do not use threads (should not be used
61                           except in special situations) [default=yes]],
62               enable_sanity=$enableval, enable_sanity=yes)
63
64 dnl Arguments to enable or disable building the static, shared, profiled,
65 dnl and -fomit-frame-pointer libraries.
66 AC_ARG_ENABLE(static, dnl
67 [  --enable-static         build static library [default=yes]],
68               static=$enableval, static=yes)
69 AC_ARG_ENABLE(shared, dnl
70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
71               shared=$enableval, shared=default)
72 AC_ARG_ENABLE(profile, dnl
73 [  --enable-profile        build profiled library [default=yes]],
74               profile=$enableval, profile=yes)
75 AC_ARG_ENABLE(omitfp, dnl
76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
77               omitfp=$enableval, omitfp=no)
78 AC_ARG_ENABLE(bounded, dnl
79 [  --enable-bounded        build with runtime bounds checking [default=no]],
80               bounded=$enableval, bounded=no)
81 AC_ARG_ENABLE(versioning, dnl
82 [  --disable-versioning    do not include versioning information in the
83                           library objects [default=yes if supported]],
84              enable_versioning=$enableval, enable_versioning=yes)
85
86 dnl Generic infrastructure for drop-in additions to libc.
87 AC_ARG_ENABLE(add-ons, dnl
88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
89                                   search for add-ons if no parameter given],
90   [case "$enableval" in
91     yes) if test "$srcdir" = "."; then
92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
93          else
94            add_ons=`echo $srcdir/*/configure | \
95                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
96          fi;;
97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
98    esac],
99   [add_ons=])
100
101 AC_CONFIG_SUBDIRS($add_ons)
102 add_ons_pfx=
103 if test x"$add_ons" != x; then
104   for f in $add_ons; do
105     # Test whether such a subdir really exists.
106     if test -d $srcdir/$f; then
107       add_ons_pfx="$add_ons_pfx $f/"
108     else
109       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
110     fi
111   done
112 fi
113
114 dnl On some platforms we cannot use dynamic loading.  We must provide
115 dnl static NSS modules.
116 AC_ARG_ENABLE(static-nss, dnl
117 [  --enable-static-nss     build static NSS modules [default=no]],
118               static_nss=$enableval, static_nss=no)
119 if test x"$static_nss" = xyes; then
120   AC_DEFINE(DO_STATIC_NSS)
121 fi
122
123 AC_CANONICAL_HOST
124
125 # The way shlib-versions is used to generate soversions.mk uses a
126 # fairly simplistic model for name recognition that can't distinguish
127 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
128 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
129 # tell.  This doesn't get used much beyond that, so it's fairly safe.
130 case "$host_os" in
131 linux*)
132   ;;
133 gnu*)
134   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
135   ;;
136 esac
137
138 ###
139 ### I put this here to prevent those annoying emails from people who cannot
140 ### read and try to compile glibc on unsupported platforms.  --drepper
141 ###
142 ### By using the undocumented --enable-hacker-mode option for configure
143 ### one can skip this test to make the configuration not fail for unsupported
144 ### platforms.
145 ###
146 if test -z "$enable_hacker_mode"; then
147   case "$machine-$host_os" in
148   *-linux* | *-gnu* | arm*-none*)
149     ;;
150   *)
151     echo "*** The GNU C library is currently not available for this platform."
152     echo "*** So far nobody cared to port it and if there is no volunteer it"
153     echo "*** might never happen.  So, if you have interest to see glibc on"
154     echo "*** this platform visit"
155     echo "***   http://www.gnu.org/software/libc/porting.html"
156     echo "*** and join the group of porters"
157     exit 1
158     ;;
159   esac
160 fi
161
162 # We keep the original values in `$config_*' and never modify them, so we
163 # can write them unchanged into config.make.  Everything else uses
164 # $machine, $vendor, and $os, and changes them whenever convenient.
165 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
166
167 # Some configurations imply other options.
168 case "$host_os" in
169 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
170   # These systems always use GNU tools.
171   gnu_ld=yes gnu_as=yes ;;
172 esac
173 case "$host_os" in
174 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
175 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
176   ;;
177 gnu* | linux* | sysv4* | solaris2* | irix6*)
178   # These systems (almost) always use the ELF format.
179   elf=yes
180   ;;
181 esac
182
183 machine=$config_machine
184 vendor=$config_vendor
185 os=$config_os
186
187 dnl We need to use [ and ] for other purposes for a while now.
188 changequote(,)dnl
189 # Expand the configuration machine name into a subdirectory by architecture
190 # type and particular chip.
191 case "$machine" in
192 a29k | am29000) base_machine=a29k machine=a29k ;;
193 alpha*)         base_machine=alpha machine=alpha/$machine ;;
194 arm*)           base_machine=arm machine=arm/$machine ;;
195 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
196 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
197 hppa*)          base_machine=hppa machine=hppa/$machine ;;
198 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
199 m680?0)         base_machine=m68k machine=m68k/$machine ;;
200 m68k)           base_machine=m68k machine=m68k/m68020 ;;
201 m88???)         base_machine=m88k machine=m88k/$machine ;;
202 m88k)           base_machine=m88k machine=m88k/m88100 ;;
203 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
204 mips*)          base_machine=mips
205                 case "`uname -m`" in
206                 IP22) machine=mips/mips3 ;;
207                 *)    machine=mips/$machine ,,
208                 esac ;;
209 sparc | sparcv[67])
210                 base_machine=sparc machine=sparc/sparc32 ;;
211 sparcv8 | supersparc | hypersparc)
212                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
213 sparc64 | ultrasparc)
214                 base_machine=sparc machine=sparc/sparc64 ;;
215 esac
216 changequote([,])dnl
217 AC_SUBST(base_machine)
218
219 if test "$base_machine" = "i386"; then
220   AC_DEFINE(USE_REGPARMS)
221 fi
222
223 # Compute the list of sysdep directories for this configuration.
224 # This can take a while to compute.
225 sysdep_dir=$srcdir/sysdeps
226 AC_MSG_CHECKING(sysdep dirs)
227 dnl We need to use [ and ] for other purposes for a while now.
228 changequote(,)dnl
229 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
230 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
231
232 case "$os" in
233 gnu*)
234   base_os=mach/hurd ;;
235 netbsd* | 386bsd* | freebsd* | bsdi*)
236   base_os=unix/bsd/bsd4.4 ;;
237 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
238   base_os=unix/bsd ;;
239 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
240   base_os=unix/sysv ;;
241 irix6*)
242   base_os=unix/sysv/irix6/$os ;;
243 solaris[2-9]*)
244   base_os=unix/sysv/sysv4 ;;
245 none)
246   base_os=standalone ;;
247 *)
248   base_os='' ;;
249 esac
250
251 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
252 tail=$os
253 ostry=$os
254 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
255   ostry="$ostry /$o"
256   tail=$o
257 done
258 o=`echo $tail | sed 's/[0-9]*$//'`
259 if test $o != $tail; then
260   ostry="$ostry /$o"
261 fi
262 # For linux-gnu, try linux-gnu, then linux.
263 o=`echo $tail | sed 's/-.*$//'`
264 if test $o != $tail; then
265   ostry="$ostry /$o"
266 fi
267
268 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
269 base=
270 tail=$base_os
271 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
272   set $b
273   base="$base /$1"
274   tail="$2"
275 done
276
277 # For sparc/sparc9, try sparc/sparc9 and then sparc.
278 mach=
279 tail=$machine
280 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
281   set $m
282   # Prepend the machine's FPU directory unless --without-fp.
283   if test "$with_fp" = yes; then
284     mach="$mach /$1/fpu"
285   fi
286   mach="$mach /$1"
287   tail="$2"
288 done
289
290 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
291 changequote([,])dnl
292
293 # Find what sysdep directories exist.
294 sysnames=
295 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
296 for d in $add_ons_pfx ''; do
297   for b in $base ''; do
298     for m0 in $mach ''; do
299       for v in /$vendor ''; do
300         test "$v" = / && continue
301         for o in /$ostry ''; do
302           test "$o" = / && continue
303           for m in $mach ''; do
304             if test "$m0$b$v$o$m"; then
305               try="${d}sysdeps$m0$b$v$o$m"
306               test -n "$enable_debug_configure" &&
307               echo "$0 [DEBUG]: try $try" >&2
308               case $try in
309                 /*) dest=$try ;;
310                 *)  dest=$srcdir/$try ;;
311               esac
312               if test -d $dest; then
313                 sysnames="$sysnames $try"
314                 { test -n "$o" || test -n "$b"; } && os_used=t
315                 { test -n "$m" || test -n "$m0"; } && machine_used=t
316               fi
317             fi
318           done
319         done
320       done
321     done
322   done
323 done
324 IFS="$ac_save_ifs"
325
326 if test -z "$os_used" && test "$os" != none; then
327   AC_MSG_ERROR(Operating system $os is not supported.)
328 fi
329 if test -z "$machine_used" && test "$machine" != none; then
330   AC_MSG_ERROR(The $machine is not supported.)
331 fi
332
333 # We have now validated the configuration.
334
335
336 # If using ELF, look for an `elf' subdirectory of each machine directory.
337 # We prepend these rather than inserting them whereever the machine appears
338 # because things specified by the machine's ELF ABI should override
339 # OS-specific things, and should always be the same for any OS on the
340 # machine (otherwise what's the point of an ABI?).
341 if test "$elf" = yes; then
342   elf_dirs=
343   for d in $add_ons_pfx ''; do
344     case $d in
345       /*) xsrcdir= ;;
346       *)  xsrcdir=$srcdir/ ;;
347     esac
348     for m in $mach; do
349       if test -d $xsrcdir${d}sysdeps$m/elf; then
350         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
351       fi
352     done
353   done
354   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
355 fi
356
357
358 # Expand the list of system names into a full list of directories
359 # from each element's parent name and Implies file (if present).
360 set $sysnames
361 names=
362 while test $# -gt 0; do
363   name=$1
364   shift
365
366   case " $names " in *" $name "*)
367     # Already in the list.
368     continue
369   esac
370
371   # Report each name as we discover it, so there is no long pause in output.
372   echo $ac_n "$name $ac_c" >&AC_FD_MSG
373
374   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
375
376   case $name in
377     /*) xsrcdir= ;;
378     *)  xsrcdir=$srcdir/ ;;
379   esac
380   test -n "$enable_debug_configure" &&
381   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
382
383   if test -f $xsrcdir$name/Implies; then
384     # Collect more names from the `Implies' file (removing comments).
385     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
386     implied=
387     for x in $implied_candidate; do
388       if test -d $xsrcdir$name_base/$x; then
389         implied="$implied $name_base/$x";
390       else
391         AC_MSG_WARN($name/Implies specifies nonexistent $x)
392       fi
393     done
394   else
395     implied=
396   fi
397
398   # Add NAME to the list of names.
399   names="$names $name"
400
401   # Find the parent of NAME, using the empty string if it has none.
402 changequote(,)dnl
403   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
404 changequote([,])dnl
405
406   # Add the names implied by NAME, and NAME's parent (if it has one), to
407   # the list of names to be processed (the argument list).  We prepend the
408   # implied names to the list and append the parent.  We want implied
409   # directories to come before further directories inferred from the
410   # configuration components; this ensures that for sysv4, unix/common
411   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
412   # after sysv4).
413   sysnames="`echo $implied $* $parent`"
414   test -n "$sysnames" && set $sysnames
415 done
416
417 # Add the default directories.
418 sysnames="$names sysdeps/generic"
419 AC_SUBST(sysnames)
420 # The other names were emitted during the scan.
421 AC_MSG_RESULT(sysdeps/generic)
422
423
424 ### Locate tools.
425
426 AC_PROG_INSTALL
427 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
428   # The makefiles need to use a different form to find it in $srcdir.
429   INSTALL='\$(..)./install-sh -c'
430 fi
431 AC_PROG_LN_S
432 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
433 if test "$MSGFMT" != ":"; then
434 changequote(,)dnl Need [] for regexps.
435   if $MSGFMT --version 2>&1 | grep 'GNU gettext.*0\.[1-9][0-9]' >/dev/null 2>&1
436 changequote([,])dnl
437   then : # msgfmt from gettext 0.10 or greater, works.
438   else
439     AC_MSG_WARN([
440 *** (g)msgfmt is too old or wrong version (need gettext 0.10 or better).])
441     MSGFMT=":"
442   fi
443 fi
444
445 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
446 if test "$MAKEINFO"; then
447 changequote(,)dnl Need [] for regexps.
448   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
449 changequote([,])dnl
450   then : # Makeinfo 3.11 or greater, works.
451   else
452     AC_MSG_WARN([
453 *** makeinfo is too old (need version 3.11 or better).
454 *** You should install the needed version and re-configure since otherwise
455 *** you won't get the info pages installed.])
456     MAKEINFO=
457   fi
458 fi
459
460 AC_PROG_CC_LOCAL
461 AC_CANONICAL_BUILD
462 if test $host != $build; then
463   AC_CHECK_PROGS(BUILD_CC, gcc cc)
464 fi
465 AC_SUBST(cross_compiling)
466 AC_PROG_CPP
467 LIBC_PROG_BINUTILS
468 AC_CHECK_TOOL(AR, ar)
469 AC_CHECK_TOOL(RANLIB, ranlib, :)
470
471 # check for recent compiler
472 AC_MSG_CHECKING(compiler version)
473 case `${CC-cc} -v 2>&1` in
474   *egcs-2.91.* | *egcs-1.0.[2-9]* | *egcs-1.1* | *2.8.[1-9]* | *2.9.[0-9] )
475     cc_is_recent="ok"
476     ;;
477   *)
478     cc_is_recent="too old"
479     ;;
480 esac
481 AC_MSG_RESULT($cc_is_recent)
482 if test $cc_is_recent != ok; then
483   AC_MSG_WARN([
484 *** Your compiler is too old.
485 *** You need at least egcs 1.0.2 or GNU CC 2.8.1 to compile glibc.
486 ])
487 fi
488
489 AC_PATH_PROG(BASH, bash, no)
490 if test "$BASH" != no &&
491    $BASH -c 'test "$BASH_VERSINFO" \
492              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
493   libc_cv_have_bash2=yes
494 else
495   libc_cv_have_bash2=no
496 fi
497 AC_SUBST(libc_cv_have_bash2)
498
499 dnl We need a ksh compatible shell for tzselect.
500 if test "$BASH" = no; then
501   AC_PATH_PROG(KSH, ksh, no)
502   if test "$KSH" = no; then
503     libc_cv_have_ksh=no
504   else
505     libc_cv_have_ksh=yes
506   fi
507 else
508   KSH="$BASH"
509   AC_SUBST(KSH)
510   libc_cv_have_ksh=yes
511 fi
512 AC_SUBST(libc_cv_have_ksh)
513
514 AC_PATH_PROGS(PERL, perl, no)
515 AC_SUBST(PERL)
516
517 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
518 echo '#include <stddef.h>
519 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
520 if eval "$ac_cpp conftest.c 2>/dev/null" \
521 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
522   libc_cv_signed_size_t=no
523 else
524   libc_cv_signed_size_t=yes
525 fi
526 rm -f conftest*])
527 if test $libc_cv_signed_size_t = yes; then
528   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
529   cat >> confdefs.h <<\EOF
530 #undef __SIZE_TYPE__
531 #define __SIZE_TYPE__ unsigned
532 EOF
533 fi
534
535 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
536 AC_TRY_COMPILE(dnl
537 [#define __need_size_t
538 #define __need_wchar_t
539 #include <stddef.h>
540 #define __need_NULL
541 #include <stddef.h>], [size_t size; wchar_t wchar;
542 #ifdef offsetof
543 #error stddef.h ignored __need_*
544 #endif
545 if (&size == NULL || &wchar == NULL) abort ();],
546                libc_cv_friendly_stddef=yes,
547                libc_cv_friendly_stddef=no)])
548 if test $libc_cv_friendly_stddef = yes; then
549   config_vars="$config_vars
550 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
551 fi
552
553 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
554                libc_cv_need_minus_P, [dnl
555 cat > conftest.S <<EOF
556 #include "confdefs.h"
557 /* Nothing whatsoever.  */
558 EOF
559 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
560   libc_cv_need_minus_P=no
561 else
562   libc_cv_need_minus_P=yes
563 fi
564 rm -f conftest*])
565 if test $libc_cv_need_minus_P = yes; then
566   config_vars="$config_vars
567 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
568 fi
569
570 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
571 # be told to read stdin.  This causes the compiler to hang when fed an
572 # .s file.
573 if test $ac_cv_prog_gcc = yes; then
574  case `${CC-cc} -v 2>&1` in
575   *2.7*)
576   # We must check this even if -pipe is not given here, because the user
577   # might do `make CFLAGS=-pipe'.
578   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
579    cp /dev/null conftest.s
580    cat >conftest1.s <<EOF
581 .nosuchdirective
582 EOF
583    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
584     libc_cv_gcc_pipe_bug=no
585    else
586     libc_cv_gcc_pipe_bug=yes
587    fi
588    rm -f conftest*])
589   if test $libc_cv_gcc_pipe_bug = yes; then
590    makeCC="${CC-cc} -B\$(common-objpfx)"
591    makeCFLAGS=$CFLAGS
592    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
593   fi;;
594  *) libc_cv_gcc_pipe_bug=no;;
595  esac
596 else
597  libc_cv_gcc_pipe_bug=no
598 fi
599
600 AC_CACHE_CHECK(for assembler global-symbol directive,
601                libc_cv_asm_global_directive, [dnl
602 libc_cv_asm_global_directive=UNKNOWN
603 for ac_globl in .globl .global; do
604   cat > conftest.s <<EOF
605 .text
606 ${ac_globl} foo
607 foo:
608 EOF
609   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
610     libc_cv_asm_global_directive=${ac_globl}
611   fi
612   rm -f conftest*
613   test $libc_cv_asm_global_directive != UNKNOWN && break
614 done])
615 if test $libc_cv_asm_global_directive = UNKNOWN; then
616   AC_MSG_ERROR(cannot determine asm global directive)
617 else
618   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
619 fi
620
621 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
622 cat > conftest.s <<EOF
623 .text
624 foo:
625 .set glibc_conftest_frobozz,foo
626 $libc_cv_asm_global_directive glibc_conftest_frobozz
627 EOF
628 # The alpha-dec-osf1 assembler gives only a warning for `.set'
629 # (but it doesn't work), so we must do a linking check to be sure.
630 cat > conftest1.c <<\EOF
631 extern int glibc_conftest_frobozz;
632 main () { printf ("%d\n", glibc_conftest_frobozz); }
633 EOF
634 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
635             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
636   libc_cv_asm_set_directive=yes
637 else
638   libc_cv_asm_set_directive=no
639 fi
640 rm -f conftest*])
641 if test $libc_cv_asm_set_directive = yes; then
642   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
643 fi
644
645 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
646 [cat > conftest.s <<EOF
647 .text
648 _sym:
649 .symver _sym,sym@VERS
650 EOF
651 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
652   libc_cv_asm_symver_directive=yes
653 else
654   libc_cv_asm_symver_directive=no
655 fi
656 rm -f conftest*])
657 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
658 if test $libc_cv_asm_symver_directive = yes; then
659   cat > conftest.s <<EOF
660 .text
661 _sym:
662 .symver _sym,sym@VERS
663 EOF
664   cat > conftest.map <<EOF
665 VERS_1 {
666         global: sym;
667 };
668
669 VERS_2 {
670         global: sym;
671 } VERS_1;
672 EOF
673   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
674     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
675                                         -nostartfiles -nostdlib
676                                         -Wl,--version-script,conftest.map
677                        1>&AC_FD_CC]);
678     then
679       libc_cv_ld_version_script_option=yes
680     else
681       libc_cv_ld_version_script_option=no
682     fi
683   else
684     libc_cv_ld_version_script_option=no
685   fi
686 else
687   libc_cv_ld_version_script_option=no
688 fi
689 rm -f conftest*])
690 if test $libc_cv_asm_symver_directive = yes &&
691    test $libc_cv_ld_version_script_option = yes &&
692    test $enable_versioning = yes; then
693   VERSIONING=yes
694   AC_DEFINE(DO_VERSIONING)
695 else
696   VERSIONING=no
697 fi
698 AC_SUBST(VERSIONING)
699
700 if test $VERSIONING = no; then
701   echo "\
702 *** WARNING: You should not compile GNU libc without versioning. Not using
703 *** versioning will introduce incompatibilities so that old binaries
704 *** will not run anymore.
705 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
706 fi
707 if test $elf = yes; then
708   AC_CACHE_CHECK(for .previous assembler directive,
709                  libc_cv_asm_previous_directive, [dnl
710   cat > conftest.s <<EOF
711 .section foo_section
712 .previous
713 EOF
714   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
715     libc_cv_asm_previous_directive=yes
716   else
717     libc_cv_asm_previous_directive=no
718   fi
719   rm -f conftest*])
720   if test $libc_cv_asm_previous_directive = yes; then
721     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
722   else
723     AC_CACHE_CHECK(for .popsection assembler directive,
724                    libc_cv_asm_popsection_directive, [dnl
725     cat > conftest.s <<EOF
726 .pushsection foo_section
727 .popsection
728 EOF
729     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
730       libc_cv_asm_popsection_directive=yes
731     else
732       libc_cv_asm_popsection_directive=no
733     fi
734     rm -f conftest*])
735     if test $libc_cv_asm_popsection_directive = yes; then
736       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
737     fi
738   fi
739 fi
740
741 if test $elf != yes; then
742   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
743                  [AC_TRY_COMPILE(, [asm (".section .init");
744                                     asm (".section .fini");
745                                     asm (".text");],
746                                  libc_cv_have_initfini=yes,
747                                  libc_cv_have_initfini=no)])
748   AC_SUBST(libc_cv_have_initfini)dnl
749   if test $libc_cv_have_initfini = yes; then
750     AC_DEFINE(HAVE_INITFINI)
751   fi
752 fi
753
754 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
755 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
756 [cat > conftest.$ac_ext <<EOF
757 dnl This sometimes fails to find confdefs.h, for some reason.
758 dnl [#]line __oline__ "[$]0"
759 [#]line __oline__ "configure"
760 #include "confdefs.h"
761 void underscore_test(void) {
762 return; }
763 EOF
764 if AC_TRY_EVAL(ac_compile); then
765   if grep _underscore_test conftest* >/dev/null; then
766     ifelse([$1], , :, [rm -f conftest*
767     $1])
768   else
769     ifelse([$2], , , [rm -f conftest*
770     $2])
771   fi
772 else
773   echo "configure: failed program was:" >&AC_FD_CC
774   cat conftest.$ac_ext >&AC_FD_CC
775   ifelse([$2], , , [rm -f conftest*
776   $2])
777 fi
778 rm -f conftest*])
779
780 if test $elf = yes; then
781   libc_cv_asm_underscores=no
782 else
783   if test $ac_cv_prog_cc_works = yes; then
784     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
785                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
786                                 libc_cv_asm_underscores=yes,
787                                 libc_cv_asm_underscores=no)])
788   else
789     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
790                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
791                                             libc_cv_asm_underscores=no)])
792   fi
793 fi
794 if test $libc_cv_asm_underscores = no; then
795   AC_DEFINE(NO_UNDERSCORES)
796 fi
797
798 if test $elf = yes; then
799   libc_cv_weak_symbols=yes
800 fi
801
802 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
803                  [dnl
804 cat > conftest.s <<EOF
805 .text
806 ${libc_cv_asm_global_directive} foo
807 foo:
808 .weak foo
809 .weak bar; bar = foo
810 EOF
811 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
812   libc_cv_asm_weak_directive=yes
813 else
814   libc_cv_asm_weak_directive=no
815 fi
816 rm -f conftest*])
817
818 if test $libc_cv_asm_weak_directive = no; then
819   AC_CACHE_CHECK(for assembler .weakext directive,
820                  libc_cv_asm_weakext_directive,
821                  [dnl
822 cat > conftest.s <<EOF
823 .text
824 ${libc_cv_asm_global_directive} foo
825 foo:
826 .weakext bar foo
827 .weakext baz
828 ${libc_cv_asm_global_directive} baz
829 baz:
830 EOF
831   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
832     libc_cv_asm_weakext_directive=yes
833   else
834     libc_cv_asm_weakext_directive=no
835   fi
836   rm -f conftest*])
837
838 fi # no .weak
839
840 if test $libc_cv_asm_weak_directive = yes; then
841   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
842 elif test $libc_cv_asm_weakext_directive = yes; then
843   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
844 fi
845
846 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
847 cat > conftest.c <<\EOF
848 _start () {}
849 int __eh_pc;
850 __throw () {}
851 EOF
852 dnl No \ in command here because it ends up inside ''.
853 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
854                             -nostdlib -nostartfiles -Wl,--no-whole-archive
855                             -o conftest conftest.c 1>&AC_FD_CC]); then
856   libc_cv_ld_no_whole_archive=yes
857 else
858   libc_cv_ld_no_whole_archive=no
859 fi
860 rm -f conftest*])
861 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
862
863 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
864 cat > conftest.c <<\EOF
865 _start () {}
866 int __eh_pc;
867 __throw () {}
868 EOF
869 dnl No \ in command here because it ends up inside ''.
870 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
871                             -nostdlib -nostartfiles -fno-exceptions
872                             -o conftest conftest.c 1>&AC_FD_CC]); then
873   libc_cv_gcc_no_exceptions=yes
874 else
875   libc_cv_gcc_no_exceptions=no
876 fi
877 rm -f conftest*])
878 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
879
880 if test "$base_machine" = alpha ; then
881 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
882 cat > conftest.c <<\EOF
883 foo () { }
884 EOF
885 dnl
886 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
887 then
888   libc_cv_gcc_alpha_ng_prefix=yes
889 else
890   libc_cv_gcc_alpha_ng_prefix=no
891 fi
892 rm -f conftest* ])
893 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
894   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
895 else
896   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
897 fi
898 fi
899
900 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
901 [cat > conftest.c <<EOF
902 #line __oline__ "configure"
903 static char __EH_FRAME_BEGIN__[];
904 _start ()
905 {
906 #ifdef CHECK__register_frame
907   __register_frame (__EH_FRAME_BEGIN__);
908   __deregister_frame (__EH_FRAME_BEGIN__);
909 #endif
910 #ifdef CHECK__register_frame_info
911   __register_frame_info (__EH_FRAME_BEGIN__);
912   __deregister_frame_info (__EH_FRAME_BEGIN__);
913 #endif
914 }
915 int __eh_pc;
916 __throw () {}
917 /* FIXME: this is fragile.  */
918 malloc () {}
919 strcmp () {}
920 strlen () {}
921 memcpy () {}
922 memset () {}
923 free () {}
924 abort () {}
925 __bzero () {}
926 EOF
927 dnl No \ in command here because it ends up inside ''.
928 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
929                             -nostdlib -nostartfiles
930                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
931   libc_cv_gcc_dwarf2_unwind_info=static
932 else
933   libc_cv_gcc_dwarf2_unwind_info=no
934 fi
935 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
936   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
937                               -nostdlib -nostartfiles
938                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
939     libc_cv_gcc_dwarf2_unwind_info=yes
940   else
941     libc_cv_gcc_dwarf2_unwind_info=no
942   fi
943 fi
944 rm -f conftest*])
945 case $libc_cv_gcc_dwarf2_unwind_info in
946 yes)
947   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
948   ;;
949 static)
950   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
951   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
952   ;;
953 esac
954
955 ### End of automated tests.
956 ### Now run sysdeps configure fragments.
957
958 # sysdeps configure fragments may set these with files to be linked below.
959 libc_link_dests=
960 libc_link_sources=
961
962 # Iterate over all the sysdep directories we will use, running their
963 # configure fragments, and looking for a uname implementation.
964 uname=
965 for dir in $sysnames; do
966   case $dir in
967     /*) dest=$dir ;;
968     *)  dest=$srcdir/$dir ;;
969   esac
970   if test -r $dest/configure; then
971     AC_MSG_RESULT(running configure fragment for $dest)
972     . $dest/configure
973   fi
974 [
975   if test -z "$uname"; then
976     if test -r $dest/uname.c ||
977        test -r $dest/uname.S ||
978        { test -r $dest/syscalls.list &&
979          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
980       uname=$dir
981     fi
982   fi
983 ]dnl
984 done
985
986 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
987
988 # If we will use the generic uname implementation, we must figure out what
989 # it will say by examining the system, and write the results in config-name.h.
990 if test "$uname" = "sysdeps/generic"; then
991
992 changequote(,)dnl
993   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
994 changequote([,])dnl
995   if test $uname_sysname != $config_os; then
996     config_release=`echo $config_os | sed s/$uname_sysname//`
997   fi
998 dnl
999 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1000     if test -r /vmunix; then
1001       kernel_id=`strings /vmunix | grep UNIX`
1002     elif test -r /dynix; then
1003       kernel_id=`strings /dynix | grep DYNIX`
1004     else
1005       kernel_id=
1006     fi
1007 ])dnl
1008
1009   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1010 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1011 changequote(,)dnl
1012   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1013 changequote([,])dnl
1014   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1015          != x$config_release; then
1016     # The configuration release is a substring of the kernel release.
1017     libc_cv_uname_release=$kernel_release
1018   elif test x$config_release != x; then
1019     libc_cv_uname_release=$config_release
1020   elif test x$kernel_release != x; then
1021     libc_cv_uname_release=$kernel_release
1022   else
1023     libc_cv_uname_release=unknown
1024   fi])
1025   uname_release="$libc_cv_uname_release"
1026
1027   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1028 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1029 changequote(,)dnl
1030   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1031 changequote([,])dnl
1032   if test -n "$kernel_version"; then
1033     libc_cv_uname_version="$kernel_version"
1034   else
1035     libc_cv_uname_version=unknown
1036   fi])
1037   uname_version="$libc_cv_uname_version"
1038
1039 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1040   config_uname=config-name.h:config-name.in
1041 else
1042   # For non-generic uname, we don't need to create config-name.h at all.
1043   config_uname=
1044 fi
1045
1046 AC_MSG_CHECKING(stdio selection)
1047 AC_SUBST(stdio)
1048 case $stdio in
1049 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1050 default) stdio=stdio ;;
1051 esac
1052 AC_MSG_RESULT($stdio)
1053
1054 AC_MSG_CHECKING(ldap selection)
1055 AC_SUBST(LDAP)
1056 case $add_ons in
1057 *ldap*)
1058    ldap=yes
1059    LDAP=ldap ;;
1060 *) ldap=no
1061    LDAP= ;;
1062 esac
1063 AC_MSG_RESULT($ldap)
1064
1065 AC_SUBST(libc_cv_slibdir)
1066 AC_SUBST(libc_cv_sysconfdir)
1067 AC_SUBST(libc_cv_rootsbindir)
1068
1069 AC_SUBST(has_ldconfig)
1070
1071 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1072 if test $gnu_ld = yes; then
1073   AC_DEFINE(HAVE_GNU_LD)
1074 fi
1075 if test $gnu_as = yes; then
1076   AC_DEFINE(HAVE_GNU_AS)
1077 fi
1078 if test $elf = yes; then
1079   AC_DEFINE(HAVE_ELF)
1080 fi
1081
1082 AC_SUBST(static)
1083 AC_SUBST(shared)
1084 if test $shared = default; then
1085   if test $gnu_ld = yes; then
1086     shared=$elf
1087   else
1088     # For now we do not assume shared libs are available.  In future more
1089     # tests might become available.
1090     shared=no
1091   fi
1092 fi
1093
1094 dnl We must not allow compilation without static library on some platforms.
1095 if test $static = no && test $shared = yes; then
1096   case "$host_os" in
1097   linux* | gnu*)
1098     AC_MSG_ERROR([
1099 *** You must compile with support for the static library since the shared
1100 *** library uses it.  Restart configure without \`--disable-static'.])
1101     ;;
1102   *)
1103     ;;
1104   esac
1105 fi
1106
1107 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1108 [pic_default=yes
1109 cat > conftest.c <<EOF
1110 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1111 # error PIC is default.
1112 #endif
1113 EOF
1114 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1115   pic_default=no
1116 fi
1117 rm -f conftest.*])
1118 AC_SUBST(pic_default)
1119
1120 AC_SUBST(profile)
1121 AC_SUBST(omitfp)
1122 AC_SUBST(bounded)
1123 AC_SUBST(static_nss)
1124 AC_SUBST(nopic_initfini)
1125
1126 AC_SUBST(DEFINES)
1127
1128 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1129   config_makefile=
1130 else
1131   config_makefile=Makefile
1132 fi
1133
1134 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1135 AC_SUBST(VERSION)
1136
1137 if test $libc_cv_gcc_pipe_bug = yes; then
1138  realCC=$CC
1139  CC=$makeCC
1140  CFLAGS=$makeCFLAGS
1141 fi
1142 AC_OUTPUT_COMMANDS([
1143 if test "$realCC"; then
1144  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1145  mv specsT specs
1146 fi], [realCC=$realCC])
1147
1148 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1149           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])