2f1edd81681bc7b575149b5ff77d51641ee4fcb6
[kopensolaris-gnu/glibc.git] / manual / summary.awk
1 # awk script to create summary.out from the library texinfo files.
2
3 # Copyright (C) 1992 Free Software Foundation, Inc.
4 # This file is part of the GNU C Library.
5
6 # The GNU C Library is free software; you can redistribute it and/or
7 # modify it under the terms of the GNU Library General Public License
8 # as published by the Free Software Foundation; either version 2 of
9 # the License, or (at your option) any later version.
10
11 # The GNU C Library is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 # Library General Public License for more details.
15
16 # You should have received a copy of the GNU Library General Public
17 # License along with the GNU C Library; see the file COPYING.LIB.  If
18 # not, write to the Free Software Foundation, Inc., 675 Mass Ave,
19 # Cambridge, MA 02139, USA.
20
21 BEGIN { header = 0;
22 nameword["@defun"]=1
23 nameword["@defmac"]=1
24 nameword["@defspec"]=1
25 nameword["@defvar"]=1
26 nameword["@defopt"]=1
27 nameword["@deffn"]=2
28 nameword["@defvr"]=2
29 nameword["@deftp"]=2
30 nameword["@deftypefun"]=2
31 nameword["@deftypevar"]=2
32 nameword["@deftypefn"]=3
33 nameword["@deftypevr"]=3
34 firstword["@defun"]=1
35 firstword["@defmac"]=1
36 firstword["@defspec"]=1
37 firstword["@defvar"]=1
38 firstword["@defopt"]=1
39 firstword["@deffn"]=2
40 firstword["@defvr"]=2
41 firstword["@deftp"]=2
42 firstword["@deftypefun"]=1
43 firstword["@deftypevar"]=1
44 firstword["@deftypefn"]=2
45 firstword["@deftypevr"]=2
46 nameword["@item"]=1
47 firstword["@item"]=1
48 nameword["@itemx"]=1
49 firstword["@itemx"]=1
50 nameword["@vindex"]=1
51 firstword["@vindex"]=1
52 }
53
54 $1 == "@node" { node=$2;
55                 for (i = 3; i <= NF; ++i)
56                  { node=node " " $i; if ( $i ~ /,/ ) break; }
57               } 
58
59 $1 == "@comment" && $2 ~ /\.h$/ { header="@file{" $2 "}";
60                                   for (i = 3; i <= NF; ++i)
61                                     header=header ", @file{" $i "}"
62                                 }
63
64 $1 == "@comment" && header != 0 { std=$2;
65                                   for (i=3;i<=NF;++i) std=std " " $i }
66
67 header != 0 && $1 ~ /@def|@item|@vindex/ \
68         { defn=""; name=""; curly=0; n=1;
69           for (i = 2; i <= NF; ++i) {
70             if ($i ~ /^{/ && $i !~ /}/) {
71               curly=1
72               word=substr ($i, 2, length ($i))
73             }
74             else {
75               if (curly) {
76                 if ($i ~ /}$/) {
77                   curly=0
78                   word=word " " substr ($i, 1, length ($i) - 1)
79                 } else
80                   word=word " " $i
81               }
82               else
83                 word=$i
84               if (!curly) {
85                 if (n >= firstword[$1])
86                   defn=defn " " word
87                 if (n == nameword[$1])
88                   name=word
89                 ++n
90               }
91             }
92           }
93           printf "@comment %s%c", name, 012 # FF
94           printf "@item%s%c", defn, 012
95           printf "%s (%s):  @ref{%s}.%c\n", header, std, node, 012;
96           header = 0 }