Grok arg --enable-libio.
[kopensolaris-gnu/glibc.git] / configure.in
1 Dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.4.2)dnl             dnl Minimum Autoconf version required.
4 AC_INIT(features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21
22 dnl Arguments to specify presence of other packages/features.
23 AC_ARG_WITH(fp, dnl
24   --with-fp               if using floating-point hardware,
25             with_fp=$withval, with_fp=yes)
26 AC_ARG_WITH(gnu-binutils, dnl
27   --with-gnu-binutils     if using GNU binutils (as and ld),
28             gnu_binutils=$withval, gnu_binutils=no)
29 AC_ARG_WITH(gnu-ld, dnl
30   --with-gnu-ld           if using GNU ld (in the binutils package),
31             gnu_ld=$withval, gnu_ld=no)
32 AC_ARG_WITH(gnu-as, dnl
33   --with-gnu-as           if using GNU as (in the binutils package),
34             gnu_as=$withval, gnu_as=no)
35 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
36 AC_ARG_WITH(elf, dnl
37   --with-elf              if using the ELF object format,
38             elf=$withval, elf=no)
39 AC_ARG_WITH(weak-symbols, dnl
40   --with-weak-symbols     if weak symbols are available in as and ld,
41             weak=$withval, weak=no)
42
43 AC_ARG_ENABLE(libio, dnl
44 [  --enable-libio          build in GNU libio instead of GNU stdio],
45               stdio=libio, stdio=stdio)
46 AC_SUBST(stdio)
47
48 dnl Arguments to enable or disable building the shared, profiled, and
49 dnl -fomit-frame-pointer libraries.
50 AC_ARG_ENABLE(shared, dnl
51 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
52             shared=$enableval, shared=default)
53 AC_ARG_ENABLE(profile, dnl
54 [  --enable-profile        build profiled library [default=yes]],
55             profile=$enableval, profile=yes)
56 AC_ARG_ENABLE(omitfp, dnl
57 [  --enable-omitfp       build undebuggable optimized library [default=no]],
58             omitfp=$enableval, omitfp=no)
59
60 AC_CANONICAL_HOST
61 # We keep the original values in `$config_*' and never modify them, so we
62 # can write them unchanged into config.make.  Everything else uses
63 # $machine, $vendor, and $os, and changes them whenever convenient.
64 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
65
66 # Some configurations imply other options.
67 case "$host_os" in
68 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
69   # These systems always use GNU tools.
70   gnu_ld=yes gnu_as=yes
71 esac
72 case "$host_os" in
73 gnu* | linux* | sysv4* | solaris2*)
74   # These systems always use the ELF format.
75   elf=yes
76 esac
77
78 # Compute the list of sysdep directories for this configuration.
79 sysdep_dir=$srcdir/sysdeps
80 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
81 machine=$config_machine
82 vendor=$config_vendor
83 os=$config_os
84
85 dnl We need to use [ and ] for other purposes for a while now.
86 changequote(,)dnl
87 # Expand the configuration machine name into a subdirectory by architecture
88 # type and particular chip.
89 case "$machine" in
90 a29k | am29000) machine=a29k ;;
91 alpha*)         machine=alpha/$machine ;;
92 hppa*)          machine=hppa/$machine ;;
93 i[345]86)       machine=i386/$machine ;;
94 m680?0)         machine=m68k/$machine ;;
95 m68k)           machine=m68k/m68020 ;;
96 m88???)         machine=m88k/$machine ;;
97 m88k)           machine=m88k/m88100 ;;
98 mips*)          machine=mips/$machine ;;
99 mips64*)        machine=mips/mips64/$machine ;;
100 sparc[6789])    machine=sparc/$machine ;;
101 supersparc)     machine=sparc/sparc8 ;;
102 esac
103
104 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
105 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
106
107 case "$os" in
108 gnu*)
109   base_os=mach/hurd ;;
110 netbsd* | 386bsd* | freebsd* | bsdi*)
111   base_os=unix/bsd/bsd4.4 ;;
112 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
113   base_os=unix/bsd ;;
114 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
115   base_os=unix/sysv ;;
116 solaris[2-9]*)
117   base_os=unix/sysv/sysv4 ;;
118 none)
119   base_os=standalone ;;
120 *)
121   base_os='' ;;
122 esac
123
124 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
125 tail=$os
126 ostry=$os
127 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
128   ostry="$ostry /$o"
129   tail=$o
130 done  
131 o=`echo $tail | sed 's/[0-9]*$//'`
132 if test $o != $tail; then
133   ostry="$ostry /$o"
134 fi
135
136 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
137 base=
138 tail=$base_os
139 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
140   set $b
141   base="$base /$1"
142   tail="$2"
143 done
144
145 # For sparc/sparc9, try sparc/sparc9 and then sparc.
146 mach=
147 tail=$machine
148 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
149   set $m
150   # Prepend the machine's FPU directory unless --without-fp.
151   if test "$with_fp" = yes; then
152     mach="$mach /$1/fpu"
153   fi
154   mach="$mach /$1"
155   tail="$2"
156 done
157
158 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
159 changequote([,])dnl
160
161 # Find what sysdep directories exist.
162 sysnames=
163 for b in $base ''; do
164   for m0 in $mach ''; do
165     for v in /$vendor ''; do
166       for o in /$ostry ''; do
167         for m in $mach ''; do
168           try="$m0$b$v$o$m"
169           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
170           if test -d $sysdep_dir$try; then
171             sysnames="$sysnames $try"
172             { test -n "$o" || test -n "$b"; } && os_used=t
173             { test -n "$m" || test -n "$m0"; } && machine_used=t
174           fi
175         done
176       done
177     done
178   done
179 done
180
181 if test -z "$os_used" && test "$os" != none; then
182   AC_MSG_ERROR(Operating system $os is not supported.)
183 fi
184 if test -z "$machine_used" && test "$machine" != none; then
185   AC_MSG_ERROR(The $machine is not supported.)
186 fi
187
188 # We have now validated the configuration.
189
190
191 # If using ELF, look for an `elf' subdirectory of each machine directory.
192 # We prepend these rather than inserting them whereever the machine appears
193 # because things specified by the machine's ELF ABI should override
194 # OS-specific things, and should always be the same for any OS on the
195 # machine (otherwise what's the point of an ABI?).
196 if test "$elf" = yes; then
197   elf_dirs=
198   for m in $mach; do
199     if test -d $sysdep_dir$m/elf; then
200       elf_dirs="$elf_dirs $m/elf"
201     fi
202   done
203   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
204 fi
205
206
207 # Remove the leading slashes.
208 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
209
210
211 # Expand the list of system names into a full list of directories
212 # from each element's parent name and Implies file (if present).
213 set $sysnames
214 while test $# -gt 0; do
215   name=$1
216   shift
217
218   if test -f $sysdep_dir/$name/Implies; then
219     # Collect more names from the `Implies' file (removing comments).
220     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
221     for x in $implied; do
222       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
223     done
224   else
225     implied=
226   fi
227
228   # Add NAME to the list of names.
229   names="$names $name"
230
231   # Find the parent of NAME, using the empty string if it has none.
232 changequote(,)dnl
233   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
234 changequote([,])dnl
235
236   # Add the names implied by NAME, and NAME's parent (if it has one), to
237   # the list of names to be processed (the argument list).  We prepend the
238   # implied names to the list and append the parent.  We want implied
239   # directories to come before further directories inferred from the
240   # configuration components; this ensures that for sysv4, unix/common
241   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
242   # after sysv4).
243   sysnames="`echo $implied $* $parent`"
244   test -n "$sysnames" && set $sysnames
245 done
246
247 # Add the default directories.
248 names="$names generic stub"
249
250 # Now uniquize the list.
251 seen=
252 sysnames=
253 for name in $names; do
254   if echo "$seen" | fgrep -x $name >/dev/null; then
255     # Already in the list.
256     true;
257   else
258     # A new one.
259     if test -z "$seen"; then
260       seen="$name" sysnames="$name"
261     else
262       seen="$seen
263 $name"
264       sysnames="$sysnames $name"
265     fi
266   fi
267 done
268 libc_cv_sysdirs="$sysnames"])
269 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
270
271 AC_PROG_INSTALL
272 if test "$INSTALL" = "${srcdir}/install-sh"; then
273   # The makefiles need to use a different form to find it in $srcdir.
274   INSTALL='$(..)./install-sh'
275 fi
276
277 AC_CHECK_TOOL(CC, gcc)
278 AC_CHECK_TOOL(AR, ar)
279 AC_CHECK_TOOL(RANLIB, ranlib, :)
280 AC_PROG_CPP
281
282 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
283 echo '#include <stddef.h>
284 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
285 if eval "$ac_cpp conftest.c 2>/dev/null" \
286 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
287   libc_cv_signed_size_t=no
288 else
289   libc_cv_signed_size_t=yes
290 fi
291 rm -f conftest*])
292 if test $libc_cv_signed_size_t = yes; then
293   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
294   cat >> confdefs.h <<\EOF
295 #undef __SIZE_TYPE__
296 #define __SIZE_TYPE__ unsigned
297 EOF
298 fi
299
300 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
301 AC_TRY_COMPILE(dnl
302 [#define __need_size_t
303 #define __need_wchar_t
304 #include <stddef.h>
305 #define __need_NULL
306 #include <stddef.h>], [size_t size; wchar_t wchar;
307 #ifdef offsetof
308 #error stddef.h ignored __need_*
309 #endif
310 if (&size == NULL || &wchar == NULL) abort ();],
311                libc_cv_friendly_stddef=yes,
312                libc_cv_friendly_stddef=no)])
313 if test $libc_cv_friendly_stddef = yes; then
314   config_vars="$config_vars
315 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
316 fi
317
318 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
319                libc_cv_need_minus_P, [dnl
320 cat > conftest.S <<EOF
321 #include "confdefs.h"
322 /* Nothing whatsoever.  */
323 EOF
324 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
325   libc_cv_need_minus_P=no
326 else
327   libc_cv_need_minus_P=yes
328 fi
329 rm -f conftest*])
330 if test $libc_cv_need_minus_P = yes; then
331   config_vars="$config_vars
332 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
333 fi
334
335 AC_CACHE_CHECK(for assembler global-symbol directive,
336                libc_cv_asm_global_directive, [dnl
337 libc_cv_asm_global_directive=UNKNOWN
338 for ac_globl in .globl .global; do
339   cat > conftest.s <<EOF
340 .text
341 ${ac_globl} foo
342 foo: .long 0
343 EOF
344   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
345     libc_cv_asm_global_directive=${ac_globl}
346   fi
347   rm -f conftest*
348   test $libc_cv_asm_global_directive != UNKNOWN && break
349 done])
350 if test $libc_cv_asm_global_directive = UNKNOWN; then
351   AC_MSG_ERROR(cannot determine asm global directive)
352 else
353   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
354 fi
355
356 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
357 cat > conftest.s <<EOF
358 .text
359 foo: .long 0
360 .set glibc_conftest_frobozz,foo
361 $libc_cv_asm_global_directive glibc_conftest_frobozz
362 EOF
363 # The alpha-dec-osf1 assembler gives only a warning for `.set'
364 # (but it doesn't work), so we must do a linking check to be sure.
365 cat > conftest1.c <<\EOF
366 extern int glibc_conftest_frobozz;
367 main () { printf ("%d\n", glibc_conftest_frobozz); }
368 EOF
369 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
370             conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
371   libc_cv_asm_set_directive=yes
372 else
373   libc_cv_asm_set_directive=no
374 fi
375 rm -f conftest*])
376 if test $libc_cv_asm_set_directive = yes; then
377   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
378 fi
379
380 if test $elf != yes; then
381   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
382                  [AC_TRY_COMPILE(, [asm (".section .init");
383                                     asm (".section .fini");],
384                                  libc_cv_have_initfini=yes,
385                                  libc_cv_have_initfini=no)])
386   AC_SUBST(libc_cv_have_initfini)dnl
387   if test $libc_cv_have_initfini = yes; then
388     AC_DEFINE(HAVE_INITFINI)
389   fi
390 fi
391
392 # sysdeps configure fragments may set these with files to be linked below.
393 libc_link_dests=
394 libc_link_sources=
395
396 # Iterate over all the sysdep directories we will use, running their
397 # configure fragments, and looking for a uname implementation.
398 uname=
399 for dir in $sysnames; do
400   if test -r $sysdep_dir/$dir/configure; then
401     AC_MSG_RESULT(running configure fragment for $dir)
402     . $sysdep_dir/$dir/configure
403   fi
404   if test -z "$uname"; then
405     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
406     && uname=$dir
407   fi
408 done
409
410 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
411
412 # If we will use the generic uname implementation, we must figure out what
413 # it will say by examining the system, and write the results in config-name.h.
414 if test "$uname" = generic; then
415
416 changequote(,)dnl
417   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
418 changequote([,])dnl
419   if test $uname_sysname != $config_os; then
420     config_release=`echo $config_os | sed s/$uname_sysname//`
421   fi
422 dnl
423 AC_DEFUN(LIBC_KERNEL_ID, [dnl
424     if test -r /vmunix; then
425       kernel_id=`strings /vmunix | grep UNIX`
426     elif test -r /dynix; then
427       kernel_id=`strings /dynix | grep DYNIX`
428     else
429       kernel_id=
430     fi
431 ])dnl
432
433   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
434 AC_REQUIRE([LIBC_KERNEL_ID])dnl
435 changequote(,)dnl
436   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
437 changequote([,])dnl
438   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
439          != x$config_release; then
440     # The configuration release is a substring of the kernel release.
441     libc_cv_uname_release=$kernel_release
442   elif test x$config_release != x; then
443     libc_cv_uname_release=$config_release
444   elif test x$kernel_release != x; then
445     libc_cv_uname_release=$kernel_release
446   else
447     libc_cv_uname_release=unknown
448   fi])
449   uname_release="$libc_cv_uname_release"
450
451   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
452 AC_REQUIRE([LIBC_KERNEL_ID])dnl
453 changequote(,)dnl
454   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
455 changequote([,])dnl
456   if test -n "$kernel_version"; then
457     libc_cv_uname_version="$kernel_version"
458   else
459     libc_cv_uname_version=unknown
460   fi])
461   uname_version="$libc_cv_uname_version"
462
463 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
464   config_uname=config-name.h:config-name.in
465 else
466   # For non-generic uname, we don't need to create config-name.h at all.
467   config_uname=
468 fi
469
470 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
471 if test $gnu_ld = yes; then
472   AC_DEFINE(HAVE_GNU_LD)
473 fi
474 if test $gnu_as = yes; then
475   AC_DEFINE(HAVE_GNU_AS)
476 fi
477 if test $elf = yes; then
478   AC_DEFINE(HAVE_ELF)
479 fi
480 if test $weak = yes; then
481   AC_DEFINE(HAVE_WEAK_SYMBOLS)
482 fi
483
484 AC_SUBST(shared)
485 if test $shared = default; then
486   if test $gnu_ld = yes; then
487     shared=$elf
488   fi
489 fi
490 AC_SUBST(profile)
491 AC_SUBST(omitfp)
492
493
494 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
495   config_makefile=
496 else
497   config_makefile=Makefile
498 fi
499
500 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
501           [echo '$config_vars' >> config.make])