Drop completely useless test instructions.
[kopensolaris-gnu/glibc.git] / nptl / sysdeps / unix / sysv / linux / i386 / i486 / pthread_barrier_wait.S
1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21 #include <lowlevelbarrier.h>
22
23 #define SYS_futex       240
24 #define FUTEX_WAIT      0
25 #define FUTEX_WAKE      1
26
27 #ifndef UP
28 # define LOCK lock
29 #else
30 # define LOCK
31 #endif
32
33
34         .text
35
36         .globl  pthread_barrier_wait
37         .type   pthread_barrier_wait,@function
38         .align  16
39 pthread_barrier_wait:
40         pushl   %ebx
41
42         movl    8(%esp), %ebx
43
44         /* Get the mutex.  */
45         movl    $1, %edx
46         xorl    %eax, %eax
47         LOCK
48         cmpxchgl %edx, MUTEX(%ebx)
49         jnz     1f
50
51         /* One less waiter.  If this was the last one needed wake
52            everybody.  */
53 2:      subl    $1, LEFT(%ebx)
54         je      3f
55
56         /* There are more threads to come.  */
57         pushl   %esi
58
59 #if CURR_EVENT == 0
60         movl    (%ebx), %edx
61 #else
62         movl    CURR_EVENT(%ebx), %edx
63 #endif
64
65         /* Release the mutex.  */
66         LOCK
67         subl    $1, MUTEX(%ebx)
68         jne     6f
69
70         /* Wait for the remaining threads.  The call will return immediately
71            if the CURR_EVENT memory has meanwhile been changed.  */
72 7:      xorl    %ecx, %ecx              /* movl $FUTEX_WAIT, %ecx */
73         xorl    %esi, %esi
74 8:      movl    $SYS_futex, %eax
75         ENTER_KERNEL
76
77         /* Don't return on spurious wakeups.  The syscall does not change
78            any register except %eax so there is no need to reload any of
79            them.  */
80 #if CURR_EVENT == 0
81         cmpl    %edx, (%ebx)
82 #else
83         cmpl    %edx, CURR_EVENT(%ebx)
84 #endif
85         je,pn   8b
86
87         /* Note: %esi is still zero.  */
88         movl    %esi, %eax              /* != PTHREAD_BARRIER_SERIAL_THREAD */
89
90         popl    %esi
91         popl    %ebx
92         ret
93
94         /* The necessary number of threads arrived.  */
95 3:      movl    INIT_COUNT(%ebx), %eax
96         movl    %eax, LEFT(%ebx)
97 #if CURR_EVENT == 0
98         addl    $1, (%ebx)
99 #else
100         addl    $1, CURR_EVENT(%ebx)
101 #endif
102
103         /* Wake up all waiters.  The count is a signed number in the kernel
104            so 0x7fffffff is the highest value.  */
105         movl    $0x7fffffff, %edx
106         movl    $FUTEX_WAKE, %ecx
107         movl    $SYS_futex, %eax
108         ENTER_KERNEL
109
110         /* Release the mutex.  We cannot release the lock before
111            waking the waiting threads since otherwise a new thread might
112            arrive and gets waken up, too.  */
113         LOCK
114         subl    $1, MUTEX(%ebx)
115         jne     4f
116
117 5:      orl     $-1, %eax               /* == PTHREAD_BARRIER_SERIAL_THREAD */
118
119         popl    %ebx
120         ret
121
122 1:      leal    MUTEX(%ebx), %ecx
123         call    __lll_mutex_lock_wait
124         jmp     2b
125
126 4:      leal    MUTEX(%ebx), %eax
127         call    __lll_mutex_unlock_wake
128         jmp     5b
129
130 6:      leal    MUTEX(%ebx), %eax
131         call    __lll_mutex_unlock_wake
132         jmp     7b
133         .size   pthread_barrier_wait,.-pthread_barrier_wait