Recognize --with-headers flag and determine commandline options to be used
[kopensolaris-gnu/glibc.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
4 AC_INIT(include/features.h)
5 AC_CONFIG_HEADER(config.h)
6
7 # This will get text that should go into config.make.
8 config_vars=
9
10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
11 AC_ARG_WITH(gmp, dnl
12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
13             [dnl
14 case "$with_gmp" in
15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
16 ''|no) ;;
17 *) config_vars="$config_vars
18 gmp-srcdir = $withval" ;;
19 esac
20 ])
21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
22 AC_ARG_WITH(gettext, dnl
23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
24             [dnl
25 case "$with_gettext" in
26 yes)
27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
28 ''|no) ;;
29 *)
30   config_vars="$config_vars
31 gettext-srcdir = $withval" ;;
32 esac
33 ])
34
35 dnl Arguments to specify presence of other packages/features.
36 AC_ARG_WITH(fp, dnl
37 [  --with-fp              if using floating-point hardware [default=yes]],
38             with_fp=$withval, with_fp=yes)
39 AC_ARG_WITH(binutils, dnl
40   --with-binutils=PATH    specify location of binutils (as and ld),
41             path_binutils=$withval, path_binutils='')
42 AC_ARG_WITH(elf, dnl
43   --with-elf              if using the ELF object format,
44             elf=$withval, elf=no)
45 AC_ARG_WITH(cvs, dnl
46 [  --without-cvs          if CVS should not be used],
47             with_cvs=$withval, with_cvs=yes)
48 AC_SUBST(with_cvs)
49
50 AC_ARG_WITH(headers, dnl
51 [  --with-headers=PATH     location of system headers to use
52                           [e.g. /usr/src/linux/include]
53                           [default=compiler default]],
54             sysheaders=$withval, sysheaders='')
55
56 AC_ARG_ENABLE(libio, dnl
57 [  --enable-libio          build in GNU libio instead of GNU stdio],
58               [if test $enableval = yes; then
59                  stdio=libio
60                else
61                  stdio=stdio
62                fi],
63               stdio=default)
64
65 AC_ARG_ENABLE(sanity-checks, dnl
66 [  --disable-sanity-checks really do not use threads (should not be used
67                           except in special situations) [default=yes]],
68               enable_sanity=$enableval, enable_sanity=yes)
69
70 dnl Arguments to enable or disable building the static, shared, profiled,
71 dnl and -fomit-frame-pointer libraries.
72 AC_ARG_ENABLE(static, dnl
73 [  --enable-static         build static library [default=yes]],
74               static=$enableval, static=yes)
75 AC_ARG_ENABLE(shared, dnl
76 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
77               shared=$enableval, shared=default)
78 AC_ARG_ENABLE(profile, dnl
79 [  --enable-profile        build profiled library [default=yes]],
80               profile=$enableval, profile=yes)
81 AC_ARG_ENABLE(omitfp, dnl
82 [  --enable-omitfp         build undebuggable optimized library [default=no]],
83               omitfp=$enableval, omitfp=no)
84 AC_ARG_ENABLE(bounded, dnl
85 [  --enable-bounded        build with runtime bounds checking [default=no]],
86               bounded=$enableval, bounded=no)
87 AC_ARG_ENABLE(versioning, dnl
88 [  --disable-versioning    do not include versioning information in the
89                           library objects [default=yes if supported]],
90              enable_versioning=$enableval, enable_versioning=yes)
91
92 dnl Generic infrastructure for drop-in additions to libc.
93 AC_ARG_ENABLE(add-ons, dnl
94 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
95                                   search for add-ons if no parameter given],
96   [case "$enableval" in
97     yes) if test "$srcdir" = "."; then
98            add_ons=`echo */configure | sed -e 's!/configure!!g'`
99          else
100            add_ons=`echo $srcdir/*/configure | \
101                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
102          fi;;
103     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
104    esac],
105   [add_ons=])
106
107 AC_CONFIG_SUBDIRS($add_ons)
108 add_ons_pfx=
109 if test x"$add_ons" != x; then
110   for f in $add_ons; do
111     # Test whether such a subdir really exists.
112     if test -d $srcdir/$f; then
113       add_ons_pfx="$add_ons_pfx $f/"
114     else
115       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
116     fi
117   done
118 fi
119
120 dnl On some platforms we cannot use dynamic loading.  We must provide
121 dnl static NSS modules.
122 AC_ARG_ENABLE(static-nss, dnl
123 [  --enable-static-nss     build static NSS modules [default=no]],
124               static_nss=$enableval, static_nss=no)
125 if test x"$static_nss" = xyes; then
126   AC_DEFINE(DO_STATIC_NSS)
127 fi
128
129 AC_CANONICAL_HOST
130
131 # The way shlib-versions is used to generate soversions.mk uses a
132 # fairly simplistic model for name recognition that can't distinguish
133 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
134 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
135 # tell.  This doesn't get used much beyond that, so it's fairly safe.
136 case "$host_os" in
137 linux*)
138   ;;
139 gnu*)
140   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
141   ;;
142 esac
143
144 ###
145 ### I put this here to prevent those annoying emails from people who cannot
146 ### read and try to compile glibc on unsupported platforms.  --drepper
147 ###
148 ### By using the undocumented --enable-hacker-mode option for configure
149 ### one can skip this test to make the configuration not fail for unsupported
150 ### platforms.
151 ###
152 if test -z "$enable_hacker_mode"; then
153   case "$machine-$host_os" in
154   *-linux* | *-gnu* | arm*-none*)
155     ;;
156   *)
157     echo "*** The GNU C library is currently not available for this platform."
158     echo "*** So far nobody cared to port it and if there is no volunteer it"
159     echo "*** might never happen.  So, if you have interest to see glibc on"
160     echo "*** this platform visit"
161     echo "***   http://www.gnu.org/software/libc/porting.html"
162     echo "*** and join the group of porters"
163     exit 1
164     ;;
165   esac
166 fi
167
168 # We keep the original values in `$config_*' and never modify them, so we
169 # can write them unchanged into config.make.  Everything else uses
170 # $machine, $vendor, and $os, and changes them whenever convenient.
171 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
172
173 # Some configurations imply other options.
174 case "$host_os" in
175 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
176   # These systems always use GNU tools.
177   gnu_ld=yes gnu_as=yes ;;
178 esac
179 case "$host_os" in
180 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
181 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
182   ;;
183 gnu* | linux* | sysv4* | solaris2* | irix6*)
184   # These systems (almost) always use the ELF format.
185   elf=yes
186   ;;
187 esac
188
189 machine=$config_machine
190 vendor=$config_vendor
191 os=$config_os
192
193 dnl We need to use [ and ] for other purposes for a while now.
194 changequote(,)dnl
195 # Expand the configuration machine name into a subdirectory by architecture
196 # type and particular chip.
197 case "$machine" in
198 a29k | am29000) base_machine=a29k machine=a29k ;;
199 alpha*)         base_machine=alpha machine=alpha/$machine ;;
200 arm*)           base_machine=arm machine=arm/$machine ;;
201 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
202 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
203 hppa*)          base_machine=hppa machine=hppa/$machine ;;
204 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
205 m680?0)         base_machine=m68k machine=m68k/$machine ;;
206 m68k)           base_machine=m68k machine=m68k/m68020 ;;
207 m88???)         base_machine=m88k machine=m88k/$machine ;;
208 m88k)           base_machine=m88k machine=m88k/m88100 ;;
209 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
210 mips*)          base_machine=mips
211                 case "`uname -m`" in
212                 IP22) machine=mips/mips3 ;;
213                 *)    machine=mips/$machine ,,
214                 esac ;;
215 sparc | sparcv[67])
216                 base_machine=sparc machine=sparc/sparc32 ;;
217 sparcv8 | supersparc | hypersparc)
218                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
219 sparc64 | ultrasparc)
220                 base_machine=sparc machine=sparc/sparc64 ;;
221 esac
222 changequote([,])dnl
223 AC_SUBST(base_machine)
224
225 if test "$base_machine" = "i386"; then
226   AC_DEFINE(USE_REGPARMS)
227 fi
228
229 # Compute the list of sysdep directories for this configuration.
230 # This can take a while to compute.
231 sysdep_dir=$srcdir/sysdeps
232 AC_MSG_CHECKING(sysdep dirs)
233 dnl We need to use [ and ] for other purposes for a while now.
234 changequote(,)dnl
235 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
236 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
237
238 case "$os" in
239 gnu*)
240   base_os=mach/hurd ;;
241 netbsd* | 386bsd* | freebsd* | bsdi*)
242   base_os=unix/bsd/bsd4.4 ;;
243 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
244   base_os=unix/bsd ;;
245 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
246   base_os=unix/sysv ;;
247 irix6*)
248   base_os=unix/sysv/irix6/$os ;;
249 solaris[2-9]*)
250   base_os=unix/sysv/sysv4 ;;
251 none)
252   base_os=standalone ;;
253 *)
254   base_os='' ;;
255 esac
256
257 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
258 tail=$os
259 ostry=$os
260 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
261   ostry="$ostry /$o"
262   tail=$o
263 done
264 o=`echo $tail | sed 's/[0-9]*$//'`
265 if test $o != $tail; then
266   ostry="$ostry /$o"
267 fi
268 # For linux-gnu, try linux-gnu, then linux.
269 o=`echo $tail | sed 's/-.*$//'`
270 if test $o != $tail; then
271   ostry="$ostry /$o"
272 fi
273
274 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
275 base=
276 tail=$base_os
277 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
278   set $b
279   base="$base /$1"
280   tail="$2"
281 done
282
283 # For sparc/sparc9, try sparc/sparc9 and then sparc.
284 mach=
285 tail=$machine
286 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
287   set $m
288   # Prepend the machine's FPU directory unless --without-fp.
289   if test "$with_fp" = yes; then
290     mach="$mach /$1/fpu"
291   fi
292   mach="$mach /$1"
293   tail="$2"
294 done
295
296 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
297 changequote([,])dnl
298
299 # Find what sysdep directories exist.
300 sysnames=
301 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
302 for d in $add_ons_pfx ''; do
303   for b in $base ''; do
304     for m0 in $mach ''; do
305       for v in /$vendor ''; do
306         test "$v" = / && continue
307         for o in /$ostry ''; do
308           test "$o" = / && continue
309           for m in $mach ''; do
310             if test "$m0$b$v$o$m"; then
311               try="${d}sysdeps$m0$b$v$o$m"
312               test -n "$enable_debug_configure" &&
313               echo "$0 [DEBUG]: try $try" >&2
314               case $try in
315                 /*) dest=$try ;;
316                 *)  dest=$srcdir/$try ;;
317               esac
318               if test -d $dest; then
319                 sysnames="$sysnames $try"
320                 { test -n "$o" || test -n "$b"; } && os_used=t
321                 { test -n "$m" || test -n "$m0"; } && machine_used=t
322               fi
323             fi
324           done
325         done
326       done
327     done
328   done
329 done
330 IFS="$ac_save_ifs"
331
332 if test -z "$os_used" && test "$os" != none; then
333   AC_MSG_ERROR(Operating system $os is not supported.)
334 fi
335 if test -z "$machine_used" && test "$machine" != none; then
336   AC_MSG_ERROR(The $machine is not supported.)
337 fi
338
339 # We have now validated the configuration.
340
341
342 # If using ELF, look for an `elf' subdirectory of each machine directory.
343 # We prepend these rather than inserting them whereever the machine appears
344 # because things specified by the machine's ELF ABI should override
345 # OS-specific things, and should always be the same for any OS on the
346 # machine (otherwise what's the point of an ABI?).
347 if test "$elf" = yes; then
348   elf_dirs=
349   for d in $add_ons_pfx ''; do
350     case $d in
351       /*) xsrcdir= ;;
352       *)  xsrcdir=$srcdir/ ;;
353     esac
354     for m in $mach; do
355       if test -d $xsrcdir${d}sysdeps$m/elf; then
356         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
357       fi
358     done
359   done
360   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
361 fi
362
363
364 # Expand the list of system names into a full list of directories
365 # from each element's parent name and Implies file (if present).
366 set $sysnames
367 names=
368 while test $# -gt 0; do
369   name=$1
370   shift
371
372   case " $names " in *" $name "*)
373     # Already in the list.
374     continue
375   esac
376
377   # Report each name as we discover it, so there is no long pause in output.
378   echo $ac_n "$name $ac_c" >&AC_FD_MSG
379
380   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
381
382   case $name in
383     /*) xsrcdir= ;;
384     *)  xsrcdir=$srcdir/ ;;
385   esac
386   test -n "$enable_debug_configure" &&
387   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
388
389   if test -f $xsrcdir$name/Implies; then
390     # Collect more names from the `Implies' file (removing comments).
391     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
392     implied=
393     for x in $implied_candidate; do
394       if test -d $xsrcdir$name_base/$x; then
395         implied="$implied $name_base/$x";
396       else
397         AC_MSG_WARN($name/Implies specifies nonexistent $x)
398       fi
399     done
400   else
401     implied=
402   fi
403
404   # Add NAME to the list of names.
405   names="$names $name"
406
407   # Find the parent of NAME, using the empty string if it has none.
408 changequote(,)dnl
409   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
410 changequote([,])dnl
411
412   # Add the names implied by NAME, and NAME's parent (if it has one), to
413   # the list of names to be processed (the argument list).  We prepend the
414   # implied names to the list and append the parent.  We want implied
415   # directories to come before further directories inferred from the
416   # configuration components; this ensures that for sysv4, unix/common
417   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
418   # after sysv4).
419   sysnames="`echo $implied $* $parent`"
420   test -n "$sysnames" && set $sysnames
421 done
422
423 # Add the default directories.
424 sysnames="$names sysdeps/generic"
425 AC_SUBST(sysnames)
426 # The other names were emitted during the scan.
427 AC_MSG_RESULT(sysdeps/generic)
428
429
430 ### Locate tools.
431
432 AC_PROG_INSTALL
433 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
434   # The makefiles need to use a different form to find it in $srcdir.
435   INSTALL='\$(..)./install-sh -c'
436 fi
437 AC_PROG_LN_S
438
439 # These programs are version sensitive.
440 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
441 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
442   [version \([egcst0-9.-]*\)],
443   [egcs-2.91.*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9.[0-9]*],
444   critic_missing=t)
445 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
446   [version \([0-9][0-9.]*\), by],
447   [3.75 | 3.76.[1-9] | 3.7[789]* | 3.[89]*], critic_missing=t)
448
449 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
450   [GNU gettext.*\([0-9][0-9]*\.[0-9]*\)],
451   [0.[1-9][0-9] | [1-9].*], MSGFMT=: aux_missing=t)
452 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
453   [GNU texinfo \([0-9][0-9.]*\)],
454   [3.1[1-9] | 3.[2-9][0-9]], MAKEINFO=: aux_missing=t)
455
456 if test -n "$critic_missing"; then
457 AC_MSG_ERROR([
458 *** Some critical program is missing or too old.
459 *** Check the INSTALL file for required versions.])
460 fi
461
462 test -n "$aux_missing" && AC_MSG_WARN([
463 *** An auxiliary program is missing or too old;
464 *** some features will be disabled.
465 *** Check the INSTALL file for required versions.])
466
467 AC_PROG_CC_LOCAL
468 AC_CANONICAL_BUILD
469 if test $host != $build; then
470   AC_CHECK_PROGS(BUILD_CC, gcc cc)
471 fi
472 AC_SUBST(cross_compiling)
473 AC_PROG_CPP
474 LIBC_PROG_BINUTILS
475 AC_CHECK_TOOL(AR, ar)
476 AC_CHECK_TOOL(RANLIB, ranlib, :)
477 AC_CHECK_TOOL(MIG, mig)
478
479 # if using special system headers, find out the compiler's sekrit
480 # header directory and add that to the list.  NOTE: Only does the right
481 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
482 if test -n "$sysheaders"; then
483   ccheaders=`$CC -print-file-name=include`
484   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
485 fi
486 AC_SUBST(SYSINCLUDES)
487
488 # check if ar takes S
489 AC_CACHE_CHECK(for ar S, libc_cv_ar_S, [dnl
490 tmpo=$$.o
491 tmplib=lib$$.a
492 rm -f $tmpo $tmplib
493 touch $tmpo
494 if AC_TRY_COMMAND([${AR-ar} rcuS $tmplib $tmpo > /dev/null 2>&1]); then
495   libc_cv_ar_S=yes
496 else
497   libc_cv_ar_S=no
498 fi
499 rm -f $tmpo $tmplib])
500 AC_SUBST(libc_cv_ar_S)dnl
501
502 # Test if LD_LIBRARY_PATH contains the notation for the current directory
503 # since this would lead to problems installing/building glibc.
504 # LD_LIBRARY_PATH contains the current directory if one of the following
505 # is true:
506 # - one of the terminals (":" and ";") is the first or last sign
507 # - two terminals occur directly after each other
508 # - the path contains an element with a dot in it
509 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
510 changequote(,)dnl
511 case ${LD_LIBRARY_PATH} in
512   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
513     ld_library_path_setting="contains current directory"
514     ;;
515   *)
516     ld_library_path_setting="ok"
517     ;;
518 esac
519 changequote([,])dnl
520 AC_MSG_RESULT($ld_library_path_setting)
521 if test "$ld_library_path_setting" != "ok"; then
522 AC_MSG_ERROR([
523 *** LD_LIBRARY_PATH shouldn't contain the current directory when
524 *** building glibc. Please change the environment variable
525 *** and run configure again.])
526 fi
527
528 AC_PATH_PROG(BASH, bash, no)
529 if test "$BASH" != no &&
530    $BASH -c 'test "$BASH_VERSINFO" \
531              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
532   libc_cv_have_bash2=yes
533 else
534   libc_cv_have_bash2=no
535 fi
536 AC_SUBST(libc_cv_have_bash2)
537
538 dnl We need a ksh compatible shell for tzselect.
539 if test "$BASH" = no; then
540   AC_PATH_PROG(KSH, ksh, no)
541   if test "$KSH" = no; then
542     libc_cv_have_ksh=no
543   else
544     libc_cv_have_ksh=yes
545   fi
546 else
547   KSH="$BASH"
548   AC_SUBST(KSH)
549   libc_cv_have_ksh=yes
550 fi
551 AC_SUBST(libc_cv_have_ksh)
552
553 AC_PATH_PROGS(PERL, perl, no)
554 AC_SUBST(PERL)
555
556 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
557 echo '#include <stddef.h>
558 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
559 if eval "$ac_cpp conftest.c 2>/dev/null" \
560 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
561   libc_cv_signed_size_t=no
562 else
563   libc_cv_signed_size_t=yes
564 fi
565 rm -f conftest*])
566 if test $libc_cv_signed_size_t = yes; then
567   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
568   cat >> confdefs.h <<\EOF
569 #undef __SIZE_TYPE__
570 #define __SIZE_TYPE__ unsigned
571 EOF
572 fi
573
574 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
575 AC_TRY_COMPILE(dnl
576 [#define __need_size_t
577 #define __need_wchar_t
578 #include <stddef.h>
579 #define __need_NULL
580 #include <stddef.h>], [size_t size; wchar_t wchar;
581 #ifdef offsetof
582 #error stddef.h ignored __need_*
583 #endif
584 if (&size == NULL || &wchar == NULL) abort ();],
585                libc_cv_friendly_stddef=yes,
586                libc_cv_friendly_stddef=no)])
587 if test $libc_cv_friendly_stddef = yes; then
588   config_vars="$config_vars
589 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
590 fi
591
592 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
593                libc_cv_need_minus_P, [dnl
594 cat > conftest.S <<EOF
595 #include "confdefs.h"
596 /* Nothing whatsoever.  */
597 EOF
598 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
599   libc_cv_need_minus_P=no
600 else
601   libc_cv_need_minus_P=yes
602 fi
603 rm -f conftest*])
604 if test $libc_cv_need_minus_P = yes; then
605   config_vars="$config_vars
606 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
607 fi
608
609 AC_CACHE_CHECK(for assembler global-symbol directive,
610                libc_cv_asm_global_directive, [dnl
611 libc_cv_asm_global_directive=UNKNOWN
612 for ac_globl in .globl .global; do
613   cat > conftest.s <<EOF
614 .text
615 ${ac_globl} foo
616 foo:
617 EOF
618   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
619     libc_cv_asm_global_directive=${ac_globl}
620   fi
621   rm -f conftest*
622   test $libc_cv_asm_global_directive != UNKNOWN && break
623 done])
624 if test $libc_cv_asm_global_directive = UNKNOWN; then
625   AC_MSG_ERROR(cannot determine asm global directive)
626 else
627   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
628 fi
629
630 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
631 cat > conftest.s <<EOF
632 .text
633 foo:
634 .set glibc_conftest_frobozz,foo
635 $libc_cv_asm_global_directive glibc_conftest_frobozz
636 EOF
637 # The alpha-dec-osf1 assembler gives only a warning for `.set'
638 # (but it doesn't work), so we must do a linking check to be sure.
639 cat > conftest1.c <<\EOF
640 extern int glibc_conftest_frobozz;
641 main () { printf ("%d\n", glibc_conftest_frobozz); }
642 EOF
643 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
644             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
645   libc_cv_asm_set_directive=yes
646 else
647   libc_cv_asm_set_directive=no
648 fi
649 rm -f conftest*])
650 if test $libc_cv_asm_set_directive = yes; then
651   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
652 fi
653
654 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
655 [cat > conftest.s <<EOF
656 .text
657 _sym:
658 .symver _sym,sym@VERS
659 EOF
660 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
661   libc_cv_asm_symver_directive=yes
662 else
663   libc_cv_asm_symver_directive=no
664 fi
665 rm -f conftest*])
666 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
667 if test $libc_cv_asm_symver_directive = yes; then
668   cat > conftest.s <<EOF
669 .text
670 _sym:
671 .symver _sym,sym@VERS
672 EOF
673   cat > conftest.map <<EOF
674 VERS_1 {
675         global: sym;
676 };
677
678 VERS_2 {
679         global: sym;
680 } VERS_1;
681 EOF
682   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
683     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
684                                         -nostartfiles -nostdlib
685                                         -Wl,--version-script,conftest.map
686                        1>&AC_FD_CC]);
687     then
688       libc_cv_ld_version_script_option=yes
689     else
690       libc_cv_ld_version_script_option=no
691     fi
692   else
693     libc_cv_ld_version_script_option=no
694   fi
695 else
696   libc_cv_ld_version_script_option=no
697 fi
698 rm -f conftest*])
699 if test $libc_cv_asm_symver_directive = yes &&
700    test $libc_cv_ld_version_script_option = yes &&
701    test $enable_versioning = yes; then
702   VERSIONING=yes
703   AC_DEFINE(DO_VERSIONING)
704 else
705   VERSIONING=no
706 fi
707 AC_SUBST(VERSIONING)
708
709 if test $VERSIONING = no; then
710   echo "\
711 *** WARNING: You should not compile GNU libc without versioning. Not using
712 *** versioning will introduce incompatibilities so that old binaries
713 *** will not run anymore.
714 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
715 fi
716 if test $elf = yes; then
717   AC_CACHE_CHECK(for .previous assembler directive,
718                  libc_cv_asm_previous_directive, [dnl
719   cat > conftest.s <<EOF
720 .section foo_section
721 .previous
722 EOF
723   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
724     libc_cv_asm_previous_directive=yes
725   else
726     libc_cv_asm_previous_directive=no
727   fi
728   rm -f conftest*])
729   if test $libc_cv_asm_previous_directive = yes; then
730     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
731   else
732     AC_CACHE_CHECK(for .popsection assembler directive,
733                    libc_cv_asm_popsection_directive, [dnl
734     cat > conftest.s <<EOF
735 .pushsection foo_section
736 .popsection
737 EOF
738     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
739       libc_cv_asm_popsection_directive=yes
740     else
741       libc_cv_asm_popsection_directive=no
742     fi
743     rm -f conftest*])
744     if test $libc_cv_asm_popsection_directive = yes; then
745       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
746     fi
747   fi
748 fi
749
750 if test $elf != yes; then
751   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
752                  [AC_TRY_COMPILE(, [asm (".section .init");
753                                     asm (".section .fini");
754                                     asm (".text");],
755                                  libc_cv_have_initfini=yes,
756                                  libc_cv_have_initfini=no)])
757   AC_SUBST(libc_cv_have_initfini)dnl
758   if test $libc_cv_have_initfini = yes; then
759     AC_DEFINE(HAVE_INITFINI)
760   fi
761 fi
762
763 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
764 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
765 [cat > conftest.$ac_ext <<EOF
766 dnl This sometimes fails to find confdefs.h, for some reason.
767 dnl [#]line __oline__ "[$]0"
768 [#]line __oline__ "configure"
769 #include "confdefs.h"
770 void underscore_test(void) {
771 return; }
772 EOF
773 if AC_TRY_EVAL(ac_compile); then
774   if grep _underscore_test conftest* >/dev/null; then
775     ifelse([$1], , :, [rm -f conftest*
776     $1])
777   else
778     ifelse([$2], , , [rm -f conftest*
779     $2])
780   fi
781 else
782   echo "configure: failed program was:" >&AC_FD_CC
783   cat conftest.$ac_ext >&AC_FD_CC
784   ifelse([$2], , , [rm -f conftest*
785   $2])
786 fi
787 rm -f conftest*])
788
789 if test $elf = yes; then
790   libc_cv_asm_underscores=no
791 else
792   if test $ac_cv_prog_cc_works = yes; then
793     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
794                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
795                                 libc_cv_asm_underscores=yes,
796                                 libc_cv_asm_underscores=no)])
797   else
798     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
799                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
800                                             libc_cv_asm_underscores=no)])
801   fi
802 fi
803 if test $libc_cv_asm_underscores = no; then
804   AC_DEFINE(NO_UNDERSCORES)
805 fi
806
807 if test $elf = yes; then
808   libc_cv_weak_symbols=yes
809 fi
810
811 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
812                  [dnl
813 cat > conftest.s <<EOF
814 .text
815 ${libc_cv_asm_global_directive} foo
816 foo:
817 .weak foo
818 .weak bar; bar = foo
819 EOF
820 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
821   libc_cv_asm_weak_directive=yes
822 else
823   libc_cv_asm_weak_directive=no
824 fi
825 rm -f conftest*])
826
827 if test $libc_cv_asm_weak_directive = no; then
828   AC_CACHE_CHECK(for assembler .weakext directive,
829                  libc_cv_asm_weakext_directive,
830                  [dnl
831 cat > conftest.s <<EOF
832 .text
833 ${libc_cv_asm_global_directive} foo
834 foo:
835 .weakext bar foo
836 .weakext baz
837 ${libc_cv_asm_global_directive} baz
838 baz:
839 EOF
840   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
841     libc_cv_asm_weakext_directive=yes
842   else
843     libc_cv_asm_weakext_directive=no
844   fi
845   rm -f conftest*])
846
847 fi # no .weak
848
849 if test $libc_cv_asm_weak_directive = yes; then
850   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
851 elif test $libc_cv_asm_weakext_directive = yes; then
852   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
853 fi
854
855 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
856 cat > conftest.c <<\EOF
857 _start () {}
858 int __eh_pc;
859 __throw () {}
860 EOF
861 dnl No \ in command here because it ends up inside ''.
862 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
863                             -nostdlib -nostartfiles -Wl,--no-whole-archive
864                             -o conftest conftest.c 1>&AC_FD_CC]); then
865   libc_cv_ld_no_whole_archive=yes
866 else
867   libc_cv_ld_no_whole_archive=no
868 fi
869 rm -f conftest*])
870 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
871
872 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
873 cat > conftest.c <<\EOF
874 _start () {}
875 int __eh_pc;
876 __throw () {}
877 EOF
878 dnl No \ in command here because it ends up inside ''.
879 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
880                             -nostdlib -nostartfiles -fno-exceptions
881                             -o conftest conftest.c 1>&AC_FD_CC]); then
882   libc_cv_gcc_no_exceptions=yes
883 else
884   libc_cv_gcc_no_exceptions=no
885 fi
886 rm -f conftest*])
887 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
888
889 if test "$base_machine" = alpha ; then
890 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
891 cat > conftest.c <<\EOF
892 foo () { }
893 EOF
894 dnl
895 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
896 then
897   libc_cv_gcc_alpha_ng_prefix=yes
898 else
899   libc_cv_gcc_alpha_ng_prefix=no
900 fi
901 rm -f conftest* ])
902 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
903   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
904 else
905   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
906 fi
907 fi
908
909 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
910 [cat > conftest.c <<EOF
911 #line __oline__ "configure"
912 static char __EH_FRAME_BEGIN__[];
913 _start ()
914 {
915 #ifdef CHECK__register_frame
916   __register_frame (__EH_FRAME_BEGIN__);
917   __deregister_frame (__EH_FRAME_BEGIN__);
918 #endif
919 #ifdef CHECK__register_frame_info
920   __register_frame_info (__EH_FRAME_BEGIN__);
921   __deregister_frame_info (__EH_FRAME_BEGIN__);
922 #endif
923 }
924 int __eh_pc;
925 __throw () {}
926 /* FIXME: this is fragile.  */
927 malloc () {}
928 strcmp () {}
929 strlen () {}
930 memcpy () {}
931 memset () {}
932 free () {}
933 abort () {}
934 __bzero () {}
935 EOF
936 dnl No \ in command here because it ends up inside ''.
937 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
938                             -nostdlib -nostartfiles
939                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
940   libc_cv_gcc_dwarf2_unwind_info=static
941 else
942   libc_cv_gcc_dwarf2_unwind_info=no
943 fi
944 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
945   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
946                               -nostdlib -nostartfiles
947                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
948     libc_cv_gcc_dwarf2_unwind_info=yes
949   else
950     libc_cv_gcc_dwarf2_unwind_info=no
951   fi
952 fi
953 rm -f conftest*])
954 case $libc_cv_gcc_dwarf2_unwind_info in
955 yes)
956   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
957   ;;
958 static)
959   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
960   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
961   ;;
962 esac
963
964 ### End of automated tests.
965 ### Now run sysdeps configure fragments.
966
967 # sysdeps configure fragments may set these with files to be linked below.
968 libc_link_dests=
969 libc_link_sources=
970
971 # They also can set these variables.
972 ldd_rewrite_script=no
973
974 # Iterate over all the sysdep directories we will use, running their
975 # configure fragments, and looking for a uname implementation.
976 uname=
977 for dir in $sysnames; do
978   case $dir in
979     /*) dest=$dir ;;
980     *)  dest=$srcdir/$dir ;;
981   esac
982   if test -r $dest/configure; then
983     AC_MSG_RESULT(running configure fragment for $dest)
984     . $dest/configure
985   fi
986 [
987   if test -z "$uname"; then
988     if test -r $dest/uname.c ||
989        test -r $dest/uname.S ||
990        { test -r $dest/syscalls.list &&
991          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
992       uname=$dir
993     fi
994   fi
995 ]dnl
996 done
997
998 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
999
1000 # If we will use the generic uname implementation, we must figure out what
1001 # it will say by examining the system, and write the results in config-name.h.
1002 if test "$uname" = "sysdeps/generic"; then
1003
1004 changequote(,)dnl
1005   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1006 changequote([,])dnl
1007   if test $uname_sysname != $config_os; then
1008     config_release=`echo $config_os | sed s/$uname_sysname//`
1009   fi
1010 dnl
1011 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1012     if test -r /vmunix; then
1013       kernel_id=`strings /vmunix | grep UNIX`
1014     elif test -r /dynix; then
1015       kernel_id=`strings /dynix | grep DYNIX`
1016     else
1017       kernel_id=
1018     fi
1019 ])dnl
1020
1021   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1022 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1023 changequote(,)dnl
1024   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1025 changequote([,])dnl
1026   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1027          != x$config_release; then
1028     # The configuration release is a substring of the kernel release.
1029     libc_cv_uname_release=$kernel_release
1030   elif test x$config_release != x; then
1031     libc_cv_uname_release=$config_release
1032   elif test x$kernel_release != x; then
1033     libc_cv_uname_release=$kernel_release
1034   else
1035     libc_cv_uname_release=unknown
1036   fi])
1037   uname_release="$libc_cv_uname_release"
1038
1039   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1040 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1041 changequote(,)dnl
1042   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1043 changequote([,])dnl
1044   if test -n "$kernel_version"; then
1045     libc_cv_uname_version="$kernel_version"
1046   else
1047     libc_cv_uname_version=unknown
1048   fi])
1049   uname_version="$libc_cv_uname_version"
1050
1051 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1052   config_uname=config-name.h:config-name.in
1053 else
1054   # For non-generic uname, we don't need to create config-name.h at all.
1055   config_uname=
1056 fi
1057
1058 AC_MSG_CHECKING(stdio selection)
1059 AC_SUBST(stdio)
1060 case $stdio in
1061 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1062 default) stdio=stdio ;;
1063 esac
1064 AC_MSG_RESULT($stdio)
1065
1066 AC_MSG_CHECKING(ldap selection)
1067 AC_SUBST(LDAP)
1068 case $add_ons in
1069 *ldap*)
1070    ldap=yes
1071    LDAP=ldap ;;
1072 *) ldap=no
1073    LDAP= ;;
1074 esac
1075 AC_MSG_RESULT($ldap)
1076
1077 AC_SUBST(libc_cv_slibdir)
1078 AC_SUBST(libc_cv_sysconfdir)
1079 AC_SUBST(libc_cv_rootsbindir)
1080
1081 AC_SUBST(has_ldconfig)
1082 AC_SUBST(ldd_rewrite_script)
1083
1084 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1085 if test $gnu_ld = yes; then
1086   AC_DEFINE(HAVE_GNU_LD)
1087 fi
1088 if test $gnu_as = yes; then
1089   AC_DEFINE(HAVE_GNU_AS)
1090 fi
1091 if test $elf = yes; then
1092   AC_DEFINE(HAVE_ELF)
1093 fi
1094
1095 AC_SUBST(static)
1096 AC_SUBST(shared)
1097 if test $shared = default; then
1098   if test $gnu_ld = yes; then
1099     shared=$elf
1100   else
1101     # For now we do not assume shared libs are available.  In future more
1102     # tests might become available.
1103     shared=no
1104   fi
1105 fi
1106
1107 dnl We must not allow compilation without static library on some platforms.
1108 if test $static = no && test $shared = yes; then
1109   case "$host_os" in
1110   linux* | gnu*)
1111     AC_MSG_ERROR([
1112 *** You must compile with support for the static library since the shared
1113 *** library uses it.  Restart configure without \`--disable-static'.])
1114     ;;
1115   *)
1116     ;;
1117   esac
1118 fi
1119
1120 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1121 [pic_default=yes
1122 cat > conftest.c <<EOF
1123 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1124 # error PIC is default.
1125 #endif
1126 EOF
1127 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1128   pic_default=no
1129 fi
1130 rm -f conftest.*])
1131 AC_SUBST(pic_default)
1132
1133 AC_SUBST(profile)
1134 AC_SUBST(omitfp)
1135 AC_SUBST(bounded)
1136 AC_SUBST(static_nss)
1137 AC_SUBST(nopic_initfini)
1138
1139 AC_SUBST(DEFINES)
1140
1141 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1142   config_makefile=
1143 else
1144   config_makefile=Makefile
1145 fi
1146
1147 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1148 AC_SUBST(VERSION)
1149
1150 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1151           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])