2000-03-22 Roland McGrath <roland@baalperazim.frob.com>
[kopensolaris-gnu/glibc.git] / scripts / abi-versions.awk
1 # Script to generate <abi-versions.h> header file from Versions.all list.
2 # See include/shlib-compat.h comments for explanation.
3
4 BEGIN {
5   print "/* This file is automatically generated by abi-versions.awk.";
6   print "   It defines symbols used by shlib-compat.h, which see.  */";
7   print "\n#ifndef _ABI_VERSIONS_H\n#define _ABI_VERSIONS_H";
8 }
9
10 NF == 2 && $2 == "{" {
11   thislib = $1;
12   gsub(/[^A-Za-z0-9_    ]/, "_"); libid = $1;
13   printf "\n/* start %s */\n", thislib;
14   n = 0;
15   next;
16 }
17 $1 == "}" {
18   printf "/* end %s */\n", thislib;
19   next;
20 }
21
22 $2 == "=" {
23   old = $1; new = $3;
24   gsub(/[^A-Za-z0-9_    ]/, "_");
25   oldid = $1; newid = $3;
26
27   printf "#define ABI_%s_%s\tABI_%s_%s\n", libid, oldid, libid, newid;
28   printf "#define VERSION_%s_%s\t%s\n", libid, oldid, new;
29   next;
30 }
31
32 {
33   vers = $1;
34   gsub(/[^A-Za-z0-9_    ]/, "_");
35   versid = $1;
36
37   printf "#define ABI_%s_%s\t%d\t/* support %s */\n", libid, versid, ++n, vers;
38   printf "#define VERSION_%s_%s\t%s\n", libid, versid, vers;
39   next;
40 }
41
42 END {
43   print "\n#endif /* abi-versions.h */";
44 }