(_nl_find_language.c): Mark as static.
[kopensolaris-gnu/glibc.git] / intl / po2test.sed
1 # po2test.sed - Convert Uniforum style .po file to C code for testing.
2 # Copyright (C) 2000 Free Software Foundation, Inc.
3 # Ulrich Drepper <drepper@cygnus.com>, 2000.
4 #
5 # This program is free software; you can redistribute it and/or modify
6 # it under the terms of the GNU General Public License as published by
7 # the Free Software Foundation; either version 2, or (at your option)
8 # any later version.
9 #
10 # This program is distributed in the hope that it will be useful,
11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 # GNU General Public License for more details.
14 #
15 # You should have received a copy of the GNU General Public License
16 # along with this program; if not, write to the Free Software
17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
18 #
19 #
20 # We copy the original message as a comment into the .msg file.  But enclose
21 # them with INPUT ( ).
22 #
23 /^msgid/ {
24   s/msgid[      ]*"\(.*\)"/INPUT ("\1")/
25 # Clear flag from last substitution.
26   tb
27 # Append the next line.
28   :b
29   N
30 # Look whether second part is a continuation line.
31   s/\(.*\)")\(\n\)"\(.*\)"/\1\\\2\3")/
32 # Yes, then branch.
33   ta
34   P
35   D
36 # Note that `D' includes a jump to the start!!
37 # We found a continuation line.  But before printing insert '\'.
38   :a
39   s/\(.*\)")\(\n.*\)/\1\\\2/
40   P
41 # We cannot use the sed command `D' here
42   s/.*\n\(.*\)/\1/
43   tb
44 }
45 #
46 # Copy the translations as well and enclose them with OUTPUT ( ).
47 #
48 /^msgstr/ {
49   s/msgstr[     ]*"\(.*\)"/OUTPUT ("\1")/
50 # Clear flag from last substitution.
51   tb
52 # Append the next line.
53   :b
54   N
55 # Look whether second part is a continuation line.
56   s/\(.*\)")\(\n\)"\(.*\)"/\1\\\2\3")/
57 # Yes, then branch.
58   ta
59   P
60   D
61 # Note that `D' includes a jump to the start!!
62 # We found a continuation line.  But before printing insert '\'.
63   :a
64   s/\(.*\)")\(\n.*\)/\1\\\2/
65   P
66 # We cannot use the sed command `D' here
67   s/.*\n\(.*\)/\1/
68   tb
69 }
70 d