configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.4.2)dnl             dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21
  22 dnl Arguments to specify presence of other packages/features.
  23 AC_ARG_WITH(fp, dnl
  24   --with-fp               if using floating-point hardware,
  25             with_fp=$withval, with_fp=yes)
  26 AC_ARG_WITH(gnu-binutils, dnl
  27   --with-gnu-binutils     if using GNU binutils (as and ld),
  28             gnu_binutils=$withval, gnu_binutils=no)
  29 AC_ARG_WITH(gnu-ld, dnl
  30   --with-gnu-ld           if using GNU ld (in the binutils package),
  31             gnu_ld=$withval, gnu_ld=no)
  32 AC_ARG_WITH(gnu-as, dnl
  33   --with-gnu-as           if using GNU as (in the binutils package),
  34             gnu_as=$withval, gnu_as=no)
  35 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  36 AC_ARG_WITH(elf, dnl
  37   --with-elf              if using the ELF object format,
  38             elf=$withval, elf=no)
  39 AC_ARG_WITH(weak-symbols, dnl
  40   --with-weak-symbols     if weak symbols are available in as and ld,
  41             weak=$withval, weak=no)
  42
  43 dnl Arguments to enable or disable building the shared, profiled, and
  44 dnl -fomit-frame-pointer libraries.
  45 AC_ARG_ENABLE(shared, dnl
  46 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  47             shared=$enableval, shared=default)
  48 AC_ARG_ENABLE(profile, dnl
  49 [  --enable-profile        build profiled library [default=yes]],
  50             profile=$enableval, profile=yes)
  51 AC_ARG_ENABLE(omitfp, dnl
  52 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  53             omitfp=$enableval, omitfp=no)
  54
  55 AC_CANONICAL_HOST
  56 # We keep the original values in `$config_*' and never modify them, so we
  57 # can write them unchanged into config.make.  Everything else uses
  58 # $machine, $vendor, and $os, and changes them whenever convenient.
  59 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  60
  61 # Some configurations imply other options.
  62 case "$host_os" in
  63 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  64   # These systems always use GNU tools.
  65   gnu_ld=yes gnu_as=yes
  66 esac
  67 case "$host_os" in
  68 gnu* | linux* | sysv4* | solaris2*)
  69   # These systems always use the ELF format.
  70   elf=yes
  71 esac
  72
  73 # Compute the list of sysdep directories for this configuration.
  74 sysdep_dir=$srcdir/sysdeps
  75 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
  76 machine=$config_machine
  77 vendor=$config_vendor
  78 os=$config_os
  79
  80 dnl We need to use [ and ] for other purposes for a while now.
  81 changequote(,)dnl
  82 # Expand the configuration machine name into a subdirectory by architecture
  83 # type and particular chip.
  84 case "$machine" in
  85 a29k | am29000) machine=a29k ;;
  86 alpha*)         machine=alpha/$machine ;;
  87 hppa*)          machine=hppa/$machine ;;
  88 i[345]86)       machine=i386/$machine ;;
  89 m680?0)         machine=m68k/$machine ;;
  90 m68k)           machine=m68k/m68020 ;;
  91 m88???)         machine=m88k/$machine ;;
  92 m88k)           machine=m88k/m88100 ;;
  93 mips*)          machine=mips/$machine ;;
  94 mips64*)        machine=mips/mips64/$machine ;;
  95 sparc[6789])    machine=sparc/$machine ;;
  96 supersparc)     machine=sparc/sparc8 ;;
  97 esac
  98
  99 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 100 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 101
 102 case "$os" in
 103 gnu*)
 104   base_os=mach/hurd ;;
 105 netbsd* | 386bsd* | freebsd* | bsdi*)
 106   base_os=unix/bsd/bsd4.4 ;;
 107 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 108   base_os=unix/bsd ;;
 109 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 110   base_os=unix/sysv ;;
 111 solaris[2-9]*)
 112   base_os=unix/sysv/sysv4 ;;
 113 none)
 114   base_os=standalone ;;
 115 *)
 116   base_os='' ;;
 117 esac
 118
 119 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 120 tail=$os
 121 ostry=$os
 122 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 123   ostry="$ostry /$o"
 124   tail=$o
 125 done
 126 o=`echo $tail | sed 's/[0-9]*$//'`
 127 if test $o != $tail; then
 128   ostry="$ostry /$o"
 129 fi
 130
 131 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 132 base=
 133 tail=$base_os
 134 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 135   set $b
 136   base="$base /$1"
 137   tail="$2"
 138 done
 139
 140 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 141 mach=
 142 tail=$machine
 143 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 144   set $m
 145   # Prepend the machine's FPU directory unless --without-fp.
 146   if test "$with_fp" = yes; then
 147     mach="$mach /$1/fpu"
 148   fi
 149   mach="$mach /$1"
 150   tail="$2"
 151 done
 152
 153 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 154 changequote([,])dnl
 155
 156 # Find what sysdep directories exist.
 157 sysnames=
 158 for b in $base ''; do
 159   for m0 in $mach ''; do
 160     for v in /$vendor ''; do
 161       for o in /$ostry ''; do
 162         for m in $mach ''; do
 163           try="$m0$b$v$o$m"
 164           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
 165           if test -d $sysdep_dir$try; then
 166             sysnames="$sysnames $try"
 167             { test -n "$o" || test -n "$b"; } && os_used=t
 168             { test -n "$m" || test -n "$m0"; } && machine_used=t
 169           fi
 170         done
 171       done
 172     done
 173   done
 174 done
 175
 176 if test -z "$os_used" && test "$os" != none; then
 177   AC_MSG_ERROR(Operating system $os is not supported.)
 178 fi
 179 if test -z "$machine_used" && test "$machine" != none; then
 180   AC_MSG_ERROR(The $machine is not supported.)
 181 fi
 182
 183 # We have now validated the configuration.
 184
 185
 186 # If using ELF, look for an `elf' subdirectory of each machine directory.
 187 # We prepend these rather than inserting them whereever the machine appears
 188 # because things specified by the machine's ELF ABI should override
 189 # OS-specific things, and should always be the same for any OS on the
 190 # machine (otherwise what's the point of an ABI?).
 191 if test "$elf" = yes; then
 192   elf_dirs=
 193   for m in $mach; do
 194     if test -d $sysdep_dir$m/elf; then
 195       elf_dirs="$elf_dirs $m/elf"
 196     fi
 197   done
 198   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 199 fi
 200
 201
 202 # Remove the leading slashes.
 203 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 204
 205
 206 # Expand the list of system names into a full list of directories
 207 # from each element's parent name and Implies file (if present).
 208 set $sysnames
 209 while test $# -gt 0; do
 210   name=$1
 211   shift
 212
 213   if test -f $sysdep_dir/$name/Implies; then
 214     # Collect more names from the `Implies' file (removing comments).
 215     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 216     for x in $implied; do
 217       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 218     done
 219   else
 220     implied=
 221   fi
 222
 223   # Add NAME to the list of names.
 224   names="$names $name"
 225
 226   # Find the parent of NAME, using the empty string if it has none.
 227 changequote(,)dnl
 228   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 229 changequote([,])dnl
 230
 231   # Add the names implied by NAME, and NAME's parent (if it has one), to
 232   # the list of names to be processed (the argument list).  We prepend the
 233   # implied names to the list and append the parent.  We want implied
 234   # directories to come before further directories inferred from the
 235   # configuration components; this ensures that for sysv4, unix/common
 236   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 237   # after sysv4).
 238   sysnames="`echo $implied $* $parent`"
 239   test -n "$sysnames" && set $sysnames
 240 done
 241
 242 # Add the default directories.
 243 names="$names generic stub"
 244
 245 # Now uniquize the list.
 246 seen=
 247 sysnames=
 248 for name in $names; do
 249   if echo "$seen" | fgrep -x $name >/dev/null; then
 250     # Already in the list.
 251     true;
 252   else
 253     # A new one.
 254     if test -z "$seen"; then
 255       seen="$name" sysnames="$name"
 256     else
 257       seen="$seen
 258 $name"
 259       sysnames="$sysnames $name"
 260     fi
 261   fi
 262 done
 263 libc_cv_sysdirs="$sysnames"])
 264 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 265
 266 AC_PROG_INSTALL
 267 if test "$INSTALL" = "${srcdir}/install-sh"; then
 268   # The makefiles need to use a different form to find it in $srcdir.
 269   INSTALL='$(..)./install-sh'
 270 fi
 271
 272 AC_CHECK_TOOL(CC, gcc)
 273 AC_CHECK_TOOL(AR, ar)
 274 AC_CHECK_TOOL(RANLIB, ranlib, :)
 275 AC_PROG_CPP
 276
 277 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 278 echo '#include <stddef.h>
 279 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 280 if eval "$ac_cpp conftest.c 2>/dev/null" \
 281 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 282   libc_cv_signed_size_t=no
 283 else
 284   libc_cv_signed_size_t=yes
 285 fi
 286 rm -f conftest*])
 287 if test $libc_cv_signed_size_t = yes; then
 288   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 289   cat >> confdefs.h <<\EOF
 290 #undef __SIZE_TYPE__
 291 #define __SIZE_TYPE__ unsigned
 292 EOF
 293 fi
 294
 295 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 296 AC_TRY_COMPILE(dnl
 297 [#define __need_size_t
 298 #define __need_wchar_t
 299 #include <stddef.h>
 300 #define __need_NULL
 301 #include <stddef.h>], [size_t size; wchar_t wchar;
 302 #ifdef offsetof
 303 #error stddef.h ignored __need_*
 304 #endif
 305 if (&size == NULL || &wchar == NULL) abort ();],
 306                libc_cv_friendly_stddef=yes,
 307                libc_cv_friendly_stddef=no)])
 308 if test $libc_cv_friendly_stddef = yes; then
 309   config_vars="$config_vars
 310 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 311 fi
 312
 313 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 314                libc_cv_need_minus_P, [dnl
 315 cat > conftest.S <<EOF
 316 #include "confdefs.h"
 317 /* Nothing whatsoever.  */
 318 EOF
 319 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 320   libc_cv_need_minus_P=no
 321 else
 322   libc_cv_need_minus_P=yes
 323 fi
 324 rm -f conftest*])
 325 if test $libc_cv_need_minus_P = yes; then
 326   config_vars="$config_vars
 327 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 328 fi
 329
 330 AC_CACHE_CHECK(for assembler global-symbol directive,
 331                libc_cv_asm_global_directive, [dnl
 332 libc_cv_asm_global_directive=UNKNOWN
 333 for ac_globl in .globl .global; do
 334   cat > conftest.s <<EOF
 335 .text
 336 ${ac_globl} foo
 337 foo: .long 0
 338 EOF
 339   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 340     libc_cv_asm_global_directive=${ac_globl}
 341   fi
 342   rm -f conftest*
 343   test $libc_cv_asm_global_directive != UNKNOWN && break
 344 done])
 345 if test $libc_cv_asm_global_directive = UNKNOWN; then
 346   AC_MSG_ERROR(cannot determine asm global directive)
 347 else
 348   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 349 fi
 350
 351 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 352 cat > conftest.s <<EOF
 353 .text
 354 foo: .long 0
 355 .set glibc_conftest_frobozz,foo
 356 $libc_cv_asm_global_directive glibc_conftest_frobozz
 357 EOF
 358 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 359 # (but it doesn't work), so we must do a linking check to be sure.
 360 cat > conftest1.c <<\EOF
 361 extern int glibc_conftest_frobozz;
 362 main () { printf ("%d\n", glibc_conftest_frobozz); }
 363 EOF
 364 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 365             conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 366   libc_cv_asm_set_directive=yes
 367 else
 368   libc_cv_asm_set_directive=no
 369 fi
 370 rm -f conftest*])
 371 if test $libc_cv_asm_set_directive = yes; then
 372   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 373 fi
 374
 375 if test $elf != yes; then
 376   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 377                  [AC_TRY_COMPILE(, [asm (".section .init");
 378                                     asm (".section .fini");],
 379                                  libc_cv_have_initfini=yes,
 380                                  libc_cv_have_initfini=no)])
 381   AC_SUBST(libc_cv_have_initfini)dnl
 382   if test $libc_cv_have_initfini = yes; then
 383     AC_DEFINE(HAVE_INITFINI)
 384   fi
 385 fi
 386
 387 # sysdeps configure fragments may set these with files to be linked below.
 388 libc_link_dests=
 389 libc_link_sources=
 390
 391 # Iterate over all the sysdep directories we will use, running their
 392 # configure fragments, and looking for a uname implementation.
 393 uname=
 394 for dir in $sysnames; do
 395   if test -r $sysdep_dir/$dir/configure; then
 396     AC_MSG_RESULT(running configure fragment for $dir)
 397     . $sysdep_dir/$dir/configure
 398   fi
 399   if test -z "$uname"; then
 400     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
 401     && uname=$dir
 402   fi
 403 done
 404
 405 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 406
 407 # If we will use the generic uname implementation, we must figure out what
 408 # it will say by examining the system, and write the results in config-name.h.
 409 if test "$uname" = generic; then
 410
 411 changequote(,)dnl
 412   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 413 changequote([,])dnl
 414   if test $uname_sysname != $config_os; then
 415     config_release=`echo $config_os | sed s/$uname_sysname//`
 416   fi
 417 dnl
 418 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 419     if test -r /vmunix; then
 420       kernel_id=`strings /vmunix | grep UNIX`
 421     elif test -r /dynix; then
 422       kernel_id=`strings /dynix | grep DYNIX`
 423     else
 424       kernel_id=
 425     fi
 426 ])dnl
 427
 428   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 429 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 430 changequote(,)dnl
 431   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 432 changequote([,])dnl
 433   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 434          != x$config_release; then
 435     # The configuration release is a substring of the kernel release.
 436     libc_cv_uname_release=$kernel_release
 437   elif test x$config_release != x; then
 438     libc_cv_uname_release=$config_release
 439   elif test x$kernel_release != x; then
 440     libc_cv_uname_release=$kernel_release
 441   else
 442     libc_cv_uname_release=unknown
 443   fi])
 444   uname_release="$libc_cv_uname_release"
 445
 446   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 447 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 448 changequote(,)dnl
 449   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 450 changequote([,])dnl
 451   if test -n "$kernel_version"; then
 452     libc_cv_uname_version="$kernel_version"
 453   else
 454     libc_cv_uname_version=unknown
 455   fi])
 456   uname_version="$libc_cv_uname_version"
 457
 458 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 459   config_uname=config-name.h:config-name.in
 460 else
 461   # For non-generic uname, we don't need to create config-name.h at all.
 462   config_uname=
 463 fi
 464
 465 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
 466 if test $gnu_ld = yes; then
 467   AC_DEFINE(HAVE_GNU_LD)
 468 fi
 469 if test $gnu_as = yes; then
 470   AC_DEFINE(HAVE_GNU_AS)
 471 fi
 472 if test $elf = yes; then
 473   AC_DEFINE(HAVE_ELF)
 474 fi
 475 if test $weak = yes; then
 476   AC_DEFINE(HAVE_WEAK_SYMBOLS)
 477 fi
 478
 479 AC_SUBST(shared)
 480 if test $shared = default; then
 481   if test $gnu_ld = yes; then
 482     shared=$elf
 483   fi
 484 fi
 485 AC_SUBST(profile)
 486 AC_SUBST(omitfp)
 487
 488
 489 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 490   config_makefile=
 491 else
 492   config_makefile=Makefile
 493 fi
 494
 495 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 496           [echo '$config_vars' >> config.make])