sem_trywait implementation for Linux/i486.
[kopensolaris-gnu/glibc.git] / nptl / sysdeps / unix / sysv / linux / i386 / i486 / sem_trywait.S
1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21 #include <shlib-compat.h>
22
23 #ifndef UP
24 # define LOCK lock
25 #else
26 # define
27 #endif
28
29 #define SYS_futex               240
30 #define FUTEX_WAKE              1
31
32 #define EAGAIN                  11
33
34
35         .text
36
37         .globl  __new_sem_trywait
38         .type   __new_sem_trywait,@function
39         .align  16
40 __new_sem_trywait:
41         movl    4(%esp), %ecx
42
43         movl    (%ecx), %eax
44 2:      testl   %eax, %eax
45         jz      1f
46
47         leal    -1(%eax), %edx
48         LOCK
49         cmpxchgl %edx, (%ecx)
50         jne,pn  2b
51         xorl    %eax, %eax
52         ret
53
54 1:
55 #ifdef PIC
56         call    __i686.get_pc_thunk.cx
57 #else
58         movl    $3f, %ecx
59 3:
60 #endif
61         addl    $_GLOBAL_OFFSET_TABLE_, %ecx
62 #if USE___THREAD
63         movl    %gs:0, %edx
64         subl    errno@gottpoff(%ecx), %edx
65         movl    $EAGAIN, (%edx)
66 #else
67         call    __errno_location@plt
68         movl    $EAGAIN, (%eax)
69 #endif
70         orl     $-1, %eax
71         ret
72         .size   __new_sem_trywait,.-__new_sem_trywait
73         .symver __new_sem_trywait, sem_trywait@@GLIBC_2.1
74 #if SHLIB_COMPAT(libpthread, GLIBC_2_0, GLIBC_2_1)
75         .global __old_sem_trywait
76 __old_sem_trywait = __new_sem_trywait
77         .symver __old_sem_trywait, sem_trywait@GLIBC_2.0
78 #endif
79
80
81 #ifdef PIC
82         .section .gnu.linkonce.t.__i686.get_pc_thunk.cx,"ax",@progbits
83         .globl  __i686.get_pc_thunk.cx
84         .hidden __i686.get_pc_thunk.cx
85         .type   __i686.get_pc_thunk.cx,@function
86 __i686.get_pc_thunk.cx:
87         movl (%esp), %ecx;
88         ret
89         .size   __i686.get_pc_thunk.cx,.-__i686.get_pc_thunk.cx
90 #endif