Avoid //s in sysdirs.
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45 AC_ARG_WITH(cvs, dnl
46 [  --without-cvs          if CVS should not be used],
47             with_cvs=$withval, with_cvs=yes)
48 AC_SUBST(with_cvs)
49
50 AC_ARG_ENABLE(libio, dnl
51 [  --enable-libio          build in GNU libio instead of GNU stdio],
52               [if test $enableval = yes; then
53                  stdio=libio
54                else
55                  stdio=stdio
56                fi],
57               stdio=default)
58
59 AC_ARG_ENABLE(sanity-checks, dnl
60 [  --disable-sanity-checks really do not use threads (should not be used
61                           except in special situations) [default=yes]],
62               enable_sanity=$enableval, enable_sanity=yes)
63
64 dnl Arguments to enable or disable building the static, shared, profiled,
65 dnl and -fomit-frame-pointer libraries.
66 AC_ARG_ENABLE(static, dnl
67 [  --enable-static         build static library [default=yes]],
68               static=$enableval, static=yes)
69 AC_ARG_ENABLE(shared, dnl
70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
71               shared=$enableval, shared=default)
72 AC_ARG_ENABLE(profile, dnl
73 [  --enable-profile        build profiled library [default=yes]],
74               profile=$enableval, profile=yes)
75 AC_ARG_ENABLE(omitfp, dnl
76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
77               omitfp=$enableval, omitfp=no)
78 AC_ARG_ENABLE(bounded, dnl
79 [  --enable-bounded        build with runtime bounds checking [default=no]],
80               bounded=$enableval, bounded=no)
81 AC_ARG_ENABLE(versioning, dnl
82 [  --disable-versioning    do not include versioning information in the
83                           library objects [default=yes if supported]],
84              enable_versioning=$enableval, enable_versioning=yes)
85
86 dnl Generic infrastructure for drop-in additions to libc.
87 AC_ARG_ENABLE(add-ons, dnl
88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
89                                   search for add-ons if no parameter given],
90   [case "$enableval" in
91     yes) if test "$srcdir" = "."; then
92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
93          else
94            add_ons=`echo $srcdir/*/configure | \
95                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
96          fi;;
97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
98    esac],
99   [add_ons=])
100
101 AC_CONFIG_SUBDIRS($add_ons)
102 add_ons_pfx=
103 if test x"$add_ons" != x; then
104   for f in $add_ons; do
105     # Test whether such a subdir really exists.
106     if test -d $srcdir/$f; then
107       add_ons_pfx="$add_ons_pfx $f/"
108     else
109       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
110     fi
111   done
112 fi
113
114 dnl On some platforms we cannot use dynamic loading.  We must provide
115 dnl static NSS modules.
116 AC_ARG_ENABLE(static-nss, dnl
117 [  --enable-static-nss     build static NSS modules [default=no]],
118               static_nss=$enableval, static_nss=no)
119 if test x"$static_nss" = xyes; then
120   AC_DEFINE(DO_STATIC_NSS)
121 fi
122
123 AC_CANONICAL_HOST
124
125 # The way shlib-versions is used to generate soversions.mk uses a
126 # fairly simplistic model for name recognition that can't distinguish
127 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
128 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
129 # tell.  This doesn't get used much beyond that, so it's fairly safe.
130 case "$host_os" in
131 linux*)
132   ;;
133 gnu*)
134   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
135   ;;
136 esac
137
138 ###
139 ### I put this here to prevent those annoying emails from people who cannot
140 ### read and try to compile glibc on unsupported platforms.  --drepper
141 ###
142 ### By using the undocumented --enable-hacker-mode option for configure
143 ### one can skip this test to make the configuration not fail for unsupported
144 ### platforms.
145 ###
146 if test -z "$enable_hacker_mode"; then
147   case "$machine-$host_os" in
148   *-linux* | *-gnu* | arm*-none*)
149     ;;
150   *)
151     echo "*** The GNU C library is currently not available for this platform."
152     echo "*** So far nobody cared to port it and if there is no volunteer it"
153     echo "*** might never happen.  So, if you have interest to see glibc on"
154     echo "*** this platform visit"
155     echo "***   http://www.gnu.org/software/libc/porting.html"
156     echo "*** and join the group of porters"
157     exit 1
158     ;;
159   esac
160 fi
161
162 # We keep the original values in `$config_*' and never modify them, so we
163 # can write them unchanged into config.make.  Everything else uses
164 # $machine, $vendor, and $os, and changes them whenever convenient.
165 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
166
167 # Some configurations imply other options.
168 case "$host_os" in
169 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
170   # These systems always use GNU tools.
171   gnu_ld=yes gnu_as=yes ;;
172 esac
173 case "$host_os" in
174 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
175 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
176   ;;
177 gnu* | linux* | sysv4* | solaris2*)
178   # These systems (almost) always use the ELF format.
179   elf=yes
180   ;;
181 esac
182
183 machine=$config_machine
184 vendor=$config_vendor
185 os=$config_os
186
187 dnl We need to use [ and ] for other purposes for a while now.
188 changequote(,)dnl
189 # Expand the configuration machine name into a subdirectory by architecture
190 # type and particular chip.
191 case "$machine" in
192 a29k | am29000) base_machine=a29k machine=a29k ;;
193 alpha*)         base_machine=alpha machine=alpha/$machine ;;
194 arm*)           base_machine=arm machine=arm/$machine ;;
195 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
196 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
197 hppa*)          base_machine=hppa machine=hppa/$machine ;;
198 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
199 m680?0)         base_machine=m68k machine=m68k/$machine ;;
200 m68k)           base_machine=m68k machine=m68k/m68020 ;;
201 m88???)         base_machine=m88k machine=m88k/$machine ;;
202 m88k)           base_machine=m88k machine=m88k/m88100 ;;
203 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
204 mips*)          base_machine=mips machine=mips/$machine ;;
205 sparc | sparcv[67])
206                 base_machine=sparc machine=sparc/sparc32 ;;
207 sparcv8 | supersparc | hypersparc)
208                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
209 sparc64 | ultrasparc)
210                 base_machine=sparc machine=sparc/sparc64 ;;
211 esac
212 changequote([,])dnl
213 AC_SUBST(base_machine)
214
215 if test "$base_machine" = "i386"; then
216   AC_DEFINE(USE_REGPARMS)
217 fi
218
219 # Compute the list of sysdep directories for this configuration.
220 # This can take a while to compute.
221 sysdep_dir=$srcdir/sysdeps
222 AC_MSG_CHECKING(sysdep dirs)
223 dnl We need to use [ and ] for other purposes for a while now.
224 changequote(,)dnl
225 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
226 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
227
228 case "$os" in
229 gnu*)
230   base_os=mach/hurd ;;
231 netbsd* | 386bsd* | freebsd* | bsdi*)
232   base_os=unix/bsd/bsd4.4 ;;
233 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
234   base_os=unix/bsd ;;
235 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
236   base_os=unix/sysv ;;
237 solaris[2-9]*)
238   base_os=unix/sysv/sysv4 ;;
239 none)
240   base_os=standalone ;;
241 *)
242   base_os='' ;;
243 esac
244
245 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
246 tail=$os
247 ostry=$os
248 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
249   ostry="$ostry /$o"
250   tail=$o
251 done
252 o=`echo $tail | sed 's/[0-9]*$//'`
253 if test $o != $tail; then
254   ostry="$ostry /$o"
255 fi
256 # For linux-gnu, try linux-gnu, then linux.
257 o=`echo $tail | sed 's/-.*$//'`
258 if test $o != $tail; then
259   ostry="$ostry /$o"
260 fi
261
262 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
263 base=
264 tail=$base_os
265 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
266   set $b
267   base="$base /$1"
268   tail="$2"
269 done
270
271 # For sparc/sparc9, try sparc/sparc9 and then sparc.
272 mach=
273 tail=$machine
274 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
275   set $m
276   # Prepend the machine's FPU directory unless --without-fp.
277   if test "$with_fp" = yes; then
278     mach="$mach /$1/fpu"
279   fi
280   mach="$mach /$1"
281   tail="$2"
282 done
283
284 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
285 changequote([,])dnl
286
287 # Find what sysdep directories exist.
288 sysnames=
289 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
290 for d in $add_ons_pfx ''; do
291   for b in $base ''; do
292     for m0 in $mach ''; do
293       for v in /$vendor ''; do
294         test $v = / && continue
295         for o in /$ostry ''; do
296           test $o = / && continue
297           for m in $mach ''; do
298             if test "$m0$b$v$o$m"; then
299               try="${d}sysdeps$m0$b$v$o$m"
300               test -n "$enable_debug_configure" &&
301               echo "$0 [DEBUG]: try $try" >&2
302               case $try in
303                 /*) dest=$try ;;
304                 *)  dest=$srcdir/$try ;;
305               esac
306               if test -d $dest; then
307                 sysnames="$sysnames $try"
308                 { test -n "$o" || test -n "$b"; } && os_used=t
309                 { test -n "$m" || test -n "$m0"; } && machine_used=t
310               fi
311             fi
312           done
313         done
314       done
315     done
316   done
317 done
318 IFS="$ac_save_ifs"
319
320 if test -z "$os_used" && test "$os" != none; then
321   AC_MSG_ERROR(Operating system $os is not supported.)
322 fi
323 if test -z "$machine_used" && test "$machine" != none; then
324   AC_MSG_ERROR(The $machine is not supported.)
325 fi
326
327 # We have now validated the configuration.
328
329
330 # If using ELF, look for an `elf' subdirectory of each machine directory.
331 # We prepend these rather than inserting them whereever the machine appears
332 # because things specified by the machine's ELF ABI should override
333 # OS-specific things, and should always be the same for any OS on the
334 # machine (otherwise what's the point of an ABI?).
335 if test "$elf" = yes; then
336   elf_dirs=
337   for d in $add_ons_pfx ''; do
338     case $d in
339       /*) xsrcdir= ;;
340       *)  xsrcdir=$srcdir/ ;;
341     esac
342     for m in $mach; do
343       if test -d $xsrcdir${d}sysdeps$m/elf; then
344         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
345       fi
346     done
347   done
348   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
349 fi
350
351
352 # Expand the list of system names into a full list of directories
353 # from each element's parent name and Implies file (if present).
354 set $sysnames
355 names=
356 while test $# -gt 0; do
357   name=$1
358   shift
359
360   case " $names " in *" $name "*)
361     # Already in the list.
362     continue
363   esac
364
365   # Report each name as we discover it, so there is no long pause in output.
366   echo $ac_n "$name $ac_c" >&AC_FD_MSG
367
368   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
369
370   case $name in
371     /*) xsrcdir= ;;
372     *)  xsrcdir=$srcdir/ ;;
373   esac
374   test -n "$enable_debug_configure" &&
375   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
376
377   if test -f $xsrcdir$name/Implies; then
378     # Collect more names from the `Implies' file (removing comments).
379     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
380     implied=
381     for x in $implied_candidate; do
382       if test -d $xsrcdir$name_base/$x; then
383         implied="$implied $name_base/$x";
384       else
385         AC_MSG_WARN($name/Implies specifies nonexistent $x)
386       fi
387     done
388   else
389     implied=
390   fi
391
392   # Add NAME to the list of names.
393   names="$names $name"
394
395   # Find the parent of NAME, using the empty string if it has none.
396 changequote(,)dnl
397   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
398 changequote([,])dnl
399
400   # Add the names implied by NAME, and NAME's parent (if it has one), to
401   # the list of names to be processed (the argument list).  We prepend the
402   # implied names to the list and append the parent.  We want implied
403   # directories to come before further directories inferred from the
404   # configuration components; this ensures that for sysv4, unix/common
405   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
406   # after sysv4).
407   sysnames="`echo $implied $* $parent`"
408   test -n "$sysnames" && set $sysnames
409 done
410
411 # Add the default directories.
412 sysnames="$names sysdeps/generic"
413 AC_SUBST(sysnames)
414 # The other names were emitted during the scan.
415 AC_MSG_RESULT(sysdeps/generic)
416
417
418 ### Locate tools.
419
420 AC_PROG_INSTALL
421 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
422   # The makefiles need to use a different form to find it in $srcdir.
423   INSTALL='\$(..)./install-sh -c'
424 fi
425 AC_PROG_LN_S
426 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
427 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
428 if test "$MAKEINFO"; then
429 changequote(,)dnl Need [] for regexps.
430   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
431 changequote([,])dnl
432   then : # Makeinfo 3.11 or greater, works.
433   else
434     AC_MSG_WARN([
435 *** makeinfo is too old (need version 3.11 or better).
436 *** You should install the needed version and re-configure since otherwise
437 *** you won't get the info pages installed.])
438     MAKEINFO=
439   fi
440 fi
441
442 AC_PROG_CC_LOCAL
443 AC_CANONICAL_BUILD
444 if test $host != $build; then
445   AC_CHECK_PROGS(BUILD_CC, gcc cc)
446 fi
447 AC_SUBST(cross_compiling)
448 AC_PROG_CPP
449 LIBC_PROG_BINUTILS
450 AC_CHECK_TOOL(AR, ar)
451 AC_CHECK_TOOL(RANLIB, ranlib, :)
452
453 AC_PATH_PROG(BASH, bash, no)
454 if test "$BASH" != no &&
455    $BASH -c 'test "$BASH_VERSINFO" \
456              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
457   libc_cv_have_bash2=yes
458 else
459   libc_cv_have_bash2=no
460 fi
461 AC_SUBST(libc_cv_have_bash2)
462
463 dnl We need a ksh compatible shell for tzselect.
464 if test "$BASH" = no; then
465   AC_PATH_PROG(KSH, ksh, no)
466   if test "$KSH" = no; then
467     libc_cv_have_ksh=no
468   else
469     libc_cv_have_ksh=yes
470   fi
471 else
472   KSH="$BASH"
473   AC_SUBST(KSH)
474   libc_cv_have_ksh=yes
475 fi
476 AC_SUBST(libc_cv_have_ksh)
477
478 AC_PATH_PROGS(PERL, perl, no)
479 AC_SUBST(PERL)
480
481 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
482 echo '#include <stddef.h>
483 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
484 if eval "$ac_cpp conftest.c 2>/dev/null" \
485 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
486   libc_cv_signed_size_t=no
487 else
488   libc_cv_signed_size_t=yes
489 fi
490 rm -f conftest*])
491 if test $libc_cv_signed_size_t = yes; then
492   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
493   cat >> confdefs.h <<\EOF
494 #undef __SIZE_TYPE__
495 #define __SIZE_TYPE__ unsigned
496 EOF
497 fi
498
499 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
500 AC_TRY_COMPILE(dnl
501 [#define __need_size_t
502 #define __need_wchar_t
503 #include <stddef.h>
504 #define __need_NULL
505 #include <stddef.h>], [size_t size; wchar_t wchar;
506 #ifdef offsetof
507 #error stddef.h ignored __need_*
508 #endif
509 if (&size == NULL || &wchar == NULL) abort ();],
510                libc_cv_friendly_stddef=yes,
511                libc_cv_friendly_stddef=no)])
512 if test $libc_cv_friendly_stddef = yes; then
513   config_vars="$config_vars
514 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
515 fi
516
517 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
518                libc_cv_need_minus_P, [dnl
519 cat > conftest.S <<EOF
520 #include "confdefs.h"
521 /* Nothing whatsoever.  */
522 EOF
523 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
524   libc_cv_need_minus_P=no
525 else
526   libc_cv_need_minus_P=yes
527 fi
528 rm -f conftest*])
529 if test $libc_cv_need_minus_P = yes; then
530   config_vars="$config_vars
531 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
532 fi
533
534 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
535 # be told to read stdin.  This causes the compiler to hang when fed an
536 # .s file.
537 if test $ac_cv_prog_gcc = yes; then
538  case `${CC-cc} -v 2>&1` in
539   *2.7*)
540   # We must check this even if -pipe is not given here, because the user
541   # might do `make CFLAGS=-pipe'.
542   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
543    cp /dev/null conftest.s
544    cat >conftest1.s <<EOF
545 .nosuchdirective
546 EOF
547    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
548     libc_cv_gcc_pipe_bug=no
549    else
550     libc_cv_gcc_pipe_bug=yes
551    fi
552    rm -f conftest*])
553   if test $libc_cv_gcc_pipe_bug = yes; then
554    makeCC="${CC-cc} -B\$(common-objpfx)"
555    makeCFLAGS=$CFLAGS
556    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
557   fi;;
558  *) libc_cv_gcc_pipe_bug=no;;
559  esac
560 else
561  libc_cv_gcc_pipe_bug=no
562 fi
563
564 AC_CACHE_CHECK(for assembler global-symbol directive,
565                libc_cv_asm_global_directive, [dnl
566 libc_cv_asm_global_directive=UNKNOWN
567 for ac_globl in .globl .global; do
568   cat > conftest.s <<EOF
569 .text
570 ${ac_globl} foo
571 foo:
572 EOF
573   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
574     libc_cv_asm_global_directive=${ac_globl}
575   fi
576   rm -f conftest*
577   test $libc_cv_asm_global_directive != UNKNOWN && break
578 done])
579 if test $libc_cv_asm_global_directive = UNKNOWN; then
580   AC_MSG_ERROR(cannot determine asm global directive)
581 else
582   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
583 fi
584
585 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
586 cat > conftest.s <<EOF
587 .text
588 foo:
589 .set glibc_conftest_frobozz,foo
590 $libc_cv_asm_global_directive glibc_conftest_frobozz
591 EOF
592 # The alpha-dec-osf1 assembler gives only a warning for `.set'
593 # (but it doesn't work), so we must do a linking check to be sure.
594 cat > conftest1.c <<\EOF
595 extern int glibc_conftest_frobozz;
596 main () { printf ("%d\n", glibc_conftest_frobozz); }
597 EOF
598 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
599             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
600   libc_cv_asm_set_directive=yes
601 else
602   libc_cv_asm_set_directive=no
603 fi
604 rm -f conftest*])
605 if test $libc_cv_asm_set_directive = yes; then
606   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
607 fi
608
609 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
610 [cat > conftest.s <<EOF
611 .text
612 _sym:
613 .symver _sym,sym@VERS
614 EOF
615 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
616   libc_cv_asm_symver_directive=yes
617 else
618   libc_cv_asm_symver_directive=no
619 fi
620 rm -f conftest*])
621 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
622 if test $libc_cv_asm_symver_directive = yes; then
623   cat > conftest.s <<EOF
624 .text
625 _sym:
626 .symver _sym,sym@VERS
627 EOF
628   cat > conftest.map <<EOF
629 VERS_1 {
630         global: sym;
631 };
632
633 VERS_2 {
634         global: sym;
635 } VERS_1;
636 EOF
637   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
638     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
639                                         -nostartfiles -nostdlib
640                                         -Wl,--version-script,conftest.map
641                        1>&AC_FD_CC]);
642     then
643       libc_cv_ld_version_script_option=yes
644     else
645       libc_cv_ld_version_script_option=no
646     fi
647   else
648     libc_cv_ld_version_script_option=no
649   fi
650 else
651   libc_cv_ld_version_script_option=no
652 fi
653 rm -f conftest*])
654 if test $libc_cv_asm_symver_directive = yes &&
655    test $libc_cv_ld_version_script_option = yes &&
656    test $enable_versioning = yes; then
657   VERSIONING=yes
658   AC_DEFINE(DO_VERSIONING)
659 else
660   VERSIONING=no
661 fi
662 AC_SUBST(VERSIONING)
663
664 if test $VERSIONING = no; then
665   echo "\
666 *** WARNING: You should not compile GNU libc without versioning. Not using
667 *** versioning will introduce incompatibilities so that old binaries
668 *** will not run anymore.
669 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
670 fi
671 if test $elf = yes; then
672   AC_CACHE_CHECK(for .previous assembler directive,
673                  libc_cv_asm_previous_directive, [dnl
674   cat > conftest.s <<EOF
675 .section foo_section
676 .previous
677 EOF
678   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
679     libc_cv_asm_previous_directive=yes
680   else
681     libc_cv_asm_previous_directive=no
682   fi
683   rm -f conftest*])
684   if test $libc_cv_asm_previous_directive = yes; then
685     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
686   else
687     AC_CACHE_CHECK(for .popsection assembler directive,
688                    libc_cv_asm_popsection_directive, [dnl
689     cat > conftest.s <<EOF
690 .pushsection foo_section
691 .popsection
692 EOF
693     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
694       libc_cv_asm_popsection_directive=yes
695     else
696       libc_cv_asm_popsection_directive=no
697     fi
698     rm -f conftest*])
699     if test $libc_cv_asm_popsection_directive = yes; then
700       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
701     fi
702   fi
703 fi
704
705 if test $elf != yes; then
706   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
707                  [AC_TRY_COMPILE(, [asm (".section .init");
708                                     asm (".section .fini");
709                                     asm (".text");],
710                                  libc_cv_have_initfini=yes,
711                                  libc_cv_have_initfini=no)])
712   AC_SUBST(libc_cv_have_initfini)dnl
713   if test $libc_cv_have_initfini = yes; then
714     AC_DEFINE(HAVE_INITFINI)
715   fi
716 fi
717
718 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
719 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
720 [cat > conftest.$ac_ext <<EOF
721 dnl This sometimes fails to find confdefs.h, for some reason.
722 dnl [#]line __oline__ "[$]0"
723 [#]line __oline__ "configure"
724 #include "confdefs.h"
725 void underscore_test(void) {
726 return; }
727 EOF
728 if AC_TRY_EVAL(ac_compile); then
729   if grep _underscore_test conftest* >/dev/null; then
730     ifelse([$1], , :, [rm -f conftest*
731     $1])
732   else
733     ifelse([$2], , , [rm -f conftest*
734     $2])
735   fi
736 else
737   echo "configure: failed program was:" >&AC_FD_CC
738   cat conftest.$ac_ext >&AC_FD_CC
739   ifelse([$2], , , [rm -f conftest*
740   $2])
741 fi
742 rm -f conftest*])
743
744 if test $elf = yes; then
745   libc_cv_asm_underscores=no
746 else
747   if test $ac_cv_prog_cc_works = yes; then
748     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
749                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
750                                 libc_cv_asm_underscores=yes,
751                                 libc_cv_asm_underscores=no)])
752   else
753     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
754                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
755                                             libc_cv_asm_underscores=no)])
756   fi
757 fi
758 if test $libc_cv_asm_underscores = no; then
759   AC_DEFINE(NO_UNDERSCORES)
760 fi
761
762 if test $elf = yes; then
763   libc_cv_weak_symbols=yes
764   libc_cv_asm_weak_directive=yes
765   libc_cv_asm_weakext_directive=no
766 else
767   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
768                  [dnl
769 cat > conftest.s <<EOF
770 .text
771 ${libc_cv_asm_global_directive} foo
772 foo:
773 .weak foo
774 .weak bar; bar = foo
775 EOF
776   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
777     libc_cv_asm_weak_directive=yes
778   else
779     libc_cv_asm_weak_directive=no
780   fi
781   rm -f conftest*])
782
783 if test $libc_cv_asm_weak_directive = no; then
784   AC_CACHE_CHECK(for assembler .weakext directive,
785                  libc_cv_asm_weakext_directive,
786                  [dnl
787 cat > conftest.s <<EOF
788 .text
789 ${libc_cv_asm_global_directive} foo
790 foo:
791 .weakext foo
792 .weakext foo, bar
793 EOF
794   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
795     libc_cv_asm_weakext_directive=yes
796   else
797     libc_cv_asm_weakext_directive=no
798   fi
799   rm -f conftest*])
800
801   fi # no .weak
802 fi # not ELF
803
804 if test $libc_cv_asm_weak_directive = yes; then
805   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
806 elif test $libc_cv_asm_weakext_directive = yes; then
807   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
808 fi
809
810 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
811 cat > conftest.c <<\EOF
812 _start () {}
813 int __eh_pc;
814 __throw () {}
815 EOF
816 dnl No \ in command here because it ends up inside ''.
817 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
818                             -nostdlib -nostartfiles -Wl,--no-whole-archive
819                             -o conftest conftest.c 1>&AC_FD_CC]); then
820   libc_cv_ld_no_whole_archive=yes
821 else
822   libc_cv_ld_no_whole_archive=no
823 fi
824 rm -f conftest*])
825 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
826
827 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
828 cat > conftest.c <<\EOF
829 _start () {}
830 int __eh_pc;
831 __throw () {}
832 EOF
833 dnl No \ in command here because it ends up inside ''.
834 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
835                             -nostdlib -nostartfiles -fno-exceptions
836                             -o conftest conftest.c 1>&AC_FD_CC]); then
837   libc_cv_gcc_no_exceptions=yes
838 else
839   libc_cv_gcc_no_exceptions=no
840 fi
841 rm -f conftest*])
842 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
843
844 if test "$base_machine" = alpha ; then
845 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
846 cat > conftest.c <<\EOF
847 foo () { }
848 EOF
849 dnl
850 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
851 then
852   libc_cv_gcc_alpha_ng_prefix=yes
853 else
854   libc_cv_gcc_alpha_ng_prefix=no
855 fi
856 rm -f conftest* ])
857 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
858   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
859 else
860   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
861 fi
862 fi
863
864 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
865 [cat > conftest.c <<EOF
866 #line __oline__ "configure"
867 static char __EH_FRAME_BEGIN__[];
868 _start ()
869 {
870 #ifdef CHECK__register_frame
871   __register_frame (__EH_FRAME_BEGIN__);
872   __deregister_frame (__EH_FRAME_BEGIN__);
873 #endif
874 #ifdef CHECK__register_frame_info
875   __register_frame_info (__EH_FRAME_BEGIN__);
876   __deregister_frame_info (__EH_FRAME_BEGIN__);
877 #endif
878 }
879 int __eh_pc;
880 __throw () {}
881 /* FIXME: this is fragile.  */
882 malloc () {}
883 strcmp () {}
884 strlen () {}
885 memcpy () {}
886 memset () {}
887 free () {}
888 abort () {}
889 __bzero () {}
890 EOF
891 dnl No \ in command here because it ends up inside ''.
892 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
893                             -nostdlib -nostartfiles
894                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
895   libc_cv_gcc_dwarf2_unwind_info=static
896 else
897   libc_cv_gcc_dwarf2_unwind_info=no
898 fi
899 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
900   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
901                               -nostdlib -nostartfiles
902                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
903     libc_cv_gcc_dwarf2_unwind_info=yes
904   else
905     libc_cv_gcc_dwarf2_unwind_info=no
906   fi
907 fi
908 rm -f conftest*])
909 case $libc_cv_gcc_dwarf2_unwind_info in
910 yes)
911   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
912   ;;
913 static)
914   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
915   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
916   ;;
917 esac
918
919 ### End of automated tests.
920 ### Now run sysdeps configure fragments.
921
922 # sysdeps configure fragments may set these with files to be linked below.
923 libc_link_dests=
924 libc_link_sources=
925
926 # Iterate over all the sysdep directories we will use, running their
927 # configure fragments, and looking for a uname implementation.
928 uname=
929 for dir in $sysnames; do
930   case $dir in
931     /*) dest=$dir ;;
932     *)  dest=$srcdir/$dir ;;
933   esac
934   if test -r $dest/configure; then
935     AC_MSG_RESULT(running configure fragment for $dest)
936     . $dest/configure
937   fi
938 [
939   if test -z "$uname"; then
940     if test -r $dest/uname.c ||
941        test -r $dest/uname.S ||
942        { test -r $dest/syscalls.list &&
943          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
944       uname=$dir
945     fi
946   fi
947 ]dnl
948 done
949
950 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
951
952 # If we will use the generic uname implementation, we must figure out what
953 # it will say by examining the system, and write the results in config-name.h.
954 if test "$uname" = "sysdeps/generic"; then
955
956 changequote(,)dnl
957   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
958 changequote([,])dnl
959   if test $uname_sysname != $config_os; then
960     config_release=`echo $config_os | sed s/$uname_sysname//`
961   fi
962 dnl
963 AC_DEFUN(LIBC_KERNEL_ID, [dnl
964     if test -r /vmunix; then
965       kernel_id=`strings /vmunix | grep UNIX`
966     elif test -r /dynix; then
967       kernel_id=`strings /dynix | grep DYNIX`
968     else
969       kernel_id=
970     fi
971 ])dnl
972
973   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
974 AC_REQUIRE([LIBC_KERNEL_ID])dnl
975 changequote(,)dnl
976   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
977 changequote([,])dnl
978   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
979          != x$config_release; then
980     # The configuration release is a substring of the kernel release.
981     libc_cv_uname_release=$kernel_release
982   elif test x$config_release != x; then
983     libc_cv_uname_release=$config_release
984   elif test x$kernel_release != x; then
985     libc_cv_uname_release=$kernel_release
986   else
987     libc_cv_uname_release=unknown
988   fi])
989   uname_release="$libc_cv_uname_release"
990
991   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
992 AC_REQUIRE([LIBC_KERNEL_ID])dnl
993 changequote(,)dnl
994   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
995 changequote([,])dnl
996   if test -n "$kernel_version"; then
997     libc_cv_uname_version="$kernel_version"
998   else
999     libc_cv_uname_version=unknown
1000   fi])
1001   uname_version="$libc_cv_uname_version"
1002
1003 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1004   config_uname=config-name.h:config-name.in
1005 else
1006   # For non-generic uname, we don't need to create config-name.h at all.
1007   config_uname=
1008 fi
1009
1010 AC_MSG_CHECKING(stdio selection)
1011 AC_SUBST(stdio)
1012 case $stdio in
1013 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1014 default) stdio=stdio ;;
1015 esac
1016 AC_MSG_RESULT($stdio)
1017
1018 AC_MSG_CHECKING(ldap selection)
1019 AC_SUBST(LDAP)
1020 case $add_ons in
1021 *ldap*)
1022    ldap=yes
1023    LDAP=ldap ;;
1024 *) ldap=no
1025    LDAP= ;;
1026 esac
1027 AC_MSG_RESULT($ldap)
1028
1029 AC_SUBST(libc_cv_slibdir)
1030 AC_SUBST(libc_cv_sysconfdir)
1031 AC_SUBST(libc_cv_rootsbindir)
1032
1033 AC_SUBST(has_ldconfig)
1034
1035 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1036 if test $gnu_ld = yes; then
1037   AC_DEFINE(HAVE_GNU_LD)
1038 fi
1039 if test $gnu_as = yes; then
1040   AC_DEFINE(HAVE_GNU_AS)
1041 fi
1042 if test $elf = yes; then
1043   AC_DEFINE(HAVE_ELF)
1044 fi
1045
1046 AC_SUBST(static)
1047 AC_SUBST(shared)
1048 if test $shared = default; then
1049   if test $gnu_ld = yes; then
1050     shared=$elf
1051   else
1052     # For now we do not assume shared libs are available.  In future more
1053     # tests might become available.
1054     shared=no
1055   fi
1056 fi
1057
1058 dnl We must not allow compilation without static library on some platforms.
1059 if test $static = no && test $shared = yes; then
1060   case "$host_os" in
1061   linux* | gnu*)
1062     AC_MSG_ERROR([
1063 *** You must compile with support for the static library since the shared
1064 *** library uses it.  Restart configure without \`--disable-static'.])
1065     ;;
1066   *)
1067     ;;
1068   esac
1069 fi
1070
1071 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1072 [pic_default=yes
1073 cat > conftest.c <<EOF
1074 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1075 # error PIC is default.
1076 #endif
1077 EOF
1078 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1079   pic_default=no
1080 fi
1081 rm -f conftest.*])
1082 AC_SUBST(pic_default)
1083
1084 AC_SUBST(profile)
1085 AC_SUBST(omitfp)
1086 AC_SUBST(bounded)
1087 AC_SUBST(static_nss)
1088 AC_SUBST(nopic_initfini)
1089
1090 AC_SUBST(DEFINES)
1091
1092 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1093   config_makefile=
1094 else
1095   config_makefile=Makefile
1096 fi
1097
1098 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1099 AC_SUBST(VERSION)
1100
1101 if test $libc_cv_gcc_pipe_bug = yes; then
1102  realCC=$CC
1103  CC=$makeCC
1104  CFLAGS=$makeCFLAGS
1105 fi
1106 AC_OUTPUT_COMMANDS([
1107 if test "$realCC"; then
1108  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1109  mv specsT specs
1110 fi], [realCC=$realCC])
1111
1112 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1113           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])