nptl/sysdeps/unix/sysv/linux/i386/i486/sem_wait.S

   1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <shlib-compat.h>
  22
  23 #ifndef UP
  24 # define LOCK lock
  25 #else
  26 # define
  27 #endif
  28
  29 #define SYS_futex               240
  30 #define FUTEX_WAKE              1
  31
  32 #define EWOULDBLOCK             11
  33
  34
  35         .text
  36
  37         .globl  __new_sem_wait
  38         .type   __new_sem_wait,@function
  39         .align  16
  40 __new_sem_wait:
  41         pushl   %ebx
  42         pushl   %esi
  43
  44         movl    12(%esp), %ebx
  45
  46 3:      movl    (%ebx), %eax
  47 2:      testl   %eax, %eax
  48         je,pn   1f
  49
  50         leal    -1(%eax), %edx
  51         LOCK
  52         cmpxchgl %edx, (%ebx)
  53         jne,pn  2b
  54         xorl    %eax, %eax
  55
  56         popl    %esi
  57         popl    %ebx
  58         ret
  59
  60 1:      xorl    %esi, %esi
  61         movl    $SYS_futex, %eax
  62         movl    %esi, %ecx
  63         movl    %esi, %edx
  64         ENTER_KERNEL
  65
  66         testl   %eax, %eax
  67         je      3b
  68         cmpl    $-EWOULDBLOCK, %eax
  69         je      3b
  70         negl    %eax
  71 #ifdef PIC
  72         call    __i686.get_pc_thunk.bx
  73 #else
  74         movl    $4f, %ebx
  75 4:
  76 #endif
  77         addl    $_GLOBAL_OFFSET_TABLE_, %ebx
  78 #if USE___THREAD
  79         movl    %gs:0, %edx
  80         subl    errno@gottpoff(%ebx), %edx
  81         movl    %eax, (%edx)
  82 #else
  83         movl    %eax, %edx
  84         call    __errno_location@plt
  85         movl    %edx, (%eax)
  86 #endif
  87         orl     $-1, %eax
  88         popl    %esi
  89         popl    %ebx
  90         ret
  91         .size   __new_sem_wait,.-__new_sem_wait
  92         .symver __new_sem_wait, sem_wait@@GLIBC_2.1
  93 #if SHLIB_COMPAT(libpthread, GLIBC_2_0, GLIBC_2_1)
  94         .global __old_sem_wait
  95 __old_sem_wait = __new_sem_wait
  96         .symver __old_sem_wait, sem_wait@GLIBC_2.0
  97 #endif