2000-03-19 Roland McGrath <roland@baalperazim.frob.com>
[kopensolaris-gnu/glibc.git] / scripts / abi-versions.awk
1 # Script to generate <abi-versions.h> header file from Versions.all list.
2 # See include/shlib-compat.h comments for explanation.
3
4 BEGIN {
5   print "/* This file is automatically generated by abi-versions.awk.";
6   print "   It defines symbols used by shlib-compat.h, which see.  */";
7   print "\n#ifndef _ABI_VERSIONS_H\n#define _ABI_VERSIONS_H";
8 }
9
10 NF == 2 && $2 == "{" {
11   thislib = $1;
12   gsub(/[^A-Za-z0-9_    ]/, "_"); libid = $1;
13   printf "\n/* start %s */\n", thislib;
14   next;
15 }
16 $1 == "}" {
17   printf "/* end %s */\n", thislib;
18   next;
19 }
20
21 $2 == "=" {
22   new = $3;
23   gsub(/[^A-Za-z0-9_    ]/, "_"); id = $1;
24   printf "#define ABI_%s_%s\t0\t/* earliest supported %s */\n", libid, id, new;
25   printf "#define VERSION_%s_%s\t%s\n", libid, id, new;
26   next;
27 }
28
29 {
30   vers = $1;
31   gsub(/[^A-Za-z0-9_    ]/, "_"); id = $1;
32   printf "#define ABI_%s_%s\t1\t/* support %s */\n", libid, id, vers;
33   printf "#define VERSION_%s_%s\t%s\n", libid, id, vers;
34   next;
35 }
36
37 END {
38   print "\n#endif /* abi-versions.h */";
39 }