(--enable-libio): If not present, set $stdio to "default".
[kopensolaris-gnu/glibc.git] / configure.in
1 Dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.4.2)dnl             dnl Minimum Autoconf version required.
4 AC_INIT(features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37   --with-fp               if using floating-point hardware,
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(gnu-binutils, dnl
40   --with-gnu-binutils     if using GNU binutils (as and ld),
41             gnu_binutils=$withval, gnu_binutils=no)
42 AC_ARG_WITH(gnu-ld, dnl
43   --with-gnu-ld           if using GNU ld (in the binutils package),
44             gnu_ld=$withval, gnu_ld=no)
45 AC_ARG_WITH(gnu-as, dnl
46   --with-gnu-as           if using GNU as (in the binutils package),
47             gnu_as=$withval, gnu_as=no)
48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
49 AC_ARG_WITH(elf, dnl
50   --with-elf              if using the ELF object format,
51             elf=$withval, elf=no)
52 AC_ARG_WITH(weak-symbols, dnl
53   --with-weak-symbols     if weak symbols are available in as and ld,
54             weak=$withval, weak=no)
55
56 AC_ARG_ENABLE(libio, dnl
57 [  --enable-libio          build in GNU libio instead of GNU stdio],
58               stdio=libio, stdio=default)
59
60 dnl Arguments to enable or disable building the shared, profiled, and
61 dnl -fomit-frame-pointer libraries.
62 AC_ARG_ENABLE(shared, dnl
63 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
64             shared=$enableval, shared=default)
65 AC_ARG_ENABLE(profile, dnl
66 [  --enable-profile        build profiled library [default=yes]],
67             profile=$enableval, profile=yes)
68 AC_ARG_ENABLE(omitfp, dnl
69 [  --enable-omitfp       build undebuggable optimized library [default=no]],
70             omitfp=$enableval, omitfp=no)
71
72 AC_CANONICAL_HOST
73 # We keep the original values in `$config_*' and never modify them, so we
74 # can write them unchanged into config.make.  Everything else uses
75 # $machine, $vendor, and $os, and changes them whenever convenient.
76 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
77
78 # Some configurations imply other options.
79 case "$host_os" in
80 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
81   # These systems always use GNU tools.
82   gnu_ld=yes gnu_as=yes
83 esac
84 case "$host_os" in
85 gnu* | linux* | sysv4* | solaris2*)
86   # These systems always use the ELF format.
87   elf=yes
88 esac
89
90 # Compute the list of sysdep directories for this configuration.
91 sysdep_dir=$srcdir/sysdeps
92 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
93 machine=$config_machine
94 vendor=$config_vendor
95 os=$config_os
96
97 dnl We need to use [ and ] for other purposes for a while now.
98 changequote(,)dnl
99 # Expand the configuration machine name into a subdirectory by architecture
100 # type and particular chip.
101 case "$machine" in
102 a29k | am29000) machine=a29k ;;
103 alpha*)         machine=alpha/$machine ;;
104 hppa*)          machine=hppa/$machine ;;
105 i[345]86)       machine=i386/$machine ;;
106 m680?0)         machine=m68k/$machine ;;
107 m68k)           machine=m68k/m68020 ;;
108 m88???)         machine=m88k/$machine ;;
109 m88k)           machine=m88k/m88100 ;;
110 mips*)          machine=mips/$machine ;;
111 mips64*)        machine=mips/mips64/$machine ;;
112 sparc[6789])    machine=sparc/$machine ;;
113 supersparc)     machine=sparc/sparc8 ;;
114 esac
115
116 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
117 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
118
119 case "$os" in
120 gnu*)
121   base_os=mach/hurd ;;
122 netbsd* | 386bsd* | freebsd* | bsdi*)
123   base_os=unix/bsd/bsd4.4 ;;
124 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
125   base_os=unix/bsd ;;
126 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
127   base_os=unix/sysv ;;
128 solaris[2-9]*)
129   base_os=unix/sysv/sysv4 ;;
130 none)
131   base_os=standalone ;;
132 *)
133   base_os='' ;;
134 esac
135
136 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
137 tail=$os
138 ostry=$os
139 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
140   ostry="$ostry /$o"
141   tail=$o
142 done
143 o=`echo $tail | sed 's/[0-9]*$//'`
144 if test $o != $tail; then
145   ostry="$ostry /$o"
146 fi
147
148 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
149 base=
150 tail=$base_os
151 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
152   set $b
153   base="$base /$1"
154   tail="$2"
155 done
156
157 # For sparc/sparc9, try sparc/sparc9 and then sparc.
158 mach=
159 tail=$machine
160 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
161   set $m
162   # Prepend the machine's FPU directory unless --without-fp.
163   if test "$with_fp" = yes; then
164     mach="$mach /$1/fpu"
165   fi
166   mach="$mach /$1"
167   tail="$2"
168 done
169
170 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
171 changequote([,])dnl
172
173 # Find what sysdep directories exist.
174 sysnames=
175 for b in $base ''; do
176   for m0 in $mach ''; do
177     for v in /$vendor ''; do
178       for o in /$ostry ''; do
179         for m in $mach ''; do
180           try="$m0$b$v$o$m"
181           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
182           if test -d $sysdep_dir$try; then
183             sysnames="$sysnames $try"
184             { test -n "$o" || test -n "$b"; } && os_used=t
185             { test -n "$m" || test -n "$m0"; } && machine_used=t
186           fi
187         done
188       done
189     done
190   done
191 done
192
193 if test -z "$os_used" && test "$os" != none; then
194   AC_MSG_ERROR(Operating system $os is not supported.)
195 fi
196 if test -z "$machine_used" && test "$machine" != none; then
197   AC_MSG_ERROR(The $machine is not supported.)
198 fi
199
200 # We have now validated the configuration.
201
202
203 # If using ELF, look for an `elf' subdirectory of each machine directory.
204 # We prepend these rather than inserting them whereever the machine appears
205 # because things specified by the machine's ELF ABI should override
206 # OS-specific things, and should always be the same for any OS on the
207 # machine (otherwise what's the point of an ABI?).
208 if test "$elf" = yes; then
209   elf_dirs=
210   for m in $mach; do
211     if test -d $sysdep_dir$m/elf; then
212       elf_dirs="$elf_dirs $m/elf"
213     fi
214   done
215   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
216 fi
217
218
219 # Remove the leading slashes.
220 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
221
222
223 # Expand the list of system names into a full list of directories
224 # from each element's parent name and Implies file (if present).
225 set $sysnames
226 while test $# -gt 0; do
227   name=$1
228   shift
229
230   if test -f $sysdep_dir/$name/Implies; then
231     # Collect more names from the `Implies' file (removing comments).
232     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
233     for x in $implied; do
234       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
235     done
236   else
237     implied=
238   fi
239
240   # Add NAME to the list of names.
241   names="$names $name"
242
243   # Find the parent of NAME, using the empty string if it has none.
244 changequote(,)dnl
245   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
246 changequote([,])dnl
247
248   # Add the names implied by NAME, and NAME's parent (if it has one), to
249   # the list of names to be processed (the argument list).  We prepend the
250   # implied names to the list and append the parent.  We want implied
251   # directories to come before further directories inferred from the
252   # configuration components; this ensures that for sysv4, unix/common
253   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
254   # after sysv4).
255   sysnames="`echo $implied $* $parent`"
256   test -n "$sysnames" && set $sysnames
257 done
258
259 # Add the default directories.
260 names="$names generic stub"
261
262 # Now uniquize the list.
263 seen=
264 sysnames=
265 for name in $names; do
266   if echo "$seen" | fgrep -x $name >/dev/null; then
267     # Already in the list.
268     true;
269   else
270     # A new one.
271     if test -z "$seen"; then
272       seen="$name" sysnames="$name"
273     else
274       seen="$seen
275 $name"
276       sysnames="$sysnames $name"
277     fi
278   fi
279 done
280 libc_cv_sysdirs="$sysnames"])
281 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
282
283 AC_PROG_INSTALL
284 if test "$INSTALL" = "${srcdir}/install-sh"; then
285   # The makefiles need to use a different form to find it in $srcdir.
286   INSTALL='$(..)./install-sh'
287 fi
288
289 AC_CHECK_TOOL(CC, gcc)
290 AC_CHECK_TOOL(AR, ar)
291 AC_CHECK_TOOL(RANLIB, ranlib, :)
292 AC_PROG_CPP
293
294 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
295 echo '#include <stddef.h>
296 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
297 if eval "$ac_cpp conftest.c 2>/dev/null" \
298 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
299   libc_cv_signed_size_t=no
300 else
301   libc_cv_signed_size_t=yes
302 fi
303 rm -f conftest*])
304 if test $libc_cv_signed_size_t = yes; then
305   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
306   cat >> confdefs.h <<\EOF
307 #undef __SIZE_TYPE__
308 #define __SIZE_TYPE__ unsigned
309 EOF
310 fi
311
312 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
313 AC_TRY_COMPILE(dnl
314 [#define __need_size_t
315 #define __need_wchar_t
316 #include <stddef.h>
317 #define __need_NULL
318 #include <stddef.h>], [size_t size; wchar_t wchar;
319 #ifdef offsetof
320 #error stddef.h ignored __need_*
321 #endif
322 if (&size == NULL || &wchar == NULL) abort ();],
323                libc_cv_friendly_stddef=yes,
324                libc_cv_friendly_stddef=no)])
325 if test $libc_cv_friendly_stddef = yes; then
326   config_vars="$config_vars
327 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
328 fi
329
330 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
331                libc_cv_need_minus_P, [dnl
332 cat > conftest.S <<EOF
333 #include "confdefs.h"
334 /* Nothing whatsoever.  */
335 EOF
336 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
337   libc_cv_need_minus_P=no
338 else
339   libc_cv_need_minus_P=yes
340 fi
341 rm -f conftest*])
342 if test $libc_cv_need_minus_P = yes; then
343   config_vars="$config_vars
344 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
345 fi
346
347 AC_CACHE_CHECK(for assembler global-symbol directive,
348                libc_cv_asm_global_directive, [dnl
349 libc_cv_asm_global_directive=UNKNOWN
350 for ac_globl in .globl .global; do
351   cat > conftest.s <<EOF
352 .text
353 ${ac_globl} foo
354 foo: .long 0
355 EOF
356   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
357     libc_cv_asm_global_directive=${ac_globl}
358   fi
359   rm -f conftest*
360   test $libc_cv_asm_global_directive != UNKNOWN && break
361 done])
362 if test $libc_cv_asm_global_directive = UNKNOWN; then
363   AC_MSG_ERROR(cannot determine asm global directive)
364 else
365   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
366 fi
367
368 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
369 cat > conftest.s <<EOF
370 .text
371 foo: .long 0
372 .set glibc_conftest_frobozz,foo
373 $libc_cv_asm_global_directive glibc_conftest_frobozz
374 EOF
375 # The alpha-dec-osf1 assembler gives only a warning for `.set'
376 # (but it doesn't work), so we must do a linking check to be sure.
377 cat > conftest1.c <<\EOF
378 extern int glibc_conftest_frobozz;
379 main () { printf ("%d\n", glibc_conftest_frobozz); }
380 EOF
381 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
382             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
383   libc_cv_asm_set_directive=yes
384 else
385   libc_cv_asm_set_directive=no
386 fi
387 rm -f conftest*])
388 if test $libc_cv_asm_set_directive = yes; then
389   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
390 fi
391
392 if test $elf != yes; then
393   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
394                  [AC_TRY_COMPILE(, [asm (".section .init");
395                                     asm (".section .fini");],
396                                  libc_cv_have_initfini=yes,
397                                  libc_cv_have_initfini=no)])
398   AC_SUBST(libc_cv_have_initfini)dnl
399   if test $libc_cv_have_initfini = yes; then
400     AC_DEFINE(HAVE_INITFINI)
401   fi
402 fi
403
404 # sysdeps configure fragments may set these with files to be linked below.
405 libc_link_dests=
406 libc_link_sources=
407
408 # Iterate over all the sysdep directories we will use, running their
409 # configure fragments, and looking for a uname implementation.
410 uname=
411 for dir in $sysnames; do
412   if test -r $sysdep_dir/$dir/configure; then
413     AC_MSG_RESULT(running configure fragment for $dir)
414     . $sysdep_dir/$dir/configure
415   fi
416   if test -z "$uname"; then
417     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
418     && uname=$dir
419   fi
420 done
421
422 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
423
424 # If we will use the generic uname implementation, we must figure out what
425 # it will say by examining the system, and write the results in config-name.h.
426 if test "$uname" = generic; then
427
428 changequote(,)dnl
429   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
430 changequote([,])dnl
431   if test $uname_sysname != $config_os; then
432     config_release=`echo $config_os | sed s/$uname_sysname//`
433   fi
434 dnl
435 AC_DEFUN(LIBC_KERNEL_ID, [dnl
436     if test -r /vmunix; then
437       kernel_id=`strings /vmunix | grep UNIX`
438     elif test -r /dynix; then
439       kernel_id=`strings /dynix | grep DYNIX`
440     else
441       kernel_id=
442     fi
443 ])dnl
444
445   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
446 AC_REQUIRE([LIBC_KERNEL_ID])dnl
447 changequote(,)dnl
448   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
449 changequote([,])dnl
450   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
451          != x$config_release; then
452     # The configuration release is a substring of the kernel release.
453     libc_cv_uname_release=$kernel_release
454   elif test x$config_release != x; then
455     libc_cv_uname_release=$config_release
456   elif test x$kernel_release != x; then
457     libc_cv_uname_release=$kernel_release
458   else
459     libc_cv_uname_release=unknown
460   fi])
461   uname_release="$libc_cv_uname_release"
462
463   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
464 AC_REQUIRE([LIBC_KERNEL_ID])dnl
465 changequote(,)dnl
466   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
467 changequote([,])dnl
468   if test -n "$kernel_version"; then
469     libc_cv_uname_version="$kernel_version"
470   else
471     libc_cv_uname_version=unknown
472   fi])
473   uname_version="$libc_cv_uname_version"
474
475 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
476   config_uname=config-name.h:config-name.in
477 else
478   # For non-generic uname, we don't need to create config-name.h at all.
479   config_uname=
480 fi
481
482 AC_MSG_CHECKING(stdio selection)
483 AC_SUBST(stdio)
484 case $stdio in
485 libio) AC_DEFINE(USE_IN_LIBIO) ;;
486 default) stdio=stdio ;;
487 esac
488 AC_MSG_RESULT($stdio)
489
490 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
491 if test $gnu_ld = yes; then
492   AC_DEFINE(HAVE_GNU_LD)
493 fi
494 if test $gnu_as = yes; then
495   AC_DEFINE(HAVE_GNU_AS)
496 fi
497 if test $elf = yes; then
498   AC_DEFINE(HAVE_ELF)
499 fi
500 if test $weak = yes; then
501   AC_DEFINE(HAVE_WEAK_SYMBOLS)
502 fi
503
504 AC_SUBST(shared)
505 if test $shared = default; then
506   if test $gnu_ld = yes; then
507     shared=$elf
508   fi
509 fi
510 AC_SUBST(profile)
511 AC_SUBST(omitfp)
512
513 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
514   config_makefile=
515 else
516   config_makefile=Makefile
517 fi
518
519 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
520           [echo '$config_vars' >> config.make])