pthread_cond_wait implementation for Linux/SH.
[kopensolaris-gnu/glibc.git] / nptl / sysdeps / unix / sysv / linux / sh / pthread_cond_broadcast.S
1 /* Copyright (C) 2003 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3
4    The GNU C Library is free software; you can redistribute it and/or
5    modify it under the terms of the GNU Lesser General Public
6    License as published by the Free Software Foundation; either
7    version 2.1 of the License, or (at your option) any later version.
8
9    The GNU C Library is distributed in the hope that it will be useful,
10    but WITHOUT ANY WARRANTY; without even the implied warranty of
11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12    Lesser General Public License for more details.
13
14    You should have received a copy of the GNU Lesser General Public
15    License along with the GNU C Library; if not, write to the Free
16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
17    02111-1307 USA.  */
18
19 #include <sysdep.h>
20 #include <shlib-compat.h>
21 #include <lowlevelcond.h>
22 #include "lowlevel-atomic.h"
23
24 #define SYS_futex               240
25 #define FUTEX_WAIT              0
26 #define FUTEX_WAKE              1
27
28
29         .text
30
31         /* int pthread_cond_broadcast (pthread_cond_t *cond) */
32         .globl  __pthread_cond_broadcast
33         .type   __pthread_cond_broadcast, @function
34         .align  5
35 __pthread_cond_broadcast:
36         mov.l   r8, @-r15
37         sts.l   pr, @-r15
38         mov     r4, r8
39
40         /* Get internal lock.  */
41         mov     #1, r3
42 #if cond_lock != 0
43         XADD (r3, @(cond_lock,r8), r2)
44 #else
45         XADD (r3, @r8, r2)
46 #endif
47         tst     r2, r2
48         bf      1f
49 2:
50         mov.l   @(total_seq+4,r8),r0
51         mov.l   @(total_seq,r8),r1
52         mov.l   @(wakeup_seq+4,r8), r2
53         cmp/hi  r2, r0
54         bt      3f
55         cmp/hi  r0, r2
56         bt      4f
57         mov.l   @(wakeup_seq,r8), r2
58         cmp/hi  r2, r1
59         bf      4f
60
61 3:
62         /* Case all currently waiting threads to wake up.  */
63         mov.l   r1, @(wakeup_seq,r8)
64         mov.l   r0, @(wakeup_seq+4,r8)
65
66         /* Wake up all threads.  */
67         mov     r8, r4
68         add     #wakeup_seq, r4
69         mov     #FUTEX_WAKE, r5
70         mov     #-1, r6
71         shlr    r6              /* r6 = 0x7fffffff */
72         mov     #0, r7
73         mov     #SYS_futex, r3
74         extu.b  r3, r3
75         trapa   #0x14
76         SYSCALL_INST_PAD
77
78 4:
79         /* Unlock.  */
80 #if cond_lock != 0
81         DEC (@(cond_lock,r8), r2)
82 #else
83         DEC (@r8, r2)
84 #endif
85         tst     r2, r2
86         bf      5f
87 6:
88         mov     #0, r0
89         lds.l   @r15+, pr
90         rts
91          mov.l  @r15+, r8
92
93 1:
94         /* Initial locking failed.  */
95         mov     r8, r5
96 #if cond_lock != 0
97         add     #cond_lock, r5
98 #endif
99         mov.l   .Lmwait5, r1
100         bsrf    r1
101          mov    r2, r4
102 .Lmwait5b:
103         bra     2b
104          nop
105
106 5:
107         /* Unlock in loop requires waekup.  */
108         mov     r8, r4
109 #if cond_lock != 0
110         add     #cond_lock, r4
111 #endif
112         mov.l   .Lmwake5, r1
113         bsrf    r1
114          nop
115 .Lmwake5b:
116         bra     6b
117          nop
118
119         .align  2
120 .Lmwait5:
121         .long   __lll_mutex_lock_wait-.Lmwait5b
122 .Lmwake5:
123         .long   __lll_mutex_unlock_wake-.Lmwake5b
124         .size   __pthread_cond_broadcast, .-__pthread_cond_broadcast
125 versioned_symbol (libpthread, __pthread_cond_broadcast, pthread_cond_broadcast,
126                   GLIBC_2_3_2)