Mon Jun 17 19:03:36 1996 Andreas Schwab <schwab@issan.informatik.uni-dortmund.de>
[kopensolaris-gnu/glibc.git] / configure.in
1 Dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.10)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37   --with-fp               if using floating-point hardware [default=yes],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(gnu-binutils, dnl
40   --with-gnu-binutils     if using GNU binutils (as and ld),
41             gnu_binutils=$withval, gnu_binutils=no)
42 AC_ARG_WITH(gnu-ld, dnl
43   --with-gnu-ld           if using GNU ld (in the binutils package),
44             gnu_ld=$withval, gnu_ld=no)
45 AC_ARG_WITH(gnu-as, dnl
46   --with-gnu-as           if using GNU as (in the binutils package),
47             gnu_as=$withval, gnu_as=no)
48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
49 AC_ARG_WITH(elf, dnl
50   --with-elf              if using the ELF object format,
51             elf=$withval, elf=no)
52
53 AC_ARG_ENABLE(libio, dnl
54 [  --enable-libio          build in GNU libio instead of GNU stdio],
55               [if test $enableval = yes; then
56                  stdio=libio
57                else
58                  stdio=stdio
59                fi],
60               stdio=default)
61
62 dnl Arguments to enable or disable building the shared, profiled, and
63 dnl -fomit-frame-pointer libraries.
64 AC_ARG_ENABLE(shared, dnl
65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
66             shared=$enableval, shared=default)
67 AC_ARG_ENABLE(profile, dnl
68 [  --enable-profile        build profiled library [default=yes]],
69             profile=$enableval, profile=yes)
70 AC_ARG_ENABLE(omitfp, dnl
71 [  --enable-omitfp       build undebuggable optimized library [default=no]],
72             omitfp=$enableval, omitfp=no)
73
74 AC_CANONICAL_HOST
75 # We keep the original values in `$config_*' and never modify them, so we
76 # can write them unchanged into config.make.  Everything else uses
77 # $machine, $vendor, and $os, and changes them whenever convenient.
78 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
79
80 # Some configurations imply other options.
81 case "$host_os" in
82 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
83   # These systems always use GNU tools.
84   gnu_ld=yes gnu_as=yes ;;
85 esac
86 case "$host_os" in
87 gnu* | linux* | sysv4* | solaris2*)
88   # These systems always use the ELF format.
89   if test "$host_cpu" != alpha; then    # Linux/Alpha is not fully ELF yet
90     elf=yes
91   fi
92   ;;
93 esac
94
95 machine=$config_machine
96 vendor=$config_vendor
97 os=$config_os
98
99 dnl We need to use [ and ] for other purposes for a while now.
100 changequote(,)dnl
101 # Expand the configuration machine name into a subdirectory by architecture
102 # type and particular chip.
103 case "$machine" in
104 a29k | am29000) base_machine=a29k machine=a29k ;;
105 alpha*)         base_machine=alpha machine=alpha/$machine ;;
106 hppa*)          base_machine=hppa machine=hppa/$machine ;;
107 i[345]86)       base_machine=i386 machine=i386/$machine ;;
108 m680?0)         base_machine=m68k machine=m68k/$machine ;;
109 m68k)           base_machine=m68k machine=m68k/m68020 ;;
110 m88???)         base_machine=m88k machine=m88k/$machine ;;
111 m88k)           base_machine=m88k machine=m88k/m88100 ;;
112 mips*)          base_machine=mips machine=mips/$machine ;;
113 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
114 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
115 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
116 esac
117 changequote([,])dnl
118 AC_SUBST(base_machine)
119
120 # Compute the list of sysdep directories for this configuration.
121 # This can take a while to compute.
122 sysdep_dir=$srcdir/sysdeps
123 AC_MSG_CHECKING(sysdep dirs)
124 dnl We need to use [ and ] for other purposes for a while now.
125 changequote(,)dnl
126 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
127 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
128
129 case "$os" in
130 gnu*)
131   base_os=mach/hurd ;;
132 netbsd* | 386bsd* | freebsd* | bsdi*)
133   base_os=unix/bsd/bsd4.4 ;;
134 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
135   base_os=unix/bsd ;;
136 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
137   base_os=unix/sysv ;;
138 solaris[2-9]*)
139   base_os=unix/sysv/sysv4 ;;
140 none)
141   base_os=standalone ;;
142 *)
143   base_os='' ;;
144 esac
145
146 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
147 tail=$os
148 ostry=$os
149 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
150   ostry="$ostry /$o"
151   tail=$o
152 done
153 o=`echo $tail | sed 's/[0-9]*$//'`
154 if test $o != $tail; then
155   ostry="$ostry /$o"
156 fi
157
158 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
159 base=
160 tail=$base_os
161 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
162   set $b
163   base="$base /$1"
164   tail="$2"
165 done
166
167 # For sparc/sparc9, try sparc/sparc9 and then sparc.
168 mach=
169 tail=$machine
170 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
171   set $m
172   # Prepend the machine's FPU directory unless --without-fp.
173   if test "$with_fp" = yes; then
174     mach="$mach /$1/fpu"
175   fi
176   mach="$mach /$1"
177   tail="$2"
178 done
179
180 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
181 changequote([,])dnl
182
183 # Find what sysdep directories exist.
184 sysnames=
185 for b in $base ''; do
186   for m0 in $mach ''; do
187     for v in /$vendor ''; do
188       for o in /$ostry ''; do
189         for m in $mach ''; do
190           try="$m0$b$v$o$m"
191           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
192           if test -d $sysdep_dir$try; then
193             sysnames="$sysnames $try"
194             { test -n "$o" || test -n "$b"; } && os_used=t
195             { test -n "$m" || test -n "$m0"; } && machine_used=t
196           fi
197         done
198       done
199     done
200   done
201 done
202
203 if test -z "$os_used" && test "$os" != none; then
204   AC_MSG_ERROR(Operating system $os is not supported.)
205 fi
206 if test -z "$machine_used" && test "$machine" != none; then
207   AC_MSG_ERROR(The $machine is not supported.)
208 fi
209
210 # We have now validated the configuration.
211
212
213 # If using ELF, look for an `elf' subdirectory of each machine directory.
214 # We prepend these rather than inserting them whereever the machine appears
215 # because things specified by the machine's ELF ABI should override
216 # OS-specific things, and should always be the same for any OS on the
217 # machine (otherwise what's the point of an ABI?).
218 if test "$elf" = yes; then
219   elf_dirs=
220   for m in $mach; do
221     if test -d $sysdep_dir$m/elf; then
222       elf_dirs="$elf_dirs $m/elf"
223     fi
224   done
225   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
226 fi
227
228
229 # Remove the leading slashes.
230 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
231
232
233 # Expand the list of system names into a full list of directories
234 # from each element's parent name and Implies file (if present).
235 set $sysnames
236 names=
237 while test $# -gt 0; do
238   name=$1
239   shift
240
241   case " $names " in *" $name "*)
242     # Already in the list.
243     continue
244   esac
245
246   # Report each name as we discover it, so there is no long pause in output.
247   echo $ac_n "$name $ac_c" >&AC_FD_MSG
248
249   if test -f $sysdep_dir/$name/Implies; then
250     # Collect more names from the `Implies' file (removing comments).
251     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
252     for x in $implied; do
253       test -d $sysdep_dir/$x || {
254         AC_MSG_WARN(sysdeps/$name/Implies specifies nonexistent $x)
255       }
256     done
257   else
258     implied=
259   fi
260
261   # Add NAME to the list of names.
262   names="$names $name"
263
264   # Find the parent of NAME, using the empty string if it has none.
265 changequote(,)dnl
266   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
267 changequote([,])dnl
268
269   # Add the names implied by NAME, and NAME's parent (if it has one), to
270   # the list of names to be processed (the argument list).  We prepend the
271   # implied names to the list and append the parent.  We want implied
272   # directories to come before further directories inferred from the
273   # configuration components; this ensures that for sysv4, unix/common
274   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
275   # after sysv4).
276   sysnames="`echo $implied $* $parent`"
277   test -n "$sysnames" && set $sysnames
278 done
279
280 # Add the default directories.
281 sysnames="$names generic stub"
282 AC_SUBST(sysnames)
283 # The other names were emitted during the scan.
284 AC_MSG_RESULT(generic stub)
285
286
287 ### Locate tools.
288
289 AC_PROG_INSTALL
290 if test "$INSTALL" = "${srcdir}/install-sh"; then
291   # The makefiles need to use a different form to find it in $srcdir.
292   INSTALL='$(..)./install-sh'
293 fi
294 AC_PROG_LN_S
295 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
296
297 AC_CHECK_TOOL(CC, gcc)
298 AC_PROG_CPP
299 AC_CHECK_TOOL(AR, ar)
300 AC_CHECK_TOOL(RANLIB, ranlib, :)
301
302 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
303 echo '#include <stddef.h>
304 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
305 if eval "$ac_cpp conftest.c 2>/dev/null" \
306 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
307   libc_cv_signed_size_t=no
308 else
309   libc_cv_signed_size_t=yes
310 fi
311 rm -f conftest*])
312 if test $libc_cv_signed_size_t = yes; then
313   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
314   cat >> confdefs.h <<\EOF
315 #undef __SIZE_TYPE__
316 #define __SIZE_TYPE__ unsigned
317 EOF
318 fi
319
320 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
321 AC_TRY_COMPILE(dnl
322 [#define __need_size_t
323 #define __need_wchar_t
324 #include <stddef.h>
325 #define __need_NULL
326 #include <stddef.h>], [size_t size; wchar_t wchar;
327 #ifdef offsetof
328 #error stddef.h ignored __need_*
329 #endif
330 if (&size == NULL || &wchar == NULL) abort ();],
331                libc_cv_friendly_stddef=yes,
332                libc_cv_friendly_stddef=no)])
333 if test $libc_cv_friendly_stddef = yes; then
334   config_vars="$config_vars
335 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
336 fi
337
338 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
339                libc_cv_need_minus_P, [dnl
340 cat > conftest.S <<EOF
341 #include "confdefs.h"
342 /* Nothing whatsoever.  */
343 EOF
344 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
345   libc_cv_need_minus_P=no
346 else
347   libc_cv_need_minus_P=yes
348 fi
349 rm -f conftest*])
350 if test $libc_cv_need_minus_P = yes; then
351   config_vars="$config_vars
352 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
353 fi
354
355 AC_CACHE_CHECK(for assembler global-symbol directive,
356                libc_cv_asm_global_directive, [dnl
357 libc_cv_asm_global_directive=UNKNOWN
358 for ac_globl in .globl .global; do
359   cat > conftest.s <<EOF
360 .text
361 ${ac_globl} foo
362 foo: .long 0
363 EOF
364   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
365     libc_cv_asm_global_directive=${ac_globl}
366   fi
367   rm -f conftest*
368   test $libc_cv_asm_global_directive != UNKNOWN && break
369 done])
370 if test $libc_cv_asm_global_directive = UNKNOWN; then
371   AC_MSG_ERROR(cannot determine asm global directive)
372 else
373   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
374 fi
375
376 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
377 cat > conftest.s <<EOF
378 .text
379 foo: .long 0
380 .set glibc_conftest_frobozz,foo
381 $libc_cv_asm_global_directive glibc_conftest_frobozz
382 EOF
383 # The alpha-dec-osf1 assembler gives only a warning for `.set'
384 # (but it doesn't work), so we must do a linking check to be sure.
385 cat > conftest1.c <<\EOF
386 extern int glibc_conftest_frobozz;
387 main () { printf ("%d\n", glibc_conftest_frobozz); }
388 EOF
389 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
390             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
391   libc_cv_asm_set_directive=yes
392 else
393   libc_cv_asm_set_directive=no
394 fi
395 rm -f conftest*])
396 if test $libc_cv_asm_set_directive = yes; then
397   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
398 fi
399
400 if test $elf != yes; then
401   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
402                  [AC_TRY_COMPILE(, [asm (".section .init");
403                                     asm (".section .fini");
404                                     asm (".text");],
405                                  libc_cv_have_initfini=yes,
406                                  libc_cv_have_initfini=no)])
407   AC_SUBST(libc_cv_have_initfini)dnl
408   if test $libc_cv_have_initfini = yes; then
409     AC_DEFINE(HAVE_INITFINI)
410   fi
411 fi
412
413 if test $elf = yes; then
414   libc_cv_asm_underscores=no
415 else
416   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
417                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
418                               libc_cv_asm_underscores=yes,
419                               libc_cv_asm_underscores=no)])
420 fi
421 if test $libc_cv_asm_underscores = no; then
422   AC_DEFINE(NO_UNDERSCORES)
423 fi
424
425 if test $elf = yes; then
426   libc_cv_weak_symbols=yes
427   libc_cv_asm_weak_directive=yes
428   libc_cv_asm_weakext_directive=no
429 else
430   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
431                  [dnl
432 cat > conftest.s <<EOF
433 .text
434 ${libc_cv_asm_global_directive} foo
435 foo: .long 0
436 .weak foo
437 .weak bar; bar = foo
438 EOF
439   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
440     libc_cv_asm_weak_directive=yes
441   else
442     libc_cv_asm_weak_directive=no
443   fi
444   rm -f conftest*])
445
446 if test $libc_cv_asm_weak_directive = no; then
447   AC_CACHE_CHECK(for assembler .weakext directive,
448                  libc_cv_asm_weakext_directive,
449                  [dnl
450 cat > conftest.s <<EOF
451 .text
452 ${libc_cv_asm_global_directive} foo
453 foo: .long 0
454 .weakext foo
455 .weakext foo, bar
456 EOF
457   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
458     libc_cv_asm_weakext_directive=yes
459   else
460     libc_cv_asm_weakext_directive=no
461   fi
462   rm -f conftest*])
463
464   fi # no .weak
465 fi # not ELF
466
467 if test $libc_cv_asm_weak_directive = yes; then
468   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
469 elif test $libc_cv_asm_weakext_directive = yes; then
470   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
471 fi
472
473 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
474 cat > conftest.c <<\EOF
475 main () { exit (0); }
476 EOF
477 if ${CC-cc} $CFLAGS -Wl,--no-whole-archive \
478             -o conftest conftest.c 2>/dev/null; then
479   libc_cv_ld_no_whole_archive=yes
480 else
481   libc_cv_ld_no_whole_archive=no
482 fi
483 rm -f conftest*])
484 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
485
486 ### End of automated tests.
487 ### Now run sysdeps configure fragments.
488
489 # sysdeps configure fragments may set these with files to be linked below.
490 libc_link_dests=
491 libc_link_sources=
492
493 # Iterate over all the sysdep directories we will use, running their
494 # configure fragments, and looking for a uname implementation.
495 uname=
496 for dir in $sysnames; do
497   if test -r $sysdep_dir/$dir/configure; then
498     AC_MSG_RESULT(running configure fragment for $dir)
499     . $sysdep_dir/$dir/configure
500   fi
501 [
502   if test -z "$uname"; then
503     if test -r $sysdep_dir/$dir/uname.c ||
504        test -r $sysdep_dir/$dir/uname.S ||
505        { test -r $sysdep_dir/$dir/syscalls.list &&
506          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
507       uname=$dir
508     fi
509   fi
510 ]dnl
511 done
512
513 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
514
515 # If we will use the generic uname implementation, we must figure out what
516 # it will say by examining the system, and write the results in config-name.h.
517 if test "$uname" = generic; then
518
519 changequote(,)dnl
520   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
521 changequote([,])dnl
522   if test $uname_sysname != $config_os; then
523     config_release=`echo $config_os | sed s/$uname_sysname//`
524   fi
525 dnl
526 AC_DEFUN(LIBC_KERNEL_ID, [dnl
527     if test -r /vmunix; then
528       kernel_id=`strings /vmunix | grep UNIX`
529     elif test -r /dynix; then
530       kernel_id=`strings /dynix | grep DYNIX`
531     else
532       kernel_id=
533     fi
534 ])dnl
535
536   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
537 AC_REQUIRE([LIBC_KERNEL_ID])dnl
538 changequote(,)dnl
539   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
540 changequote([,])dnl
541   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
542          != x$config_release; then
543     # The configuration release is a substring of the kernel release.
544     libc_cv_uname_release=$kernel_release
545   elif test x$config_release != x; then
546     libc_cv_uname_release=$config_release
547   elif test x$kernel_release != x; then
548     libc_cv_uname_release=$kernel_release
549   else
550     libc_cv_uname_release=unknown
551   fi])
552   uname_release="$libc_cv_uname_release"
553
554   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
555 AC_REQUIRE([LIBC_KERNEL_ID])dnl
556 changequote(,)dnl
557   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
558 changequote([,])dnl
559   if test -n "$kernel_version"; then
560     libc_cv_uname_version="$kernel_version"
561   else
562     libc_cv_uname_version=unknown
563   fi])
564   uname_version="$libc_cv_uname_version"
565
566 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
567   config_uname=config-name.h:config-name.in
568 else
569   # For non-generic uname, we don't need to create config-name.h at all.
570   config_uname=
571 fi
572
573 AC_MSG_CHECKING(stdio selection)
574 AC_SUBST(stdio)
575 case $stdio in
576 libio) AC_DEFINE(USE_IN_LIBIO) ;;
577 default) stdio=stdio ;;
578 esac
579 AC_MSG_RESULT($stdio)
580
581 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
582 if test $gnu_ld = yes; then
583   AC_DEFINE(HAVE_GNU_LD)
584 fi
585 if test $gnu_as = yes; then
586   AC_DEFINE(HAVE_GNU_AS)
587 fi
588 if test $elf = yes; then
589   AC_DEFINE(HAVE_ELF)
590 fi
591
592 AC_SUBST(shared)
593 if test $shared = default; then
594   if test $gnu_ld = yes; then
595     shared=$elf
596   fi
597 fi
598 AC_SUBST(profile)
599 AC_SUBST(omitfp)
600
601 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
602   config_makefile=
603 else
604   config_makefile=Makefile
605 fi
606
607 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
608           [echo '$config_vars' >> config.make])