Allow makeinfo 4.*.
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6 AC_CONFIG_AUX_DIR(scripts)
7
8 # This will get text that should go into config.make.
9 config_vars=
10
11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
12 AC_ARG_WITH(gmp, dnl
13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
14             [dnl
15 case "$with_gmp" in
16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
17 ''|no) ;;
18 *) config_vars="$config_vars
19 gmp-srcdir = $withval" ;;
20 esac
21 ])
22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
23 AC_ARG_WITH(gettext, dnl
24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
25             [dnl
26 case "$with_gettext" in
27 yes)
28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
29 ''|no) ;;
30 *)
31   config_vars="$config_vars
32 gettext-srcdir = $withval" ;;
33 esac
34 ])
35 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
36 AC_ARG_WITH(gd, dnl
37   --with-gd=DIR           find libgd include dir and library with prefix DIR,
38             [dnl
39 case "$with_gd" in
40 yes|''|no) ;;
41 *) libgd_include="-I$withval/include"
42    libgd_ldflags="-L$withval/lib" ;;
43 esac
44 ])
45 AC_ARG_WITH(gd-include, dnl
46   --with-gd-include=DIR   find libgd include files in DIR,
47             [dnl
48 case "$with_gd_include" in
49 ''|no) ;;
50 *) libgd_include="-I$withval" ;;
51 esac
52 ])
53 AC_ARG_WITH(gd-lib, dnl
54   --with-gd-lib=DIR       find libgd library files in DIR,
55             [dnl
56 case "$with_gd_lib" in
57 ''|no) ;;
58 *) libgd_ldflags="-L$withval" ;;
59 esac
60 ])
61
62 if test -n "$libgd_include"; then
63   config_vars="$config_vars
64 CFLAGS-memprofstat.c = $libgd_include"
65 fi
66 if test -n "$libgd_ldflags"; then
67   config_vars="$config_vars
68 libgd-LDFLAGS = $libgd_ldflags"
69 fi
70
71 dnl Arguments to specify presence of other packages/features.
72 AC_ARG_WITH(fp, dnl
73 [  --with-fp              if using floating-point hardware [default=yes]],
74             with_fp=$withval, with_fp=yes)
75 AC_ARG_WITH(binutils, dnl
76   --with-binutils=PATH    specify location of binutils (as and ld),
77             path_binutils=$withval, path_binutils='')
78 AC_ARG_WITH(elf, dnl
79   --with-elf              if using the ELF object format,
80             elf=$withval, elf=no)
81 AC_ARG_WITH(cvs, dnl
82 [  --without-cvs          if CVS should not be used],
83             with_cvs=$withval, with_cvs=yes)
84 AC_SUBST(with_cvs)
85
86 AC_ARG_WITH(headers, dnl
87 [  --with-headers=PATH     location of system headers to use
88                           [e.g. /usr/src/linux/include]
89                           [default=compiler default]],
90             sysheaders=$withval, sysheaders='')
91
92 AC_ARG_ENABLE(libio, dnl
93 [  --enable-libio          build in GNU libio instead of GNU stdio],
94               [if test $enableval = yes; then
95                  stdio=libio
96                else
97                  stdio=stdio
98                fi],
99               stdio=default)
100
101 AC_ARG_ENABLE(sanity-checks, dnl
102 [  --disable-sanity-checks really do not use threads (should not be used
103                           except in special situations) [default=yes]],
104               enable_sanity=$enableval, enable_sanity=yes)
105
106 dnl Arguments to enable or disable building the static, shared, profiled,
107 dnl and -fomit-frame-pointer libraries.
108 dnl I've disabled this for now since we cannot build glibc without static
109 dnl libraries built in the moment.
110 dnl AC_ARG_ENABLE(static, dnl
111 dnl [  --enable-static         build static library [default=yes]],
112 dnl           static=$enableval, static=yes)
113 static=yes
114 AC_ARG_ENABLE(shared, dnl
115 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
116               shared=$enableval, shared=default)
117 AC_ARG_ENABLE(profile, dnl
118 [  --enable-profile        build profiled library [default=yes]],
119               profile=$enableval, profile=yes)
120 AC_ARG_ENABLE(omitfp, dnl
121 [  --enable-omitfp         build undebuggable optimized library [default=no]],
122               omitfp=$enableval, omitfp=no)
123 AC_ARG_ENABLE(bounded, dnl
124 [  --enable-bounded        build with runtime bounds checking [default=no]],
125               bounded=$enableval, bounded=no)
126 AC_ARG_ENABLE(versioning, dnl
127 [  --disable-versioning    do not include versioning information in the
128                           library objects [default=yes if supported]],
129              enable_versioning=$enableval, enable_versioning=yes)
130
131 dnl Generic infrastructure for drop-in additions to libc.
132 AC_ARG_ENABLE(add-ons, dnl
133 [  --enable-add-ons[=DIR1,DIR2]...
134                           configure and build add-ons in DIR1,DIR2,...
135                           search for add-ons if no parameter given],
136   [case "$enableval" in
137     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
138          test "$add_ons" = "*" && add_ons= ;;
139     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
140    esac],
141   [add_ons=])
142
143 AC_CONFIG_SUBDIRS($add_ons)
144 add_ons_pfx=
145 if test x"$add_ons" != x; then
146   for f in $add_ons; do
147     # Test whether such a subdir really exists.
148     if test -d $srcdir/$f; then
149       add_ons_pfx="$add_ons_pfx $f/"
150     else
151       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
152     fi
153   done
154 fi
155
156 dnl On some platforms we cannot use dynamic loading.  We must provide
157 dnl static NSS modules.
158 AC_ARG_ENABLE(static-nss, dnl
159 [  --enable-static-nss     build static NSS modules [default=no]],
160               static_nss=$enableval, static_nss=no)
161 if test x"$static_nss" = xyes; then
162   AC_DEFINE(DO_STATIC_NSS)
163 fi
164
165 AC_ARG_ENABLE(force-install,
166 [  --disable-force-install don't force installation of files from this package,
167                           even if they are older than the installed files],
168               force_install=$enableval, force_install=yes)
169 AC_SUBST(force_install)
170
171 dnl On some platforms we allow dropping compatibility with all kernel
172 dnl versions.
173 AC_ARG_ENABLE(kernel,
174 [  --enable-kernel=VERSION compile for compatibility with kernel not older
175                            than VERSION],
176               minimum_kernel=$enableval)
177
178 AC_CANONICAL_HOST
179
180 # The way shlib-versions is used to generate soversions.mk uses a
181 # fairly simplistic model for name recognition that can't distinguish
182 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
183 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
184 # tell.  This doesn't get used much beyond that, so it's fairly safe.
185 case "$host_os" in
186 linux*)
187   ;;
188 gnu*)
189   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
190   ;;
191 esac
192
193 # We keep the original values in `$config_*' and never modify them, so we
194 # can write them unchanged into config.make.  Everything else uses
195 # $machine, $vendor, and $os, and changes them whenever convenient.
196 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
197
198 # Some configurations imply other options.
199 case "$host_os" in
200 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
201   # These systems always use GNU tools.
202   gnu_ld=yes gnu_as=yes ;;
203 esac
204 case "$host_os" in
205 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
206 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
207   ;;
208 gnu* | linux* | sysv4* | solaris2* | irix6*)
209   # These systems (almost) always use the ELF format.
210   elf=yes
211   ;;
212 esac
213
214 machine=$config_machine
215 vendor=$config_vendor
216 os=$config_os
217
218 ###
219 ### I put this here to prevent those annoying emails from people who cannot
220 ### read and try to compile glibc on unsupported platforms.  --drepper
221 ###
222 ### By using the undocumented --enable-hacker-mode option for configure
223 ### one can skip this test to make the configuration not fail for unsupported
224 ### platforms.
225 ###
226 if test -z "$enable_hacker_mode"; then
227   case "$machine-$host_os" in
228   *-linux* | *-gnu* | arm*-none*)
229     ;;
230   *)
231     echo "*** The GNU C library is currently not available for this platform."
232     echo "*** So far nobody cared to port it and if there is no volunteer it"
233     echo "*** might never happen.  So, if you have interest to see glibc on"
234     echo "*** this platform visit"
235     echo "***   http://www.gnu.org/software/libc/porting.html"
236     echo "*** and join the group of porters"
237     exit 1
238     ;;
239   esac
240 fi
241
242 dnl We need to use [ and ] for other purposes for a while now.
243 changequote(,)dnl
244 # Expand the configuration machine name into a subdirectory by architecture
245 # type and particular chip.
246 case "$machine" in
247 a29k | am29000) base_machine=a29k machine=a29k ;;
248 alpha*)         base_machine=alpha machine=alpha/$machine ;;
249 arm*)           base_machine=arm machine=arm/$machine ;;
250 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
251 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
252 hppa*)          base_machine=hppa machine=hppa/$machine ;;
253 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
254 m680?0)         base_machine=m68k machine=m68k/$machine ;;
255 m68k)           base_machine=m68k machine=m68k/m68020 ;;
256 m88???)         base_machine=m88k machine=m88k/$machine ;;
257 m88k)           base_machine=m88k machine=m88k/m88100 ;;
258 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
259 mips*)          base_machine=mips
260                 case "`uname -m`" in
261                 IP22) machine=mips/mips3 ;;
262                 *)    machine=mips/$machine ;;
263                 esac ;;
264 sparc | sparcv[67])
265                 base_machine=sparc machine=sparc/sparc32 ;;
266 sparcv8 | supersparc | hypersparc)
267                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
268 sparcv8plus | sparcv8plusa | sparcv9)
269                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
270 sparc64 | ultrasparc)
271                 base_machine=sparc machine=sparc/sparc64 ;;
272 esac
273 changequote([,])dnl
274 AC_SUBST(base_machine)
275
276 if test "$base_machine" = "i386"; then
277   AC_DEFINE(USE_REGPARMS)
278 fi
279
280 # Compute the list of sysdep directories for this configuration.
281 # This can take a while to compute.
282 sysdep_dir=$srcdir/sysdeps
283 AC_MSG_CHECKING(sysdep dirs)
284 dnl We need to use [ and ] for other purposes for a while now.
285 changequote(,)dnl
286 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
287 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
288
289 case "$os" in
290 gnu*)
291   base_os=mach/hurd ;;
292 netbsd* | 386bsd* | freebsd* | bsdi*)
293   base_os=unix/bsd/bsd4.4 ;;
294 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
295   base_os=unix/bsd ;;
296 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
297   base_os=unix/sysv ;;
298 irix6*)
299   base_os=unix/sysv/irix6/$os ;;
300 solaris[2-9]*)
301   base_os=unix/sysv/sysv4 ;;
302 hpux*)
303   base_os=unix/sysv/hpux/$os ;;
304 none)
305   base_os=standalone ;;
306 *)
307   base_os='' ;;
308 esac
309
310 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
311 tail=$os
312 ostry=$os
313 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
314   ostry="$ostry /$o"
315   tail=$o
316 done
317 o=`echo $tail | sed 's/[0-9]*$//'`
318 if test $o != $tail; then
319   ostry="$ostry /$o"
320 fi
321 # For linux-gnu, try linux-gnu, then linux.
322 o=`echo $tail | sed 's/-.*$//'`
323 if test $o != $tail; then
324   ostry="$ostry /$o"
325 fi
326
327 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
328 base=
329 tail=$base_os
330 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
331   set $b
332   base="$base /$1"
333   tail="$2"
334 done
335
336 # For sparc/sparc32, try sparc/sparc32 and then sparc.
337 mach=
338 tail=$machine
339 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
340   set $m
341   # Prepend the machine's FPU directory unless --without-fp.
342   if test "$with_fp" = yes; then
343     mach="$mach /$1/fpu"
344   fi
345   mach="$mach /$1"
346   tail="$2"
347 done
348
349 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
350 changequote([,])dnl
351
352 # Find what sysdep directories exist.
353 sysnames=
354 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
355 for d in $add_ons_pfx ''; do
356   for b in $base ''; do
357     for m0 in $mach ''; do
358       for v in /$vendor ''; do
359         test "$v" = / && continue
360         for o in /$ostry ''; do
361           test "$o" = / && continue
362           for m in $mach ''; do
363             if test "$m0$b$v$o$m"; then
364               try="${d}sysdeps$m0$b$v$o$m"
365               test -n "$enable_debug_configure" &&
366               echo "$0 [DEBUG]: try $try" >&2
367               if test -d $srcdir/$try; then
368                 sysnames="$sysnames $try"
369                 { test -n "$o" || test -n "$b"; } && os_used=t
370                 { test -n "$m" || test -n "$m0"; } && machine_used=t
371               fi
372             fi
373           done
374         done
375       done
376     done
377   done
378 done
379 IFS="$ac_save_ifs"
380
381 if test -z "$os_used" && test "$os" != none; then
382   AC_MSG_ERROR(Operating system $os is not supported.)
383 fi
384 if test -z "$machine_used" && test "$machine" != none; then
385   AC_MSG_ERROR(The $machine is not supported.)
386 fi
387
388 # We have now validated the configuration.
389
390
391 # If using ELF, look for an `elf' subdirectory of each machine directory.
392 # We prepend these rather than inserting them whereever the machine appears
393 # because things specified by the machine's ELF ABI should override
394 # OS-specific things, and should always be the same for any OS on the
395 # machine (otherwise what's the point of an ABI?).
396 if test "$elf" = yes; then
397   elf_dirs=
398   for d in $add_ons_pfx ''; do
399     for m in $mach; do
400       if test -d $srcdir/${d}sysdeps$m/elf; then
401         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
402       fi
403     done
404   done
405   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
406 fi
407
408
409 # Expand the list of system names into a full list of directories
410 # from each element's parent name and Implies file (if present).
411 set $sysnames
412 names=
413 while test $# -gt 0; do
414   name=$1
415   shift
416
417   case " $names " in *" $name "*)
418     # Already in the list.
419     continue
420   esac
421
422   # Report each name as we discover it, so there is no long pause in output.
423   echo $ac_n "$name $ac_c" >&AC_FD_MSG
424
425   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
426
427   case $name in
428     /*) xsrcdir= ;;
429     *)  xsrcdir=$srcdir/ ;;
430   esac
431   test -n "$enable_debug_configure" &&
432   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
433
434   if test -f $xsrcdir$name/Implies; then
435     # Collect more names from the `Implies' file (removing comments).
436     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
437     implied=
438     for x in $implied_candidate; do
439       if test -d $xsrcdir$name_base/$x; then
440         implied="$implied $name_base/$x";
441       else
442         AC_MSG_WARN($name/Implies specifies nonexistent $x)
443       fi
444     done
445   else
446     implied=
447   fi
448
449   # Add NAME to the list of names.
450   names="$names $name"
451
452   # Find the parent of NAME, using the empty string if it has none.
453 changequote(,)dnl
454   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
455 changequote([,])dnl
456
457   # Add the names implied by NAME, and NAME's parent (if it has one), to
458   # the list of names to be processed (the argument list).  We prepend the
459   # implied names to the list and append the parent.  We want implied
460   # directories to come before further directories inferred from the
461   # configuration components; this ensures that for sysv4, unix/common
462   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
463   # after sysv4).
464   sysnames="`echo $implied $* $parent`"
465   test -n "$sysnames" && set $sysnames
466 done
467
468 # Add the default directories.
469 default_sysnames=sysdeps/generic
470 if test "$elf" = yes; then
471   default_sysnames="sysdeps/generic/elf $default_sysnames"
472 fi
473 sysnames="$names $default_sysnames"
474 AC_SUBST(sysnames)
475 # The other names were emitted during the scan.
476 AC_MSG_RESULT($default_sysnames)
477
478
479 ### Locate tools.
480
481 AC_PROG_INSTALL
482 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
483   # The makefiles need to use a different form to find it in $srcdir.
484   INSTALL='\$(..)./scripts/install-sh -c'
485 fi
486 AC_PROG_LN_S
487
488 # These programs are version sensitive.
489 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
490 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
491   [version \([egcygnustp-]*[0-9.]*\)],
492   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9].*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]],
493   critic_missing=t)
494 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
495   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
496   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
497
498 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
499   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
500   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
501 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
502   [GNU texinfo.* \([0-9][0-9.]*\)],
503   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
504
505 if test -n "$critic_missing"; then
506 AC_MSG_ERROR([
507 *** Some critical program is missing or too old.
508 *** Check the INSTALL file for required versions.])
509 fi
510
511 test -n "$aux_missing" && AC_MSG_WARN([
512 *** An auxiliary program is missing or too old;
513 *** some features will be disabled.
514 *** Check the INSTALL file for required versions.])
515
516 # glibcbug.in wants to know the compiler version.
517 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
518 AC_SUBST(CCVERSION)
519
520 AC_PROG_CC_LOCAL
521 AC_CANONICAL_BUILD
522 if test $host != $build; then
523   AC_CHECK_PROGS(BUILD_CC, gcc cc)
524 fi
525 AC_SUBST(cross_compiling)
526 AC_PROG_CPP
527 LIBC_PROG_BINUTILS
528 AC_CHECK_TOOL(MIG, mig)
529
530 # if using special system headers, find out the compiler's sekrit
531 # header directory and add that to the list.  NOTE: Only does the right
532 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
533 if test -n "$sysheaders"; then
534   ccheaders=`$CC -print-file-name=include`
535   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
536 fi
537 AC_SUBST(SYSINCLUDES)
538
539 # check if ranlib is necessary
540 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
541 cat > conftest.c <<EOF
542 int a;
543 char b;
544 void c(void) {}
545 EOF
546 $CC $CFLAGS -c conftest.c
547 $AR cr conftest.a conftest.c
548 cp conftest.a conftest2.a
549 $RANLIB conftest.a
550 if cmp -s conftest.a conftest2.a; then
551   libc_cv_ranlib_necessary=no
552 else
553   libc_cv_ranlib_necessary=yes
554 fi
555 rm -rf conftest*])
556 if test "$libc_cv_ranlib_necessary" = no; then
557  RANLIB=:
558 fi
559
560 # Test if LD_LIBRARY_PATH contains the notation for the current directory
561 # since this would lead to problems installing/building glibc.
562 # LD_LIBRARY_PATH contains the current directory if one of the following
563 # is true:
564 # - one of the terminals (":" and ";") is the first or last sign
565 # - two terminals occur directly after each other
566 # - the path contains an element with a dot in it
567 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
568 changequote(,)dnl
569 case ${LD_LIBRARY_PATH} in
570   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
571     ld_library_path_setting="contains current directory"
572     ;;
573   *)
574     ld_library_path_setting="ok"
575     ;;
576 esac
577 changequote([,])dnl
578 AC_MSG_RESULT($ld_library_path_setting)
579 if test "$ld_library_path_setting" != "ok"; then
580 AC_MSG_ERROR([
581 *** LD_LIBRARY_PATH shouldn't contain the current directory when
582 *** building glibc. Please change the environment variable
583 *** and run configure again.])
584 fi
585
586 AC_PATH_PROG(BASH, bash, no)
587 if test "$BASH" != no &&
588    $BASH -c 'test "$BASH_VERSINFO" \
589              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
590   libc_cv_have_bash2=yes
591 else
592   libc_cv_have_bash2=no
593 fi
594 AC_SUBST(libc_cv_have_bash2)
595
596 dnl We need a ksh compatible shell for tzselect.
597 if test "$BASH" = no; then
598   AC_PATH_PROG(KSH, ksh, no)
599   if test "$KSH" = no; then
600     libc_cv_have_ksh=no
601   else
602     libc_cv_have_ksh=yes
603   fi
604 else
605   KSH="$BASH"
606   AC_SUBST(KSH)
607   libc_cv_have_ksh=yes
608 fi
609 AC_SUBST(libc_cv_have_ksh)
610
611 AC_PROG_AWK
612 AC_PATH_PROG(PERL, perl, no)
613 AC_SUBST(PERL)
614 AC_PATH_PROG(INSTALL_INFO, install-info, no,
615              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
616 AC_SUBST(INSTALL_INFO)
617 if test "$INSTALL_INFO" != "no"; then
618 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
619  [mkdir conftest.d
620   # There is a hard ^_ on the next line.  I am open to better ideas.
621   (echo '\1f'
622   echo 'File: dir       Node: Top       This is the top of the INFO tree'
623   echo '* Menu:') >conftest.d/dir
624   (echo 'INFO-DIR-SECTION i-d-s works'
625   echo 'START-INFO-DIR-ENTRY'
626   echo '* Prog: (prog).   Program.'
627   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
628   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
629   then
630     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
631     then libc_cv_old_debian_install_info=no
632     else libc_cv_old_debian_install_info=yes
633     fi
634   else libc_cv_old_debian_install_info=no testfailed=t
635   fi
636   rm -fr conftest.d])
637 if test -n "$testfailed"
638 then AC_MSG_WARN([install-info errored out, check config.log])
639 fi
640 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
641 fi
642 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
643
644 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
645 echo '#include <stddef.h>
646 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
647 if eval "$ac_cpp conftest.c 2>/dev/null" \
648 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
649   libc_cv_signed_size_t=no
650 else
651   libc_cv_signed_size_t=yes
652 fi
653 rm -f conftest*])
654 if test $libc_cv_signed_size_t = yes; then
655   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
656   cat >> confdefs.h <<\EOF
657 #undef __SIZE_TYPE__
658 #define __SIZE_TYPE__ unsigned
659 EOF
660 fi
661
662 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
663 AC_TRY_COMPILE(dnl
664 [#define __need_size_t
665 #define __need_wchar_t
666 #include <stddef.h>
667 #define __need_NULL
668 #include <stddef.h>], [size_t size; wchar_t wchar;
669 #ifdef offsetof
670 #error stddef.h ignored __need_*
671 #endif
672 if (&size == NULL || &wchar == NULL) abort ();],
673                libc_cv_friendly_stddef=yes,
674                libc_cv_friendly_stddef=no)])
675 if test $libc_cv_friendly_stddef = yes; then
676   config_vars="$config_vars
677 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
678 fi
679
680 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
681                libc_cv_need_minus_P, [dnl
682 cat > conftest.S <<EOF
683 #include "confdefs.h"
684 /* Nothing whatsoever.  */
685 EOF
686 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
687   libc_cv_need_minus_P=no
688 else
689   libc_cv_need_minus_P=yes
690 fi
691 rm -f conftest*])
692 if test $libc_cv_need_minus_P = yes; then
693   config_vars="$config_vars
694 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
695 fi
696
697 AC_CACHE_CHECK(for assembler global-symbol directive,
698                libc_cv_asm_global_directive, [dnl
699 libc_cv_asm_global_directive=UNKNOWN
700 for ac_globl in .globl .global .EXPORT; do
701   cat > conftest.s <<EOF
702         .text
703         ${ac_globl} foo
704 foo:
705 EOF
706   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
707     libc_cv_asm_global_directive=${ac_globl}
708   fi
709   rm -f conftest*
710   test $libc_cv_asm_global_directive != UNKNOWN && break
711 done])
712 if test $libc_cv_asm_global_directive = UNKNOWN; then
713   AC_MSG_ERROR(cannot determine asm global directive)
714 else
715   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
716 fi
717
718 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
719 cat > conftest.s <<EOF
720 .text
721 foo:
722 .set glibc_conftest_frobozz,foo
723 $libc_cv_asm_global_directive glibc_conftest_frobozz
724 EOF
725 # The alpha-dec-osf1 assembler gives only a warning for `.set'
726 # (but it doesn't work), so we must do a linking check to be sure.
727 cat > conftest1.c <<\EOF
728 extern int glibc_conftest_frobozz;
729 main () { printf ("%d\n", glibc_conftest_frobozz); }
730 EOF
731 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
732             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
733   libc_cv_asm_set_directive=yes
734 else
735   libc_cv_asm_set_directive=no
736 fi
737 rm -f conftest*])
738 if test $libc_cv_asm_set_directive = yes; then
739   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
740 fi
741
742 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
743 [cat > conftest.s <<EOF
744 .text
745 _sym:
746 .symver _sym,sym@VERS
747 EOF
748 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
749   libc_cv_asm_symver_directive=yes
750 else
751   libc_cv_asm_symver_directive=no
752 fi
753 rm -f conftest*])
754 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
755 if test $libc_cv_asm_symver_directive = yes; then
756   cat > conftest.s <<EOF
757 .text
758 _sym:
759 .symver _sym,sym@VERS
760 EOF
761   cat > conftest.map <<EOF
762 VERS_1 {
763         global: sym;
764 };
765
766 VERS_2 {
767         global: sym;
768 } VERS_1;
769 EOF
770   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
771     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
772                                         -nostartfiles -nostdlib
773                                         -Wl,--version-script,conftest.map
774                        1>&AC_FD_CC]);
775     then
776       libc_cv_ld_version_script_option=yes
777     else
778       libc_cv_ld_version_script_option=no
779     fi
780   else
781     libc_cv_ld_version_script_option=no
782   fi
783 else
784   libc_cv_ld_version_script_option=no
785 fi
786 rm -f conftest*])
787 if test $libc_cv_asm_symver_directive = yes &&
788    test $libc_cv_ld_version_script_option = yes &&
789    test $enable_versioning = yes; then
790   VERSIONING=yes
791   AC_DEFINE(DO_VERSIONING)
792 else
793   VERSIONING=no
794 fi
795 AC_SUBST(VERSIONING)
796
797 if test $VERSIONING = no; then
798   echo "\
799 *** WARNING: You should not compile GNU libc without versioning. Not using
800 *** versioning will introduce incompatibilities so that old binaries
801 *** will not run anymore.
802 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
803 fi
804 if test $elf = yes; then
805   AC_CACHE_CHECK(for .previous assembler directive,
806                  libc_cv_asm_previous_directive, [dnl
807   cat > conftest.s <<EOF
808 .section foo_section
809 .previous
810 EOF
811   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
812     libc_cv_asm_previous_directive=yes
813   else
814     libc_cv_asm_previous_directive=no
815   fi
816   rm -f conftest*])
817   if test $libc_cv_asm_previous_directive = yes; then
818     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
819   else
820     AC_CACHE_CHECK(for .popsection assembler directive,
821                    libc_cv_asm_popsection_directive, [dnl
822     cat > conftest.s <<EOF
823 .pushsection foo_section
824 .popsection
825 EOF
826     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
827       libc_cv_asm_popsection_directive=yes
828     else
829       libc_cv_asm_popsection_directive=no
830     fi
831     rm -f conftest*])
832     if test $libc_cv_asm_popsection_directive = yes; then
833       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
834     fi
835   fi
836 fi
837
838 if test $elf != yes; then
839   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
840                  [AC_TRY_COMPILE(, [asm (".section .init");
841                                     asm (".section .fini");
842                                     asm (".text");],
843                                  libc_cv_have_initfini=yes,
844                                  libc_cv_have_initfini=no)])
845   AC_SUBST(libc_cv_have_initfini)dnl
846   if test $libc_cv_have_initfini = yes; then
847     AC_DEFINE(HAVE_INITFINI)
848   fi
849 fi
850
851 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
852 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
853 [cat > conftest.$ac_ext <<EOF
854 dnl This sometimes fails to find confdefs.h, for some reason.
855 dnl [#]line __oline__ "[$]0"
856 [#]line __oline__ "configure"
857 #include "confdefs.h"
858 void underscore_test(void) {
859 return; }
860 EOF
861 if AC_TRY_EVAL(ac_compile); then
862   if grep _underscore_test conftest* >/dev/null; then
863     ifelse([$1], , :, [rm -f conftest*
864     $1])
865   else
866     ifelse([$2], , , [rm -f conftest*
867     $2])
868   fi
869 else
870   echo "configure: failed program was:" >&AC_FD_CC
871   cat conftest.$ac_ext >&AC_FD_CC
872   ifelse([$2], , , [rm -f conftest*
873   $2])
874 fi
875 rm -f conftest*])
876
877 if test $elf = yes; then
878   libc_cv_asm_underscores=no
879 else
880   if test $ac_cv_prog_cc_works = yes; then
881     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
882                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
883                                 libc_cv_asm_underscores=yes,
884                                 libc_cv_asm_underscores=no)])
885   else
886     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
887                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
888                                             libc_cv_asm_underscores=no)])
889   fi
890 fi
891 if test $libc_cv_asm_underscores = no; then
892   AC_DEFINE(NO_UNDERSCORES)
893 fi
894
895 if test $elf = yes; then
896   libc_cv_weak_symbols=yes
897 fi
898
899 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
900                  [dnl
901 cat > conftest.s <<EOF
902 .text
903 ${libc_cv_asm_global_directive} foo
904 foo:
905 .weak foo
906 .weak bar; bar = foo
907 EOF
908 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
909   libc_cv_asm_weak_directive=yes
910 else
911   libc_cv_asm_weak_directive=no
912 fi
913 rm -f conftest*])
914
915 if test $libc_cv_asm_weak_directive = no; then
916   AC_CACHE_CHECK(for assembler .weakext directive,
917                  libc_cv_asm_weakext_directive,
918                  [dnl
919 cat > conftest.s <<EOF
920 .text
921 ${libc_cv_asm_global_directive} foo
922 foo:
923 .weakext bar foo
924 .weakext baz
925 ${libc_cv_asm_global_directive} baz
926 baz:
927 EOF
928   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
929     libc_cv_asm_weakext_directive=yes
930   else
931     libc_cv_asm_weakext_directive=no
932   fi
933   rm -f conftest*])
934
935 fi # no .weak
936
937 if test $libc_cv_asm_weak_directive = yes; then
938   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
939 elif test $libc_cv_asm_weakext_directive = yes; then
940   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
941 fi
942
943 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
944 cat > conftest.c <<\EOF
945 _start () {}
946 int __eh_pc;
947 __throw () {}
948 EOF
949 dnl No \ in command here because it ends up inside ''.
950 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
951                             -nostdlib -nostartfiles -Wl,--no-whole-archive
952                             -o conftest conftest.c 1>&AC_FD_CC]); then
953   libc_cv_ld_no_whole_archive=yes
954 else
955   libc_cv_ld_no_whole_archive=no
956 fi
957 rm -f conftest*])
958 if test $libc_cv_ld_no_whole_archive = yes; then
959   no_whole_archive=-Wl,--no-whole-archive
960 fi
961 AC_SUBST(no_whole_archive)dnl
962
963 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
964 cat > conftest.c <<\EOF
965 _start () {}
966 int __eh_pc;
967 __throw () {}
968 EOF
969 dnl No \ in command here because it ends up inside ''.
970 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
971                             -nostdlib -nostartfiles -fexceptions
972                             -o conftest conftest.c 1>&AC_FD_CC]); then
973   libc_cv_gcc_exceptions=yes
974 else
975   libc_cv_gcc_exceptions=no
976 fi
977 rm -f conftest*])
978 if test $libc_cv_gcc_exceptions = yes; then
979   exceptions=-fexceptions
980 fi
981 AC_SUBST(exceptions)dnl
982
983 if test "$base_machine" = alpha ; then
984 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
985 cat > conftest.c <<\EOF
986 foo () { }
987 EOF
988 dnl
989 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
990 then
991   libc_cv_gcc_alpha_ng_prefix=yes
992 else
993   libc_cv_gcc_alpha_ng_prefix=no
994 fi
995 rm -f conftest* ])
996 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
997   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
998 else
999   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1000 fi
1001 fi
1002
1003 if test "$host_cpu" = powerpc ; then
1004 # Check for a bug present in at least versions 2.8.x of GCC
1005 # and versions 1.0.x of EGCS.
1006 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1007 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1008                libc_cv_c_asmcr0_bug='no',
1009                libc_cv_c_asmcr0_bug='yes')])
1010 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1011   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1012 fi
1013 fi
1014
1015 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1016 [cat > conftest.c <<EOF
1017 #line __oline__ "configure"
1018 static char __EH_FRAME_BEGIN__[];
1019 _start ()
1020 {
1021 #ifdef CHECK__register_frame
1022   __register_frame (__EH_FRAME_BEGIN__);
1023   __deregister_frame (__EH_FRAME_BEGIN__);
1024 #endif
1025 #ifdef CHECK__register_frame_info
1026   __register_frame_info (__EH_FRAME_BEGIN__);
1027   __deregister_frame_info (__EH_FRAME_BEGIN__);
1028 #endif
1029 }
1030 int __eh_pc;
1031 __throw () {}
1032 /* FIXME: this is fragile.  */
1033 malloc () {}
1034 strcmp () {}
1035 strlen () {}
1036 memcpy () {}
1037 memset () {}
1038 free () {}
1039 abort () {}
1040 __bzero () {}
1041 EOF
1042 dnl No \ in command here because it ends up inside ''.
1043 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1044                             -nostdlib -nostartfiles
1045                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1046   libc_cv_gcc_dwarf2_unwind_info=static
1047 else
1048   libc_cv_gcc_dwarf2_unwind_info=no
1049 fi
1050 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1051   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1052                               -nostdlib -nostartfiles
1053                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1054     libc_cv_gcc_dwarf2_unwind_info=yes
1055   else
1056     libc_cv_gcc_dwarf2_unwind_info=no
1057   fi
1058 fi
1059 rm -f conftest*])
1060 case $libc_cv_gcc_dwarf2_unwind_info in
1061 yes)
1062   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1063   ;;
1064 static)
1065   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1066   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1067   ;;
1068 esac
1069
1070 dnl Check whether compiler understands __builtin_expect.
1071 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1072 [cat > conftest.c <<EOF
1073 #line __oline__ "configure"
1074 int foo (int a)
1075 {
1076   a = __builtin_expect (a, 10);
1077   return a == 10 ? 0 : 1;
1078 }
1079 EOF
1080 dnl No \ in command here because it ends up inside ''.
1081 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1082                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1083   libc_cv_gcc_builtin_expect=yes
1084 else
1085   libc_cv_gcc_builtin_expect=no
1086 fi
1087 rm -f conftest*])
1088 if test "$libc_cv_gcc_builtin_expect" = yes; then
1089   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1090 fi
1091
1092 dnl Check whether the compiler supports subtraction of local labels.
1093 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1094 [cat > conftest.c <<EOF
1095 changequote(,)dnl
1096 #line __oline__ "configure"
1097 int foo (int a)
1098 {
1099   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1100   void *p = &&l1 + ar[a];
1101   goto *p;
1102  l1:
1103   return 1;
1104  l2:
1105   return 2;
1106 }
1107 changequote([,])dnl
1108 EOF
1109 dnl No \ in command here because it ends up inside ''.
1110 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1111                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1112   libc_cv_gcc_subtract_local_labels=yes
1113 else
1114   libc_cv_gcc_subtract_local_labels=no
1115 fi
1116 rm -f conftest*])
1117 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1118   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1119 fi
1120
1121 dnl Check whether we have the gd library available.
1122 AC_MSG_CHECKING(for libgd)
1123 old_CFLAGS="$CFLAGS"
1124 CFLAGS="$CFLAGS $libgd_include"
1125 old_LDFLAGS="$LDFLAGS"
1126 LDFLAGS="$LDFLAGS $libgd_ldflags"
1127 old_LIBS="$LIBS"
1128 LIBS="$LIBS -lgd -lpng -lz"
1129 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1130 CFLAGS="$old_CFLAGS"
1131 LDFLAGS="$old_LDFLAGS"
1132 LIBS="$old_LIBS"
1133 AC_MSG_RESULT($LIBGD)
1134 AC_SUBST(LIBGD)
1135
1136 ### End of automated tests.
1137 ### Now run sysdeps configure fragments.
1138
1139 # sysdeps configure fragments may set these with files to be linked below.
1140 libc_link_dests=
1141 libc_link_sources=
1142
1143 # They also can set these variables.
1144 ldd_rewrite_script=no
1145
1146 # Iterate over all the sysdep directories we will use, running their
1147 # configure fragments, and looking for a uname implementation.
1148 uname=
1149 for dir in $sysnames; do
1150   case $dir in
1151     /*) dest=$dir ;;
1152     *)  dest=$srcdir/$dir ;;
1153   esac
1154   if test -r $dest/configure; then
1155     AC_MSG_RESULT(running configure fragment for $dest)
1156     . $dest/configure
1157   fi
1158 [
1159   if test -z "$uname"; then
1160     if test -r $dest/uname.c ||
1161        test -r $dest/uname.S ||
1162        { test -r $dest/syscalls.list &&
1163          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1164       uname=$dir
1165     fi
1166   fi
1167 ]dnl
1168 done
1169
1170 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1171
1172 # If we will use the generic uname implementation, we must figure out what
1173 # it will say by examining the system, and write the results in config-name.h.
1174 if test "$uname" = "sysdeps/generic"; then
1175
1176 changequote(,)dnl
1177   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1178 changequote([,])dnl
1179   if test $uname_sysname != $config_os; then
1180     config_release=`echo $config_os | sed s/$uname_sysname//`
1181   fi
1182 dnl
1183 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1184     if test -r /vmunix; then
1185       kernel_id=`strings /vmunix | grep UNIX`
1186     elif test -r /dynix; then
1187       kernel_id=`strings /dynix | grep DYNIX`
1188     else
1189       kernel_id=
1190     fi
1191 ])dnl
1192
1193   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1194 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1195 changequote(,)dnl
1196   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1197 changequote([,])dnl
1198   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1199          != x$config_release; then
1200     # The configuration release is a substring of the kernel release.
1201     libc_cv_uname_release=$kernel_release
1202   elif test x$config_release != x; then
1203     libc_cv_uname_release=$config_release
1204   elif test x$kernel_release != x; then
1205     libc_cv_uname_release=$kernel_release
1206   else
1207     libc_cv_uname_release=unknown
1208   fi])
1209   uname_release="$libc_cv_uname_release"
1210
1211   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1212 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1213 changequote(,)dnl
1214   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1215 changequote([,])dnl
1216   if test -n "$kernel_version"; then
1217     libc_cv_uname_version="$kernel_version"
1218   else
1219     libc_cv_uname_version=unknown
1220   fi])
1221   uname_version="$libc_cv_uname_version"
1222
1223 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1224   config_uname=config-name.h:config-name.in
1225 else
1226   # For non-generic uname, we don't need to create config-name.h at all.
1227   config_uname=
1228 fi
1229
1230 AC_MSG_CHECKING(stdio selection)
1231 AC_SUBST(stdio)
1232 case $stdio in
1233 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1234 default) stdio=stdio ;;
1235 esac
1236 AC_MSG_RESULT($stdio)
1237
1238 # Test for old glibc 2.0.x headers so that they can be removed properly
1239 # Search only in includedir.
1240 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1241 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1242 then
1243   old_glibc_headers=yes
1244 else
1245   old_glibc_headers=no
1246 fi
1247 AC_MSG_RESULT($old_glibc_headers)
1248 if test ${old_glibc_headers} = yes; then
1249   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1250   AC_MSG_WARN(*** be removed.)
1251 fi
1252 AC_SUBST(old_glibc_headers)
1253
1254 AC_SUBST(libc_cv_slibdir)
1255 AC_SUBST(libc_cv_sysconfdir)
1256 AC_SUBST(libc_cv_rootsbindir)
1257
1258 AC_SUBST(has_ldconfig)
1259 AC_SUBST(ldd_rewrite_script)
1260
1261 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1262 if test $gnu_ld = yes; then
1263   AC_DEFINE(HAVE_GNU_LD)
1264 fi
1265 if test $gnu_as = yes; then
1266   AC_DEFINE(HAVE_GNU_AS)
1267 fi
1268 if test $elf = yes; then
1269   AC_DEFINE(HAVE_ELF)
1270 fi
1271
1272 AC_SUBST(static)
1273 AC_SUBST(shared)
1274 if test $shared = default; then
1275   if test $gnu_ld = yes; then
1276     shared=$elf
1277   else
1278     # For now we do not assume shared libs are available.  In future more
1279     # tests might become available.
1280     shared=no
1281   fi
1282 fi
1283
1284 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1285 [pic_default=yes
1286 cat > conftest.c <<EOF
1287 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1288 # error PIC is default.
1289 #endif
1290 EOF
1291 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1292   pic_default=no
1293 fi
1294 rm -f conftest.*])
1295 AC_SUBST(pic_default)
1296
1297 AC_SUBST(profile)
1298 AC_SUBST(omitfp)
1299 AC_SUBST(bounded)
1300 AC_SUBST(static_nss)
1301 AC_SUBST(nopic_initfini)
1302
1303 AC_SUBST(DEFINES)
1304
1305 case "$add_ons" in
1306   *door*) linux_doors=yes ;;
1307   *) linux_doors=no ;;
1308 esac
1309 AC_SUBST(linux_doors)
1310
1311 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1312   config_makefile=
1313 else
1314   config_makefile=Makefile
1315 fi
1316
1317 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1318 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1319 AC_SUBST(VERSION)
1320 AC_SUBST(RELEASE)
1321
1322 echo '*** Do NOT install this release on any production system!'
1323 echo '*** It is known to be broken and will be so for quite some time.'
1324 echo '*** Use the latest released version instead.'
1325
1326 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1327 case $CONFIG_FILES in *config.make*)
1328 echo "$config_vars" >> config.make;;
1329 esac
1330 test -d bits || mkdir bits], [config_vars='$config_vars'])