Require autoconf 2.4.2 or later. Change all AC_CACHE_VAL uses to use new
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.4.2)dnl             dnl Minimum Autoconf version required.
4 AC_INIT(features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21
22 dnl Arguments to specify presence of other packages/features.
23 AC_ARG_WITH(fp, dnl
24   --with-fp               if using floating-point hardware,
25             with_fp=$withval, with_fp=yes)
26 AC_ARG_WITH(gnu-binutils, dnl
27   --with-gnu-binutils     if using GNU binutils (as and ld),
28             gnu_binutils=$withval, gnu_binutils=no)
29 AC_ARG_WITH(gnu-ld, dnl
30   --with-gnu-ld           if using GNU ld (in the binutils package),
31             gnu_ld=$withval, gnu_ld=no)
32 AC_ARG_WITH(gnu-as, dnl
33   --with-gnu-as           if using GNU as (in the binutils package),
34             gnu_as=$withval, gnu_as=no)
35 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
36 AC_ARG_WITH(elf, dnl
37   --with-elf              if using the ELF object format,
38             elf=$withval, elf=no)
39 AC_ARG_WITH(weak-symbols, dnl
40   --with-weak-symbols     if weak symbols are available in as and ld,
41             weak=$withval, weak=no)
42
43 dnl Arguments to enable or disable building the shared, profiled, and
44 dnl -fomit-frame-pointer libraries.
45 AC_ARG_ENABLE(shared, dnl
46 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
47             shared=$enableval, shared=default)
48 AC_ARG_ENABLE(profile, dnl
49 [  --enable-profile        build profiled library [default=yes]],
50             profile=$enableval, profile=yes)
51 AC_ARG_ENABLE(omitfp, dnl
52 [  --enable-omitfp       build undebuggable optimized library [default=no]],
53             omitfp=$enableval, omitfp=no)
54
55 AC_CANONICAL_HOST
56 # We keep the original values in `$config_*' and never modify them, so we
57 # can write them unchanged into config.make.  Everything else uses
58 # $machine, $vendor, and $os, and changes them whenever convenient.
59 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
60
61 # Some configurations imply other options.
62 case "$host_os" in
63 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
64   # These systems always use GNU tools.
65   gnu_ld=yes gnu_as=yes
66 esac
67 case "$host_os" in
68 gnu* | linux* | sysv4* | solaris2*)
69   # These systems always use the ELF format.
70   elf=yes
71 esac
72
73 # Compute the list of sysdep directories for this configuration.
74 sysdep_dir=$srcdir/sysdeps
75 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
76 machine=$config_machine
77 vendor=$config_vendor
78 os=$config_os
79
80 dnl We need to use [ and ] for other purposes for a while now.
81 changequote(,)dnl
82 # Expand the configuration machine name into a subdirectory by architecture
83 # type and particular chip.
84 case "$machine" in
85 i[345]86)
86   machine=i386/$machine ;;
87 sparc[6789])
88   machine=sparc/$machine ;;
89 m68k)
90   machine=m68k/m68020 ;;
91 m680?0)
92   machine=m68k/$machine ;;
93 m88k)
94   machine=m88k/m88100 ;;
95 m88???)
96   machine=m88k/$machine ;;
97 mips64*)
98   machine=mips/mips64/$machine ;;
99 mips*)
100   machine=mips/$machine ;;
101 esac
102
103 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
104 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
105
106 case "$os" in
107 gnu*)
108   base_os=mach/hurd ;;
109 netbsd* | 386bsd* | freebsd* | bsdi*)
110   base_os=unix/bsd/bsd4.4 ;;
111 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
112   base_os=unix/bsd ;;
113 sysv* | isc* | esix* | sco* | minix* | irix4*)
114   base_os=unix/sysv ;;
115 linux* | solaris[2-9]*)
116   base_os=unix/sysv/sysv4 ;;
117 none)
118   base_os=standalone ;;
119 *)
120   base_os='' ;;
121 esac
122
123 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
124 tail=$os
125 ostry=$os
126 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
127   ostry="$ostry /$o"
128   tail=$o
129 done  
130 o=`echo $tail | sed 's/[0-9]*$//'`
131 if test $o != $tail; then
132   ostry="$ostry /$o"
133 fi
134
135 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
136 base=
137 tail=$base_os
138 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
139   set $b
140   base="$base /$1"
141   tail="$2"
142 done
143
144 # For sparc/sparc9, try sparc/sparc9 and then sparc.
145 mach=
146 tail=$machine
147 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
148   set $m
149   # Prepend the machine's FPU directory unless --without-fp.
150   if test "$with_fp" = yes; then
151     mach="$mach /$1/fpu"
152   fi
153   mach="$mach /$1"
154   tail="$2"
155 done
156
157 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
158 changequote([,])dnl
159
160 # Find what sysdep directories exist.
161 sysnames=
162 for b in $base ''; do
163   for m0 in $mach ''; do
164     for v in /$vendor ''; do
165       for o in /$ostry ''; do
166         for m in $mach ''; do
167           try="$m0$b$v$o$m"
168           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
169           if test -d $sysdep_dir$try; then
170             sysnames="$sysnames $try"
171             { test -n "$o" || test -n "$b"; } && os_used=t
172             { test -n "$m" || test -n "$m0"; } && machine_used=t
173           fi
174         done
175       done
176     done
177   done
178 done
179
180 if test -z "$os_used" && test "$os" != none; then
181   AC_MSG_ERROR(Operating system $os is not supported.)
182 fi
183 if test -z "$machine_used" && test "$machine" != none; then
184   AC_MSG_ERROR(The $machine is not supported.)
185 fi
186
187 # We have now validated the configuration.
188
189
190 # If using ELF, look for an `elf' subdirectory of each machine directory.
191 # We prepend these rather than inserting them whereever the machine appears
192 # because things specified by the machine's ELF ABI should override
193 # OS-specific things, and should always be the same for any OS on the
194 # machine (otherwise what's the point of an ABI?).
195 if test "$elf" = yes; then
196   elf_dirs=
197   for m in $mach; do
198     if test -d $sysdep_dir$m/elf; then
199       elf_dirs="$elf_dirs $m/elf"
200     fi
201   done
202   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
203 fi
204
205
206 # Remove the leading slashes.
207 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
208
209
210 # Expand the list of system names into a full list of directories
211 # from each element's parent name and Implies file (if present).
212 set $sysnames
213 while test $# -gt 0; do
214   name=$1
215   shift
216
217   if test -f $sysdep_dir/$name/Implies; then
218     # Collect more names from the `Implies' file (removing comments).
219     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
220     for x in $implied; do
221       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
222     done
223   else
224     implied=
225   fi
226
227   # Add NAME to the list of names.
228   names="$names $name"
229
230   # Find the parent of NAME, using the empty string if it has none.
231 changequote(,)dnl
232   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
233 changequote([,])dnl
234
235   # Add the names implied by NAME, and NAME's parent (if it has one), to
236   # the list of names to be processed (the argument list).  We prepend the
237   # implied names to the list and append the parent.  We want implied
238   # directories to come before further directories inferred from the
239   # configuration components; this ensures that for sysv4, unix/common
240   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
241   # after sysv4).
242   sysnames="`echo $implied $* $parent`"
243   test -n "$sysnames" && set $sysnames
244 done
245
246 # Add the default directories.
247 names="$names generic stub"
248
249 # Now uniquize the list.
250 seen=
251 sysnames=
252 for name in $names; do
253   if echo "$seen" | fgrep -x $name >/dev/null; then
254     # Already in the list.
255     true;
256   else
257     # A new one.
258     if test -z "$seen"; then
259       seen="$name" sysnames="$name"
260     else
261       seen="$seen
262 $name"
263       sysnames="$sysnames $name"
264     fi
265   fi
266 done
267 libc_cv_sysdirs="$sysnames"])
268 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
269
270 AC_PROG_INSTALL
271 if test "$INSTALL" = "${srcdir}/install-sh"; then
272   # The makefiles need to use a different form to find it in $srcdir.
273   INSTALL='$(..)./install-sh'
274 fi
275
276 AC_CHECK_TOOL(CC, gcc)
277 AC_CHECK_TOOL(AR, ar)
278 AC_CHECK_TOOL(RANLIB, ranlib, :)
279 AC_PROG_CPP
280
281 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
282 echo '#include <stddef.h>
283 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
284 if eval "$ac_cpp conftest.c 2>/dev/null" \
285 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
286   libc_cv_signed_size_t=no
287 else
288   libc_cv_signed_size_t=yes
289 fi
290 rm -f conftest*])
291 if test $libc_cv_signed_size_t = yes; then
292   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
293   cat >> confdefs.h <<\EOF
294 #undef __SIZE_TYPE__
295 #define __SIZE_TYPE__ unsigned
296 EOF
297 fi
298
299 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
300 AC_TRY_COMPILE(dnl
301 [#define __need_size_t
302 #define __need_wchar_t
303 #include <stddef.h>
304 #define __need_NULL
305 #include <stddef.h>], [size_t size; wchar_t wchar;
306 #ifdef offsetof
307 #error stddef.h ignored __need_*
308 #endif
309 if (&size == NULL || &wchar == NULL) abort ();],
310                libc_cv_friendly_stddef=yes,
311                libc_cv_friendly_stddef=no)])
312 if test $libc_cv_friendly_stddef = yes; then
313   config_vars="$config_vars
314 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
315 fi
316
317 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
318                libc_cv_need_minus_P, [dnl
319 cat > conftest.S <<EOF
320 #include "confdefs.h"
321 /* Nothing whatsoever.  */
322 EOF
323 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
324   libc_cv_need_minus_P=no
325 else
326   libc_cv_need_minus_P=yes
327 fi
328 rm -f conftest*])
329 if test $libc_cv_need_minus_P = yes; then
330   config_vars="$config_vars
331 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
332 fi
333
334 AC_CACHE_CHECK(for assembler global-symbol directive,
335                libc_cv_asm_global_directive, [dnl
336 libc_cv_asm_global_directive=UNKNOWN
337 for ac_globl in .globl .global; do
338   cat > conftest.s <<EOF
339 .text
340 ${ac_globl} foo
341 foo: .long 0
342 EOF
343   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
344     libc_cv_asm_global_directive=${ac_globl}
345   fi
346   rm -f conftest*
347   test $libc_cv_asm_global_directive != UNKNOWN && break
348 done])
349 if test $libc_cv_asm_global_directive = UNKNOWN; then
350   AC_MSG_ERROR(cannot determine asm global directive)
351 else
352   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
353 fi
354
355 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
356 cat > conftest.s <<EOF
357 .text
358 foo: .long 0
359 .set glibc_conftest_frobozz,foo
360 $libc_cv_asm_global_directive glibc_conftest_frobozz
361 EOF
362 # The alpha-dec-osf1 assembler gives only a warning for `.set'
363 # (but it doesn't work), so we must do a linking check to be sure.
364 cat > conftest1.c <<\EOF
365 extern int glibc_conftest_frobozz;
366 main () { printf ("%d\n", glibc_conftest_frobozz); }
367 EOF
368 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
369             conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
370   libc_cv_asm_set_directive=yes
371 else
372   libc_cv_asm_set_directive=no
373 fi
374 rm -f conftest*])
375 if test $libc_cv_asm_set_directive = yes; then
376   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
377 fi
378
379 if test $elf != yes; then
380   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
381                  [AC_TRY_COMPILE(, [asm (".section .init");
382                                     asm (".section .fini");],
383                                  libc_cv_have_initfini=yes,
384                                  libc_cv_have_initfini=no)])
385   AC_SUBST(libc_cv_have_initfini)dnl
386   if test $libc_cv_have_initfini = yes; then
387     AC_DEFINE(HAVE_INITFINI)
388   fi
389 fi
390
391 # sysdeps configure fragments may set these with files to be linked below.
392 libc_link_dests=
393 libc_link_sources=
394
395 # Iterate over all the sysdep directories we will use, running their
396 # configure fragments, and looking for a uname implementation.
397 uname=
398 for dir in $sysnames; do
399   if test -r $sysdep_dir/$dir/configure; then
400     AC_MSG_RESULT(running configure fragment for $dir)
401     . $sysdep_dir/$dir/configure
402   fi
403   if test -z "$uname"; then
404     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
405     && uname=$dir
406   fi
407 done
408
409 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
410
411 # If we will use the generic uname implementation, we must figure out what
412 # it will say by examining the system, and write the results in config-name.h.
413 if test "$uname" = generic; then
414
415 changequote(,)dnl
416   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
417 changequote([,])dnl
418   if test $uname_sysname != $config_os; then
419     config_release=`echo $config_os | sed s/$uname_sysname//`
420   fi
421 dnl
422 AC_DEFUN(LIBC_KERNEL_ID, [dnl
423     if test -r /vmunix; then
424       kernel_id=`strings /vmunix | grep UNIX`
425     elif test -r /dynix; then
426       kernel_id=`strings /dynix | grep DYNIX`
427     else
428       kernel_id=
429     fi
430 ])dnl
431
432   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
433 AC_REQUIRE([LIBC_KERNEL_ID])dnl
434 changequote(,)dnl
435   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
436 changequote([,])dnl
437   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
438          != x$config_release; then
439     # The configuration release is a substring of the kernel release.
440     libc_cv_uname_release=$kernel_release
441   elif test x$config_release != x; then
442     libc_cv_uname_release=$config_release
443   elif test x$kernel_release != x; then
444     libc_cv_uname_release=$kernel_release
445   else
446     libc_cv_uname_release=unknown
447   fi])
448   uname_release="$libc_cv_uname_release"
449
450   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
451 AC_REQUIRE([LIBC_KERNEL_ID])dnl
452 changequote(,)dnl
453   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
454 changequote([,])dnl
455   if test -n "$kernel_version"; then
456     libc_cv_uname_version="$kernel_version"
457   else
458     libc_cv_uname_version=unknown
459   fi])
460   uname_version="$libc_cv_uname_version"
461
462 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
463   config_uname=config-name.h:config-name.in
464 else
465   # For non-generic uname, we don't need to create config-name.h at all.
466   config_uname=
467 fi
468
469 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
470 if test $gnu_ld = yes; then
471   AC_DEFINE(HAVE_GNU_LD)
472 fi
473 if test $gnu_as = yes; then
474   AC_DEFINE(HAVE_GNU_AS)
475 fi
476 if test $elf = yes; then
477   AC_DEFINE(HAVE_ELF)
478 fi
479 if test $weak = yes; then
480   AC_DEFINE(HAVE_WEAK_SYMBOLS)
481 fi
482
483 AC_SUBST(shared)
484 if test $shared = default; then
485   if test $gnu_ld = yes; then
486     shared=$elf
487   fi
488 fi
489 AC_SUBST(profile)
490 AC_SUBST(omitfp)
491
492
493 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
494   config_makefile=
495 else
496   config_makefile=Makefile
497 fi
498
499 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
500           [echo '$config_vars' >> config.make])