nptl/sysdeps/unix/sysv/linux/i386/i486/pthread_rwlock_timedrdlock.S

   1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <lowlevelrwlock.h>
  22
  23
  24 #define SYS_gettimeofday        __NR_gettimeofday
  25 #define SYS_futex               240
  26 #define FUTEX_WAIT              0
  27 #define FUTEX_WAKE              1
  28
  29 #define EAGAIN          11
  30 #define EINVAL          22
  31 #define EDEADLK         35
  32 #define ETIMEDOUT       110
  33
  34 #ifndef UP
  35 # define LOCK lock
  36 #else
  37 # define LOCK
  38 #endif
  39
  40
  41         .text
  42
  43         .globl  pthread_rwlock_timedrdlock
  44         .type   pthread_rwlock_timedrdlock,@function
  45         .align  16
  46 pthread_rwlock_timedrdlock:
  47         pushl   %esi
  48         pushl   %edi
  49         pushl   %ebx
  50         pushl   %ebp
  51         subl    $8, %esp
  52
  53         movl    28(%esp), %ebp
  54         movl    32(%esp), %edi
  55
  56         /* Get the lock.  */
  57         movl    $1, %eax
  58         LOCK
  59 #if MUTEX == 0
  60         xaddl   %eax, (%ebp)
  61 #else
  62         xaddl   %eax, MUTEX(%ebp)
  63 #endif
  64         testl   %eax, %eax
  65         jne     1f
  66
  67 2:      movl    WRITER(%ebp), %eax
  68         testl   %eax, %eax
  69         jne     14f
  70         cmp     $0, WRITERS_QUEUED(%ebp)
  71         je      5f
  72         cmpl    $0, FLAGS(%ebp)
  73         je      5f
  74
  75         /* Check the value of the timeout parameter.  */
  76 3:      cmpl    $1000000000, 4(%edi)
  77         jae     19f
  78
  79         incl    READERS_QUEUED(%ebp)
  80         je      4f
  81
  82         LOCK
  83 #if MUTEX == 0
  84         decl    (%ebp)
  85 #else
  86         decl    MUTEX(%ebp)
  87 #endif
  88         jne     10f
  89
  90         /* Get current time.  */
  91 11:     movl    %esp, %ebx
  92         xorl    %ecx, %ecx
  93         movl    $SYS_gettimeofday, %eax
  94         ENTER_KERNEL
  95
  96         /* Compute relative timeout.  */
  97         movl    4(%esp), %eax
  98         movl    $1000, %edx
  99         mul     %edx            /* Milli seconds to nano seconds.  */
 100         movl    (%edi), %ecx
 101         movl    4(%edi), %edx
 102         subl    (%esp), %ecx
 103         subl    %eax, %edx
 104         jns     15f
 105         addl    $1000000000, %edx
 106         decl    %ecx
 107 15:     testl   %ecx, %ecx
 108         js      16f             /* Time is already up.  */
 109
 110         /* Futex call.  */
 111         movl    %ecx, (%esp)    /* Store relative timeout.  */
 112         movl    %edx, 4(%esp)
 113         xorl    %ecx, %ecx      /* movl $FUTEX_WAIT, %ecx */
 114         movl    %esp, %esi
 115         movl    %ecx, %edx
 116         leal    READERS_WAKEUP(%ebp), %ebx
 117         movl    $SYS_futex, %eax
 118         ENTER_KERNEL
 119         movl    %eax, %edx
 120 17:
 121
 122         /* Reget the lock.  */
 123         movl    $1, %eax
 124         LOCK
 125 #if MUTEX == 0
 126         xaddl   %eax, (%ebp)
 127 #else
 128         xaddl   %eax, MUTEX(%ebp)
 129 #endif
 130         testl   %eax, %eax
 131         jne     12f
 132
 133 13:     cmpl    $-ETIMEDOUT, %ecx
 134         je      18f
 135         decl    READERS_QUEUED(%ebp)
 136         jne     2b
 137         movl    $0, READERS_WAKEUP(%ebp)
 138         jmp     2b
 139
 140
 141 5:      xorl    %ecx, %ecx
 142         incl    NR_READERS(%ebp)
 143         je      8f
 144 9:      LOCK
 145 #if MUTEX == 0
 146         decl    (%ebp)
 147 #else
 148         decl    MUTEX(%ebp)
 149 #endif
 150         jne     6f
 151
 152 7:      movl    %ecx, %eax
 153
 154         addl    $8, %esp
 155         popl    %ebp
 156         popl    %ebx
 157         popl    %edi
 158         popl    %esi
 159         ret
 160
 161 1:      movl    %ebp, %ecx
 162         call    __lll_mutex_lock_wait
 163         jmp     2b
 164
 165 14:     cmpl    %gs:8, %eax
 166         jne     3b
 167         movl    $EDEADLK, %ecx
 168         jmp     9b
 169
 170 6:      movl    %ebp, %eax
 171         call    __lll_mutex_unlock_wake
 172         jmp     7b
 173
 174         /* Overflow.  */
 175 8:      decl    NR_READERS(%ebp)
 176         movl    $EAGAIN, %ecx
 177         jmp     9b
 178
 179         /* Overflow.  */
 180 4:      decl    READERS_QUEUED(%ebp)
 181         movl    $EAGAIN, %ecx
 182         jmp     9b
 183
 184 10:     movl    %ebp, %eax
 185         call    __lll_mutex_unlock_wake
 186         jmp     11b
 187
 188 12:     movl    %ebx, %ecx
 189         call    __lll_mutex_lock_wait
 190         jmp     13b
 191
 192 16:     movl    $-ETIMEDOUT, %ecx
 193         jmp     17b
 194
 195 18:     movl    $ETIMEDOUT, %ecx
 196         jmp     9b
 197
 198 19:     movl    $EINVAL, %ecx
 199         jmp     9b
 200         .size   pthread_rwlock_timedrdlock,.-pthread_rwlock_timedrdlock