nptl/sysdeps/unix/sysv/linux/i386/i486/pthread_barrier_wait.S

   1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22 #define SYS_futex       240
  23 #define FUTEX_WAIT      0
  24 #define FUTEX_WAKE      1
  25
  26 #ifndef UP
  27 # define LOCK lock
  28 #else
  29 # define LOCK
  30 #endif
  31
  32 #define CURR_EVENT      0
  33 #define MUTEX           4
  34 #define LEFT            8
  35 #define INIT_COUNT      12
  36
  37
  38         .text
  39
  40         .globl  pthread_barrier_wait
  41         .type   pthread_barrier_wait,@function
  42         .align  16
  43 pthread_barrier_wait:
  44         pushl   %esi
  45         pushl   %ebx
  46
  47         movl    12(%esp), %ebx
  48         xorl    %esi, %esi
  49
  50         /* Get the mutex.  */
  51         orl     $-1, %eax
  52         LOCK
  53         xaddl   %eax, MUTEX(%ebx)
  54         jne     1f
  55
  56         /* One less waiter.  If this was the last one needed wake
  57            everybody.  */
  58 2:      decl    LEFT(%ebx)
  59         je      3f
  60
  61         /* There are more threads to come.  */
  62 #if CURR_EVENT == 0
  63         movl    (%ebx), %edx
  64 #else
  65         movl    CURR_EVENT(%ebx), %edx
  66 #endif
  67
  68         /* Release the mutex.  */
  69         LOCK
  70         incl    MUTEX(%ebx)
  71         jng     6f
  72
  73         /* Wait for the remaining threads.  The call will return immediately
  74            if the CURR_EVENT memory has meanwhile been changed.  */
  75 7:      movl    %esi, %ecx              /* movl $FUTEX_WAIT, %ecx */
  76 8:      movl    $SYS_futex, %eax
  77         ENTER_KERNEL
  78
  79         /* Don't return on spurious wakeups.  The syscall does not change
  80            any register except %eax so there is no need to reload any of
  81            them.  */
  82 #if CURR_EVENT == 0
  83         cmpl    %edx, (%ebx)
  84 #else
  85         cmpl    %edx, CURR_EVENT(%ebx)
  86 #endif
  87         je,pn   8b
  88
  89         /* Note: %esi is still zero.  */
  90         movl    %esi, %eax              /* != PTHREAD_BARRIER_SERIAL_THREAD */
  91
  92         popl    %ebx
  93         popl    %esi
  94         ret
  95
  96         /* The necessary number of threads arrived.  */
  97 3:      movl    INIT_COUNT(%ebx), %eax
  98         movl    %eax, LEFT(%ebx)
  99 #if CURR_EVENT == 0
 100         incl    (%ebx)
 101 #else
 102         incl    CURR_EVENT(%ebx)
 103 #endif
 104
 105         /* Wake up all waiters.  The count is a signed number in the kernel
 106            so 0x7fffffff is the highest value.  */
 107         movl    $0x7fffffff, %edx
 108         movl    $FUTEX_WAKE, %ecx
 109         movl    $SYS_futex, %eax
 110         ENTER_KERNEL
 111
 112         /* Release the mutex.  */
 113         LOCK
 114         incl    MUTEX(%ebx)
 115         jng     4f
 116
 117 5:      orl     $-1, %eax               /* == PTHREAD_BARRIER_SERIAL_THREAD */
 118
 119         popl    %ebx
 120         popl    %esi
 121         ret
 122
 123 1:      leal    MUTEX(%ebx), %ecx
 124         call    __lll_lock_wait
 125         jmp     2b
 126
 127 4:      leal    MUTEX(%ebx), %eax
 128         call    __lll_unlock_wake
 129         jmp     5b
 130
 131 6:      leal    MUTEX(%ebx), %eax
 132         call    __lll_unlock_wake
 133         jmp     7b
 134         .size   pthread_barrier_wait,.-pthread_barrier_wait