Use AC_PROG_CHECK_VER to check versions of gcc, gmake, msgfmt,
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45 AC_ARG_WITH(cvs, dnl
46 [  --without-cvs          if CVS should not be used],
47             with_cvs=$withval, with_cvs=yes)
48 AC_SUBST(with_cvs)
49
50 AC_ARG_ENABLE(libio, dnl
51 [  --enable-libio          build in GNU libio instead of GNU stdio],
52               [if test $enableval = yes; then
53                  stdio=libio
54                else
55                  stdio=stdio
56                fi],
57               stdio=default)
58
59 AC_ARG_ENABLE(sanity-checks, dnl
60 [  --disable-sanity-checks really do not use threads (should not be used
61                           except in special situations) [default=yes]],
62               enable_sanity=$enableval, enable_sanity=yes)
63
64 dnl Arguments to enable or disable building the static, shared, profiled,
65 dnl and -fomit-frame-pointer libraries.
66 AC_ARG_ENABLE(static, dnl
67 [  --enable-static         build static library [default=yes]],
68               static=$enableval, static=yes)
69 AC_ARG_ENABLE(shared, dnl
70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
71               shared=$enableval, shared=default)
72 AC_ARG_ENABLE(profile, dnl
73 [  --enable-profile        build profiled library [default=yes]],
74               profile=$enableval, profile=yes)
75 AC_ARG_ENABLE(omitfp, dnl
76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
77               omitfp=$enableval, omitfp=no)
78 AC_ARG_ENABLE(bounded, dnl
79 [  --enable-bounded        build with runtime bounds checking [default=no]],
80               bounded=$enableval, bounded=no)
81 AC_ARG_ENABLE(versioning, dnl
82 [  --disable-versioning    do not include versioning information in the
83                           library objects [default=yes if supported]],
84              enable_versioning=$enableval, enable_versioning=yes)
85
86 dnl Generic infrastructure for drop-in additions to libc.
87 AC_ARG_ENABLE(add-ons, dnl
88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
89                                   search for add-ons if no parameter given],
90   [case "$enableval" in
91     yes) if test "$srcdir" = "."; then
92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
93          else
94            add_ons=`echo $srcdir/*/configure | \
95                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
96          fi;;
97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
98    esac],
99   [add_ons=])
100
101 AC_CONFIG_SUBDIRS($add_ons)
102 add_ons_pfx=
103 if test x"$add_ons" != x; then
104   for f in $add_ons; do
105     # Test whether such a subdir really exists.
106     if test -d $srcdir/$f; then
107       add_ons_pfx="$add_ons_pfx $f/"
108     else
109       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
110     fi
111   done
112 fi
113
114 dnl On some platforms we cannot use dynamic loading.  We must provide
115 dnl static NSS modules.
116 AC_ARG_ENABLE(static-nss, dnl
117 [  --enable-static-nss     build static NSS modules [default=no]],
118               static_nss=$enableval, static_nss=no)
119 if test x"$static_nss" = xyes; then
120   AC_DEFINE(DO_STATIC_NSS)
121 fi
122
123 AC_CANONICAL_HOST
124
125 # The way shlib-versions is used to generate soversions.mk uses a
126 # fairly simplistic model for name recognition that can't distinguish
127 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
128 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
129 # tell.  This doesn't get used much beyond that, so it's fairly safe.
130 case "$host_os" in
131 linux*)
132   ;;
133 gnu*)
134   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
135   ;;
136 esac
137
138 ###
139 ### I put this here to prevent those annoying emails from people who cannot
140 ### read and try to compile glibc on unsupported platforms.  --drepper
141 ###
142 ### By using the undocumented --enable-hacker-mode option for configure
143 ### one can skip this test to make the configuration not fail for unsupported
144 ### platforms.
145 ###
146 if test -z "$enable_hacker_mode"; then
147   case "$machine-$host_os" in
148   *-linux* | *-gnu* | arm*-none*)
149     ;;
150   *)
151     echo "*** The GNU C library is currently not available for this platform."
152     echo "*** So far nobody cared to port it and if there is no volunteer it"
153     echo "*** might never happen.  So, if you have interest to see glibc on"
154     echo "*** this platform visit"
155     echo "***   http://www.gnu.org/software/libc/porting.html"
156     echo "*** and join the group of porters"
157     exit 1
158     ;;
159   esac
160 fi
161
162 # We keep the original values in `$config_*' and never modify them, so we
163 # can write them unchanged into config.make.  Everything else uses
164 # $machine, $vendor, and $os, and changes them whenever convenient.
165 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
166
167 # Some configurations imply other options.
168 case "$host_os" in
169 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
170   # These systems always use GNU tools.
171   gnu_ld=yes gnu_as=yes ;;
172 esac
173 case "$host_os" in
174 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
175 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
176   ;;
177 gnu* | linux* | sysv4* | solaris2* | irix6*)
178   # These systems (almost) always use the ELF format.
179   elf=yes
180   ;;
181 esac
182
183 machine=$config_machine
184 vendor=$config_vendor
185 os=$config_os
186
187 dnl We need to use [ and ] for other purposes for a while now.
188 changequote(,)dnl
189 # Expand the configuration machine name into a subdirectory by architecture
190 # type and particular chip.
191 case "$machine" in
192 a29k | am29000) base_machine=a29k machine=a29k ;;
193 alpha*)         base_machine=alpha machine=alpha/$machine ;;
194 arm*)           base_machine=arm machine=arm/$machine ;;
195 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
196 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
197 hppa*)          base_machine=hppa machine=hppa/$machine ;;
198 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
199 m680?0)         base_machine=m68k machine=m68k/$machine ;;
200 m68k)           base_machine=m68k machine=m68k/m68020 ;;
201 m88???)         base_machine=m88k machine=m88k/$machine ;;
202 m88k)           base_machine=m88k machine=m88k/m88100 ;;
203 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
204 mips*)          base_machine=mips
205                 case "`uname -m`" in
206                 IP22) machine=mips/mips3 ;;
207                 *)    machine=mips/$machine ,,
208                 esac ;;
209 sparc | sparcv[67])
210                 base_machine=sparc machine=sparc/sparc32 ;;
211 sparcv8 | supersparc | hypersparc)
212                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
213 sparc64 | ultrasparc)
214                 base_machine=sparc machine=sparc/sparc64 ;;
215 esac
216 changequote([,])dnl
217 AC_SUBST(base_machine)
218
219 if test "$base_machine" = "i386"; then
220   AC_DEFINE(USE_REGPARMS)
221 fi
222
223 # Compute the list of sysdep directories for this configuration.
224 # This can take a while to compute.
225 sysdep_dir=$srcdir/sysdeps
226 AC_MSG_CHECKING(sysdep dirs)
227 dnl We need to use [ and ] for other purposes for a while now.
228 changequote(,)dnl
229 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
230 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
231
232 case "$os" in
233 gnu*)
234   base_os=mach/hurd ;;
235 netbsd* | 386bsd* | freebsd* | bsdi*)
236   base_os=unix/bsd/bsd4.4 ;;
237 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
238   base_os=unix/bsd ;;
239 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
240   base_os=unix/sysv ;;
241 irix6*)
242   base_os=unix/sysv/irix6/$os ;;
243 solaris[2-9]*)
244   base_os=unix/sysv/sysv4 ;;
245 none)
246   base_os=standalone ;;
247 *)
248   base_os='' ;;
249 esac
250
251 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
252 tail=$os
253 ostry=$os
254 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
255   ostry="$ostry /$o"
256   tail=$o
257 done
258 o=`echo $tail | sed 's/[0-9]*$//'`
259 if test $o != $tail; then
260   ostry="$ostry /$o"
261 fi
262 # For linux-gnu, try linux-gnu, then linux.
263 o=`echo $tail | sed 's/-.*$//'`
264 if test $o != $tail; then
265   ostry="$ostry /$o"
266 fi
267
268 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
269 base=
270 tail=$base_os
271 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
272   set $b
273   base="$base /$1"
274   tail="$2"
275 done
276
277 # For sparc/sparc9, try sparc/sparc9 and then sparc.
278 mach=
279 tail=$machine
280 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
281   set $m
282   # Prepend the machine's FPU directory unless --without-fp.
283   if test "$with_fp" = yes; then
284     mach="$mach /$1/fpu"
285   fi
286   mach="$mach /$1"
287   tail="$2"
288 done
289
290 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
291 changequote([,])dnl
292
293 # Find what sysdep directories exist.
294 sysnames=
295 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
296 for d in $add_ons_pfx ''; do
297   for b in $base ''; do
298     for m0 in $mach ''; do
299       for v in /$vendor ''; do
300         test "$v" = / && continue
301         for o in /$ostry ''; do
302           test "$o" = / && continue
303           for m in $mach ''; do
304             if test "$m0$b$v$o$m"; then
305               try="${d}sysdeps$m0$b$v$o$m"
306               test -n "$enable_debug_configure" &&
307               echo "$0 [DEBUG]: try $try" >&2
308               case $try in
309                 /*) dest=$try ;;
310                 *)  dest=$srcdir/$try ;;
311               esac
312               if test -d $dest; then
313                 sysnames="$sysnames $try"
314                 { test -n "$o" || test -n "$b"; } && os_used=t
315                 { test -n "$m" || test -n "$m0"; } && machine_used=t
316               fi
317             fi
318           done
319         done
320       done
321     done
322   done
323 done
324 IFS="$ac_save_ifs"
325
326 if test -z "$os_used" && test "$os" != none; then
327   AC_MSG_ERROR(Operating system $os is not supported.)
328 fi
329 if test -z "$machine_used" && test "$machine" != none; then
330   AC_MSG_ERROR(The $machine is not supported.)
331 fi
332
333 # We have now validated the configuration.
334
335
336 # If using ELF, look for an `elf' subdirectory of each machine directory.
337 # We prepend these rather than inserting them whereever the machine appears
338 # because things specified by the machine's ELF ABI should override
339 # OS-specific things, and should always be the same for any OS on the
340 # machine (otherwise what's the point of an ABI?).
341 if test "$elf" = yes; then
342   elf_dirs=
343   for d in $add_ons_pfx ''; do
344     case $d in
345       /*) xsrcdir= ;;
346       *)  xsrcdir=$srcdir/ ;;
347     esac
348     for m in $mach; do
349       if test -d $xsrcdir${d}sysdeps$m/elf; then
350         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
351       fi
352     done
353   done
354   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
355 fi
356
357
358 # Expand the list of system names into a full list of directories
359 # from each element's parent name and Implies file (if present).
360 set $sysnames
361 names=
362 while test $# -gt 0; do
363   name=$1
364   shift
365
366   case " $names " in *" $name "*)
367     # Already in the list.
368     continue
369   esac
370
371   # Report each name as we discover it, so there is no long pause in output.
372   echo $ac_n "$name $ac_c" >&AC_FD_MSG
373
374   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
375
376   case $name in
377     /*) xsrcdir= ;;
378     *)  xsrcdir=$srcdir/ ;;
379   esac
380   test -n "$enable_debug_configure" &&
381   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
382
383   if test -f $xsrcdir$name/Implies; then
384     # Collect more names from the `Implies' file (removing comments).
385     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
386     implied=
387     for x in $implied_candidate; do
388       if test -d $xsrcdir$name_base/$x; then
389         implied="$implied $name_base/$x";
390       else
391         AC_MSG_WARN($name/Implies specifies nonexistent $x)
392       fi
393     done
394   else
395     implied=
396   fi
397
398   # Add NAME to the list of names.
399   names="$names $name"
400
401   # Find the parent of NAME, using the empty string if it has none.
402 changequote(,)dnl
403   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
404 changequote([,])dnl
405
406   # Add the names implied by NAME, and NAME's parent (if it has one), to
407   # the list of names to be processed (the argument list).  We prepend the
408   # implied names to the list and append the parent.  We want implied
409   # directories to come before further directories inferred from the
410   # configuration components; this ensures that for sysv4, unix/common
411   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
412   # after sysv4).
413   sysnames="`echo $implied $* $parent`"
414   test -n "$sysnames" && set $sysnames
415 done
416
417 # Add the default directories.
418 sysnames="$names sysdeps/generic"
419 AC_SUBST(sysnames)
420 # The other names were emitted during the scan.
421 AC_MSG_RESULT(sysdeps/generic)
422
423
424 ### Locate tools.
425
426 AC_PROG_INSTALL
427 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
428   # The makefiles need to use a different form to find it in $srcdir.
429   INSTALL='\$(..)./install-sh -c'
430 fi
431 AC_PROG_LN_S
432
433 # These programs are version sensitive.
434 AC_CHECK_PROG_VER(CC, gcc cc, -v,
435   [version \([egcs0-9.-]*\)],
436   [egcs-2.91.*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|2.8.[1-9]*|2.9.[0-9]*], t)
437 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
438   [version \([0-9][0-9.]*\), by],
439   [3.75 | 3.76.[2-9] | 3.7[789]* | 3.[89]*], t)
440
441 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
442   [GNU gettext.*\([0-9][0-9]*\.[0-9]*\)],
443   [0.[1-9][0-9] | [1-9].*])
444 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
445   [GNU texinfo \([0-9][0-9.]*\)],
446   [3.1[1-9] | 3.[2-9][0-9]])
447
448 test -n "$ac_verc_fatal" && AC_MSG_ERROR([
449 *** Some critical program is missing or too old.
450 *** Check the INSTALL file for required versions.])
451
452 test -n "$ac_verc_fail" && AC_MSG_WARN([
453 *** An auxiliary program is missing or too old;
454 *** some features will be disabled.
455 *** Check the INSTALL file for required versions.])
456
457 AC_PROG_CC_LOCAL
458 AC_CANONICAL_BUILD
459 if test $host != $build; then
460   AC_CHECK_PROGS(BUILD_CC, gcc cc)
461 fi
462 AC_SUBST(cross_compiling)
463 AC_PROG_CPP
464 LIBC_PROG_BINUTILS
465 AC_CHECK_TOOL(AR, ar)
466 AC_CHECK_TOOL(RANLIB, ranlib, :)
467
468 # check if ar takes S
469 AC_CACHE_CHECK(for ar S, libc_cv_ar_S, [dnl
470 tmpo=$$.o
471 tmplib=lib$$.a
472 rm -f $tmpo $tmplib
473 touch $tmpo
474 if AC_TRY_COMMAND([${AR-ar} rcuS $tmplib $tmpo > /dev/null 2>&1]); then
475   libc_cv_ar_S=yes
476 else
477   libc_cv_ar_S=no
478 fi
479 rm -f $tmpo $tmplib])
480 AC_SUBST(libc_cv_ar_S)dnl
481
482 # Test if LD_LIBRARY_PATH contains the notation for the current directory
483 # since this would lead to problems installing/building glibc.
484 # LD_LIBRARY_PATH contains the current directory if one of the following
485 # is true:
486 # - one of the terminals (":" and ";") is the first or last sign
487 # - two terminals occur directly after each other
488 # - the path contains an element with a dot in it
489 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
490 changequote(,)dnl
491 case ${LD_LIBRARY_PATH} in
492   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
493     ld_library_path_setting="contains current directory"
494     ;;
495   *)
496     ld_library_path_setting="ok"
497     ;;
498 esac
499 changequote([,])dnl
500 AC_MSG_RESULT($ld_library_path_setting)
501 if test "$ld_library_path_setting" != "ok"; then
502 AC_MSG_ERROR([
503 *** LD_LIBRARY_PATH shouldn't contain the current directory when
504 *** building glibc. Please change the environment variable
505 *** and run configure again.])
506 fi
507
508 AC_PATH_PROG(BASH, bash, no)
509 if test "$BASH" != no &&
510    $BASH -c 'test "$BASH_VERSINFO" \
511              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
512   libc_cv_have_bash2=yes
513 else
514   libc_cv_have_bash2=no
515 fi
516 AC_SUBST(libc_cv_have_bash2)
517
518 dnl We need a ksh compatible shell for tzselect.
519 if test "$BASH" = no; then
520   AC_PATH_PROG(KSH, ksh, no)
521   if test "$KSH" = no; then
522     libc_cv_have_ksh=no
523   else
524     libc_cv_have_ksh=yes
525   fi
526 else
527   KSH="$BASH"
528   AC_SUBST(KSH)
529   libc_cv_have_ksh=yes
530 fi
531 AC_SUBST(libc_cv_have_ksh)
532
533 AC_PATH_PROGS(PERL, perl, no)
534 AC_SUBST(PERL)
535
536 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
537 echo '#include <stddef.h>
538 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
539 if eval "$ac_cpp conftest.c 2>/dev/null" \
540 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
541   libc_cv_signed_size_t=no
542 else
543   libc_cv_signed_size_t=yes
544 fi
545 rm -f conftest*])
546 if test $libc_cv_signed_size_t = yes; then
547   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
548   cat >> confdefs.h <<\EOF
549 #undef __SIZE_TYPE__
550 #define __SIZE_TYPE__ unsigned
551 EOF
552 fi
553
554 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
555 AC_TRY_COMPILE(dnl
556 [#define __need_size_t
557 #define __need_wchar_t
558 #include <stddef.h>
559 #define __need_NULL
560 #include <stddef.h>], [size_t size; wchar_t wchar;
561 #ifdef offsetof
562 #error stddef.h ignored __need_*
563 #endif
564 if (&size == NULL || &wchar == NULL) abort ();],
565                libc_cv_friendly_stddef=yes,
566                libc_cv_friendly_stddef=no)])
567 if test $libc_cv_friendly_stddef = yes; then
568   config_vars="$config_vars
569 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
570 fi
571
572 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
573                libc_cv_need_minus_P, [dnl
574 cat > conftest.S <<EOF
575 #include "confdefs.h"
576 /* Nothing whatsoever.  */
577 EOF
578 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
579   libc_cv_need_minus_P=no
580 else
581   libc_cv_need_minus_P=yes
582 fi
583 rm -f conftest*])
584 if test $libc_cv_need_minus_P = yes; then
585   config_vars="$config_vars
586 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
587 fi
588
589 AC_CACHE_CHECK(for assembler global-symbol directive,
590                libc_cv_asm_global_directive, [dnl
591 libc_cv_asm_global_directive=UNKNOWN
592 for ac_globl in .globl .global; do
593   cat > conftest.s <<EOF
594 .text
595 ${ac_globl} foo
596 foo:
597 EOF
598   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
599     libc_cv_asm_global_directive=${ac_globl}
600   fi
601   rm -f conftest*
602   test $libc_cv_asm_global_directive != UNKNOWN && break
603 done])
604 if test $libc_cv_asm_global_directive = UNKNOWN; then
605   AC_MSG_ERROR(cannot determine asm global directive)
606 else
607   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
608 fi
609
610 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
611 cat > conftest.s <<EOF
612 .text
613 foo:
614 .set glibc_conftest_frobozz,foo
615 $libc_cv_asm_global_directive glibc_conftest_frobozz
616 EOF
617 # The alpha-dec-osf1 assembler gives only a warning for `.set'
618 # (but it doesn't work), so we must do a linking check to be sure.
619 cat > conftest1.c <<\EOF
620 extern int glibc_conftest_frobozz;
621 main () { printf ("%d\n", glibc_conftest_frobozz); }
622 EOF
623 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
624             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
625   libc_cv_asm_set_directive=yes
626 else
627   libc_cv_asm_set_directive=no
628 fi
629 rm -f conftest*])
630 if test $libc_cv_asm_set_directive = yes; then
631   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
632 fi
633
634 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
635 [cat > conftest.s <<EOF
636 .text
637 _sym:
638 .symver _sym,sym@VERS
639 EOF
640 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
641   libc_cv_asm_symver_directive=yes
642 else
643   libc_cv_asm_symver_directive=no
644 fi
645 rm -f conftest*])
646 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
647 if test $libc_cv_asm_symver_directive = yes; then
648   cat > conftest.s <<EOF
649 .text
650 _sym:
651 .symver _sym,sym@VERS
652 EOF
653   cat > conftest.map <<EOF
654 VERS_1 {
655         global: sym;
656 };
657
658 VERS_2 {
659         global: sym;
660 } VERS_1;
661 EOF
662   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
663     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
664                                         -nostartfiles -nostdlib
665                                         -Wl,--version-script,conftest.map
666                        1>&AC_FD_CC]);
667     then
668       libc_cv_ld_version_script_option=yes
669     else
670       libc_cv_ld_version_script_option=no
671     fi
672   else
673     libc_cv_ld_version_script_option=no
674   fi
675 else
676   libc_cv_ld_version_script_option=no
677 fi
678 rm -f conftest*])
679 if test $libc_cv_asm_symver_directive = yes &&
680    test $libc_cv_ld_version_script_option = yes &&
681    test $enable_versioning = yes; then
682   VERSIONING=yes
683   AC_DEFINE(DO_VERSIONING)
684 else
685   VERSIONING=no
686 fi
687 AC_SUBST(VERSIONING)
688
689 if test $VERSIONING = no; then
690   echo "\
691 *** WARNING: You should not compile GNU libc without versioning. Not using
692 *** versioning will introduce incompatibilities so that old binaries
693 *** will not run anymore.
694 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
695 fi
696 if test $elf = yes; then
697   AC_CACHE_CHECK(for .previous assembler directive,
698                  libc_cv_asm_previous_directive, [dnl
699   cat > conftest.s <<EOF
700 .section foo_section
701 .previous
702 EOF
703   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
704     libc_cv_asm_previous_directive=yes
705   else
706     libc_cv_asm_previous_directive=no
707   fi
708   rm -f conftest*])
709   if test $libc_cv_asm_previous_directive = yes; then
710     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
711   else
712     AC_CACHE_CHECK(for .popsection assembler directive,
713                    libc_cv_asm_popsection_directive, [dnl
714     cat > conftest.s <<EOF
715 .pushsection foo_section
716 .popsection
717 EOF
718     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
719       libc_cv_asm_popsection_directive=yes
720     else
721       libc_cv_asm_popsection_directive=no
722     fi
723     rm -f conftest*])
724     if test $libc_cv_asm_popsection_directive = yes; then
725       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
726     fi
727   fi
728 fi
729
730 if test $elf != yes; then
731   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
732                  [AC_TRY_COMPILE(, [asm (".section .init");
733                                     asm (".section .fini");
734                                     asm (".text");],
735                                  libc_cv_have_initfini=yes,
736                                  libc_cv_have_initfini=no)])
737   AC_SUBST(libc_cv_have_initfini)dnl
738   if test $libc_cv_have_initfini = yes; then
739     AC_DEFINE(HAVE_INITFINI)
740   fi
741 fi
742
743 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
744 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
745 [cat > conftest.$ac_ext <<EOF
746 dnl This sometimes fails to find confdefs.h, for some reason.
747 dnl [#]line __oline__ "[$]0"
748 [#]line __oline__ "configure"
749 #include "confdefs.h"
750 void underscore_test(void) {
751 return; }
752 EOF
753 if AC_TRY_EVAL(ac_compile); then
754   if grep _underscore_test conftest* >/dev/null; then
755     ifelse([$1], , :, [rm -f conftest*
756     $1])
757   else
758     ifelse([$2], , , [rm -f conftest*
759     $2])
760   fi
761 else
762   echo "configure: failed program was:" >&AC_FD_CC
763   cat conftest.$ac_ext >&AC_FD_CC
764   ifelse([$2], , , [rm -f conftest*
765   $2])
766 fi
767 rm -f conftest*])
768
769 if test $elf = yes; then
770   libc_cv_asm_underscores=no
771 else
772   if test $ac_cv_prog_cc_works = yes; then
773     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
774                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
775                                 libc_cv_asm_underscores=yes,
776                                 libc_cv_asm_underscores=no)])
777   else
778     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
779                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
780                                             libc_cv_asm_underscores=no)])
781   fi
782 fi
783 if test $libc_cv_asm_underscores = no; then
784   AC_DEFINE(NO_UNDERSCORES)
785 fi
786
787 if test $elf = yes; then
788   libc_cv_weak_symbols=yes
789 fi
790
791 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
792                  [dnl
793 cat > conftest.s <<EOF
794 .text
795 ${libc_cv_asm_global_directive} foo
796 foo:
797 .weak foo
798 .weak bar; bar = foo
799 EOF
800 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
801   libc_cv_asm_weak_directive=yes
802 else
803   libc_cv_asm_weak_directive=no
804 fi
805 rm -f conftest*])
806
807 if test $libc_cv_asm_weak_directive = no; then
808   AC_CACHE_CHECK(for assembler .weakext directive,
809                  libc_cv_asm_weakext_directive,
810                  [dnl
811 cat > conftest.s <<EOF
812 .text
813 ${libc_cv_asm_global_directive} foo
814 foo:
815 .weakext bar foo
816 .weakext baz
817 ${libc_cv_asm_global_directive} baz
818 baz:
819 EOF
820   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
821     libc_cv_asm_weakext_directive=yes
822   else
823     libc_cv_asm_weakext_directive=no
824   fi
825   rm -f conftest*])
826
827 fi # no .weak
828
829 if test $libc_cv_asm_weak_directive = yes; then
830   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
831 elif test $libc_cv_asm_weakext_directive = yes; then
832   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
833 fi
834
835 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
836 cat > conftest.c <<\EOF
837 _start () {}
838 int __eh_pc;
839 __throw () {}
840 EOF
841 dnl No \ in command here because it ends up inside ''.
842 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
843                             -nostdlib -nostartfiles -Wl,--no-whole-archive
844                             -o conftest conftest.c 1>&AC_FD_CC]); then
845   libc_cv_ld_no_whole_archive=yes
846 else
847   libc_cv_ld_no_whole_archive=no
848 fi
849 rm -f conftest*])
850 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
851
852 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
853 cat > conftest.c <<\EOF
854 _start () {}
855 int __eh_pc;
856 __throw () {}
857 EOF
858 dnl No \ in command here because it ends up inside ''.
859 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
860                             -nostdlib -nostartfiles -fno-exceptions
861                             -o conftest conftest.c 1>&AC_FD_CC]); then
862   libc_cv_gcc_no_exceptions=yes
863 else
864   libc_cv_gcc_no_exceptions=no
865 fi
866 rm -f conftest*])
867 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
868
869 if test "$base_machine" = alpha ; then
870 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
871 cat > conftest.c <<\EOF
872 foo () { }
873 EOF
874 dnl
875 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
876 then
877   libc_cv_gcc_alpha_ng_prefix=yes
878 else
879   libc_cv_gcc_alpha_ng_prefix=no
880 fi
881 rm -f conftest* ])
882 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
883   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
884 else
885   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
886 fi
887 fi
888
889 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
890 [cat > conftest.c <<EOF
891 #line __oline__ "configure"
892 static char __EH_FRAME_BEGIN__[];
893 _start ()
894 {
895 #ifdef CHECK__register_frame
896   __register_frame (__EH_FRAME_BEGIN__);
897   __deregister_frame (__EH_FRAME_BEGIN__);
898 #endif
899 #ifdef CHECK__register_frame_info
900   __register_frame_info (__EH_FRAME_BEGIN__);
901   __deregister_frame_info (__EH_FRAME_BEGIN__);
902 #endif
903 }
904 int __eh_pc;
905 __throw () {}
906 /* FIXME: this is fragile.  */
907 malloc () {}
908 strcmp () {}
909 strlen () {}
910 memcpy () {}
911 memset () {}
912 free () {}
913 abort () {}
914 __bzero () {}
915 EOF
916 dnl No \ in command here because it ends up inside ''.
917 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
918                             -nostdlib -nostartfiles
919                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
920   libc_cv_gcc_dwarf2_unwind_info=static
921 else
922   libc_cv_gcc_dwarf2_unwind_info=no
923 fi
924 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
925   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
926                               -nostdlib -nostartfiles
927                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
928     libc_cv_gcc_dwarf2_unwind_info=yes
929   else
930     libc_cv_gcc_dwarf2_unwind_info=no
931   fi
932 fi
933 rm -f conftest*])
934 case $libc_cv_gcc_dwarf2_unwind_info in
935 yes)
936   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
937   ;;
938 static)
939   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
940   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
941   ;;
942 esac
943
944 ### End of automated tests.
945 ### Now run sysdeps configure fragments.
946
947 # sysdeps configure fragments may set these with files to be linked below.
948 libc_link_dests=
949 libc_link_sources=
950
951 # They also can set these variables.
952 ldd_rewrite_script=no
953
954 # Iterate over all the sysdep directories we will use, running their
955 # configure fragments, and looking for a uname implementation.
956 uname=
957 for dir in $sysnames; do
958   case $dir in
959     /*) dest=$dir ;;
960     *)  dest=$srcdir/$dir ;;
961   esac
962   if test -r $dest/configure; then
963     AC_MSG_RESULT(running configure fragment for $dest)
964     . $dest/configure
965   fi
966 [
967   if test -z "$uname"; then
968     if test -r $dest/uname.c ||
969        test -r $dest/uname.S ||
970        { test -r $dest/syscalls.list &&
971          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
972       uname=$dir
973     fi
974   fi
975 ]dnl
976 done
977
978 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
979
980 # If we will use the generic uname implementation, we must figure out what
981 # it will say by examining the system, and write the results in config-name.h.
982 if test "$uname" = "sysdeps/generic"; then
983
984 changequote(,)dnl
985   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
986 changequote([,])dnl
987   if test $uname_sysname != $config_os; then
988     config_release=`echo $config_os | sed s/$uname_sysname//`
989   fi
990 dnl
991 AC_DEFUN(LIBC_KERNEL_ID, [dnl
992     if test -r /vmunix; then
993       kernel_id=`strings /vmunix | grep UNIX`
994     elif test -r /dynix; then
995       kernel_id=`strings /dynix | grep DYNIX`
996     else
997       kernel_id=
998     fi
999 ])dnl
1000
1001   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1002 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1003 changequote(,)dnl
1004   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1005 changequote([,])dnl
1006   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1007          != x$config_release; then
1008     # The configuration release is a substring of the kernel release.
1009     libc_cv_uname_release=$kernel_release
1010   elif test x$config_release != x; then
1011     libc_cv_uname_release=$config_release
1012   elif test x$kernel_release != x; then
1013     libc_cv_uname_release=$kernel_release
1014   else
1015     libc_cv_uname_release=unknown
1016   fi])
1017   uname_release="$libc_cv_uname_release"
1018
1019   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1020 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1021 changequote(,)dnl
1022   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1023 changequote([,])dnl
1024   if test -n "$kernel_version"; then
1025     libc_cv_uname_version="$kernel_version"
1026   else
1027     libc_cv_uname_version=unknown
1028   fi])
1029   uname_version="$libc_cv_uname_version"
1030
1031 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1032   config_uname=config-name.h:config-name.in
1033 else
1034   # For non-generic uname, we don't need to create config-name.h at all.
1035   config_uname=
1036 fi
1037
1038 AC_MSG_CHECKING(stdio selection)
1039 AC_SUBST(stdio)
1040 case $stdio in
1041 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1042 default) stdio=stdio ;;
1043 esac
1044 AC_MSG_RESULT($stdio)
1045
1046 AC_MSG_CHECKING(ldap selection)
1047 AC_SUBST(LDAP)
1048 case $add_ons in
1049 *ldap*)
1050    ldap=yes
1051    LDAP=ldap ;;
1052 *) ldap=no
1053    LDAP= ;;
1054 esac
1055 AC_MSG_RESULT($ldap)
1056
1057 AC_SUBST(libc_cv_slibdir)
1058 AC_SUBST(libc_cv_sysconfdir)
1059 AC_SUBST(libc_cv_rootsbindir)
1060
1061 AC_SUBST(has_ldconfig)
1062 AC_SUBST(ldd_rewrite_script)
1063
1064 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1065 if test $gnu_ld = yes; then
1066   AC_DEFINE(HAVE_GNU_LD)
1067 fi
1068 if test $gnu_as = yes; then
1069   AC_DEFINE(HAVE_GNU_AS)
1070 fi
1071 if test $elf = yes; then
1072   AC_DEFINE(HAVE_ELF)
1073 fi
1074
1075 AC_SUBST(static)
1076 AC_SUBST(shared)
1077 if test $shared = default; then
1078   if test $gnu_ld = yes; then
1079     shared=$elf
1080   else
1081     # For now we do not assume shared libs are available.  In future more
1082     # tests might become available.
1083     shared=no
1084   fi
1085 fi
1086
1087 dnl We must not allow compilation without static library on some platforms.
1088 if test $static = no && test $shared = yes; then
1089   case "$host_os" in
1090   linux* | gnu*)
1091     AC_MSG_ERROR([
1092 *** You must compile with support for the static library since the shared
1093 *** library uses it.  Restart configure without \`--disable-static'.])
1094     ;;
1095   *)
1096     ;;
1097   esac
1098 fi
1099
1100 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1101 [pic_default=yes
1102 cat > conftest.c <<EOF
1103 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1104 # error PIC is default.
1105 #endif
1106 EOF
1107 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1108   pic_default=no
1109 fi
1110 rm -f conftest.*])
1111 AC_SUBST(pic_default)
1112
1113 AC_SUBST(profile)
1114 AC_SUBST(omitfp)
1115 AC_SUBST(bounded)
1116 AC_SUBST(static_nss)
1117 AC_SUBST(nopic_initfini)
1118
1119 AC_SUBST(DEFINES)
1120
1121 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1122   config_makefile=
1123 else
1124   config_makefile=Makefile
1125 fi
1126
1127 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1128 AC_SUBST(VERSION)
1129
1130 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1131           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])