2000-03-19 Roland McGrath <roland@baalperazim.frob.com>
[kopensolaris-gnu/glibc.git] / scripts / versions.awk
1 # Combine version map fragments into version files for the generated
2 # shared object.
3 # (C) Copyright 1998, 1999 Free Software Foundation, Inc.
4 # Written by Ulrich Drepper <drepper@cygnus.com>, 1998.
5
6 # This script expects the following variables to be defined:
7 # defsfile              name of Versions.def file
8 # buildroot             name of build directory with trailing slash
9 # move_if_change        move-if-change command
10
11 # Read definitions for the versions.
12 BEGIN {
13   nlibs=0;
14   while (getline < defsfile) {
15     if (/^[a-zA-Z0-9_.]+ \{/) {
16       libs[$1] = 1;
17       curlib = $1;
18       while (getline < defsfile && ! /^}/) {
19         if ($2 == "=")
20           renamed[$1] = $3;
21         else
22           versions[$1] = 1;
23       }
24     }
25   }
26   close(defsfile);
27
28   tmpfile = buildroot "Versions.tmp";
29   sort = "sort -n > " tmpfile;
30 }
31
32 # Remove comment lines.
33 /^ *#/ {
34   next;
35 }
36
37 # This matches the beginning of the version information for a new library.
38 /^[a-zA-Z0-9_.]+/ {
39   delete renamed;
40   actlib = $1;
41   if (!libs[$1]) {
42     printf("no versions defined for %s\n", $1) > "/dev/stderr";
43     exit 1;
44   }
45   next;
46 }
47
48 # This matches the beginning of a new version for the current library.
49 /^  [A-Za-z_]/ {
50   if (renamed[$1])
51     actver = renamed[$1];
52   else if (!versions[$1]) {
53     printf("version %s not defined\n", $1) > "/dev/stderr";
54     exit 1;
55   }
56   else
57     actver = $1;
58   next;
59 }
60
61 # This matches lines with names to be added to the current version in the
62 # current library.  This is the only place where we print something to
63 # the intermediate file.
64 /^   / {
65   printf("%s %s %s\n", actlib, actver, $0) | sort;
66 }
67
68
69 function closeversion(name, oldname) {
70   if (firstinfile) {
71     printf("  local:\n    *;\n") > outfile;
72     firstinfile = 0;
73   }
74   printf("}%s;\n", oldname) > outfile;
75 }
76
77 function close_and_move(name, real_name) {
78   close(name);
79   system(move_if_change " " name " " real_name " >&2");
80 }
81
82 # Now print the accumulated information.
83 END {
84   close(sort);
85   oldlib = "";
86   oldver = "";
87   printf("version-maps =");
88   while(getline < tmpfile) {
89     if ($1 != oldlib) {
90       if (oldlib != "") {
91         closeversion(oldver, veryoldver);
92         oldver = "";
93         close_and_move(outfile, real_outfile);
94       }
95       oldlib = $1;
96       real_outfile = buildroot oldlib ".map";
97       outfile = real_outfile "T";
98       firstinfile = 1;
99       veryoldver = "";
100       printf(" %s.map", oldlib);
101     }
102     if ($2 != oldver) {
103       if (oldver != "") {
104         closeversion(oldver, veryoldver);
105         veryoldver = oldver;
106       }
107       printf("%s {\n  global:\n", $2) > outfile;
108       oldver = $2;
109     }
110     printf("   ") > outfile;
111     for (n = 3; n <= NF; ++n) {
112       printf(" %s", $n) > outfile;
113     }
114     printf("\n") > outfile;
115   }
116   printf("\n");
117   closeversion(oldver, veryoldver);
118   close_and_move(outfile, real_outfile);
119   system("rm -f " tmpfile);
120 }