Tue Mar 19 14:18:42 1996 Roland McGrath <roland@charlie-brown.gnu.ai.mit.edu>
[kopensolaris-gnu/glibc.git] / configure.in
1 Dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.9)dnl               dnl Minimum Autoconf version required.
4 AC_INIT(features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37   --with-fp               if using floating-point hardware,
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(gnu-binutils, dnl
40   --with-gnu-binutils     if using GNU binutils (as and ld),
41             gnu_binutils=$withval, gnu_binutils=no)
42 AC_ARG_WITH(gnu-ld, dnl
43   --with-gnu-ld           if using GNU ld (in the binutils package),
44             gnu_ld=$withval, gnu_ld=no)
45 AC_ARG_WITH(gnu-as, dnl
46   --with-gnu-as           if using GNU as (in the binutils package),
47             gnu_as=$withval, gnu_as=no)
48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
49 AC_ARG_WITH(elf, dnl
50   --with-elf              if using the ELF object format,
51             elf=$withval, elf=no)
52
53 AC_ARG_ENABLE(libio, dnl
54 [  --enable-libio          build in GNU libio instead of GNU stdio],
55               [if test $enableval = yes; then
56                  stdio=libio
57                else
58                  stdio=stdio
59                fi],
60               stdio=default)
61
62 dnl Arguments to enable or disable building the shared, profiled, and
63 dnl -fomit-frame-pointer libraries.
64 AC_ARG_ENABLE(shared, dnl
65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
66             shared=$enableval, shared=default)
67 AC_ARG_ENABLE(profile, dnl
68 [  --enable-profile        build profiled library [default=yes]],
69             profile=$enableval, profile=yes)
70 AC_ARG_ENABLE(omitfp, dnl
71 [  --enable-omitfp       build undebuggable optimized library [default=no]],
72             omitfp=$enableval, omitfp=no)
73
74 AC_CANONICAL_HOST
75 # We keep the original values in `$config_*' and never modify them, so we
76 # can write them unchanged into config.make.  Everything else uses
77 # $machine, $vendor, and $os, and changes them whenever convenient.
78 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
79
80 # Some configurations imply other options.
81 case "$host_os" in
82 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
83   # These systems always use GNU tools.
84   gnu_ld=yes gnu_as=yes
85 esac
86 case "$host_os" in
87 gnu* | linux* | sysv4* | solaris2*)
88   # These systems always use the ELF format.
89   elf=yes
90 esac
91
92 # Compute the list of sysdep directories for this configuration.
93 sysdep_dir=$srcdir/sysdeps
94 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
95 machine=$config_machine
96 vendor=$config_vendor
97 os=$config_os
98
99 dnl We need to use [ and ] for other purposes for a while now.
100 changequote(,)dnl
101 # Expand the configuration machine name into a subdirectory by architecture
102 # type and particular chip.
103 case "$machine" in
104 a29k | am29000) machine=a29k ;;
105 alpha*)         machine=alpha/$machine ;;
106 hppa*)          machine=hppa/$machine ;;
107 i[345]86)       machine=i386/$machine ;;
108 m680?0)         machine=m68k/$machine ;;
109 m68k)           machine=m68k/m68020 ;;
110 m88???)         machine=m88k/$machine ;;
111 m88k)           machine=m88k/m88100 ;;
112 mips*)          machine=mips/$machine ;;
113 mips64*)        machine=mips/mips64/$machine ;;
114 sparc[6789])    machine=sparc/$machine ;;
115 supersparc)     machine=sparc/sparc8 ;;
116 esac
117
118 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
119 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
120
121 case "$os" in
122 gnu*)
123   base_os=mach/hurd ;;
124 netbsd* | 386bsd* | freebsd* | bsdi*)
125   base_os=unix/bsd/bsd4.4 ;;
126 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
127   base_os=unix/bsd ;;
128 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
129   base_os=unix/sysv ;;
130 solaris[2-9]*)
131   base_os=unix/sysv/sysv4 ;;
132 none)
133   base_os=standalone ;;
134 *)
135   base_os='' ;;
136 esac
137
138 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
139 tail=$os
140 ostry=$os
141 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
142   ostry="$ostry /$o"
143   tail=$o
144 done
145 o=`echo $tail | sed 's/[0-9]*$//'`
146 if test $o != $tail; then
147   ostry="$ostry /$o"
148 fi
149
150 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
151 base=
152 tail=$base_os
153 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
154   set $b
155   base="$base /$1"
156   tail="$2"
157 done
158
159 # For sparc/sparc9, try sparc/sparc9 and then sparc.
160 mach=
161 tail=$machine
162 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
163   set $m
164   # Prepend the machine's FPU directory unless --without-fp.
165   if test "$with_fp" = yes; then
166     mach="$mach /$1/fpu"
167   fi
168   mach="$mach /$1"
169   tail="$2"
170 done
171
172 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
173 changequote([,])dnl
174
175 # Find what sysdep directories exist.
176 sysnames=
177 for b in $base ''; do
178   for m0 in $mach ''; do
179     for v in /$vendor ''; do
180       for o in /$ostry ''; do
181         for m in $mach ''; do
182           try="$m0$b$v$o$m"
183           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
184           if test -d $sysdep_dir$try; then
185             sysnames="$sysnames $try"
186             { test -n "$o" || test -n "$b"; } && os_used=t
187             { test -n "$m" || test -n "$m0"; } && machine_used=t
188           fi
189         done
190       done
191     done
192   done
193 done
194
195 if test -z "$os_used" && test "$os" != none; then
196   AC_MSG_ERROR(Operating system $os is not supported.)
197 fi
198 if test -z "$machine_used" && test "$machine" != none; then
199   AC_MSG_ERROR(The $machine is not supported.)
200 fi
201
202 # We have now validated the configuration.
203
204
205 # If using ELF, look for an `elf' subdirectory of each machine directory.
206 # We prepend these rather than inserting them whereever the machine appears
207 # because things specified by the machine's ELF ABI should override
208 # OS-specific things, and should always be the same for any OS on the
209 # machine (otherwise what's the point of an ABI?).
210 if test "$elf" = yes; then
211   elf_dirs=
212   for m in $mach; do
213     if test -d $sysdep_dir$m/elf; then
214       elf_dirs="$elf_dirs $m/elf"
215     fi
216   done
217   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
218 fi
219
220
221 # Remove the leading slashes.
222 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
223
224
225 # Expand the list of system names into a full list of directories
226 # from each element's parent name and Implies file (if present).
227 set $sysnames
228 while test $# -gt 0; do
229   name=$1
230   shift
231
232   if test -f $sysdep_dir/$name/Implies; then
233     # Collect more names from the `Implies' file (removing comments).
234     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
235     for x in $implied; do
236       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
237     done
238   else
239     implied=
240   fi
241
242   # Add NAME to the list of names.
243   names="$names $name"
244
245   # Find the parent of NAME, using the empty string if it has none.
246 changequote(,)dnl
247   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
248 changequote([,])dnl
249
250   # Add the names implied by NAME, and NAME's parent (if it has one), to
251   # the list of names to be processed (the argument list).  We prepend the
252   # implied names to the list and append the parent.  We want implied
253   # directories to come before further directories inferred from the
254   # configuration components; this ensures that for sysv4, unix/common
255   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
256   # after sysv4).
257   sysnames="`echo $implied $* $parent`"
258   test -n "$sysnames" && set $sysnames
259 done
260
261 # Add the default directories.
262 names="$names generic stub"
263
264 # Now uniquize the list.
265 seen=
266 sysnames=
267 for name in $names; do
268   if echo "$seen" | fgrep -x $name >/dev/null; then
269     # Already in the list.
270     true;
271   else
272     # A new one.
273     if test -z "$seen"; then
274       seen="$name" sysnames="$name"
275     else
276       seen="$seen
277 $name"
278       sysnames="$sysnames $name"
279     fi
280   fi
281 done
282 libc_cv_sysdirs="$sysnames"])
283 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
284
285 AC_PROG_INSTALL
286 if test "$INSTALL" = "${srcdir}/install-sh"; then
287   # The makefiles need to use a different form to find it in $srcdir.
288   INSTALL='$(..)./install-sh'
289 fi
290
291 AC_CHECK_TOOL(CC, gcc)
292 AC_CHECK_TOOL(AR, ar)
293 AC_CHECK_TOOL(RANLIB, ranlib, :)
294 AC_PROG_CPP
295
296 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
297 echo '#include <stddef.h>
298 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
299 if eval "$ac_cpp conftest.c 2>/dev/null" \
300 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
301   libc_cv_signed_size_t=no
302 else
303   libc_cv_signed_size_t=yes
304 fi
305 rm -f conftest*])
306 if test $libc_cv_signed_size_t = yes; then
307   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
308   cat >> confdefs.h <<\EOF
309 #undef __SIZE_TYPE__
310 #define __SIZE_TYPE__ unsigned
311 EOF
312 fi
313
314 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
315 AC_TRY_COMPILE(dnl
316 [#define __need_size_t
317 #define __need_wchar_t
318 #include <stddef.h>
319 #define __need_NULL
320 #include <stddef.h>], [size_t size; wchar_t wchar;
321 #ifdef offsetof
322 #error stddef.h ignored __need_*
323 #endif
324 if (&size == NULL || &wchar == NULL) abort ();],
325                libc_cv_friendly_stddef=yes,
326                libc_cv_friendly_stddef=no)])
327 if test $libc_cv_friendly_stddef = yes; then
328   config_vars="$config_vars
329 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
330 fi
331
332 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
333                libc_cv_need_minus_P, [dnl
334 cat > conftest.S <<EOF
335 #include "confdefs.h"
336 /* Nothing whatsoever.  */
337 EOF
338 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
339   libc_cv_need_minus_P=no
340 else
341   libc_cv_need_minus_P=yes
342 fi
343 rm -f conftest*])
344 if test $libc_cv_need_minus_P = yes; then
345   config_vars="$config_vars
346 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
347 fi
348
349 AC_CACHE_CHECK(for assembler global-symbol directive,
350                libc_cv_asm_global_directive, [dnl
351 libc_cv_asm_global_directive=UNKNOWN
352 for ac_globl in .globl .global; do
353   cat > conftest.s <<EOF
354 .text
355 ${ac_globl} foo
356 foo: .long 0
357 EOF
358   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
359     libc_cv_asm_global_directive=${ac_globl}
360   fi
361   rm -f conftest*
362   test $libc_cv_asm_global_directive != UNKNOWN && break
363 done])
364 if test $libc_cv_asm_global_directive = UNKNOWN; then
365   AC_MSG_ERROR(cannot determine asm global directive)
366 else
367   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
368 fi
369
370 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
371 cat > conftest.s <<EOF
372 .text
373 foo: .long 0
374 .set glibc_conftest_frobozz,foo
375 $libc_cv_asm_global_directive glibc_conftest_frobozz
376 EOF
377 # The alpha-dec-osf1 assembler gives only a warning for `.set'
378 # (but it doesn't work), so we must do a linking check to be sure.
379 cat > conftest1.c <<\EOF
380 extern int glibc_conftest_frobozz;
381 main () { printf ("%d\n", glibc_conftest_frobozz); }
382 EOF
383 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
384             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
385   libc_cv_asm_set_directive=yes
386 else
387   libc_cv_asm_set_directive=no
388 fi
389 rm -f conftest*])
390 if test $libc_cv_asm_set_directive = yes; then
391   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
392 fi
393
394 if test $elf != yes; then
395   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
396                  [AC_TRY_COMPILE(, [asm (".section .init");
397                                     asm (".section .fini");],
398                                  libc_cv_have_initfini=yes,
399                                  libc_cv_have_initfini=no)])
400   AC_SUBST(libc_cv_have_initfini)dnl
401   if test $libc_cv_have_initfini = yes; then
402     AC_DEFINE(HAVE_INITFINI)
403   fi
404 fi
405
406 if test $elf = yes; then
407   libc_cv_asm_underscores=no
408 else
409   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
410                  [AC_TRY_COMPILE([asm ("_glibc_foobar:");], [glibc_foobar ();],
411                                  libc_cv_asm_underscores=yes,
412                                  libc_cv_asm_underscores=no)])
413 fi
414 if test $libc_cv_asm_underscores = no; then
415   AC_DEFINE(NO_UNDERSCORES)
416 fi
417
418 if test $elf = yes; then
419   libc_cv_weak_symbols=yes
420   libc_cv_asm_weak_directive=yes
421   libc_cv_asm_weakext_directive=no
422 else
423   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
424                  [dnl
425 cat > conftest.s <<EOF
426 .text
427 ${libc_cv_asm_global_directive} foo
428 foo: .long 0
429 .weak foo
430 .weak bar; bar = foo
431 EOF
432   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
433     libc_cv_asm_weak_directive=yes
434   else
435     libc_cv_asm_weak_directive=no
436   fi
437   rm -f conftest*])
438
439 if $libc_cv_asm_weak_directive = no; then
440   AC_CACHE_CHECK(for assembler .weakext directive,
441                  libc_cv_asm_weakext_directive,
442                  [dnl
443 cat > conftest.s <<EOF
444 .text
445 ${libc_cv_asm_global_directive} foo
446 foo: .long 0
447 .weakext foo
448 .weak bar, foo
449 EOF
450   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
451     libc_cv_asm_weakext_directive=yes
452   else
453     libc_cv_asm_weakext_directive=no
454   fi
455   rm -f conftest*])
456
457   fi # no .weak
458 fi # not ELF
459
460 if test $libc_cv_asm_weak_directive; then
461   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
462 elif test $libc_cv_asm_weakext_directive; then
463   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
464 fi
465
466 ### End of automated tests.
467 ### Now run sysdeps configure fragments.
468
469 # sysdeps configure fragments may set these with files to be linked below.
470 libc_link_dests=
471 libc_link_sources=
472
473 # Iterate over all the sysdep directories we will use, running their
474 # configure fragments, and looking for a uname implementation.
475 uname=
476 for dir in $sysnames; do
477   if test -r $sysdep_dir/$dir/configure; then
478     AC_MSG_RESULT(running configure fragment for $dir)
479     . $sysdep_dir/$dir/configure
480   fi
481 [
482   if test -z "$uname"; then
483     if test -r $sysdep_dir/$dir/uname.c ||
484        test -r $sysdep_dir/$dir/uname.S ||
485        { test -r $sysdep_dir/$dir/syscalls.list &&
486          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
487       uname=$dir
488     fi
489   fi
490 ]dnl
491 done
492
493 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
494
495 # If we will use the generic uname implementation, we must figure out what
496 # it will say by examining the system, and write the results in config-name.h.
497 if test "$uname" = generic; then
498
499 changequote(,)dnl
500   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
501 changequote([,])dnl
502   if test $uname_sysname != $config_os; then
503     config_release=`echo $config_os | sed s/$uname_sysname//`
504   fi
505 dnl
506 AC_DEFUN(LIBC_KERNEL_ID, [dnl
507     if test -r /vmunix; then
508       kernel_id=`strings /vmunix | grep UNIX`
509     elif test -r /dynix; then
510       kernel_id=`strings /dynix | grep DYNIX`
511     else
512       kernel_id=
513     fi
514 ])dnl
515
516   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
517 AC_REQUIRE([LIBC_KERNEL_ID])dnl
518 changequote(,)dnl
519   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
520 changequote([,])dnl
521   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
522          != x$config_release; then
523     # The configuration release is a substring of the kernel release.
524     libc_cv_uname_release=$kernel_release
525   elif test x$config_release != x; then
526     libc_cv_uname_release=$config_release
527   elif test x$kernel_release != x; then
528     libc_cv_uname_release=$kernel_release
529   else
530     libc_cv_uname_release=unknown
531   fi])
532   uname_release="$libc_cv_uname_release"
533
534   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
535 AC_REQUIRE([LIBC_KERNEL_ID])dnl
536 changequote(,)dnl
537   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
538 changequote([,])dnl
539   if test -n "$kernel_version"; then
540     libc_cv_uname_version="$kernel_version"
541   else
542     libc_cv_uname_version=unknown
543   fi])
544   uname_version="$libc_cv_uname_version"
545
546 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
547   config_uname=config-name.h:config-name.in
548 else
549   # For non-generic uname, we don't need to create config-name.h at all.
550   config_uname=
551 fi
552
553 AC_MSG_CHECKING(stdio selection)
554 AC_SUBST(stdio)
555 case $stdio in
556 libio) AC_DEFINE(USE_IN_LIBIO) ;;
557 default) stdio=stdio ;;
558 esac
559 AC_MSG_RESULT($stdio)
560
561 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
562 if test $gnu_ld = yes; then
563   AC_DEFINE(HAVE_GNU_LD)
564 fi
565 if test $gnu_as = yes; then
566   AC_DEFINE(HAVE_GNU_AS)
567 fi
568 if test $elf = yes; then
569   AC_DEFINE(HAVE_ELF)
570 fi
571
572 AC_SUBST(shared)
573 if test $shared = default; then
574   if test $gnu_ld = yes; then
575     shared=$elf
576   fi
577 fi
578 AC_SUBST(profile)
579 AC_SUBST(omitfp)
580
581 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
582   config_makefile=
583 else
584   config_makefile=Makefile
585 fi
586
587 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
588           [echo '$config_vars' >> config.make])