Irix6 is an ELF platform.
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45 AC_ARG_WITH(cvs, dnl
46 [  --without-cvs          if CVS should not be used],
47             with_cvs=$withval, with_cvs=yes)
48 AC_SUBST(with_cvs)
49
50 AC_ARG_ENABLE(libio, dnl
51 [  --enable-libio          build in GNU libio instead of GNU stdio],
52               [if test $enableval = yes; then
53                  stdio=libio
54                else
55                  stdio=stdio
56                fi],
57               stdio=default)
58
59 AC_ARG_ENABLE(sanity-checks, dnl
60 [  --disable-sanity-checks really do not use threads (should not be used
61                           except in special situations) [default=yes]],
62               enable_sanity=$enableval, enable_sanity=yes)
63
64 dnl Arguments to enable or disable building the static, shared, profiled,
65 dnl and -fomit-frame-pointer libraries.
66 AC_ARG_ENABLE(static, dnl
67 [  --enable-static         build static library [default=yes]],
68               static=$enableval, static=yes)
69 AC_ARG_ENABLE(shared, dnl
70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
71               shared=$enableval, shared=default)
72 AC_ARG_ENABLE(profile, dnl
73 [  --enable-profile        build profiled library [default=yes]],
74               profile=$enableval, profile=yes)
75 AC_ARG_ENABLE(omitfp, dnl
76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
77               omitfp=$enableval, omitfp=no)
78 AC_ARG_ENABLE(bounded, dnl
79 [  --enable-bounded        build with runtime bounds checking [default=no]],
80               bounded=$enableval, bounded=no)
81 AC_ARG_ENABLE(versioning, dnl
82 [  --disable-versioning    do not include versioning information in the
83                           library objects [default=yes if supported]],
84              enable_versioning=$enableval, enable_versioning=yes)
85
86 dnl Generic infrastructure for drop-in additions to libc.
87 AC_ARG_ENABLE(add-ons, dnl
88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
89                                   search for add-ons if no parameter given],
90   [case "$enableval" in
91     yes) if test "$srcdir" = "."; then
92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
93          else
94            add_ons=`echo $srcdir/*/configure | \
95                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
96          fi;;
97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
98    esac],
99   [add_ons=])
100
101 AC_CONFIG_SUBDIRS($add_ons)
102 add_ons_pfx=
103 if test x"$add_ons" != x; then
104   for f in $add_ons; do
105     # Test whether such a subdir really exists.
106     if test -d $srcdir/$f; then
107       add_ons_pfx="$add_ons_pfx $f/"
108     else
109       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
110     fi
111   done
112 fi
113
114 dnl On some platforms we cannot use dynamic loading.  We must provide
115 dnl static NSS modules.
116 AC_ARG_ENABLE(static-nss, dnl
117 [  --enable-static-nss     build static NSS modules [default=no]],
118               static_nss=$enableval, static_nss=no)
119 if test x"$static_nss" = xyes; then
120   AC_DEFINE(DO_STATIC_NSS)
121 fi
122
123 AC_CANONICAL_HOST
124
125 # The way shlib-versions is used to generate soversions.mk uses a
126 # fairly simplistic model for name recognition that can't distinguish
127 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
128 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
129 # tell.  This doesn't get used much beyond that, so it's fairly safe.
130 case "$host_os" in
131 linux*)
132   ;;
133 gnu*)
134   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
135   ;;
136 esac
137
138 ###
139 ### I put this here to prevent those annoying emails from people who cannot
140 ### read and try to compile glibc on unsupported platforms.  --drepper
141 ###
142 ### By using the undocumented --enable-hacker-mode option for configure
143 ### one can skip this test to make the configuration not fail for unsupported
144 ### platforms.
145 ###
146 if test -z "$enable_hacker_mode"; then
147   case "$machine-$host_os" in
148   *-linux* | *-gnu* | arm*-none*)
149     ;;
150   *)
151     echo "*** The GNU C library is currently not available for this platform."
152     echo "*** So far nobody cared to port it and if there is no volunteer it"
153     echo "*** might never happen.  So, if you have interest to see glibc on"
154     echo "*** this platform visit"
155     echo "***   http://www.gnu.org/software/libc/porting.html"
156     echo "*** and join the group of porters"
157     exit 1
158     ;;
159   esac
160 fi
161
162 # We keep the original values in `$config_*' and never modify them, so we
163 # can write them unchanged into config.make.  Everything else uses
164 # $machine, $vendor, and $os, and changes them whenever convenient.
165 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
166
167 # Some configurations imply other options.
168 case "$host_os" in
169 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
170   # These systems always use GNU tools.
171   gnu_ld=yes gnu_as=yes ;;
172 esac
173 case "$host_os" in
174 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
175 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
176   ;;
177 gnu* | linux* | sysv4* | solaris2* | irix6*)
178   # These systems (almost) always use the ELF format.
179   elf=yes
180   ;;
181 esac
182
183 machine=$config_machine
184 vendor=$config_vendor
185 os=$config_os
186
187 dnl We need to use [ and ] for other purposes for a while now.
188 changequote(,)dnl
189 # Expand the configuration machine name into a subdirectory by architecture
190 # type and particular chip.
191 case "$machine" in
192 a29k | am29000) base_machine=a29k machine=a29k ;;
193 alpha*)         base_machine=alpha machine=alpha/$machine ;;
194 arm*)           base_machine=arm machine=arm/$machine ;;
195 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
196 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
197 hppa*)          base_machine=hppa machine=hppa/$machine ;;
198 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
199 m680?0)         base_machine=m68k machine=m68k/$machine ;;
200 m68k)           base_machine=m68k machine=m68k/m68020 ;;
201 m88???)         base_machine=m88k machine=m88k/$machine ;;
202 m88k)           base_machine=m88k machine=m88k/m88100 ;;
203 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
204 mips*)          base_machine=mips machine=mips/$machine ;;
205 sparc | sparcv[67])
206                 base_machine=sparc machine=sparc/sparc32 ;;
207 sparcv8 | supersparc | hypersparc)
208                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
209 sparc64 | ultrasparc)
210                 base_machine=sparc machine=sparc/sparc64 ;;
211 esac
212 changequote([,])dnl
213 AC_SUBST(base_machine)
214
215 if test "$base_machine" = "i386"; then
216   AC_DEFINE(USE_REGPARMS)
217 fi
218
219 # Compute the list of sysdep directories for this configuration.
220 # This can take a while to compute.
221 sysdep_dir=$srcdir/sysdeps
222 AC_MSG_CHECKING(sysdep dirs)
223 dnl We need to use [ and ] for other purposes for a while now.
224 changequote(,)dnl
225 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
226 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
227
228 case "$os" in
229 gnu*)
230   base_os=mach/hurd ;;
231 netbsd* | 386bsd* | freebsd* | bsdi*)
232   base_os=unix/bsd/bsd4.4 ;;
233 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
234   base_os=unix/bsd ;;
235 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
236   base_os=unix/sysv ;;
237 irix6*)
238   base_os=unix/sysv/irix6/$os ;;
239 solaris[2-9]*)
240   base_os=unix/sysv/sysv4 ;;
241 none)
242   base_os=standalone ;;
243 *)
244   base_os='' ;;
245 esac
246
247 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
248 tail=$os
249 ostry=$os
250 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
251   ostry="$ostry /$o"
252   tail=$o
253 done
254 o=`echo $tail | sed 's/[0-9]*$//'`
255 if test $o != $tail; then
256   ostry="$ostry /$o"
257 fi
258 # For linux-gnu, try linux-gnu, then linux.
259 o=`echo $tail | sed 's/-.*$//'`
260 if test $o != $tail; then
261   ostry="$ostry /$o"
262 fi
263
264 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
265 base=
266 tail=$base_os
267 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
268   set $b
269   base="$base /$1"
270   tail="$2"
271 done
272
273 # For sparc/sparc9, try sparc/sparc9 and then sparc.
274 mach=
275 tail=$machine
276 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
277   set $m
278   # Prepend the machine's FPU directory unless --without-fp.
279   if test "$with_fp" = yes; then
280     mach="$mach /$1/fpu"
281   fi
282   mach="$mach /$1"
283   tail="$2"
284 done
285
286 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
287 changequote([,])dnl
288
289 # Find what sysdep directories exist.
290 sysnames=
291 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
292 for d in $add_ons_pfx ''; do
293   for b in $base ''; do
294     for m0 in $mach ''; do
295       for v in /$vendor ''; do
296         test "$v" = / && continue
297         for o in /$ostry ''; do
298           test "$o" = / && continue
299           for m in $mach ''; do
300             if test "$m0$b$v$o$m"; then
301               try="${d}sysdeps$m0$b$v$o$m"
302               test -n "$enable_debug_configure" &&
303               echo "$0 [DEBUG]: try $try" >&2
304               case $try in
305                 /*) dest=$try ;;
306                 *)  dest=$srcdir/$try ;;
307               esac
308               if test -d $dest; then
309                 sysnames="$sysnames $try"
310                 { test -n "$o" || test -n "$b"; } && os_used=t
311                 { test -n "$m" || test -n "$m0"; } && machine_used=t
312               fi
313             fi
314           done
315         done
316       done
317     done
318   done
319 done
320 IFS="$ac_save_ifs"
321
322 if test -z "$os_used" && test "$os" != none; then
323   AC_MSG_ERROR(Operating system $os is not supported.)
324 fi
325 if test -z "$machine_used" && test "$machine" != none; then
326   AC_MSG_ERROR(The $machine is not supported.)
327 fi
328
329 # We have now validated the configuration.
330
331
332 # If using ELF, look for an `elf' subdirectory of each machine directory.
333 # We prepend these rather than inserting them whereever the machine appears
334 # because things specified by the machine's ELF ABI should override
335 # OS-specific things, and should always be the same for any OS on the
336 # machine (otherwise what's the point of an ABI?).
337 if test "$elf" = yes; then
338   elf_dirs=
339   for d in $add_ons_pfx ''; do
340     case $d in
341       /*) xsrcdir= ;;
342       *)  xsrcdir=$srcdir/ ;;
343     esac
344     for m in $mach; do
345       if test -d $xsrcdir${d}sysdeps$m/elf; then
346         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
347       fi
348     done
349   done
350   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
351 fi
352
353
354 # Expand the list of system names into a full list of directories
355 # from each element's parent name and Implies file (if present).
356 set $sysnames
357 names=
358 while test $# -gt 0; do
359   name=$1
360   shift
361
362   case " $names " in *" $name "*)
363     # Already in the list.
364     continue
365   esac
366
367   # Report each name as we discover it, so there is no long pause in output.
368   echo $ac_n "$name $ac_c" >&AC_FD_MSG
369
370   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
371
372   case $name in
373     /*) xsrcdir= ;;
374     *)  xsrcdir=$srcdir/ ;;
375   esac
376   test -n "$enable_debug_configure" &&
377   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
378
379   if test -f $xsrcdir$name/Implies; then
380     # Collect more names from the `Implies' file (removing comments).
381     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
382     implied=
383     for x in $implied_candidate; do
384       if test -d $xsrcdir$name_base/$x; then
385         implied="$implied $name_base/$x";
386       else
387         AC_MSG_WARN($name/Implies specifies nonexistent $x)
388       fi
389     done
390   else
391     implied=
392   fi
393
394   # Add NAME to the list of names.
395   names="$names $name"
396
397   # Find the parent of NAME, using the empty string if it has none.
398 changequote(,)dnl
399   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
400 changequote([,])dnl
401
402   # Add the names implied by NAME, and NAME's parent (if it has one), to
403   # the list of names to be processed (the argument list).  We prepend the
404   # implied names to the list and append the parent.  We want implied
405   # directories to come before further directories inferred from the
406   # configuration components; this ensures that for sysv4, unix/common
407   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
408   # after sysv4).
409   sysnames="`echo $implied $* $parent`"
410   test -n "$sysnames" && set $sysnames
411 done
412
413 # Add the default directories.
414 sysnames="$names sysdeps/generic"
415 AC_SUBST(sysnames)
416 # The other names were emitted during the scan.
417 AC_MSG_RESULT(sysdeps/generic)
418
419
420 ### Locate tools.
421
422 AC_PROG_INSTALL
423 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
424   # The makefiles need to use a different form to find it in $srcdir.
425   INSTALL='\$(..)./install-sh -c'
426 fi
427 AC_PROG_LN_S
428 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
429 if test "$MSGFMT" != ":"; then
430 changequote(,)dnl Need [] for regexps.
431   if $MSGFMT --version 2>&1 | grep 'GNU gettext.*0\.[1-9][0-9]' >/dev/null 2>&1
432 changequote([,])dnl
433   then : # msgfmt from gettext 0.10 or greater, works.
434   else
435     AC_MSG_WARN([
436 *** (g)msgfmt is too old or wrong version (need gettext 0.10 or better).])
437     MSGFMT=":"
438   fi
439 fi
440
441 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
442 if test "$MAKEINFO"; then
443 changequote(,)dnl Need [] for regexps.
444   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
445 changequote([,])dnl
446   then : # Makeinfo 3.11 or greater, works.
447   else
448     AC_MSG_WARN([
449 *** makeinfo is too old (need version 3.11 or better).
450 *** You should install the needed version and re-configure since otherwise
451 *** you won't get the info pages installed.])
452     MAKEINFO=
453   fi
454 fi
455
456 AC_PROG_CC_LOCAL
457 AC_CANONICAL_BUILD
458 if test $host != $build; then
459   AC_CHECK_PROGS(BUILD_CC, gcc cc)
460 fi
461 AC_SUBST(cross_compiling)
462 AC_PROG_CPP
463 LIBC_PROG_BINUTILS
464 AC_CHECK_TOOL(AR, ar)
465 AC_CHECK_TOOL(RANLIB, ranlib, :)
466
467 AC_PATH_PROG(BASH, bash, no)
468 if test "$BASH" != no &&
469    $BASH -c 'test "$BASH_VERSINFO" \
470              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
471   libc_cv_have_bash2=yes
472 else
473   libc_cv_have_bash2=no
474 fi
475 AC_SUBST(libc_cv_have_bash2)
476
477 dnl We need a ksh compatible shell for tzselect.
478 if test "$BASH" = no; then
479   AC_PATH_PROG(KSH, ksh, no)
480   if test "$KSH" = no; then
481     libc_cv_have_ksh=no
482   else
483     libc_cv_have_ksh=yes
484   fi
485 else
486   KSH="$BASH"
487   AC_SUBST(KSH)
488   libc_cv_have_ksh=yes
489 fi
490 AC_SUBST(libc_cv_have_ksh)
491
492 AC_PATH_PROGS(PERL, perl, no)
493 AC_SUBST(PERL)
494
495 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
496 echo '#include <stddef.h>
497 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
498 if eval "$ac_cpp conftest.c 2>/dev/null" \
499 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
500   libc_cv_signed_size_t=no
501 else
502   libc_cv_signed_size_t=yes
503 fi
504 rm -f conftest*])
505 if test $libc_cv_signed_size_t = yes; then
506   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
507   cat >> confdefs.h <<\EOF
508 #undef __SIZE_TYPE__
509 #define __SIZE_TYPE__ unsigned
510 EOF
511 fi
512
513 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
514 AC_TRY_COMPILE(dnl
515 [#define __need_size_t
516 #define __need_wchar_t
517 #include <stddef.h>
518 #define __need_NULL
519 #include <stddef.h>], [size_t size; wchar_t wchar;
520 #ifdef offsetof
521 #error stddef.h ignored __need_*
522 #endif
523 if (&size == NULL || &wchar == NULL) abort ();],
524                libc_cv_friendly_stddef=yes,
525                libc_cv_friendly_stddef=no)])
526 if test $libc_cv_friendly_stddef = yes; then
527   config_vars="$config_vars
528 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
529 fi
530
531 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
532                libc_cv_need_minus_P, [dnl
533 cat > conftest.S <<EOF
534 #include "confdefs.h"
535 /* Nothing whatsoever.  */
536 EOF
537 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
538   libc_cv_need_minus_P=no
539 else
540   libc_cv_need_minus_P=yes
541 fi
542 rm -f conftest*])
543 if test $libc_cv_need_minus_P = yes; then
544   config_vars="$config_vars
545 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
546 fi
547
548 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
549 # be told to read stdin.  This causes the compiler to hang when fed an
550 # .s file.
551 if test $ac_cv_prog_gcc = yes; then
552  case `${CC-cc} -v 2>&1` in
553   *2.7*)
554   # We must check this even if -pipe is not given here, because the user
555   # might do `make CFLAGS=-pipe'.
556   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
557    cp /dev/null conftest.s
558    cat >conftest1.s <<EOF
559 .nosuchdirective
560 EOF
561    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
562     libc_cv_gcc_pipe_bug=no
563    else
564     libc_cv_gcc_pipe_bug=yes
565    fi
566    rm -f conftest*])
567   if test $libc_cv_gcc_pipe_bug = yes; then
568    makeCC="${CC-cc} -B\$(common-objpfx)"
569    makeCFLAGS=$CFLAGS
570    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
571   fi;;
572  *) libc_cv_gcc_pipe_bug=no;;
573  esac
574 else
575  libc_cv_gcc_pipe_bug=no
576 fi
577
578 AC_CACHE_CHECK(for assembler global-symbol directive,
579                libc_cv_asm_global_directive, [dnl
580 libc_cv_asm_global_directive=UNKNOWN
581 for ac_globl in .globl .global; do
582   cat > conftest.s <<EOF
583 .text
584 ${ac_globl} foo
585 foo:
586 EOF
587   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
588     libc_cv_asm_global_directive=${ac_globl}
589   fi
590   rm -f conftest*
591   test $libc_cv_asm_global_directive != UNKNOWN && break
592 done])
593 if test $libc_cv_asm_global_directive = UNKNOWN; then
594   AC_MSG_ERROR(cannot determine asm global directive)
595 else
596   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
597 fi
598
599 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
600 cat > conftest.s <<EOF
601 .text
602 foo:
603 .set glibc_conftest_frobozz,foo
604 $libc_cv_asm_global_directive glibc_conftest_frobozz
605 EOF
606 # The alpha-dec-osf1 assembler gives only a warning for `.set'
607 # (but it doesn't work), so we must do a linking check to be sure.
608 cat > conftest1.c <<\EOF
609 extern int glibc_conftest_frobozz;
610 main () { printf ("%d\n", glibc_conftest_frobozz); }
611 EOF
612 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
613             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
614   libc_cv_asm_set_directive=yes
615 else
616   libc_cv_asm_set_directive=no
617 fi
618 rm -f conftest*])
619 if test $libc_cv_asm_set_directive = yes; then
620   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
621 fi
622
623 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
624 [cat > conftest.s <<EOF
625 .text
626 _sym:
627 .symver _sym,sym@VERS
628 EOF
629 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
630   libc_cv_asm_symver_directive=yes
631 else
632   libc_cv_asm_symver_directive=no
633 fi
634 rm -f conftest*])
635 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
636 if test $libc_cv_asm_symver_directive = yes; then
637   cat > conftest.s <<EOF
638 .text
639 _sym:
640 .symver _sym,sym@VERS
641 EOF
642   cat > conftest.map <<EOF
643 VERS_1 {
644         global: sym;
645 };
646
647 VERS_2 {
648         global: sym;
649 } VERS_1;
650 EOF
651   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
652     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
653                                         -nostartfiles -nostdlib
654                                         -Wl,--version-script,conftest.map
655                        1>&AC_FD_CC]);
656     then
657       libc_cv_ld_version_script_option=yes
658     else
659       libc_cv_ld_version_script_option=no
660     fi
661   else
662     libc_cv_ld_version_script_option=no
663   fi
664 else
665   libc_cv_ld_version_script_option=no
666 fi
667 rm -f conftest*])
668 if test $libc_cv_asm_symver_directive = yes &&
669    test $libc_cv_ld_version_script_option = yes &&
670    test $enable_versioning = yes; then
671   VERSIONING=yes
672   AC_DEFINE(DO_VERSIONING)
673 else
674   VERSIONING=no
675 fi
676 AC_SUBST(VERSIONING)
677
678 if test $VERSIONING = no; then
679   echo "\
680 *** WARNING: You should not compile GNU libc without versioning. Not using
681 *** versioning will introduce incompatibilities so that old binaries
682 *** will not run anymore.
683 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
684 fi
685 if test $elf = yes; then
686   AC_CACHE_CHECK(for .previous assembler directive,
687                  libc_cv_asm_previous_directive, [dnl
688   cat > conftest.s <<EOF
689 .section foo_section
690 .previous
691 EOF
692   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
693     libc_cv_asm_previous_directive=yes
694   else
695     libc_cv_asm_previous_directive=no
696   fi
697   rm -f conftest*])
698   if test $libc_cv_asm_previous_directive = yes; then
699     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
700   else
701     AC_CACHE_CHECK(for .popsection assembler directive,
702                    libc_cv_asm_popsection_directive, [dnl
703     cat > conftest.s <<EOF
704 .pushsection foo_section
705 .popsection
706 EOF
707     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
708       libc_cv_asm_popsection_directive=yes
709     else
710       libc_cv_asm_popsection_directive=no
711     fi
712     rm -f conftest*])
713     if test $libc_cv_asm_popsection_directive = yes; then
714       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
715     fi
716   fi
717 fi
718
719 if test $elf != yes; then
720   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
721                  [AC_TRY_COMPILE(, [asm (".section .init");
722                                     asm (".section .fini");
723                                     asm (".text");],
724                                  libc_cv_have_initfini=yes,
725                                  libc_cv_have_initfini=no)])
726   AC_SUBST(libc_cv_have_initfini)dnl
727   if test $libc_cv_have_initfini = yes; then
728     AC_DEFINE(HAVE_INITFINI)
729   fi
730 fi
731
732 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
733 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
734 [cat > conftest.$ac_ext <<EOF
735 dnl This sometimes fails to find confdefs.h, for some reason.
736 dnl [#]line __oline__ "[$]0"
737 [#]line __oline__ "configure"
738 #include "confdefs.h"
739 void underscore_test(void) {
740 return; }
741 EOF
742 if AC_TRY_EVAL(ac_compile); then
743   if grep _underscore_test conftest* >/dev/null; then
744     ifelse([$1], , :, [rm -f conftest*
745     $1])
746   else
747     ifelse([$2], , , [rm -f conftest*
748     $2])
749   fi
750 else
751   echo "configure: failed program was:" >&AC_FD_CC
752   cat conftest.$ac_ext >&AC_FD_CC
753   ifelse([$2], , , [rm -f conftest*
754   $2])
755 fi
756 rm -f conftest*])
757
758 if test $elf = yes; then
759   libc_cv_asm_underscores=no
760 else
761   if test $ac_cv_prog_cc_works = yes; then
762     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
763                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
764                                 libc_cv_asm_underscores=yes,
765                                 libc_cv_asm_underscores=no)])
766   else
767     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
768                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
769                                             libc_cv_asm_underscores=no)])
770   fi
771 fi
772 if test $libc_cv_asm_underscores = no; then
773   AC_DEFINE(NO_UNDERSCORES)
774 fi
775
776 if test $elf = yes; then
777   libc_cv_weak_symbols=yes
778   libc_cv_asm_weak_directive=yes
779   libc_cv_asm_weakext_directive=no
780 else
781   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
782                  [dnl
783 cat > conftest.s <<EOF
784 .text
785 ${libc_cv_asm_global_directive} foo
786 foo:
787 .weak foo
788 .weak bar; bar = foo
789 EOF
790   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
791     libc_cv_asm_weak_directive=yes
792   else
793     libc_cv_asm_weak_directive=no
794   fi
795   rm -f conftest*])
796
797 if test $libc_cv_asm_weak_directive = no; then
798   AC_CACHE_CHECK(for assembler .weakext directive,
799                  libc_cv_asm_weakext_directive,
800                  [dnl
801 cat > conftest.s <<EOF
802 .text
803 ${libc_cv_asm_global_directive} foo
804 foo:
805 .weakext bar foo
806 .weakext baz
807 ${libc_cv_asm_global_directive} baz
808 EOF
809   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
810     libc_cv_asm_weakext_directive=yes
811   else
812     libc_cv_asm_weakext_directive=no
813   fi
814   rm -f conftest*])
815
816   fi # no .weak
817 fi # not ELF
818
819 if test $libc_cv_asm_weak_directive = yes; then
820   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
821 elif test $libc_cv_asm_weakext_directive = yes; then
822   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
823 fi
824
825 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
826 cat > conftest.c <<\EOF
827 _start () {}
828 int __eh_pc;
829 __throw () {}
830 EOF
831 dnl No \ in command here because it ends up inside ''.
832 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
833                             -nostdlib -nostartfiles -Wl,--no-whole-archive
834                             -o conftest conftest.c 1>&AC_FD_CC]); then
835   libc_cv_ld_no_whole_archive=yes
836 else
837   libc_cv_ld_no_whole_archive=no
838 fi
839 rm -f conftest*])
840 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
841
842 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
843 cat > conftest.c <<\EOF
844 _start () {}
845 int __eh_pc;
846 __throw () {}
847 EOF
848 dnl No \ in command here because it ends up inside ''.
849 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
850                             -nostdlib -nostartfiles -fno-exceptions
851                             -o conftest conftest.c 1>&AC_FD_CC]); then
852   libc_cv_gcc_no_exceptions=yes
853 else
854   libc_cv_gcc_no_exceptions=no
855 fi
856 rm -f conftest*])
857 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
858
859 if test "$base_machine" = alpha ; then
860 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
861 cat > conftest.c <<\EOF
862 foo () { }
863 EOF
864 dnl
865 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
866 then
867   libc_cv_gcc_alpha_ng_prefix=yes
868 else
869   libc_cv_gcc_alpha_ng_prefix=no
870 fi
871 rm -f conftest* ])
872 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
873   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
874 else
875   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
876 fi
877 fi
878
879 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
880 [cat > conftest.c <<EOF
881 #line __oline__ "configure"
882 static char __EH_FRAME_BEGIN__[];
883 _start ()
884 {
885 #ifdef CHECK__register_frame
886   __register_frame (__EH_FRAME_BEGIN__);
887   __deregister_frame (__EH_FRAME_BEGIN__);
888 #endif
889 #ifdef CHECK__register_frame_info
890   __register_frame_info (__EH_FRAME_BEGIN__);
891   __deregister_frame_info (__EH_FRAME_BEGIN__);
892 #endif
893 }
894 int __eh_pc;
895 __throw () {}
896 /* FIXME: this is fragile.  */
897 malloc () {}
898 strcmp () {}
899 strlen () {}
900 memcpy () {}
901 memset () {}
902 free () {}
903 abort () {}
904 __bzero () {}
905 EOF
906 dnl No \ in command here because it ends up inside ''.
907 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
908                             -nostdlib -nostartfiles
909                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
910   libc_cv_gcc_dwarf2_unwind_info=static
911 else
912   libc_cv_gcc_dwarf2_unwind_info=no
913 fi
914 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
915   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
916                               -nostdlib -nostartfiles
917                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
918     libc_cv_gcc_dwarf2_unwind_info=yes
919   else
920     libc_cv_gcc_dwarf2_unwind_info=no
921   fi
922 fi
923 rm -f conftest*])
924 case $libc_cv_gcc_dwarf2_unwind_info in
925 yes)
926   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
927   ;;
928 static)
929   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
930   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
931   ;;
932 esac
933
934 ### End of automated tests.
935 ### Now run sysdeps configure fragments.
936
937 # sysdeps configure fragments may set these with files to be linked below.
938 libc_link_dests=
939 libc_link_sources=
940
941 # Iterate over all the sysdep directories we will use, running their
942 # configure fragments, and looking for a uname implementation.
943 uname=
944 for dir in $sysnames; do
945   case $dir in
946     /*) dest=$dir ;;
947     *)  dest=$srcdir/$dir ;;
948   esac
949   if test -r $dest/configure; then
950     AC_MSG_RESULT(running configure fragment for $dest)
951     . $dest/configure
952   fi
953 [
954   if test -z "$uname"; then
955     if test -r $dest/uname.c ||
956        test -r $dest/uname.S ||
957        { test -r $dest/syscalls.list &&
958          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
959       uname=$dir
960     fi
961   fi
962 ]dnl
963 done
964
965 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
966
967 # If we will use the generic uname implementation, we must figure out what
968 # it will say by examining the system, and write the results in config-name.h.
969 if test "$uname" = "sysdeps/generic"; then
970
971 changequote(,)dnl
972   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
973 changequote([,])dnl
974   if test $uname_sysname != $config_os; then
975     config_release=`echo $config_os | sed s/$uname_sysname//`
976   fi
977 dnl
978 AC_DEFUN(LIBC_KERNEL_ID, [dnl
979     if test -r /vmunix; then
980       kernel_id=`strings /vmunix | grep UNIX`
981     elif test -r /dynix; then
982       kernel_id=`strings /dynix | grep DYNIX`
983     else
984       kernel_id=
985     fi
986 ])dnl
987
988   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
989 AC_REQUIRE([LIBC_KERNEL_ID])dnl
990 changequote(,)dnl
991   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
992 changequote([,])dnl
993   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
994          != x$config_release; then
995     # The configuration release is a substring of the kernel release.
996     libc_cv_uname_release=$kernel_release
997   elif test x$config_release != x; then
998     libc_cv_uname_release=$config_release
999   elif test x$kernel_release != x; then
1000     libc_cv_uname_release=$kernel_release
1001   else
1002     libc_cv_uname_release=unknown
1003   fi])
1004   uname_release="$libc_cv_uname_release"
1005
1006   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1007 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1008 changequote(,)dnl
1009   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1010 changequote([,])dnl
1011   if test -n "$kernel_version"; then
1012     libc_cv_uname_version="$kernel_version"
1013   else
1014     libc_cv_uname_version=unknown
1015   fi])
1016   uname_version="$libc_cv_uname_version"
1017
1018 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1019   config_uname=config-name.h:config-name.in
1020 else
1021   # For non-generic uname, we don't need to create config-name.h at all.
1022   config_uname=
1023 fi
1024
1025 AC_MSG_CHECKING(stdio selection)
1026 AC_SUBST(stdio)
1027 case $stdio in
1028 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1029 default) stdio=stdio ;;
1030 esac
1031 AC_MSG_RESULT($stdio)
1032
1033 AC_MSG_CHECKING(ldap selection)
1034 AC_SUBST(LDAP)
1035 case $add_ons in
1036 *ldap*)
1037    ldap=yes
1038    LDAP=ldap ;;
1039 *) ldap=no
1040    LDAP= ;;
1041 esac
1042 AC_MSG_RESULT($ldap)
1043
1044 AC_SUBST(libc_cv_slibdir)
1045 AC_SUBST(libc_cv_sysconfdir)
1046 AC_SUBST(libc_cv_rootsbindir)
1047
1048 AC_SUBST(has_ldconfig)
1049
1050 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1051 if test $gnu_ld = yes; then
1052   AC_DEFINE(HAVE_GNU_LD)
1053 fi
1054 if test $gnu_as = yes; then
1055   AC_DEFINE(HAVE_GNU_AS)
1056 fi
1057 if test $elf = yes; then
1058   AC_DEFINE(HAVE_ELF)
1059 fi
1060
1061 AC_SUBST(static)
1062 AC_SUBST(shared)
1063 if test $shared = default; then
1064   if test $gnu_ld = yes; then
1065     shared=$elf
1066   else
1067     # For now we do not assume shared libs are available.  In future more
1068     # tests might become available.
1069     shared=no
1070   fi
1071 fi
1072
1073 dnl We must not allow compilation without static library on some platforms.
1074 if test $static = no && test $shared = yes; then
1075   case "$host_os" in
1076   linux* | gnu*)
1077     AC_MSG_ERROR([
1078 *** You must compile with support for the static library since the shared
1079 *** library uses it.  Restart configure without \`--disable-static'.])
1080     ;;
1081   *)
1082     ;;
1083   esac
1084 fi
1085
1086 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1087 [pic_default=yes
1088 cat > conftest.c <<EOF
1089 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1090 # error PIC is default.
1091 #endif
1092 EOF
1093 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1094   pic_default=no
1095 fi
1096 rm -f conftest.*])
1097 AC_SUBST(pic_default)
1098
1099 AC_SUBST(profile)
1100 AC_SUBST(omitfp)
1101 AC_SUBST(bounded)
1102 AC_SUBST(static_nss)
1103 AC_SUBST(nopic_initfini)
1104
1105 AC_SUBST(DEFINES)
1106
1107 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1108   config_makefile=
1109 else
1110   config_makefile=Makefile
1111 fi
1112
1113 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1114 AC_SUBST(VERSION)
1115
1116 if test $libc_cv_gcc_pipe_bug = yes; then
1117  realCC=$CC
1118  CC=$makeCC
1119  CFLAGS=$makeCFLAGS
1120 fi
1121 AC_OUTPUT_COMMANDS([
1122 if test "$realCC"; then
1123  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1124  mv specsT specs
1125 fi], [realCC=$realCC])
1126
1127 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1128           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])