(ld --version-script): Test if the same symbol
[kopensolaris-gnu/glibc.git] / configure.in
1 Dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45
46 AC_ARG_ENABLE(libio, dnl
47 [  --enable-libio          build in GNU libio instead of GNU stdio],
48               [if test $enableval = yes; then
49                  stdio=libio
50                else
51                  stdio=stdio
52                fi],
53               stdio=default)
54
55 AC_ARG_ENABLE(sanity-checks, dnl
56 [  --disable-sanity-checks really do not use threads (should not be used
57                           except in special situations) [default=yes]],
58               enable_sanity=$enableval, enable_sanity=yes)
59
60 dnl Arguments to enable or disable building the static, shared, profiled,
61 dnl and -fomit-frame-pointer libraries.
62 AC_ARG_ENABLE(static, dnl
63 [  --enable-static         build static library [default=yes]],
64               static=$enableval, static=yes)
65 AC_ARG_ENABLE(shared, dnl
66 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
67               shared=$enableval, shared=default)
68 AC_ARG_ENABLE(profile, dnl
69 [  --enable-profile        build profiled library [default=yes]],
70               profile=$enableval, profile=yes)
71 AC_ARG_ENABLE(omitfp, dnl
72 [  --enable-omitfp         build undebuggable optimized library [default=no]],
73               omitfp=$enableval, omitfp=no)
74 AC_ARG_ENABLE(bounded, dnl
75 [  --enable-bounded        build with runtime bounds checking [default=no]],
76               bounded=$enableval, bounded=no)
77 AC_ARG_ENABLE(versioning, dnl
78 [  --disable-versioning    do not include versioning information in the
79                           library objects [default=yes if supported]],
80              enable_versioning=$enableval, enable_versioning=yes)
81
82 dnl Generic infrastructure for drop-in additions to libc.
83 AC_ARG_ENABLE(add-ons, dnl
84 [  --enable-add-ons=DIR... configure and build named extra directories],
85               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
86               [add_ons=])
87 AC_CONFIG_SUBDIRS($add_ons)
88 add_ons_pfx=
89 if test x"$add_ons" != x; then
90   for f in $add_ons; do
91     # Test whether such a subdir really exists.
92     if test -d $srcdir/$f; then
93       add_ons_pfx="$add_ons_pfx $f/"
94     else
95       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
96     fi
97   done
98 fi
99
100 dnl On some platforms we cannot use dynamic loading.  We must provide
101 dnl static NSS modules.
102 AC_ARG_ENABLE(static-nss, dnl
103 [  --enable-static-nss     build static NSS modules [default=no]],
104               static_nss=$enableval, static_nss=no)
105 if test x"$static_nss" = xyes; then
106   AC_DEFINE(DO_STATIC_NSS)
107 fi
108
109 AC_CANONICAL_HOST
110
111 # The way shlib-versions is used to generate soversions.mk uses a
112 # fairly simplistic model for name recognition that can't distinguish
113 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
114 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
115 # tell.  This doesn't get used much beyond that, so it's fairly safe.
116 case "$host_os" in
117 linux*)
118   ;;
119 gnu*)
120   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
121   ;;
122 esac
123
124 ###
125 ### I put this here to prevent those annoying emails from people who cannot
126 ### read and try to compile glibc on unsupported platforms.  --drepper
127 ###
128 ### By using the undocumented --enable-hacker-mode option for configure
129 ### one can skip this test to make the configuration not fail for unsupported
130 ### platforms.
131 ###
132 if test -z "$enable_hacker_mode"; then
133   case "$host_os" in
134   linux* | gnu*)
135     ;;
136   *)
137     echo "*** The GNU C library is currently not available for this platform."
138     echo "*** So far nobody cared to port it and if there is no volunteer it"
139     echo "*** might never happen.  So, if you have interest to see glibc on"
140     echo "*** this platform visit"
141     echo "***   http://www.gnu.ai.mit.edu/software/libc/porting.html"
142     echo "*** and join the group of porters"
143     exit 1
144     ;;
145   esac
146 fi
147
148 # We keep the original values in `$config_*' and never modify them, so we
149 # can write them unchanged into config.make.  Everything else uses
150 # $machine, $vendor, and $os, and changes them whenever convenient.
151 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
152
153 # Some configurations imply other options.
154 case "$host_os" in
155 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
156   # These systems always use GNU tools.
157   gnu_ld=yes gnu_as=yes ;;
158 esac
159 case "$host_os" in
160 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
161 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
162   ;;
163 gnu* | linux* | sysv4* | solaris2*)
164   # These systems (almost) always use the ELF format.
165   elf=yes
166   ;;
167 esac
168
169 machine=$config_machine
170 vendor=$config_vendor
171 os=$config_os
172
173 dnl We need to use [ and ] for other purposes for a while now.
174 changequote(,)dnl
175 # Expand the configuration machine name into a subdirectory by architecture
176 # type and particular chip.
177 case "$machine" in
178 a29k | am29000) base_machine=a29k machine=a29k ;;
179 alpha*)         base_machine=alpha machine=alpha/$machine ;;
180 arm*)           base_machine=arm machine=arm/$machine ;;
181 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
182 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
183 hppa*)          base_machine=hppa machine=hppa/$machine ;;
184 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
185 m680?0)         base_machine=m68k machine=m68k/$machine ;;
186 m68k)           base_machine=m68k machine=m68k/m68020 ;;
187 m88???)         base_machine=m88k machine=m88k/$machine ;;
188 m88k)           base_machine=m88k machine=m88k/m88100 ;;
189 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
190 mips*)          base_machine=mips machine=mips/$machine ;;
191 sparc | sparcv[67])
192                 base_machine=sparc machine=sparc/sparc32 ;;
193 sparcv8 | supersparc | hypersparc)
194                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
195 sparc64 | ultrasparc)
196                 base_machine=sparc machine=sparc/sparc64 ;;
197 esac
198 changequote([,])dnl
199 AC_SUBST(base_machine)
200
201 if test "$base_machine" = "i386"; then
202   AC_DEFINE(USE_REGPARMS)
203 fi
204
205 # Compute the list of sysdep directories for this configuration.
206 # This can take a while to compute.
207 sysdep_dir=$srcdir/sysdeps
208 AC_MSG_CHECKING(sysdep dirs)
209 dnl We need to use [ and ] for other purposes for a while now.
210 changequote(,)dnl
211 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
212 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
213
214 case "$os" in
215 gnu*)
216   base_os=mach/hurd ;;
217 netbsd* | 386bsd* | freebsd* | bsdi*)
218   base_os=unix/bsd/bsd4.4 ;;
219 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
220   base_os=unix/bsd ;;
221 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
222   base_os=unix/sysv ;;
223 solaris[2-9]*)
224   base_os=unix/sysv/sysv4 ;;
225 none)
226   base_os=standalone ;;
227 *)
228   base_os='' ;;
229 esac
230
231 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
232 tail=$os
233 ostry=$os
234 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
235   ostry="$ostry /$o"
236   tail=$o
237 done
238 o=`echo $tail | sed 's/[0-9]*$//'`
239 if test $o != $tail; then
240   ostry="$ostry /$o"
241 fi
242 # For linux-gnu, try linux-gnu, then linux.
243 o=`echo $tail | sed 's/-.*$//'`
244 if test $o != $tail; then
245   ostry="$ostry /$o"
246 fi
247
248 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
249 base=
250 tail=$base_os
251 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
252   set $b
253   base="$base /$1"
254   tail="$2"
255 done
256
257 # For sparc/sparc9, try sparc/sparc9 and then sparc.
258 mach=
259 tail=$machine
260 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
261   set $m
262   # Prepend the machine's FPU directory unless --without-fp.
263   if test "$with_fp" = yes; then
264     mach="$mach /$1/fpu"
265   fi
266   mach="$mach /$1"
267   tail="$2"
268 done
269
270 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
271 changequote([,])dnl
272
273 # Find what sysdep directories exist.
274 sysnames=
275 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
276 for d in $add_ons_pfx ''; do
277   for b in $base ''; do
278     for m0 in $mach ''; do
279       for v in /$vendor ''; do
280         for o in /$ostry ''; do
281           for m in $mach ''; do
282             if test "$m0$b$v$o$m"; then
283               try="${d}sysdeps$m0$b$v$o$m"
284               test -n "$enable_debug_configure" &&
285               echo "$0 [DEBUG]: try $try" >&2
286               case $try in
287                 /*) dest=$try ;;
288                 *)  dest=$srcdir/$try ;;
289               esac
290               if test -d $dest; then
291                 sysnames="$sysnames $try"
292                 { test -n "$o" || test -n "$b"; } && os_used=t
293                 { test -n "$m" || test -n "$m0"; } && machine_used=t
294               fi
295             fi
296           done
297         done
298       done
299     done
300   done
301 done
302 IFS="$ac_save_ifs"
303
304 if test -z "$os_used" && test "$os" != none; then
305   AC_MSG_ERROR(Operating system $os is not supported.)
306 fi
307 if test -z "$machine_used" && test "$machine" != none; then
308   AC_MSG_ERROR(The $machine is not supported.)
309 fi
310
311 # We have now validated the configuration.
312
313
314 # If using ELF, look for an `elf' subdirectory of each machine directory.
315 # We prepend these rather than inserting them whereever the machine appears
316 # because things specified by the machine's ELF ABI should override
317 # OS-specific things, and should always be the same for any OS on the
318 # machine (otherwise what's the point of an ABI?).
319 if test "$elf" = yes; then
320   elf_dirs=
321   for d in $add_ons_pfx ''; do
322     case $d in
323       /*) xsrcdir= ;;
324       *)  xsrcdir=$srcdir/ ;;
325     esac
326     for m in $mach; do
327       if test -d $xsrcdir${d}sysdeps$m/elf; then
328         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
329       fi
330     done
331   done
332   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
333 fi
334
335
336 # Expand the list of system names into a full list of directories
337 # from each element's parent name and Implies file (if present).
338 set $sysnames
339 names=
340 while test $# -gt 0; do
341   name=$1
342   shift
343
344   case " $names " in *" $name "*)
345     # Already in the list.
346     continue
347   esac
348
349   # Report each name as we discover it, so there is no long pause in output.
350   echo $ac_n "$name $ac_c" >&AC_FD_MSG
351
352   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
353
354   case $name in
355     /*) xsrcdir= ;;
356     *)  xsrcdir=$srcdir/ ;;
357   esac
358   test -n "$enable_debug_configure" &&
359   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
360
361   if test -f $xsrcdir$name/Implies; then
362     # Collect more names from the `Implies' file (removing comments).
363     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
364     implied=
365     for x in $implied_candidate; do
366       if test -d $xsrcdir$name_base/$x; then
367         implied="$implied $name_base/$x";
368       else
369         AC_MSG_WARN($name/Implies specifies nonexistent $x)
370       fi
371     done
372   else
373     implied=
374   fi
375
376   # Add NAME to the list of names.
377   names="$names $name"
378
379   # Find the parent of NAME, using the empty string if it has none.
380 changequote(,)dnl
381   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
382 changequote([,])dnl
383
384   # Add the names implied by NAME, and NAME's parent (if it has one), to
385   # the list of names to be processed (the argument list).  We prepend the
386   # implied names to the list and append the parent.  We want implied
387   # directories to come before further directories inferred from the
388   # configuration components; this ensures that for sysv4, unix/common
389   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
390   # after sysv4).
391   sysnames="`echo $implied $* $parent`"
392   test -n "$sysnames" && set $sysnames
393 done
394
395 # Add the default directories.
396 sysnames="$names sysdeps/generic"
397 AC_SUBST(sysnames)
398 # The other names were emitted during the scan.
399 AC_MSG_RESULT(sysdeps/generic)
400
401
402 ### Locate tools.
403
404 AC_PROG_INSTALL
405 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
406   # The makefiles need to use a different form to find it in $srcdir.
407   INSTALL='\$(..)./install-sh -c'
408 fi
409 AC_PROG_LN_S
410 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
411
412 AC_PROG_CC_LOCAL
413 AC_CANONICAL_BUILD
414 if test $host != $build; then
415   AC_CHECK_PROGS(BUILD_CC, gcc cc)
416 fi
417 AC_SUBST(cross_compiling)
418 AC_PROG_CPP
419 LIBC_PROG_BINUTILS
420 AC_CHECK_TOOL(AR, ar)
421 AC_CHECK_TOOL(RANLIB, ranlib, :)
422
423 AC_PATH_PROG(BASH, bash, no)
424 if test "$BASH" != no &&
425    $BASH -c 'test "$BASH_VERSINFO" \
426              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
427   libc_cv_have_bash2=yes
428 else
429   libc_cv_have_bash2=no
430 fi
431 AC_SUBST(libc_cv_have_bash2)
432
433 dnl We need a ksh compatible shell for tzselect.
434 if test "$BASH" = no; then
435   AC_PATH_PROG(KSH, ksh, no)
436   if test "$KSH" = no; then
437     libc_cv_have_ksh=no
438   else
439     libc_cv_have_ksh=yes
440   fi
441 else
442   KSH="$BASH"
443   AC_SUBST(KSH)
444   libc_cv_have_ksh=yes
445 fi
446 AC_SUBST(libc_cv_have_ksh)
447
448 AC_PATH_PROGS(PERL, perl, no)
449 AC_SUBST(PERL)
450
451 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
452 echo '#include <stddef.h>
453 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
454 if eval "$ac_cpp conftest.c 2>/dev/null" \
455 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
456   libc_cv_signed_size_t=no
457 else
458   libc_cv_signed_size_t=yes
459 fi
460 rm -f conftest*])
461 if test $libc_cv_signed_size_t = yes; then
462   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
463   cat >> confdefs.h <<\EOF
464 #undef __SIZE_TYPE__
465 #define __SIZE_TYPE__ unsigned
466 EOF
467 fi
468
469 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
470 AC_TRY_COMPILE(dnl
471 [#define __need_size_t
472 #define __need_wchar_t
473 #include <stddef.h>
474 #define __need_NULL
475 #include <stddef.h>], [size_t size; wchar_t wchar;
476 #ifdef offsetof
477 #error stddef.h ignored __need_*
478 #endif
479 if (&size == NULL || &wchar == NULL) abort ();],
480                libc_cv_friendly_stddef=yes,
481                libc_cv_friendly_stddef=no)])
482 if test $libc_cv_friendly_stddef = yes; then
483   config_vars="$config_vars
484 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
485 fi
486
487 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
488                libc_cv_need_minus_P, [dnl
489 cat > conftest.S <<EOF
490 #include "confdefs.h"
491 /* Nothing whatsoever.  */
492 EOF
493 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
494   libc_cv_need_minus_P=no
495 else
496   libc_cv_need_minus_P=yes
497 fi
498 rm -f conftest*])
499 if test $libc_cv_need_minus_P = yes; then
500   config_vars="$config_vars
501 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
502 fi
503
504 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
505 # be told to read stdin.  This causes the compiler to hang when fed an
506 # .s file.
507 if test $ac_cv_prog_gcc = yes; then
508  case `${CC-cc} -v 2>&1` in
509   *2.7*)
510   # We must check this even if -pipe is not given here, because the user
511   # might do `make CFLAGS=-pipe'.
512   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
513    cp /dev/null conftest.s
514    cat >conftest1.s <<EOF
515 .nosuchdirective
516 EOF
517    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
518     libc_cv_gcc_pipe_bug=no
519    else
520     libc_cv_gcc_pipe_bug=yes
521    fi
522    rm -f conftest*])
523   if test $libc_cv_gcc_pipe_bug = yes; then
524    makeCC="${CC-cc} -B\$(common-objpfx)"
525    makeCFLAGS=$CFLAGS
526    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
527   fi;;
528  *) libc_cv_gcc_pipe_bug=no;;
529  esac
530 else
531  libc_cv_gcc_pipe_bug=no
532 fi
533
534 AC_CACHE_CHECK(for assembler global-symbol directive,
535                libc_cv_asm_global_directive, [dnl
536 libc_cv_asm_global_directive=UNKNOWN
537 for ac_globl in .globl .global; do
538   cat > conftest.s <<EOF
539 .text
540 ${ac_globl} foo
541 foo:
542 EOF
543   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
544     libc_cv_asm_global_directive=${ac_globl}
545   fi
546   rm -f conftest*
547   test $libc_cv_asm_global_directive != UNKNOWN && break
548 done])
549 if test $libc_cv_asm_global_directive = UNKNOWN; then
550   AC_MSG_ERROR(cannot determine asm global directive)
551 else
552   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
553 fi
554
555 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
556 cat > conftest.s <<EOF
557 .text
558 foo:
559 .set glibc_conftest_frobozz,foo
560 $libc_cv_asm_global_directive glibc_conftest_frobozz
561 EOF
562 # The alpha-dec-osf1 assembler gives only a warning for `.set'
563 # (but it doesn't work), so we must do a linking check to be sure.
564 cat > conftest1.c <<\EOF
565 extern int glibc_conftest_frobozz;
566 main () { printf ("%d\n", glibc_conftest_frobozz); }
567 EOF
568 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
569             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
570   libc_cv_asm_set_directive=yes
571 else
572   libc_cv_asm_set_directive=no
573 fi
574 rm -f conftest*])
575 if test $libc_cv_asm_set_directive = yes; then
576   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
577 fi
578
579 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
580 [cat > conftest.s <<EOF
581 .text
582 _sym:
583 .symver _sym,sym@VERS
584 EOF
585 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
586   libc_cv_asm_symver_directive=yes
587 else
588   libc_cv_asm_symver_directive=no
589 fi
590 rm -f conftest*])
591 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
592 if test $libc_cv_asm_symver_directive = yes; then
593   cat > conftest.s <<EOF
594 .text
595 _sym:
596 .symver _sym,sym@VERS
597 EOF
598   cat > conftest.map <<EOF
599 VERS_1 {
600         global: sym;
601 };
602
603 VERS_2 {
604         global: sym;
605 } VERS_1;
606 EOF
607   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
608     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
609                                         -nostartfiles -nostdlib
610                                         -Wl,--version-script,conftest.map
611                        1>&AC_FD_CC]);
612     then
613       libc_cv_ld_version_script_option=yes
614     else
615       libc_cv_ld_version_script_option=no
616     fi
617   else
618     libc_cv_ld_version_script_option=no
619   fi
620 else
621   libc_cv_ld_version_script_option=no
622 fi
623 rm -f conftest*])
624 if test $libc_cv_asm_symver_directive = yes &&
625    test $libc_cv_ld_version_script_option = yes &&
626    test $enable_versioning = yes; then
627   VERSIONING=yes
628   AC_DEFINE(DO_VERSIONING)
629 else
630   VERSIONING=no
631 fi
632 AC_SUBST(VERSIONING)
633
634 if test $VERSIONING = no; then
635   echo "\
636 *** WARNING: You should not compile GNU libc without versioning. Not using 
637 *** versioning will introduce incompatibilities so that old binaries
638 *** will not run anymore.
639 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
640 fi
641 if test $elf = yes; then
642   AC_CACHE_CHECK(for .previous assembler directive,
643                  libc_cv_asm_previous_directive, [dnl
644   cat > conftest.s <<EOF
645 .section foo_section
646 .previous
647 EOF
648   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
649     libc_cv_asm_previous_directive=yes
650   else
651     libc_cv_asm_previous_directive=no
652   fi
653   rm -f conftest*])
654   if test $libc_cv_asm_previous_directive = yes; then
655     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
656   else
657     AC_CACHE_CHECK(for .popsection assembler directive,
658                    libc_cv_asm_popsection_directive, [dnl
659     cat > conftest.s <<EOF
660 .pushsection foo_section
661 .popsection
662 EOF
663     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
664       libc_cv_asm_popsection_directive=yes
665     else
666       libc_cv_asm_popsection_directive=no
667     fi
668     rm -f conftest*])
669     if test $libc_cv_asm_popsection_directive = yes; then
670       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
671     fi
672   fi
673 fi
674
675 if test $elf != yes; then
676   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
677                  [AC_TRY_COMPILE(, [asm (".section .init");
678                                     asm (".section .fini");
679                                     asm (".text");],
680                                  libc_cv_have_initfini=yes,
681                                  libc_cv_have_initfini=no)])
682   AC_SUBST(libc_cv_have_initfini)dnl
683   if test $libc_cv_have_initfini = yes; then
684     AC_DEFINE(HAVE_INITFINI)
685   fi
686 fi
687
688 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
689 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
690 [cat > conftest.$ac_ext <<EOF
691 dnl This sometimes fails to find confdefs.h, for some reason.
692 dnl [#]line __oline__ "[$]0"
693 [#]line __oline__ "configure"
694 #include "confdefs.h"
695 void underscore_test(void) {
696 return; }
697 EOF
698 if AC_TRY_EVAL(ac_compile); then
699   if grep _underscore_test conftest* >/dev/null; then
700     ifelse([$1], , :, [rm -f conftest*
701     $1])
702   else
703     ifelse([$2], , , [rm -f conftest*
704     $2])
705   fi
706 else
707   echo "configure: failed program was:" >&AC_FD_CC
708   cat conftest.$ac_ext >&AC_FD_CC
709   ifelse([$2], , , [rm -f conftest*
710   $2])
711 fi
712 rm -f conftest*])
713
714 if test $elf = yes; then
715   libc_cv_asm_underscores=no
716 else
717   if test $ac_cv_prog_cc_works = yes; then
718     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
719                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
720                                 libc_cv_asm_underscores=yes,
721                                 libc_cv_asm_underscores=no)])
722   else
723     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
724                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
725                                             libc_cv_asm_underscores=no)])
726   fi
727 fi
728 if test $libc_cv_asm_underscores = no; then
729   AC_DEFINE(NO_UNDERSCORES)
730 fi
731
732 if test $elf = yes; then
733   libc_cv_weak_symbols=yes
734   libc_cv_asm_weak_directive=yes
735   libc_cv_asm_weakext_directive=no
736 else
737   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
738                  [dnl
739 cat > conftest.s <<EOF
740 .text
741 ${libc_cv_asm_global_directive} foo
742 foo:
743 .weak foo
744 .weak bar; bar = foo
745 EOF
746   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
747     libc_cv_asm_weak_directive=yes
748   else
749     libc_cv_asm_weak_directive=no
750   fi
751   rm -f conftest*])
752
753 if test $libc_cv_asm_weak_directive = no; then
754   AC_CACHE_CHECK(for assembler .weakext directive,
755                  libc_cv_asm_weakext_directive,
756                  [dnl
757 cat > conftest.s <<EOF
758 .text
759 ${libc_cv_asm_global_directive} foo
760 foo:
761 .weakext foo
762 .weakext foo, bar
763 EOF
764   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
765     libc_cv_asm_weakext_directive=yes
766   else
767     libc_cv_asm_weakext_directive=no
768   fi
769   rm -f conftest*])
770
771   fi # no .weak
772 fi # not ELF
773
774 if test $libc_cv_asm_weak_directive = yes; then
775   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
776 elif test $libc_cv_asm_weakext_directive = yes; then
777   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
778 fi
779
780 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
781 cat > conftest.c <<\EOF
782 _start () {}
783 int __eh_pc;
784 __throw () {}
785 EOF
786 dnl No \ in command here because it ends up inside ''.
787 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
788                             -nostdlib -nostartfiles -Wl,--no-whole-archive
789                             -o conftest conftest.c 1>&AC_FD_CC]); then
790   libc_cv_ld_no_whole_archive=yes
791 else
792   libc_cv_ld_no_whole_archive=no
793 fi
794 rm -f conftest*])
795 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
796
797 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
798 cat > conftest.c <<\EOF
799 _start () {}
800 int __eh_pc;
801 __throw () {}
802 EOF
803 dnl No \ in command here because it ends up inside ''.
804 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
805                             -nostdlib -nostartfiles -fno-exceptions
806                             -o conftest conftest.c 1>&AC_FD_CC]); then
807   libc_cv_gcc_no_exceptions=yes
808 else
809   libc_cv_gcc_no_exceptions=no
810 fi
811 rm -f conftest*])
812 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
813
814 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
815 [cat > conftest.c <<EOF
816 #line __oline__ "configure"
817 static char __EH_FRAME_BEGIN__[];
818 _start ()
819 {
820   __register_frame (__EH_FRAME_BEGIN__);
821   __deregister_frame (__EH_FRAME_BEGIN__);
822 }
823 int __eh_pc;
824 __throw () {}
825 /* FIXME: this is fragile.  */
826 malloc () {}
827 strcmp () {}
828 strlen () {}
829 memcpy () {}
830 memset () {}
831 free () {}
832 abort () {}
833 __bzero () {}
834 EOF
835 dnl No \ in command here because it ends up inside ''.
836 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
837                             -nostdlib -nostartfiles
838                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
839   libc_cv_gcc_dwarf2_unwind_info=yes
840 else
841   libc_cv_gcc_dwarf2_unwind_info=no
842 fi
843 rm -f conftest*])
844 if test $libc_cv_gcc_dwarf2_unwind_info = yes; then
845   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
846 fi
847
848 ### End of automated tests.
849 ### Now run sysdeps configure fragments.
850
851 # sysdeps configure fragments may set these with files to be linked below.
852 libc_link_dests=
853 libc_link_sources=
854
855 # Iterate over all the sysdep directories we will use, running their
856 # configure fragments, and looking for a uname implementation.
857 uname=
858 for dir in $sysnames; do
859   case $dir in
860     /*) dest=$dir ;;
861     *)  dest=$srcdir/$dir ;;
862   esac
863   if test -r $dest/configure; then
864     AC_MSG_RESULT(running configure fragment for $dest)
865     . $dest/configure
866   fi
867 [
868   if test -z "$uname"; then
869     if test -r $dest/uname.c ||
870        test -r $dest/uname.S ||
871        { test -r $dest/syscalls.list &&
872          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
873       uname=$dir
874     fi
875   fi
876 ]dnl
877 done
878
879 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
880
881 # If we will use the generic uname implementation, we must figure out what
882 # it will say by examining the system, and write the results in config-name.h.
883 if test "$uname" = "sysdeps/generic"; then
884
885 changequote(,)dnl
886   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
887 changequote([,])dnl
888   if test $uname_sysname != $config_os; then
889     config_release=`echo $config_os | sed s/$uname_sysname//`
890   fi
891 dnl
892 AC_DEFUN(LIBC_KERNEL_ID, [dnl
893     if test -r /vmunix; then
894       kernel_id=`strings /vmunix | grep UNIX`
895     elif test -r /dynix; then
896       kernel_id=`strings /dynix | grep DYNIX`
897     else
898       kernel_id=
899     fi
900 ])dnl
901
902   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
903 AC_REQUIRE([LIBC_KERNEL_ID])dnl
904 changequote(,)dnl
905   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
906 changequote([,])dnl
907   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
908          != x$config_release; then
909     # The configuration release is a substring of the kernel release.
910     libc_cv_uname_release=$kernel_release
911   elif test x$config_release != x; then
912     libc_cv_uname_release=$config_release
913   elif test x$kernel_release != x; then
914     libc_cv_uname_release=$kernel_release
915   else
916     libc_cv_uname_release=unknown
917   fi])
918   uname_release="$libc_cv_uname_release"
919
920   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
921 AC_REQUIRE([LIBC_KERNEL_ID])dnl
922 changequote(,)dnl
923   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
924 changequote([,])dnl
925   if test -n "$kernel_version"; then
926     libc_cv_uname_version="$kernel_version"
927   else
928     libc_cv_uname_version=unknown
929   fi])
930   uname_version="$libc_cv_uname_version"
931
932 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
933   config_uname=config-name.h:config-name.in
934 else
935   # For non-generic uname, we don't need to create config-name.h at all.
936   config_uname=
937 fi
938
939 AC_MSG_CHECKING(stdio selection)
940 AC_SUBST(stdio)
941 case $stdio in
942 libio) AC_DEFINE(USE_IN_LIBIO) ;;
943 default) stdio=stdio ;;
944 esac
945 AC_MSG_RESULT($stdio)
946
947 AC_MSG_CHECKING(ldap selection)
948 AC_SUBST(LDAP)
949 case $add_ons in
950 *ldap*)
951    ldap=yes
952    LDAP=ldap ;;
953 *) ldap=no
954    LDAP= ;;
955 esac
956 AC_MSG_RESULT($ldap)
957
958 AC_SUBST(libc_cv_slibdir)
959 AC_SUBST(libc_cv_sysconfdir)
960 AC_SUBST(libc_cv_rootsbindir)
961
962 AC_SUBST(has_ldconfig)
963
964 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
965 if test $gnu_ld = yes; then
966   AC_DEFINE(HAVE_GNU_LD)
967 fi
968 if test $gnu_as = yes; then
969   AC_DEFINE(HAVE_GNU_AS)
970 fi
971 if test $elf = yes; then
972   AC_DEFINE(HAVE_ELF)
973 fi
974
975 AC_SUBST(static)
976 AC_SUBST(shared)
977 if test $shared = default; then
978   if test $gnu_ld = yes; then
979     shared=$elf
980   else
981     # For now we do not assume shared libs are available.  In future more
982     # tests might become available.
983     shared=no
984   fi
985 fi
986
987 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
988 [pic_default=yes
989 cat > conftest.c <<EOF
990 #if defined(__PIC__) || defined(__pic__) || defined(PIC) || defined(pic)
991 # error PIC is default.
992 #endif
993 EOF
994 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
995   pic_default=no
996 fi
997 rm -f conftest.*])
998 AC_SUBST(pic_default)
999
1000 AC_SUBST(profile)
1001 AC_SUBST(omitfp)
1002 AC_SUBST(bounded)
1003 AC_SUBST(static_nss)
1004 AC_SUBST(nopic_initfini)
1005
1006 AC_SUBST(DEFINES)
1007
1008 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1009   config_makefile=
1010 else
1011   config_makefile=Makefile
1012 fi
1013
1014 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1015 AC_SUBST(VERSION)
1016
1017 if test $libc_cv_gcc_pipe_bug = yes; then
1018  realCC=$CC
1019  CC=$makeCC
1020  CFLAGS=$makeCFLAGS
1021 fi
1022 AC_OUTPUT_COMMANDS([
1023 if test "$realCC"; then
1024  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1025  mv specsT specs
1026 fi], [realCC=$realCC])
1027
1028 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1029           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])