Add more symbols.
[kopensolaris-gnu/glibc.git] / libc.map
1 GLIBC_2.0 {
2   global:
3     # global variables
4     _errno; _itoa_lower_digits; _itoa_upper_digits;
5     __ctype_b; __ctype_tolower; __ctype_toupper;
6     _IO_stderr_; _IO_stdin_; _IO_stdout_;
7     _nl_msg_cat_cntr; __environ; _environ; _res;
8     ___brk_addr; __curbrk; _nl_current_LC_CTYPE; _libc_intl_domainname;
9     _sys_errlist; _sys_siglist; __progname; _nl_default_dirname;
10     __timezone; __daylight; __tzname;
11     _nl_current_LC_COLLATE; __collate_element_hash;
12     __collate_element_strings; __collate_symbol_classes;
13     __collate_symbol_hash; __collate_symbol_strings;
14     _obstack;
15
16     # helper functions
17     __errno_location; __libc_init_first; __h_errno_location;
18
19     # functions with special/multiple interfaces
20     __sigsetjmp; _setjmp; __sigaddset; __sigdelset; __sigismember;
21     __sysv_signal; __bsd_getpgrp; _longjmp;
22
23     # functions which have an additional interface since they are
24     # are cancelable.
25     __libc_wait; __libc_waitpid; __libc_pause; __libc_nanosleep;
26     __libc_open; __libc_close; __libc_read; __libc_write;
27     __libc_lseek; __libc_fcntl; __libc_tcdrain; __libc_fsync;
28     __libc_msync; __libc_system;
29
30     # interface of malloc functions
31     __libc_calloc; __libc_free; __libc_mallinfo; __libc_malloc;
32     __libc_mallopt; __libc_memalign; __libc_pvalloc; __libc_realloc;
33     __libc_valloc;
34     __malloc_initialize_hook; __free_hook; __malloc_hook; __realloc_hook;
35     __memalign_hook; __after_morecore_hook;
36     __malloc_initialized; __default_morecore; __morecore;
37
38     # functions with required interface outside normal name space
39     _exit; __ivaliduser; __open_catalog;
40     __argz_count; __argz_stringify; __argz_next;
41     __check_rhosts_file; __rcmd_errstr;
42
43     # functions from the experimental locale implementation
44     __*_l; __newlocale; __duplocale; __freelocale;
45
46     # functions used in inline functions or macros
47     __strto*_internal; __wcsto*_internal; __getdelim;
48     __isnan; __isnanf; __isnanl; __finite; __finitef; __finitel;
49     __isinf; __isinff; __isinfl;
50     __signbit; __signbitf; __signbitl; __cmsg_nxthdr;
51     _obstack_allocated_p; _obstack_begin; _obstack_begin_1;
52     _obstack_free; _obstack_memory_used; _obstack_newchunk;
53     __assert_fail; __assert_perror_fail;
54     _IO_getc; _IO_peekc_unlocked; _IO_putc; _IO_feof; _IO_ferror;
55     __xstat; __fxstat; __lxstat; __xmknod; __dcgettext;
56     __uflow; __underflow; __overflow; __iswctype; __sigpause;
57     __ctype_get_mb_cur_max;
58
59     # functions used in other libraries
60     __printf_fp; __stpncpy;
61     _nss_files_parse_grent; _nss_files_parse_pwent; _nss_files_parse_spent;
62     __nss_database_lookup; __internal_endnetgrent; __internal_getnetgrent_r;
63     __internal_setnetgrent; __gmtime_r; __secure_getenv;
64     __select; __sched_get_priority_max; __sched_get_priority_min;
65     __sched_getparam; __sched_getscheduler; __sched_setscheduler;
66     __sched_yield; __on_exit; __gettimeofday; __fork; __clone;
67     __nss_configure_lookup; _dl_open; _dl_close; _IO_file_setbuf;
68     _IO_file_init; _IO_file_attach; _IO_do_write; _IO_seekoff;
69     _IO_link_in; _IO_file_open; _IO_file_doallocate; _IO_file_fopen;
70     _IO_file_overflow; _IO_file_underflow; _IO_file_sync; _IO_file_seekoff;
71     _IO_file_close_it; _IO_file_read; _IO_file_seek; _IO_file_write;
72     _IO_file_stat; _IO_file_close; _IO_file_xsputn; _IO_sgetn;
73     _IO_seekpos; _IO_padn; _IO_getline; _IO_vfprintf;
74     _IO_proc_open; _IO_proc_close; _IO_vfscanf; _IO_free_backup_area;
75     _IO_un_link; _IO_switch_to_get_mode; _IO_default_uflow;
76     _IO_default_xsputn; _IO_default_xsgetn; _IO_default_pbackfail;
77     _IO_setb; _IO_default_doallocate; _IO_doallocbuf; _IO_init;
78     _IO_default_finish; _IO_sputbackc; _IO_sungetc; _IO_adjust_column;
79     _IO_flush_all; _IO_flush_all_linebuffered; _IO_init_marker;
80     _IO_remove_marker; _IO_marker_difference; _IO_marker_delta;
81     _IO_seekmark; _IO_unsave_markers; _IO_str_overflow;
82     _IO_str_underflow; _IO_str_init_static; _IO_str_init_readonly;
83     _IO_str_seekoff; _IO_str_pbackfail; _IO_list_all; _IO_file_jumps;
84     _IO_peekc_locked;
85     _rpc_dtablesize; _null_auth; _seterr_reply;
86
87     # all functions and variables in the normal name space
88     a*; b*; c*; d*; e*; f*; g*; h*; i*; j*; k*; l*; m*;
89     n*; o*; p*; q*; r*; s*; t*; u*; v*; w*; x*; y*; z*;
90
91   local:
92     *;
93 };