(HAVE_DWARF2_UNWIND_INFO_STATIC): Define it if gcc uses static
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45
46 AC_ARG_ENABLE(libio, dnl
47 [  --enable-libio          build in GNU libio instead of GNU stdio],
48               [if test $enableval = yes; then
49                  stdio=libio
50                else
51                  stdio=stdio
52                fi],
53               stdio=default)
54
55 AC_ARG_ENABLE(sanity-checks, dnl
56 [  --disable-sanity-checks really do not use threads (should not be used
57                           except in special situations) [default=yes]],
58               enable_sanity=$enableval, enable_sanity=yes)
59
60 dnl Arguments to enable or disable building the static, shared, profiled,
61 dnl and -fomit-frame-pointer libraries.
62 AC_ARG_ENABLE(static, dnl
63 [  --enable-static         build static library [default=yes]],
64               static=$enableval, static=yes)
65 AC_ARG_ENABLE(shared, dnl
66 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
67               shared=$enableval, shared=default)
68 AC_ARG_ENABLE(profile, dnl
69 [  --enable-profile        build profiled library [default=yes]],
70               profile=$enableval, profile=yes)
71 AC_ARG_ENABLE(omitfp, dnl
72 [  --enable-omitfp         build undebuggable optimized library [default=no]],
73               omitfp=$enableval, omitfp=no)
74 AC_ARG_ENABLE(bounded, dnl
75 [  --enable-bounded        build with runtime bounds checking [default=no]],
76               bounded=$enableval, bounded=no)
77 AC_ARG_ENABLE(versioning, dnl
78 [  --disable-versioning    do not include versioning information in the
79                           library objects [default=yes if supported]],
80              enable_versioning=$enableval, enable_versioning=yes)
81
82 dnl Generic infrastructure for drop-in additions to libc.
83 AC_ARG_ENABLE(add-ons, dnl
84 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
85                                   search for add-ons if no parameter given],
86   [case "$enableval" in
87     yes) add_ons=`echo $srcdir/*/configure | \
88                   sed -e "s!$srcdir/!!g" -e 's!/configure!!g'`;;
89     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
90    esac],
91   [add_ons=])
92
93 AC_CONFIG_SUBDIRS($add_ons)
94 add_ons_pfx=
95 if test x"$add_ons" != x; then
96   for f in $add_ons; do
97     # Test whether such a subdir really exists.
98     if test -d $srcdir/$f; then
99       add_ons_pfx="$add_ons_pfx $f/"
100     else
101       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
102     fi
103   done
104 fi
105
106 dnl On some platforms we cannot use dynamic loading.  We must provide
107 dnl static NSS modules.
108 AC_ARG_ENABLE(static-nss, dnl
109 [  --enable-static-nss     build static NSS modules [default=no]],
110               static_nss=$enableval, static_nss=no)
111 if test x"$static_nss" = xyes; then
112   AC_DEFINE(DO_STATIC_NSS)
113 fi
114
115 AC_CANONICAL_HOST
116
117 # The way shlib-versions is used to generate soversions.mk uses a
118 # fairly simplistic model for name recognition that can't distinguish
119 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
120 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
121 # tell.  This doesn't get used much beyond that, so it's fairly safe.
122 case "$host_os" in
123 linux*)
124   ;;
125 gnu*)
126   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
127   ;;
128 esac
129
130 ###
131 ### I put this here to prevent those annoying emails from people who cannot
132 ### read and try to compile glibc on unsupported platforms.  --drepper
133 ###
134 ### By using the undocumented --enable-hacker-mode option for configure
135 ### one can skip this test to make the configuration not fail for unsupported
136 ### platforms.
137 ###
138 if test -z "$enable_hacker_mode"; then
139   case "$host_os" in
140   linux* | gnu*)
141     ;;
142   *)
143     echo "*** The GNU C library is currently not available for this platform."
144     echo "*** So far nobody cared to port it and if there is no volunteer it"
145     echo "*** might never happen.  So, if you have interest to see glibc on"
146     echo "*** this platform visit"
147     echo "***   http://www.gnu.ai.mit.edu/software/libc/porting.html"
148     echo "*** and join the group of porters"
149     exit 1
150     ;;
151   esac
152 fi
153
154 # We keep the original values in `$config_*' and never modify them, so we
155 # can write them unchanged into config.make.  Everything else uses
156 # $machine, $vendor, and $os, and changes them whenever convenient.
157 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
158
159 # Some configurations imply other options.
160 case "$host_os" in
161 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
162   # These systems always use GNU tools.
163   gnu_ld=yes gnu_as=yes ;;
164 esac
165 case "$host_os" in
166 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
167 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
168   ;;
169 gnu* | linux* | sysv4* | solaris2*)
170   # These systems (almost) always use the ELF format.
171   elf=yes
172   ;;
173 esac
174
175 machine=$config_machine
176 vendor=$config_vendor
177 os=$config_os
178
179 dnl We need to use [ and ] for other purposes for a while now.
180 changequote(,)dnl
181 # Expand the configuration machine name into a subdirectory by architecture
182 # type and particular chip.
183 case "$machine" in
184 a29k | am29000) base_machine=a29k machine=a29k ;;
185 alpha*)         base_machine=alpha machine=alpha/$machine ;;
186 arm*)           base_machine=arm machine=arm/$machine ;;
187 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
188 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
189 hppa*)          base_machine=hppa machine=hppa/$machine ;;
190 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
191 m680?0)         base_machine=m68k machine=m68k/$machine ;;
192 m68k)           base_machine=m68k machine=m68k/m68020 ;;
193 m88???)         base_machine=m88k machine=m88k/$machine ;;
194 m88k)           base_machine=m88k machine=m88k/m88100 ;;
195 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
196 mips*)          base_machine=mips machine=mips/$machine ;;
197 sparc | sparcv[67])
198                 base_machine=sparc machine=sparc/sparc32 ;;
199 sparcv8 | supersparc | hypersparc)
200                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
201 sparc64 | ultrasparc)
202                 base_machine=sparc machine=sparc/sparc64 ;;
203 esac
204 changequote([,])dnl
205 AC_SUBST(base_machine)
206
207 if test "$base_machine" = "i386"; then
208   AC_DEFINE(USE_REGPARMS)
209 fi
210
211 # Compute the list of sysdep directories for this configuration.
212 # This can take a while to compute.
213 sysdep_dir=$srcdir/sysdeps
214 AC_MSG_CHECKING(sysdep dirs)
215 dnl We need to use [ and ] for other purposes for a while now.
216 changequote(,)dnl
217 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
218 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
219
220 case "$os" in
221 gnu*)
222   base_os=mach/hurd ;;
223 netbsd* | 386bsd* | freebsd* | bsdi*)
224   base_os=unix/bsd/bsd4.4 ;;
225 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
226   base_os=unix/bsd ;;
227 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
228   base_os=unix/sysv ;;
229 solaris[2-9]*)
230   base_os=unix/sysv/sysv4 ;;
231 none)
232   base_os=standalone ;;
233 *)
234   base_os='' ;;
235 esac
236
237 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
238 tail=$os
239 ostry=$os
240 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
241   ostry="$ostry /$o"
242   tail=$o
243 done
244 o=`echo $tail | sed 's/[0-9]*$//'`
245 if test $o != $tail; then
246   ostry="$ostry /$o"
247 fi
248 # For linux-gnu, try linux-gnu, then linux.
249 o=`echo $tail | sed 's/-.*$//'`
250 if test $o != $tail; then
251   ostry="$ostry /$o"
252 fi
253
254 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
255 base=
256 tail=$base_os
257 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
258   set $b
259   base="$base /$1"
260   tail="$2"
261 done
262
263 # For sparc/sparc9, try sparc/sparc9 and then sparc.
264 mach=
265 tail=$machine
266 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
267   set $m
268   # Prepend the machine's FPU directory unless --without-fp.
269   if test "$with_fp" = yes; then
270     mach="$mach /$1/fpu"
271   fi
272   mach="$mach /$1"
273   tail="$2"
274 done
275
276 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
277 changequote([,])dnl
278
279 # Find what sysdep directories exist.
280 sysnames=
281 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
282 for d in $add_ons_pfx ''; do
283   for b in $base ''; do
284     for m0 in $mach ''; do
285       for v in /$vendor ''; do
286         for o in /$ostry ''; do
287           for m in $mach ''; do
288             if test "$m0$b$v$o$m"; then
289               try="${d}sysdeps$m0$b$v$o$m"
290               test -n "$enable_debug_configure" &&
291               echo "$0 [DEBUG]: try $try" >&2
292               case $try in
293                 /*) dest=$try ;;
294                 *)  dest=$srcdir/$try ;;
295               esac
296               if test -d $dest; then
297                 sysnames="$sysnames $try"
298                 { test -n "$o" || test -n "$b"; } && os_used=t
299                 { test -n "$m" || test -n "$m0"; } && machine_used=t
300               fi
301             fi
302           done
303         done
304       done
305     done
306   done
307 done
308 IFS="$ac_save_ifs"
309
310 if test -z "$os_used" && test "$os" != none; then
311   AC_MSG_ERROR(Operating system $os is not supported.)
312 fi
313 if test -z "$machine_used" && test "$machine" != none; then
314   AC_MSG_ERROR(The $machine is not supported.)
315 fi
316
317 # We have now validated the configuration.
318
319
320 # If using ELF, look for an `elf' subdirectory of each machine directory.
321 # We prepend these rather than inserting them whereever the machine appears
322 # because things specified by the machine's ELF ABI should override
323 # OS-specific things, and should always be the same for any OS on the
324 # machine (otherwise what's the point of an ABI?).
325 if test "$elf" = yes; then
326   elf_dirs=
327   for d in $add_ons_pfx ''; do
328     case $d in
329       /*) xsrcdir= ;;
330       *)  xsrcdir=$srcdir/ ;;
331     esac
332     for m in $mach; do
333       if test -d $xsrcdir${d}sysdeps$m/elf; then
334         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
335       fi
336     done
337   done
338   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
339 fi
340
341
342 # Expand the list of system names into a full list of directories
343 # from each element's parent name and Implies file (if present).
344 set $sysnames
345 names=
346 while test $# -gt 0; do
347   name=$1
348   shift
349
350   case " $names " in *" $name "*)
351     # Already in the list.
352     continue
353   esac
354
355   # Report each name as we discover it, so there is no long pause in output.
356   echo $ac_n "$name $ac_c" >&AC_FD_MSG
357
358   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
359
360   case $name in
361     /*) xsrcdir= ;;
362     *)  xsrcdir=$srcdir/ ;;
363   esac
364   test -n "$enable_debug_configure" &&
365   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
366
367   if test -f $xsrcdir$name/Implies; then
368     # Collect more names from the `Implies' file (removing comments).
369     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
370     implied=
371     for x in $implied_candidate; do
372       if test -d $xsrcdir$name_base/$x; then
373         implied="$implied $name_base/$x";
374       else
375         AC_MSG_WARN($name/Implies specifies nonexistent $x)
376       fi
377     done
378   else
379     implied=
380   fi
381
382   # Add NAME to the list of names.
383   names="$names $name"
384
385   # Find the parent of NAME, using the empty string if it has none.
386 changequote(,)dnl
387   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
388 changequote([,])dnl
389
390   # Add the names implied by NAME, and NAME's parent (if it has one), to
391   # the list of names to be processed (the argument list).  We prepend the
392   # implied names to the list and append the parent.  We want implied
393   # directories to come before further directories inferred from the
394   # configuration components; this ensures that for sysv4, unix/common
395   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
396   # after sysv4).
397   sysnames="`echo $implied $* $parent`"
398   test -n "$sysnames" && set $sysnames
399 done
400
401 # Add the default directories.
402 sysnames="$names sysdeps/generic"
403 AC_SUBST(sysnames)
404 # The other names were emitted during the scan.
405 AC_MSG_RESULT(sysdeps/generic)
406
407
408 ### Locate tools.
409
410 AC_PROG_INSTALL
411 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
412   # The makefiles need to use a different form to find it in $srcdir.
413   INSTALL='\$(..)./install-sh -c'
414 fi
415 AC_PROG_LN_S
416 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
417 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
418 if test "$MAKEINFO"; then
419 changequote(,)dnl Need [] for regexps.
420   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
421 changequote([,])dnl
422   then : # Makeinfo 3.11 or greater, works.
423   else
424     AC_MSG_WARN([
425 *** makeinfo is too old (need version 3.11 or better).
426 *** You should install the needed version and re-configure since otherwise
427 *** you won't get the info pages installed.])
428     MAKEINFO=
429   fi
430 fi
431
432 AC_PROG_CC_LOCAL
433 AC_CANONICAL_BUILD
434 if test $host != $build; then
435   AC_CHECK_PROGS(BUILD_CC, gcc cc)
436 fi
437 AC_SUBST(cross_compiling)
438 AC_PROG_CPP
439 LIBC_PROG_BINUTILS
440 AC_CHECK_TOOL(AR, ar)
441 AC_CHECK_TOOL(RANLIB, ranlib, :)
442
443 AC_PATH_PROG(BASH, bash, no)
444 if test "$BASH" != no &&
445    $BASH -c 'test "$BASH_VERSINFO" \
446              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
447   libc_cv_have_bash2=yes
448 else
449   libc_cv_have_bash2=no
450 fi
451 AC_SUBST(libc_cv_have_bash2)
452
453 dnl We need a ksh compatible shell for tzselect.
454 if test "$BASH" = no; then
455   AC_PATH_PROG(KSH, ksh, no)
456   if test "$KSH" = no; then
457     libc_cv_have_ksh=no
458   else
459     libc_cv_have_ksh=yes
460   fi
461 else
462   KSH="$BASH"
463   AC_SUBST(KSH)
464   libc_cv_have_ksh=yes
465 fi
466 AC_SUBST(libc_cv_have_ksh)
467
468 AC_PATH_PROGS(PERL, perl, no)
469 AC_SUBST(PERL)
470
471 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
472 echo '#include <stddef.h>
473 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
474 if eval "$ac_cpp conftest.c 2>/dev/null" \
475 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
476   libc_cv_signed_size_t=no
477 else
478   libc_cv_signed_size_t=yes
479 fi
480 rm -f conftest*])
481 if test $libc_cv_signed_size_t = yes; then
482   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
483   cat >> confdefs.h <<\EOF
484 #undef __SIZE_TYPE__
485 #define __SIZE_TYPE__ unsigned
486 EOF
487 fi
488
489 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
490 AC_TRY_COMPILE(dnl
491 [#define __need_size_t
492 #define __need_wchar_t
493 #include <stddef.h>
494 #define __need_NULL
495 #include <stddef.h>], [size_t size; wchar_t wchar;
496 #ifdef offsetof
497 #error stddef.h ignored __need_*
498 #endif
499 if (&size == NULL || &wchar == NULL) abort ();],
500                libc_cv_friendly_stddef=yes,
501                libc_cv_friendly_stddef=no)])
502 if test $libc_cv_friendly_stddef = yes; then
503   config_vars="$config_vars
504 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
505 fi
506
507 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
508                libc_cv_need_minus_P, [dnl
509 cat > conftest.S <<EOF
510 #include "confdefs.h"
511 /* Nothing whatsoever.  */
512 EOF
513 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
514   libc_cv_need_minus_P=no
515 else
516   libc_cv_need_minus_P=yes
517 fi
518 rm -f conftest*])
519 if test $libc_cv_need_minus_P = yes; then
520   config_vars="$config_vars
521 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
522 fi
523
524 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
525 # be told to read stdin.  This causes the compiler to hang when fed an
526 # .s file.
527 if test $ac_cv_prog_gcc = yes; then
528  case `${CC-cc} -v 2>&1` in
529   *2.7*)
530   # We must check this even if -pipe is not given here, because the user
531   # might do `make CFLAGS=-pipe'.
532   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
533    cp /dev/null conftest.s
534    cat >conftest1.s <<EOF
535 .nosuchdirective
536 EOF
537    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
538     libc_cv_gcc_pipe_bug=no
539    else
540     libc_cv_gcc_pipe_bug=yes
541    fi
542    rm -f conftest*])
543   if test $libc_cv_gcc_pipe_bug = yes; then
544    makeCC="${CC-cc} -B\$(common-objpfx)"
545    makeCFLAGS=$CFLAGS
546    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
547   fi;;
548  *) libc_cv_gcc_pipe_bug=no;;
549  esac
550 else
551  libc_cv_gcc_pipe_bug=no
552 fi
553
554 AC_CACHE_CHECK(for assembler global-symbol directive,
555                libc_cv_asm_global_directive, [dnl
556 libc_cv_asm_global_directive=UNKNOWN
557 for ac_globl in .globl .global; do
558   cat > conftest.s <<EOF
559 .text
560 ${ac_globl} foo
561 foo:
562 EOF
563   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
564     libc_cv_asm_global_directive=${ac_globl}
565   fi
566   rm -f conftest*
567   test $libc_cv_asm_global_directive != UNKNOWN && break
568 done])
569 if test $libc_cv_asm_global_directive = UNKNOWN; then
570   AC_MSG_ERROR(cannot determine asm global directive)
571 else
572   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
573 fi
574
575 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
576 cat > conftest.s <<EOF
577 .text
578 foo:
579 .set glibc_conftest_frobozz,foo
580 $libc_cv_asm_global_directive glibc_conftest_frobozz
581 EOF
582 # The alpha-dec-osf1 assembler gives only a warning for `.set'
583 # (but it doesn't work), so we must do a linking check to be sure.
584 cat > conftest1.c <<\EOF
585 extern int glibc_conftest_frobozz;
586 main () { printf ("%d\n", glibc_conftest_frobozz); }
587 EOF
588 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
589             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
590   libc_cv_asm_set_directive=yes
591 else
592   libc_cv_asm_set_directive=no
593 fi
594 rm -f conftest*])
595 if test $libc_cv_asm_set_directive = yes; then
596   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
597 fi
598
599 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
600 [cat > conftest.s <<EOF
601 .text
602 _sym:
603 .symver _sym,sym@VERS
604 EOF
605 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
606   libc_cv_asm_symver_directive=yes
607 else
608   libc_cv_asm_symver_directive=no
609 fi
610 rm -f conftest*])
611 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
612 if test $libc_cv_asm_symver_directive = yes; then
613   cat > conftest.s <<EOF
614 .text
615 _sym:
616 .symver _sym,sym@VERS
617 EOF
618   cat > conftest.map <<EOF
619 VERS_1 {
620         global: sym;
621 };
622
623 VERS_2 {
624         global: sym;
625 } VERS_1;
626 EOF
627   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
628     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
629                                         -nostartfiles -nostdlib
630                                         -Wl,--version-script,conftest.map
631                        1>&AC_FD_CC]);
632     then
633       libc_cv_ld_version_script_option=yes
634     else
635       libc_cv_ld_version_script_option=no
636     fi
637   else
638     libc_cv_ld_version_script_option=no
639   fi
640 else
641   libc_cv_ld_version_script_option=no
642 fi
643 rm -f conftest*])
644 if test $libc_cv_asm_symver_directive = yes &&
645    test $libc_cv_ld_version_script_option = yes &&
646    test $enable_versioning = yes; then
647   VERSIONING=yes
648   AC_DEFINE(DO_VERSIONING)
649 else
650   VERSIONING=no
651 fi
652 AC_SUBST(VERSIONING)
653
654 if test $VERSIONING = no; then
655   echo "\
656 *** WARNING: You should not compile GNU libc without versioning. Not using
657 *** versioning will introduce incompatibilities so that old binaries
658 *** will not run anymore.
659 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
660 fi
661 if test $elf = yes; then
662   AC_CACHE_CHECK(for .previous assembler directive,
663                  libc_cv_asm_previous_directive, [dnl
664   cat > conftest.s <<EOF
665 .section foo_section
666 .previous
667 EOF
668   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
669     libc_cv_asm_previous_directive=yes
670   else
671     libc_cv_asm_previous_directive=no
672   fi
673   rm -f conftest*])
674   if test $libc_cv_asm_previous_directive = yes; then
675     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
676   else
677     AC_CACHE_CHECK(for .popsection assembler directive,
678                    libc_cv_asm_popsection_directive, [dnl
679     cat > conftest.s <<EOF
680 .pushsection foo_section
681 .popsection
682 EOF
683     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
684       libc_cv_asm_popsection_directive=yes
685     else
686       libc_cv_asm_popsection_directive=no
687     fi
688     rm -f conftest*])
689     if test $libc_cv_asm_popsection_directive = yes; then
690       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
691     fi
692   fi
693 fi
694
695 if test $elf != yes; then
696   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
697                  [AC_TRY_COMPILE(, [asm (".section .init");
698                                     asm (".section .fini");
699                                     asm (".text");],
700                                  libc_cv_have_initfini=yes,
701                                  libc_cv_have_initfini=no)])
702   AC_SUBST(libc_cv_have_initfini)dnl
703   if test $libc_cv_have_initfini = yes; then
704     AC_DEFINE(HAVE_INITFINI)
705   fi
706 fi
707
708 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
709 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
710 [cat > conftest.$ac_ext <<EOF
711 dnl This sometimes fails to find confdefs.h, for some reason.
712 dnl [#]line __oline__ "[$]0"
713 [#]line __oline__ "configure"
714 #include "confdefs.h"
715 void underscore_test(void) {
716 return; }
717 EOF
718 if AC_TRY_EVAL(ac_compile); then
719   if grep _underscore_test conftest* >/dev/null; then
720     ifelse([$1], , :, [rm -f conftest*
721     $1])
722   else
723     ifelse([$2], , , [rm -f conftest*
724     $2])
725   fi
726 else
727   echo "configure: failed program was:" >&AC_FD_CC
728   cat conftest.$ac_ext >&AC_FD_CC
729   ifelse([$2], , , [rm -f conftest*
730   $2])
731 fi
732 rm -f conftest*])
733
734 if test $elf = yes; then
735   libc_cv_asm_underscores=no
736 else
737   if test $ac_cv_prog_cc_works = yes; then
738     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
739                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
740                                 libc_cv_asm_underscores=yes,
741                                 libc_cv_asm_underscores=no)])
742   else
743     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
744                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
745                                             libc_cv_asm_underscores=no)])
746   fi
747 fi
748 if test $libc_cv_asm_underscores = no; then
749   AC_DEFINE(NO_UNDERSCORES)
750 fi
751
752 if test $elf = yes; then
753   libc_cv_weak_symbols=yes
754   libc_cv_asm_weak_directive=yes
755   libc_cv_asm_weakext_directive=no
756 else
757   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
758                  [dnl
759 cat > conftest.s <<EOF
760 .text
761 ${libc_cv_asm_global_directive} foo
762 foo:
763 .weak foo
764 .weak bar; bar = foo
765 EOF
766   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
767     libc_cv_asm_weak_directive=yes
768   else
769     libc_cv_asm_weak_directive=no
770   fi
771   rm -f conftest*])
772
773 if test $libc_cv_asm_weak_directive = no; then
774   AC_CACHE_CHECK(for assembler .weakext directive,
775                  libc_cv_asm_weakext_directive,
776                  [dnl
777 cat > conftest.s <<EOF
778 .text
779 ${libc_cv_asm_global_directive} foo
780 foo:
781 .weakext foo
782 .weakext foo, bar
783 EOF
784   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
785     libc_cv_asm_weakext_directive=yes
786   else
787     libc_cv_asm_weakext_directive=no
788   fi
789   rm -f conftest*])
790
791   fi # no .weak
792 fi # not ELF
793
794 if test $libc_cv_asm_weak_directive = yes; then
795   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
796 elif test $libc_cv_asm_weakext_directive = yes; then
797   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
798 fi
799
800 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
801 cat > conftest.c <<\EOF
802 _start () {}
803 int __eh_pc;
804 __throw () {}
805 EOF
806 dnl No \ in command here because it ends up inside ''.
807 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
808                             -nostdlib -nostartfiles -Wl,--no-whole-archive
809                             -o conftest conftest.c 1>&AC_FD_CC]); then
810   libc_cv_ld_no_whole_archive=yes
811 else
812   libc_cv_ld_no_whole_archive=no
813 fi
814 rm -f conftest*])
815 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
816
817 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
818 cat > conftest.c <<\EOF
819 _start () {}
820 int __eh_pc;
821 __throw () {}
822 EOF
823 dnl No \ in command here because it ends up inside ''.
824 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
825                             -nostdlib -nostartfiles -fno-exceptions
826                             -o conftest conftest.c 1>&AC_FD_CC]); then
827   libc_cv_gcc_no_exceptions=yes
828 else
829   libc_cv_gcc_no_exceptions=no
830 fi
831 rm -f conftest*])
832 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
833
834 if test "$base_machine" = alpha ; then
835 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
836 cat > conftest.c <<\EOF
837 foo () { }
838 EOF
839 dnl
840 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
841 then
842   libc_cv_gcc_alpha_ng_prefix=yes
843 else
844   libc_cv_gcc_alpha_ng_prefix=no
845 fi
846 rm -f conftest* ])
847 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
848   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
849 else
850   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
851 fi
852 fi
853
854 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
855 [cat > conftest.c <<EOF
856 #line __oline__ "configure"
857 static char __EH_FRAME_BEGIN__[];
858 _start ()
859 {
860 #ifdef CHECK__register_frame
861   __register_frame (__EH_FRAME_BEGIN__);
862   __deregister_frame (__EH_FRAME_BEGIN__);
863 #endif
864 #ifdef CHECK__register_frame_info
865   __register_frame_info (__EH_FRAME_BEGIN__);
866   __deregister_frame_info (__EH_FRAME_BEGIN__);
867 #endif
868 }
869 int __eh_pc;
870 __throw () {}
871 /* FIXME: this is fragile.  */
872 malloc () {}
873 strcmp () {}
874 strlen () {}
875 memcpy () {}
876 memset () {}
877 free () {}
878 abort () {}
879 __bzero () {}
880 EOF
881 dnl No \ in command here because it ends up inside ''.
882 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
883                             -nostdlib -nostartfiles
884                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
885   libc_cv_gcc_dwarf2_unwind_info=static
886 else
887   libc_cv_gcc_dwarf2_unwind_info=no
888 fi
889 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
890   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
891                               -nostdlib -nostartfiles
892                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
893     libc_cv_gcc_dwarf2_unwind_info=yes
894   else
895     libc_cv_gcc_dwarf2_unwind_info=no
896   fi
897 fi
898 rm -f conftest*])
899 case $libc_cv_gcc_dwarf2_unwind_info in
900 yes)
901   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
902   ;;
903 static)
904   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
905   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
906   ;;
907 esac
908
909 ### End of automated tests.
910 ### Now run sysdeps configure fragments.
911
912 # sysdeps configure fragments may set these with files to be linked below.
913 libc_link_dests=
914 libc_link_sources=
915
916 # Iterate over all the sysdep directories we will use, running their
917 # configure fragments, and looking for a uname implementation.
918 uname=
919 for dir in $sysnames; do
920   case $dir in
921     /*) dest=$dir ;;
922     *)  dest=$srcdir/$dir ;;
923   esac
924   if test -r $dest/configure; then
925     AC_MSG_RESULT(running configure fragment for $dest)
926     . $dest/configure
927   fi
928 [
929   if test -z "$uname"; then
930     if test -r $dest/uname.c ||
931        test -r $dest/uname.S ||
932        { test -r $dest/syscalls.list &&
933          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
934       uname=$dir
935     fi
936   fi
937 ]dnl
938 done
939
940 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
941
942 # If we will use the generic uname implementation, we must figure out what
943 # it will say by examining the system, and write the results in config-name.h.
944 if test "$uname" = "sysdeps/generic"; then
945
946 changequote(,)dnl
947   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
948 changequote([,])dnl
949   if test $uname_sysname != $config_os; then
950     config_release=`echo $config_os | sed s/$uname_sysname//`
951   fi
952 dnl
953 AC_DEFUN(LIBC_KERNEL_ID, [dnl
954     if test -r /vmunix; then
955       kernel_id=`strings /vmunix | grep UNIX`
956     elif test -r /dynix; then
957       kernel_id=`strings /dynix | grep DYNIX`
958     else
959       kernel_id=
960     fi
961 ])dnl
962
963   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
964 AC_REQUIRE([LIBC_KERNEL_ID])dnl
965 changequote(,)dnl
966   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
967 changequote([,])dnl
968   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
969          != x$config_release; then
970     # The configuration release is a substring of the kernel release.
971     libc_cv_uname_release=$kernel_release
972   elif test x$config_release != x; then
973     libc_cv_uname_release=$config_release
974   elif test x$kernel_release != x; then
975     libc_cv_uname_release=$kernel_release
976   else
977     libc_cv_uname_release=unknown
978   fi])
979   uname_release="$libc_cv_uname_release"
980
981   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
982 AC_REQUIRE([LIBC_KERNEL_ID])dnl
983 changequote(,)dnl
984   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
985 changequote([,])dnl
986   if test -n "$kernel_version"; then
987     libc_cv_uname_version="$kernel_version"
988   else
989     libc_cv_uname_version=unknown
990   fi])
991   uname_version="$libc_cv_uname_version"
992
993 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
994   config_uname=config-name.h:config-name.in
995 else
996   # For non-generic uname, we don't need to create config-name.h at all.
997   config_uname=
998 fi
999
1000 AC_MSG_CHECKING(stdio selection)
1001 AC_SUBST(stdio)
1002 case $stdio in
1003 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1004 default) stdio=stdio ;;
1005 esac
1006 AC_MSG_RESULT($stdio)
1007
1008 AC_MSG_CHECKING(ldap selection)
1009 AC_SUBST(LDAP)
1010 case $add_ons in
1011 *ldap*)
1012    ldap=yes
1013    LDAP=ldap ;;
1014 *) ldap=no
1015    LDAP= ;;
1016 esac
1017 AC_MSG_RESULT($ldap)
1018
1019 AC_SUBST(libc_cv_slibdir)
1020 AC_SUBST(libc_cv_sysconfdir)
1021 AC_SUBST(libc_cv_rootsbindir)
1022
1023 AC_SUBST(has_ldconfig)
1024
1025 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1026 if test $gnu_ld = yes; then
1027   AC_DEFINE(HAVE_GNU_LD)
1028 fi
1029 if test $gnu_as = yes; then
1030   AC_DEFINE(HAVE_GNU_AS)
1031 fi
1032 if test $elf = yes; then
1033   AC_DEFINE(HAVE_ELF)
1034 fi
1035
1036 AC_SUBST(static)
1037 AC_SUBST(shared)
1038 if test $shared = default; then
1039   if test $gnu_ld = yes; then
1040     shared=$elf
1041   else
1042     # For now we do not assume shared libs are available.  In future more
1043     # tests might become available.
1044     shared=no
1045   fi
1046 fi
1047
1048 dnl We must not allow compilation without static library on some platforms.
1049 if test $static = no && test $shared = yes; then
1050   case "$host_os" in
1051   linux* | gnu*)
1052     AC_MSG_ERROR([
1053 *** You must compile with support for the static library since the shared
1054 *** library uses it.  Restart configure without \`--disable-static'.])
1055     ;;
1056   *)
1057     ;;
1058   esac
1059 fi
1060
1061 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1062 [pic_default=yes
1063 cat > conftest.c <<EOF
1064 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1065 # error PIC is default.
1066 #endif
1067 EOF
1068 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1069   pic_default=no
1070 fi
1071 rm -f conftest.*])
1072 AC_SUBST(pic_default)
1073
1074 AC_SUBST(profile)
1075 AC_SUBST(omitfp)
1076 AC_SUBST(bounded)
1077 AC_SUBST(static_nss)
1078 AC_SUBST(nopic_initfini)
1079
1080 AC_SUBST(DEFINES)
1081
1082 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1083   config_makefile=
1084 else
1085   config_makefile=Makefile
1086 fi
1087
1088 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1089 AC_SUBST(VERSION)
1090
1091 if test $libc_cv_gcc_pipe_bug = yes; then
1092  realCC=$CC
1093  CC=$makeCC
1094  CFLAGS=$makeCFLAGS
1095 fi
1096 AC_OUTPUT_COMMANDS([
1097 if test "$realCC"; then
1098  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1099  mv specsT specs
1100 fi], [realCC=$realCC])
1101
1102 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1103           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])