Adjust for new mutex implementation.
[kopensolaris-gnu/glibc.git] / nptl / sysdeps / unix / sysv / linux / i386 / i486 / pthread_barrier_wait.S
1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21 #include <lowlevelbarrier.h>
22
23 #define SYS_futex       240
24 #define FUTEX_WAIT      0
25 #define FUTEX_WAKE      1
26
27 #ifndef UP
28 # define LOCK lock
29 #else
30 # define LOCK
31 #endif
32
33
34         .text
35
36         .globl  pthread_barrier_wait
37         .type   pthread_barrier_wait,@function
38         .align  16
39 pthread_barrier_wait:
40         pushl   %ebx
41
42         movl    8(%esp), %ebx
43
44         /* Get the mutex.  */
45         movl    $1, %edx
46         xorl    %eax, %eax
47         LOCK
48         cmpxchgl %edx, MUTEX(%ebx)
49         testl   %eax, %eax
50         jne     1f
51
52         /* One less waiter.  If this was the last one needed wake
53            everybody.  */
54 2:      subl    $1, LEFT(%ebx)
55         je      3f
56
57         /* There are more threads to come.  */
58         pushl   %esi
59
60 #if CURR_EVENT == 0
61         movl    (%ebx), %edx
62 #else
63         movl    CURR_EVENT(%ebx), %edx
64 #endif
65
66         /* Release the mutex.  */
67         LOCK
68         subl    $1, MUTEX(%ebx)
69         jne     6f
70
71         /* Wait for the remaining threads.  The call will return immediately
72            if the CURR_EVENT memory has meanwhile been changed.  */
73 7:      xorl    %ecx, %ecx              /* movl $FUTEX_WAIT, %ecx */
74         xorl    %esi, %esi
75 8:      movl    $SYS_futex, %eax
76         ENTER_KERNEL
77
78         /* Don't return on spurious wakeups.  The syscall does not change
79            any register except %eax so there is no need to reload any of
80            them.  */
81 #if CURR_EVENT == 0
82         cmpl    %edx, (%ebx)
83 #else
84         cmpl    %edx, CURR_EVENT(%ebx)
85 #endif
86         je,pn   8b
87
88         /* Note: %esi is still zero.  */
89         movl    %esi, %eax              /* != PTHREAD_BARRIER_SERIAL_THREAD */
90
91         popl    %esi
92         popl    %ebx
93         ret
94
95         /* The necessary number of threads arrived.  */
96 3:      movl    INIT_COUNT(%ebx), %eax
97         movl    %eax, LEFT(%ebx)
98 #if CURR_EVENT == 0
99         addl    $1, (%ebx)
100 #else
101         addl    $1, CURR_EVENT(%ebx)
102 #endif
103
104         /* Wake up all waiters.  The count is a signed number in the kernel
105            so 0x7fffffff is the highest value.  */
106         movl    $0x7fffffff, %edx
107         movl    $FUTEX_WAKE, %ecx
108         movl    $SYS_futex, %eax
109         ENTER_KERNEL
110
111         /* Release the mutex.  We cannot release the lock before
112            waking the waiting threads since otherwise a new thread might
113            arrive and gets waken up, too.  */
114         LOCK
115         subl    $1, MUTEX(%ebx)
116         jne     4f
117
118 5:      orl     $-1, %eax               /* == PTHREAD_BARRIER_SERIAL_THREAD */
119
120         popl    %ebx
121         ret
122
123 1:      leal    MUTEX(%ebx), %ecx
124         call    __lll_mutex_lock_wait
125         jmp     2b
126
127 4:      leal    MUTEX(%ebx), %eax
128         call    __lll_mutex_unlock_wake
129         jmp     5b
130
131 6:      leal    MUTEX(%ebx), %eax
132         call    __lll_mutex_unlock_wake
133         jmp     7b
134         .size   pthread_barrier_wait,.-pthread_barrier_wait