Thu Jun 13 00:02:25 1996 Roland McGrath <roland@delasyd.gnu.ai.mit.edu>
[kopensolaris-gnu/glibc.git] / sysdeps / alpha / _mcount.S
1 /* Machine-specific calling sequence for `mcount' profiling function.  alpha
2 Copyright (C) 1995, 1996 Free Software Foundation, Inc.
3 Contributed by David Mosberger (davidm@cs.arizona.edu).
4 This file is part of the GNU C Library.
5
6 The GNU C Library is free software; you can redistribute it and/or
7 modify it under the terms of the GNU Library General Public License as
8 published by the Free Software Foundation; either version 2 of the
9 License, or (at your option) any later version.
10
11 The GNU C Library is distributed in the hope that it will be useful,
12 but WITHOUT ANY WARRANTY; without even the implied warranty of
13 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 Library General Public License for more details.
15
16 You should have received a copy of the GNU Library General Public
17 License along with the GNU C Library; see the file COPYING.LIB.  If
18 not, write to the Free Software Foundation, Inc., 675 Mass Ave,
19 Cambridge, MA 02139, USA.  */
20
21 /* Assembly stub to invoke _mcount().  Compiler generated code calls
22 this stub after executing a function's prologue and without saving any
23 registers.  It is therefore necessary to preserve a0..a5 as they may
24 contain function arguments.  To work correctly with frame- less
25 functions, it is also necessary to preserve ra.  Finally, division
26 routines are invoked with a special calling convention and the
27 compiler treats those calls as if they were instructions.  In
28 particular, it doesn't save any of the temporary registers (caller
29 saved registers).  It is therefore necessary to preserve all
30 caller-saved registers as well
31  
32 Upon entering _mcount, register $at holds the return address and ra
33 holds the return address of the function's caller (selfpc and frompc,
34 respectively in gmon.c language...). */
35
36 #include <sysdep.h>
37
38 #undef ret      /* discard `ret' as defined in sysdep.h */
39
40         .set    noat
41         .set    noreorder
42
43 LEAF(_mcount, 0xb0)
44 weak_alias (_mcount, mcount)
45         .prologue 0
46
47         subq     sp, 0xb0, sp
48         stq      a0, 0x00(sp)
49         mov      ra, a0         # a0 = caller-pc
50         stq      a1, 0x08(sp)
51         mov     $at, a1         # a1 = self-pc
52         stq     $at, 0x10(sp)
53
54         stq      a2, 0x18(sp)
55         stq      a3, 0x20(sp)
56         stq      a4, 0x28(sp)
57         stq      a5, 0x30(sp)
58         stq      ra, 0x38(sp)
59         stq      gp, 0x40(sp)
60
61         br      gp, 1f
62 1:      ldgp    gp, 0(gp)
63
64         stq      t0, 0x48(sp)
65         stq      t1, 0x50(sp)
66         stq      t2, 0x58(sp)
67         stq      t3, 0x60(sp)
68         stq      t4, 0x68(sp)
69         stq      t5, 0x70(sp)
70         stq      t6, 0x78(sp)
71
72         lda      pv, __mcount
73
74         stq      t7, 0x80(sp)
75         stq      t8, 0x88(sp)
76         stq      t9, 0x90(sp)
77         stq     t10, 0x98(sp)
78         stq     t11, 0xa0(sp)
79         stq      v0, 0xa8(sp)
80
81         jsr     ra, (pv), __mcount
82
83         ldq      a0, 0x00(sp)
84         ldq      a1, 0x08(sp)
85         ldq     $at, 0x10(sp)   # restore self-pc
86         ldq      a2, 0x18(sp)
87         ldq      a3, 0x20(sp)
88         ldq      a4, 0x28(sp)
89         ldq      a5, 0x30(sp)
90         ldq      ra, 0x38(sp)
91         ldq      gp, 0x40(sp)
92         mov     $at, pv         # make pv point to return address
93         ldq      t0, 0x48(sp)   # this is important under OSF/1 to
94         ldq      t1, 0x50(sp)   # ensure that the code that we return
95         ldq      t2, 0x58(sp)   # can correctly compute its gp
96         ldq      t3, 0x60(sp)
97         ldq      t4, 0x68(sp)
98         ldq      t5, 0x70(sp)
99         ldq      t6, 0x78(sp)
100         ldq      t7, 0x80(sp)
101         ldq      t8, 0x88(sp)
102         ldq      t9, 0x90(sp)
103         ldq     t10, 0x98(sp)
104         ldq     t11, 0xa0(sp)
105         ldq      v0, 0xa8(sp)
106
107         addq    sp, 0xb0, sp
108         ret     zero,($at),1
109
110         END(_mcount)