(sysnames): Better wording.
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45 AC_ARG_WITH(cvs, dnl
46 [  --without-cvs          if CVS should not be used],
47             with_cvs=$withval, with_cvs=yes)
48 AC_SUBST(with_cvs)
49
50 AC_ARG_ENABLE(libio, dnl
51 [  --enable-libio          build in GNU libio instead of GNU stdio],
52               [if test $enableval = yes; then
53                  stdio=libio
54                else
55                  stdio=stdio
56                fi],
57               stdio=default)
58
59 AC_ARG_ENABLE(sanity-checks, dnl
60 [  --disable-sanity-checks really do not use threads (should not be used
61                           except in special situations) [default=yes]],
62               enable_sanity=$enableval, enable_sanity=yes)
63
64 dnl Arguments to enable or disable building the static, shared, profiled,
65 dnl and -fomit-frame-pointer libraries.
66 AC_ARG_ENABLE(static, dnl
67 [  --enable-static         build static library [default=yes]],
68               static=$enableval, static=yes)
69 AC_ARG_ENABLE(shared, dnl
70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
71               shared=$enableval, shared=default)
72 AC_ARG_ENABLE(profile, dnl
73 [  --enable-profile        build profiled library [default=yes]],
74               profile=$enableval, profile=yes)
75 AC_ARG_ENABLE(omitfp, dnl
76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
77               omitfp=$enableval, omitfp=no)
78 AC_ARG_ENABLE(bounded, dnl
79 [  --enable-bounded        build with runtime bounds checking [default=no]],
80               bounded=$enableval, bounded=no)
81 AC_ARG_ENABLE(versioning, dnl
82 [  --disable-versioning    do not include versioning information in the
83                           library objects [default=yes if supported]],
84              enable_versioning=$enableval, enable_versioning=yes)
85
86 dnl Generic infrastructure for drop-in additions to libc.
87 AC_ARG_ENABLE(add-ons, dnl
88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
89                                   search for add-ons if no parameter given],
90   [case "$enableval" in
91     yes) if test "$srcdir" = "."; then
92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
93          else
94            add_ons=`echo $srcdir/*/configure | \
95                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
96          fi;;
97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
98    esac],
99   [add_ons=])
100
101 AC_CONFIG_SUBDIRS($add_ons)
102 add_ons_pfx=
103 if test x"$add_ons" != x; then
104   for f in $add_ons; do
105     # Test whether such a subdir really exists.
106     if test -d $srcdir/$f; then
107       add_ons_pfx="$add_ons_pfx $f/"
108     else
109       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
110     fi
111   done
112 fi
113
114 dnl On some platforms we cannot use dynamic loading.  We must provide
115 dnl static NSS modules.
116 AC_ARG_ENABLE(static-nss, dnl
117 [  --enable-static-nss     build static NSS modules [default=no]],
118               static_nss=$enableval, static_nss=no)
119 if test x"$static_nss" = xyes; then
120   AC_DEFINE(DO_STATIC_NSS)
121 fi
122
123 AC_CANONICAL_HOST
124
125 # The way shlib-versions is used to generate soversions.mk uses a
126 # fairly simplistic model for name recognition that can't distinguish
127 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
128 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
129 # tell.  This doesn't get used much beyond that, so it's fairly safe.
130 case "$host_os" in
131 linux*)
132   ;;
133 gnu*)
134   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
135   ;;
136 esac
137
138 ###
139 ### I put this here to prevent those annoying emails from people who cannot
140 ### read and try to compile glibc on unsupported platforms.  --drepper
141 ###
142 ### By using the undocumented --enable-hacker-mode option for configure
143 ### one can skip this test to make the configuration not fail for unsupported
144 ### platforms.
145 ###
146 if test -z "$enable_hacker_mode"; then
147   case "$machine-$host_os" in
148   *-linux* | *-gnu* | arm*-none*)
149     ;;
150   *)
151     echo "*** The GNU C library is currently not available for this platform."
152     echo "*** So far nobody cared to port it and if there is no volunteer it"
153     echo "*** might never happen.  So, if you have interest to see glibc on"
154     echo "*** this platform visit"
155     echo "***   http://www.gnu.org/software/libc/porting.html"
156     echo "*** and join the group of porters"
157     exit 1
158     ;;
159   esac
160 fi
161
162 # We keep the original values in `$config_*' and never modify them, so we
163 # can write them unchanged into config.make.  Everything else uses
164 # $machine, $vendor, and $os, and changes them whenever convenient.
165 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
166
167 # Some configurations imply other options.
168 case "$host_os" in
169 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
170   # These systems always use GNU tools.
171   gnu_ld=yes gnu_as=yes ;;
172 esac
173 case "$host_os" in
174 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
175 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
176   ;;
177 gnu* | linux* | sysv4* | solaris2* | irix6*)
178   # These systems (almost) always use the ELF format.
179   elf=yes
180   ;;
181 esac
182
183 machine=$config_machine
184 vendor=$config_vendor
185 os=$config_os
186
187 dnl We need to use [ and ] for other purposes for a while now.
188 changequote(,)dnl
189 # Expand the configuration machine name into a subdirectory by architecture
190 # type and particular chip.
191 case "$machine" in
192 a29k | am29000) base_machine=a29k machine=a29k ;;
193 alpha*)         base_machine=alpha machine=alpha/$machine ;;
194 arm*)           base_machine=arm machine=arm/$machine ;;
195 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
196 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
197 hppa*)          base_machine=hppa machine=hppa/$machine ;;
198 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
199 m680?0)         base_machine=m68k machine=m68k/$machine ;;
200 m68k)           base_machine=m68k machine=m68k/m68020 ;;
201 m88???)         base_machine=m88k machine=m88k/$machine ;;
202 m88k)           base_machine=m88k machine=m88k/m88100 ;;
203 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
204 mips*)          base_machine=mips
205                 case "`uname -m`" in
206                 IP22) machine=mips/mips3 ;;
207                 *)    machine=mips/$machine ,,
208                 esac ;;
209 sparc | sparcv[67])
210                 base_machine=sparc machine=sparc/sparc32 ;;
211 sparcv8 | supersparc | hypersparc)
212                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
213 sparc64 | ultrasparc)
214                 base_machine=sparc machine=sparc/sparc64 ;;
215 esac
216 changequote([,])dnl
217 AC_SUBST(base_machine)
218
219 if test "$base_machine" = "i386"; then
220   AC_DEFINE(USE_REGPARMS)
221 fi
222
223 # Compute the list of sysdep directories for this configuration.
224 # This can take a while to compute.
225 sysdep_dir=$srcdir/sysdeps
226 AC_MSG_CHECKING(sysdep dirs)
227 dnl We need to use [ and ] for other purposes for a while now.
228 changequote(,)dnl
229 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
230 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
231
232 case "$os" in
233 gnu*)
234   base_os=mach/hurd ;;
235 netbsd* | 386bsd* | freebsd* | bsdi*)
236   base_os=unix/bsd/bsd4.4 ;;
237 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
238   base_os=unix/bsd ;;
239 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
240   base_os=unix/sysv ;;
241 irix6*)
242   base_os=unix/sysv/irix6/$os ;;
243 solaris[2-9]*)
244   base_os=unix/sysv/sysv4 ;;
245 none)
246   base_os=standalone ;;
247 *)
248   base_os='' ;;
249 esac
250
251 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
252 tail=$os
253 ostry=$os
254 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
255   ostry="$ostry /$o"
256   tail=$o
257 done
258 o=`echo $tail | sed 's/[0-9]*$//'`
259 if test $o != $tail; then
260   ostry="$ostry /$o"
261 fi
262 # For linux-gnu, try linux-gnu, then linux.
263 o=`echo $tail | sed 's/-.*$//'`
264 if test $o != $tail; then
265   ostry="$ostry /$o"
266 fi
267
268 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
269 base=
270 tail=$base_os
271 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
272   set $b
273   base="$base /$1"
274   tail="$2"
275 done
276
277 # For sparc/sparc9, try sparc/sparc9 and then sparc.
278 mach=
279 tail=$machine
280 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
281   set $m
282   # Prepend the machine's FPU directory unless --without-fp.
283   if test "$with_fp" = yes; then
284     mach="$mach /$1/fpu"
285   fi
286   mach="$mach /$1"
287   tail="$2"
288 done
289
290 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
291 changequote([,])dnl
292
293 # Find what sysdep directories exist.
294 sysnames=
295 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
296 for d in $add_ons_pfx ''; do
297   for b in $base ''; do
298     for m0 in $mach ''; do
299       for v in /$vendor ''; do
300         test "$v" = / && continue
301         for o in /$ostry ''; do
302           test "$o" = / && continue
303           for m in $mach ''; do
304             if test "$m0$b$v$o$m"; then
305               try="${d}sysdeps$m0$b$v$o$m"
306               test -n "$enable_debug_configure" &&
307               echo "$0 [DEBUG]: try $try" >&2
308               case $try in
309                 /*) dest=$try ;;
310                 *)  dest=$srcdir/$try ;;
311               esac
312               if test -d $dest; then
313                 sysnames="$sysnames $try"
314                 { test -n "$o" || test -n "$b"; } && os_used=t
315                 { test -n "$m" || test -n "$m0"; } && machine_used=t
316               fi
317             fi
318           done
319         done
320       done
321     done
322   done
323 done
324 IFS="$ac_save_ifs"
325
326 if test -z "$os_used" && test "$os" != none; then
327   AC_MSG_ERROR(Operating system $os is not supported.)
328 fi
329 if test -z "$machine_used" && test "$machine" != none; then
330   AC_MSG_ERROR(The $machine is not supported.)
331 fi
332
333 # We have now validated the configuration.
334
335
336 # If using ELF, look for an `elf' subdirectory of each machine directory.
337 # We prepend these rather than inserting them whereever the machine appears
338 # because things specified by the machine's ELF ABI should override
339 # OS-specific things, and should always be the same for any OS on the
340 # machine (otherwise what's the point of an ABI?).
341 if test "$elf" = yes; then
342   elf_dirs=
343   for d in $add_ons_pfx ''; do
344     case $d in
345       /*) xsrcdir= ;;
346       *)  xsrcdir=$srcdir/ ;;
347     esac
348     for m in $mach; do
349       if test -d $xsrcdir${d}sysdeps$m/elf; then
350         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
351       fi
352     done
353   done
354   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
355 fi
356
357
358 # Expand the list of system names into a full list of directories
359 # from each element's parent name and Implies file (if present).
360 set $sysnames
361 names=
362 while test $# -gt 0; do
363   name=$1
364   shift
365
366   case " $names " in *" $name "*)
367     # Already in the list.
368     continue
369   esac
370
371   # Report each name as we discover it, so there is no long pause in output.
372   echo $ac_n "$name $ac_c" >&AC_FD_MSG
373
374   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
375
376   case $name in
377     /*) xsrcdir= ;;
378     *)  xsrcdir=$srcdir/ ;;
379   esac
380   test -n "$enable_debug_configure" &&
381   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
382
383   if test -f $xsrcdir$name/Implies; then
384     # Collect more names from the `Implies' file (removing comments).
385     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
386     implied=
387     for x in $implied_candidate; do
388       if test -d $xsrcdir$name_base/$x; then
389         implied="$implied $name_base/$x";
390       else
391         AC_MSG_WARN($name/Implies specifies nonexistent $x)
392       fi
393     done
394   else
395     implied=
396   fi
397
398   # Add NAME to the list of names.
399   names="$names $name"
400
401   # Find the parent of NAME, using the empty string if it has none.
402 changequote(,)dnl
403   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
404 changequote([,])dnl
405
406   # Add the names implied by NAME, and NAME's parent (if it has one), to
407   # the list of names to be processed (the argument list).  We prepend the
408   # implied names to the list and append the parent.  We want implied
409   # directories to come before further directories inferred from the
410   # configuration components; this ensures that for sysv4, unix/common
411   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
412   # after sysv4).
413   sysnames="`echo $implied $* $parent`"
414   test -n "$sysnames" && set $sysnames
415 done
416
417 # Add the default directories.
418 sysnames="$names sysdeps/generic"
419 AC_SUBST(sysnames)
420 # The other names were emitted during the scan.
421 AC_MSG_RESULT(sysdeps/generic)
422
423
424 ### Locate tools.
425
426 AC_PROG_INSTALL
427 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
428   # The makefiles need to use a different form to find it in $srcdir.
429   INSTALL='\$(..)./install-sh -c'
430 fi
431 AC_PROG_LN_S
432 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
433 if test "$MSGFMT" != ":"; then
434 changequote(,)dnl Need [] for regexps.
435   if $MSGFMT --version 2>&1 | grep 'GNU gettext.*0\.[1-9][0-9]' >/dev/null 2>&1
436 changequote([,])dnl
437   then : # msgfmt from gettext 0.10 or greater, works.
438   else
439     AC_MSG_WARN([
440 *** (g)msgfmt is too old or wrong version (need gettext 0.10 or better).])
441     MSGFMT=":"
442   fi
443 fi
444
445 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
446 if test "$MAKEINFO"; then
447 changequote(,)dnl Need [] for regexps.
448   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
449 changequote([,])dnl
450   then : # Makeinfo 3.11 or greater, works.
451   else
452     AC_MSG_WARN([
453 *** makeinfo is too old (need version 3.11 or better).
454 *** You should install the needed version and re-configure since otherwise
455 *** you won't get the info pages installed.])
456     MAKEINFO=
457   fi
458 fi
459
460 AC_PROG_CC_LOCAL
461 AC_CANONICAL_BUILD
462 if test $host != $build; then
463   AC_CHECK_PROGS(BUILD_CC, gcc cc)
464 fi
465 AC_SUBST(cross_compiling)
466 AC_PROG_CPP
467 LIBC_PROG_BINUTILS
468 AC_CHECK_TOOL(AR, ar)
469 AC_CHECK_TOOL(RANLIB, ranlib, :)
470
471 # check for recent compiler
472 AC_MSG_CHECKING(compiler version)
473 case `${CC-cc} -v 2>&1` in
474   *egcs-2.91.* | *egcs-1.0.[2-9]* | *egcs-1.1* | *2.8.[1-9]* | *2.9.[0-9] )
475     cc_is_recent="ok"
476     ;;
477   *)
478     cc_is_recent="too old"
479     ;;
480 esac
481 AC_MSG_RESULT($cc_is_recent)
482 if test "$cc_is_recent" != "ok"; then
483   AC_MSG_WARN([
484 *** Your compiler is too old.
485 *** You need at least egcs 1.0.2 or GNU CC 2.8.1 to compile glibc.
486 ])
487 fi
488
489 # Test if LD_LIBRARY_PATH contains the notation for the current directory
490 # since this would lead to problems installing/building glibc.
491 # LD_LIBRARY_PATH contains the current directory if one of the following
492 # is true:
493 # - one of the terminals (":" and ";") is the first or last sign
494 # - two terminals occur directly after each other
495 # - the path contains an element with a dot in it
496 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
497 changequote(,)dnl
498 case ${LD_LIBRARY_PATH} in
499   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
500     ld_library_path_setting="contains current directory"
501     ;;
502   *)
503     ld_library_path_setting="ok"
504     ;;
505 esac
506 changequote([,])dnl
507 AC_MSG_RESULT($ld_library_path_setting)
508 if test "$ld_library_path_setting" != "ok"; then
509 AC_MSG_ERROR(
510 *** LD_LIBRARY_PATH shouldn't contain the current path when building glibc.
511 *** Please change the environment variable and run configure again.)
512 fi
513
514 AC_PATH_PROG(BASH, bash, no)
515 if test "$BASH" != no &&
516    $BASH -c 'test "$BASH_VERSINFO" \
517              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
518   libc_cv_have_bash2=yes
519 else
520   libc_cv_have_bash2=no
521 fi
522 AC_SUBST(libc_cv_have_bash2)
523
524 dnl We need a ksh compatible shell for tzselect.
525 if test "$BASH" = no; then
526   AC_PATH_PROG(KSH, ksh, no)
527   if test "$KSH" = no; then
528     libc_cv_have_ksh=no
529   else
530     libc_cv_have_ksh=yes
531   fi
532 else
533   KSH="$BASH"
534   AC_SUBST(KSH)
535   libc_cv_have_ksh=yes
536 fi
537 AC_SUBST(libc_cv_have_ksh)
538
539 AC_PATH_PROGS(PERL, perl, no)
540 AC_SUBST(PERL)
541
542 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
543 echo '#include <stddef.h>
544 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
545 if eval "$ac_cpp conftest.c 2>/dev/null" \
546 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
547   libc_cv_signed_size_t=no
548 else
549   libc_cv_signed_size_t=yes
550 fi
551 rm -f conftest*])
552 if test $libc_cv_signed_size_t = yes; then
553   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
554   cat >> confdefs.h <<\EOF
555 #undef __SIZE_TYPE__
556 #define __SIZE_TYPE__ unsigned
557 EOF
558 fi
559
560 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
561 AC_TRY_COMPILE(dnl
562 [#define __need_size_t
563 #define __need_wchar_t
564 #include <stddef.h>
565 #define __need_NULL
566 #include <stddef.h>], [size_t size; wchar_t wchar;
567 #ifdef offsetof
568 #error stddef.h ignored __need_*
569 #endif
570 if (&size == NULL || &wchar == NULL) abort ();],
571                libc_cv_friendly_stddef=yes,
572                libc_cv_friendly_stddef=no)])
573 if test $libc_cv_friendly_stddef = yes; then
574   config_vars="$config_vars
575 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
576 fi
577
578 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
579                libc_cv_need_minus_P, [dnl
580 cat > conftest.S <<EOF
581 #include "confdefs.h"
582 /* Nothing whatsoever.  */
583 EOF
584 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
585   libc_cv_need_minus_P=no
586 else
587   libc_cv_need_minus_P=yes
588 fi
589 rm -f conftest*])
590 if test $libc_cv_need_minus_P = yes; then
591   config_vars="$config_vars
592 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
593 fi
594
595 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
596 # be told to read stdin.  This causes the compiler to hang when fed an
597 # .s file.
598 if test $ac_cv_prog_gcc = yes; then
599  case `${CC-cc} -v 2>&1` in
600   *2.7*)
601   # We must check this even if -pipe is not given here, because the user
602   # might do `make CFLAGS=-pipe'.
603   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
604    cp /dev/null conftest.s
605    cat >conftest1.s <<EOF
606 .nosuchdirective
607 EOF
608    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
609     libc_cv_gcc_pipe_bug=no
610    else
611     libc_cv_gcc_pipe_bug=yes
612    fi
613    rm -f conftest*])
614   if test $libc_cv_gcc_pipe_bug = yes; then
615    makeCC="${CC-cc} -B\$(common-objpfx)"
616    makeCFLAGS=$CFLAGS
617    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
618   fi;;
619  *) libc_cv_gcc_pipe_bug=no;;
620  esac
621 else
622  libc_cv_gcc_pipe_bug=no
623 fi
624
625 AC_CACHE_CHECK(for assembler global-symbol directive,
626                libc_cv_asm_global_directive, [dnl
627 libc_cv_asm_global_directive=UNKNOWN
628 for ac_globl in .globl .global; do
629   cat > conftest.s <<EOF
630 .text
631 ${ac_globl} foo
632 foo:
633 EOF
634   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
635     libc_cv_asm_global_directive=${ac_globl}
636   fi
637   rm -f conftest*
638   test $libc_cv_asm_global_directive != UNKNOWN && break
639 done])
640 if test $libc_cv_asm_global_directive = UNKNOWN; then
641   AC_MSG_ERROR(cannot determine asm global directive)
642 else
643   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
644 fi
645
646 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
647 cat > conftest.s <<EOF
648 .text
649 foo:
650 .set glibc_conftest_frobozz,foo
651 $libc_cv_asm_global_directive glibc_conftest_frobozz
652 EOF
653 # The alpha-dec-osf1 assembler gives only a warning for `.set'
654 # (but it doesn't work), so we must do a linking check to be sure.
655 cat > conftest1.c <<\EOF
656 extern int glibc_conftest_frobozz;
657 main () { printf ("%d\n", glibc_conftest_frobozz); }
658 EOF
659 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
660             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
661   libc_cv_asm_set_directive=yes
662 else
663   libc_cv_asm_set_directive=no
664 fi
665 rm -f conftest*])
666 if test $libc_cv_asm_set_directive = yes; then
667   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
668 fi
669
670 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
671 [cat > conftest.s <<EOF
672 .text
673 _sym:
674 .symver _sym,sym@VERS
675 EOF
676 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
677   libc_cv_asm_symver_directive=yes
678 else
679   libc_cv_asm_symver_directive=no
680 fi
681 rm -f conftest*])
682 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
683 if test $libc_cv_asm_symver_directive = yes; then
684   cat > conftest.s <<EOF
685 .text
686 _sym:
687 .symver _sym,sym@VERS
688 EOF
689   cat > conftest.map <<EOF
690 VERS_1 {
691         global: sym;
692 };
693
694 VERS_2 {
695         global: sym;
696 } VERS_1;
697 EOF
698   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
699     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
700                                         -nostartfiles -nostdlib
701                                         -Wl,--version-script,conftest.map
702                        1>&AC_FD_CC]);
703     then
704       libc_cv_ld_version_script_option=yes
705     else
706       libc_cv_ld_version_script_option=no
707     fi
708   else
709     libc_cv_ld_version_script_option=no
710   fi
711 else
712   libc_cv_ld_version_script_option=no
713 fi
714 rm -f conftest*])
715 if test $libc_cv_asm_symver_directive = yes &&
716    test $libc_cv_ld_version_script_option = yes &&
717    test $enable_versioning = yes; then
718   VERSIONING=yes
719   AC_DEFINE(DO_VERSIONING)
720 else
721   VERSIONING=no
722 fi
723 AC_SUBST(VERSIONING)
724
725 if test $VERSIONING = no; then
726   echo "\
727 *** WARNING: You should not compile GNU libc without versioning. Not using
728 *** versioning will introduce incompatibilities so that old binaries
729 *** will not run anymore.
730 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
731 fi
732 if test $elf = yes; then
733   AC_CACHE_CHECK(for .previous assembler directive,
734                  libc_cv_asm_previous_directive, [dnl
735   cat > conftest.s <<EOF
736 .section foo_section
737 .previous
738 EOF
739   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
740     libc_cv_asm_previous_directive=yes
741   else
742     libc_cv_asm_previous_directive=no
743   fi
744   rm -f conftest*])
745   if test $libc_cv_asm_previous_directive = yes; then
746     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
747   else
748     AC_CACHE_CHECK(for .popsection assembler directive,
749                    libc_cv_asm_popsection_directive, [dnl
750     cat > conftest.s <<EOF
751 .pushsection foo_section
752 .popsection
753 EOF
754     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
755       libc_cv_asm_popsection_directive=yes
756     else
757       libc_cv_asm_popsection_directive=no
758     fi
759     rm -f conftest*])
760     if test $libc_cv_asm_popsection_directive = yes; then
761       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
762     fi
763   fi
764 fi
765
766 if test $elf != yes; then
767   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
768                  [AC_TRY_COMPILE(, [asm (".section .init");
769                                     asm (".section .fini");
770                                     asm (".text");],
771                                  libc_cv_have_initfini=yes,
772                                  libc_cv_have_initfini=no)])
773   AC_SUBST(libc_cv_have_initfini)dnl
774   if test $libc_cv_have_initfini = yes; then
775     AC_DEFINE(HAVE_INITFINI)
776   fi
777 fi
778
779 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
780 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
781 [cat > conftest.$ac_ext <<EOF
782 dnl This sometimes fails to find confdefs.h, for some reason.
783 dnl [#]line __oline__ "[$]0"
784 [#]line __oline__ "configure"
785 #include "confdefs.h"
786 void underscore_test(void) {
787 return; }
788 EOF
789 if AC_TRY_EVAL(ac_compile); then
790   if grep _underscore_test conftest* >/dev/null; then
791     ifelse([$1], , :, [rm -f conftest*
792     $1])
793   else
794     ifelse([$2], , , [rm -f conftest*
795     $2])
796   fi
797 else
798   echo "configure: failed program was:" >&AC_FD_CC
799   cat conftest.$ac_ext >&AC_FD_CC
800   ifelse([$2], , , [rm -f conftest*
801   $2])
802 fi
803 rm -f conftest*])
804
805 if test $elf = yes; then
806   libc_cv_asm_underscores=no
807 else
808   if test $ac_cv_prog_cc_works = yes; then
809     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
810                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
811                                 libc_cv_asm_underscores=yes,
812                                 libc_cv_asm_underscores=no)])
813   else
814     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
815                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
816                                             libc_cv_asm_underscores=no)])
817   fi
818 fi
819 if test $libc_cv_asm_underscores = no; then
820   AC_DEFINE(NO_UNDERSCORES)
821 fi
822
823 if test $elf = yes; then
824   libc_cv_weak_symbols=yes
825 fi
826
827 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
828                  [dnl
829 cat > conftest.s <<EOF
830 .text
831 ${libc_cv_asm_global_directive} foo
832 foo:
833 .weak foo
834 .weak bar; bar = foo
835 EOF
836 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
837   libc_cv_asm_weak_directive=yes
838 else
839   libc_cv_asm_weak_directive=no
840 fi
841 rm -f conftest*])
842
843 if test $libc_cv_asm_weak_directive = no; then
844   AC_CACHE_CHECK(for assembler .weakext directive,
845                  libc_cv_asm_weakext_directive,
846                  [dnl
847 cat > conftest.s <<EOF
848 .text
849 ${libc_cv_asm_global_directive} foo
850 foo:
851 .weakext bar foo
852 .weakext baz
853 ${libc_cv_asm_global_directive} baz
854 baz:
855 EOF
856   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
857     libc_cv_asm_weakext_directive=yes
858   else
859     libc_cv_asm_weakext_directive=no
860   fi
861   rm -f conftest*])
862
863 fi # no .weak
864
865 if test $libc_cv_asm_weak_directive = yes; then
866   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
867 elif test $libc_cv_asm_weakext_directive = yes; then
868   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
869 fi
870
871 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
872 cat > conftest.c <<\EOF
873 _start () {}
874 int __eh_pc;
875 __throw () {}
876 EOF
877 dnl No \ in command here because it ends up inside ''.
878 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
879                             -nostdlib -nostartfiles -Wl,--no-whole-archive
880                             -o conftest conftest.c 1>&AC_FD_CC]); then
881   libc_cv_ld_no_whole_archive=yes
882 else
883   libc_cv_ld_no_whole_archive=no
884 fi
885 rm -f conftest*])
886 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
887
888 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
889 cat > conftest.c <<\EOF
890 _start () {}
891 int __eh_pc;
892 __throw () {}
893 EOF
894 dnl No \ in command here because it ends up inside ''.
895 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
896                             -nostdlib -nostartfiles -fno-exceptions
897                             -o conftest conftest.c 1>&AC_FD_CC]); then
898   libc_cv_gcc_no_exceptions=yes
899 else
900   libc_cv_gcc_no_exceptions=no
901 fi
902 rm -f conftest*])
903 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
904
905 if test "$base_machine" = alpha ; then
906 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
907 cat > conftest.c <<\EOF
908 foo () { }
909 EOF
910 dnl
911 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
912 then
913   libc_cv_gcc_alpha_ng_prefix=yes
914 else
915   libc_cv_gcc_alpha_ng_prefix=no
916 fi
917 rm -f conftest* ])
918 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
919   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
920 else
921   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
922 fi
923 fi
924
925 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
926 [cat > conftest.c <<EOF
927 #line __oline__ "configure"
928 static char __EH_FRAME_BEGIN__[];
929 _start ()
930 {
931 #ifdef CHECK__register_frame
932   __register_frame (__EH_FRAME_BEGIN__);
933   __deregister_frame (__EH_FRAME_BEGIN__);
934 #endif
935 #ifdef CHECK__register_frame_info
936   __register_frame_info (__EH_FRAME_BEGIN__);
937   __deregister_frame_info (__EH_FRAME_BEGIN__);
938 #endif
939 }
940 int __eh_pc;
941 __throw () {}
942 /* FIXME: this is fragile.  */
943 malloc () {}
944 strcmp () {}
945 strlen () {}
946 memcpy () {}
947 memset () {}
948 free () {}
949 abort () {}
950 __bzero () {}
951 EOF
952 dnl No \ in command here because it ends up inside ''.
953 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
954                             -nostdlib -nostartfiles
955                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
956   libc_cv_gcc_dwarf2_unwind_info=static
957 else
958   libc_cv_gcc_dwarf2_unwind_info=no
959 fi
960 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
961   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
962                               -nostdlib -nostartfiles
963                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
964     libc_cv_gcc_dwarf2_unwind_info=yes
965   else
966     libc_cv_gcc_dwarf2_unwind_info=no
967   fi
968 fi
969 rm -f conftest*])
970 case $libc_cv_gcc_dwarf2_unwind_info in
971 yes)
972   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
973   ;;
974 static)
975   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
976   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
977   ;;
978 esac
979
980 ### End of automated tests.
981 ### Now run sysdeps configure fragments.
982
983 # sysdeps configure fragments may set these with files to be linked below.
984 libc_link_dests=
985 libc_link_sources=
986
987 # Iterate over all the sysdep directories we will use, running their
988 # configure fragments, and looking for a uname implementation.
989 uname=
990 for dir in $sysnames; do
991   case $dir in
992     /*) dest=$dir ;;
993     *)  dest=$srcdir/$dir ;;
994   esac
995   if test -r $dest/configure; then
996     AC_MSG_RESULT(running configure fragment for $dest)
997     . $dest/configure
998   fi
999 [
1000   if test -z "$uname"; then
1001     if test -r $dest/uname.c ||
1002        test -r $dest/uname.S ||
1003        { test -r $dest/syscalls.list &&
1004          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1005       uname=$dir
1006     fi
1007   fi
1008 ]dnl
1009 done
1010
1011 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1012
1013 # If we will use the generic uname implementation, we must figure out what
1014 # it will say by examining the system, and write the results in config-name.h.
1015 if test "$uname" = "sysdeps/generic"; then
1016
1017 changequote(,)dnl
1018   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1019 changequote([,])dnl
1020   if test $uname_sysname != $config_os; then
1021     config_release=`echo $config_os | sed s/$uname_sysname//`
1022   fi
1023 dnl
1024 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1025     if test -r /vmunix; then
1026       kernel_id=`strings /vmunix | grep UNIX`
1027     elif test -r /dynix; then
1028       kernel_id=`strings /dynix | grep DYNIX`
1029     else
1030       kernel_id=
1031     fi
1032 ])dnl
1033
1034   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1035 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1036 changequote(,)dnl
1037   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1038 changequote([,])dnl
1039   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1040          != x$config_release; then
1041     # The configuration release is a substring of the kernel release.
1042     libc_cv_uname_release=$kernel_release
1043   elif test x$config_release != x; then
1044     libc_cv_uname_release=$config_release
1045   elif test x$kernel_release != x; then
1046     libc_cv_uname_release=$kernel_release
1047   else
1048     libc_cv_uname_release=unknown
1049   fi])
1050   uname_release="$libc_cv_uname_release"
1051
1052   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1053 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1054 changequote(,)dnl
1055   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1056 changequote([,])dnl
1057   if test -n "$kernel_version"; then
1058     libc_cv_uname_version="$kernel_version"
1059   else
1060     libc_cv_uname_version=unknown
1061   fi])
1062   uname_version="$libc_cv_uname_version"
1063
1064 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1065   config_uname=config-name.h:config-name.in
1066 else
1067   # For non-generic uname, we don't need to create config-name.h at all.
1068   config_uname=
1069 fi
1070
1071 AC_MSG_CHECKING(stdio selection)
1072 AC_SUBST(stdio)
1073 case $stdio in
1074 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1075 default) stdio=stdio ;;
1076 esac
1077 AC_MSG_RESULT($stdio)
1078
1079 AC_MSG_CHECKING(ldap selection)
1080 AC_SUBST(LDAP)
1081 case $add_ons in
1082 *ldap*)
1083    ldap=yes
1084    LDAP=ldap ;;
1085 *) ldap=no
1086    LDAP= ;;
1087 esac
1088 AC_MSG_RESULT($ldap)
1089
1090 AC_SUBST(libc_cv_slibdir)
1091 AC_SUBST(libc_cv_sysconfdir)
1092 AC_SUBST(libc_cv_rootsbindir)
1093
1094 AC_SUBST(has_ldconfig)
1095
1096 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1097 if test $gnu_ld = yes; then
1098   AC_DEFINE(HAVE_GNU_LD)
1099 fi
1100 if test $gnu_as = yes; then
1101   AC_DEFINE(HAVE_GNU_AS)
1102 fi
1103 if test $elf = yes; then
1104   AC_DEFINE(HAVE_ELF)
1105 fi
1106
1107 AC_SUBST(static)
1108 AC_SUBST(shared)
1109 if test $shared = default; then
1110   if test $gnu_ld = yes; then
1111     shared=$elf
1112   else
1113     # For now we do not assume shared libs are available.  In future more
1114     # tests might become available.
1115     shared=no
1116   fi
1117 fi
1118
1119 dnl We must not allow compilation without static library on some platforms.
1120 if test $static = no && test $shared = yes; then
1121   case "$host_os" in
1122   linux* | gnu*)
1123     AC_MSG_ERROR([
1124 *** You must compile with support for the static library since the shared
1125 *** library uses it.  Restart configure without \`--disable-static'.])
1126     ;;
1127   *)
1128     ;;
1129   esac
1130 fi
1131
1132 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1133 [pic_default=yes
1134 cat > conftest.c <<EOF
1135 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1136 # error PIC is default.
1137 #endif
1138 EOF
1139 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1140   pic_default=no
1141 fi
1142 rm -f conftest.*])
1143 AC_SUBST(pic_default)
1144
1145 AC_SUBST(profile)
1146 AC_SUBST(omitfp)
1147 AC_SUBST(bounded)
1148 AC_SUBST(static_nss)
1149 AC_SUBST(nopic_initfini)
1150
1151 AC_SUBST(DEFINES)
1152
1153 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1154   config_makefile=
1155 else
1156   config_makefile=Makefile
1157 fi
1158
1159 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1160 AC_SUBST(VERSION)
1161
1162 if test $libc_cv_gcc_pipe_bug = yes; then
1163  realCC=$CC
1164  CC=$makeCC
1165  CFLAGS=$makeCFLAGS
1166 fi
1167 AC_OUTPUT_COMMANDS([
1168 if test "$realCC"; then
1169  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1170  mv specsT specs
1171 fi], [realCC=$realCC])
1172
1173 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1174           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])