nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_unlock.S

   1 /* Copyright (C) 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #include <lowlevelrwlock.h>
  21 #include "lowlevel-atomic.h"
  22
  23 #define SYS_futex               240
  24 #define FUTEX_WAIT              0
  25 #define FUTEX_WAKE              1
  26
  27
  28         .text
  29
  30         .globl  __pthread_rwlock_unlock
  31         .type   __pthread_rwlock_unlock,@function
  32         .align  5
  33 __pthread_rwlock_unlock:
  34         mov.l   r12, @-r15
  35         mov.l   r8, @-r15
  36         sts.l   pr, @-r15
  37         mov     r4, r8
  38
  39         /* Get the lock.  */
  40         mov     #1, r3
  41 #if MUTEX == 0
  42         XADD    (r3, @r4, r2)
  43 #else
  44         XADD    (r3, @(MUTEX,r4), r2)
  45 #endif
  46         tst     r2, r2
  47         bf      1f
  48 2:
  49         mov.l   @(WRITER,r8), r0
  50         tst     r0, r0
  51         bf      5f
  52         mov.l   @(NR_READERS,r8), r0
  53         add     #-1, r0
  54         mov.l   r0, @(NR_READERS,r8)
  55         tst     r0, r0
  56         bf      6f
  57 5:
  58         mov     #0, r0
  59         mov.l   r0, @(WRITER,r8)
  60         mov     r8, r4
  61         mov.l   @(WRITERS_QUEUED,r8), r0
  62         tst     r0, r0
  63         bf      9f
  64         mov     #-1, r6
  65         shlr    r6              /* r6 = 0x7fffffff */
  66         bra     0f
  67          add    #READERS_WAKEUP, r4
  68 9:
  69         mov     #1, r6
  70         add     #WRITERS_WAKEUP, r4
  71 0:
  72         mov     #FUTEX_WAKE, r5
  73         mov     #SYS_futex, r3
  74         extu.b  r3, r3
  75         trapa   #0x14
  76         SYSCALL_INST_PAD
  77
  78 6:
  79 #if MUTEX == 0
  80         DEC (@r8, r2)
  81 #else
  82         DEC (@(MUTEX,r8), r2)
  83 #endif
  84         tst     r2, r2
  85         bf      3f
  86 4:
  87         lds.l   @r15+, pr
  88         mov.l   @r15+, r8
  89         mov.l   @r15+, r12
  90         rts
  91          mov    #0, r0
  92
  93 1:
  94         mov     r8, r5
  95 #if MUTEX != 0
  96         add     #MUTEX, r5
  97 #endif
  98         mov     r2, r4
  99         mov.l   .Lwait8, r1
 100         bsrf    r1
 101          nop
 102 .Lwait8b:
 103         bra     2b
 104          nop
 105 3:
 106         mov     r8, r4
 107 #if MUTEX != 0
 108         add     #MUTEX, r4
 109 #endif
 110         mov.l   .Lwake8, r1
 111         bsrf    r1
 112          nop
 113 .Lwake8b:
 114         bra     4b
 115          nop
 116
 117         .align  2
 118 .Lwait8:
 119         .long   __lll_mutex_lock_wait-.Lwait8b
 120 .Lwake8:
 121         .long   __lll_mutex_unlock_wake-.Lwake8b
 122         .size   __pthread_rwlock_unlock,.-__pthread_rwlock_unlock
 123
 124         .globl  pthread_rwlock_unlock
 125 pthread_rwlock_unlock = __pthread_rwlock_unlock
 126
 127         .globl  __pthread_rwlock_unlock_internal
 128 __pthread_rwlock_unlock_internal = __pthread_rwlock_unlock