(_dl_map_object_deps): Revert patch from 2002-05-28. This cripples
[kopensolaris-gnu/glibc.git] / scripts / firstversions.awk
1 # Script to preprocess Versions.all lists based on "earliest version"
2 # specifications in the shlib-versions file.
3
4 NF > 2 && $2 == ":" {
5   for (i = 0; i <= NF - 3; ++i)
6     firstversion[$1, i] = $(3 + i);
7   idx[$1] = 0;
8   next;
9 }
10
11 NF == 2 && $2 == "{" { thislib = $1; print; next }
12
13 $1 == "}" {
14   if ((thislib, idx[thislib]) in firstversion) {
15     # We haven't seen the stated version, but have produced
16     # others pointing to it, so we synthesize it now.
17     printf "  %s\n", firstversion[thislib, idx[thislib]];
18     idx[thislib]++;
19   }
20   print;
21   next;
22 }
23
24 /GLIBC_PRIVATE/ { print; next }
25
26 {
27   if ((thislib, idx[thislib]) in firstversion) {
28     # XXX relative string comparison loses if we ever have multiple digits
29     # between dots in GLIBC_x.y[.z] names.
30     f = firstversion[thislib, idx[thislib]];
31     v = f;
32     while ($1 >= v) {
33       firstversion[thislib, idx[thislib]] = 0;
34       idx[thislib]++;
35       if ((thislib, idx[thislib]) in firstversion)
36         v = firstversion[thislib, idx[thislib]];
37       else
38         break;
39     }
40     if ($1 >= v || $1 == f)
41       print;
42     else
43       print $1, "=", v;
44   }
45   else
46     print;
47 }