Updated from /src/gmp-1.937
[kopensolaris-gnu/glibc.git] / sysdeps / alpha / addmul_1.s
1  # Alpha 21064 __mpn_addmul_1 -- Multiply a limb vector with a limb and add
2  # the result to a second limb vector.
3
4  # Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
5
6  # This file is part of the GNU MP Library.
7
8  # The GNU MP Library is free software; you can redistribute it and/or modify
9  # it under the terms of the GNU Library General Public License as published by
10  # the Free Software Foundation; either version 2 of the License, or (at your
11  # option) any later version.
12
13  # The GNU MP Library is distributed in the hope that it will be useful, but
14  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
16  # License for more details.
17
18  # You should have received a copy of the GNU Library General Public License
19  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20  # the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21
22
23  # INPUT PARAMETERS
24  # res_ptr      r16
25  # s1_ptr       r17
26  # size         r18
27  # s2_limb      r19
28
29  # This code runs at 42 cycles/limb on EV4 and 18 cycles/limb on EV5.
30
31         .set    noreorder
32         .set    noat
33 .text
34         .align  3
35         .globl  __mpn_addmul_1
36         .ent    __mpn_addmul_1 2
37 __mpn_addmul_1:
38         .frame  $30,0,$26
39
40         ldq     $2,0($17)       # $2 = s1_limb
41         addq    $17,8,$17       # s1_ptr++
42         subq    $18,1,$18       # size--
43         mulq    $2,$19,$3       # $3 = prod_low
44         ldq     $5,0($16)       # $5 = *res_ptr
45         umulh   $2,$19,$0       # $0 = prod_high
46         beq     $18,.Lend1      # jump if size was == 1
47         ldq     $2,0($17)       # $2 = s1_limb
48         addq    $17,8,$17       # s1_ptr++
49         subq    $18,1,$18       # size--
50         addq    $5,$3,$3
51         cmpult  $3,$5,$4
52         stq     $3,0($16)
53         addq    $16,8,$16       # res_ptr++
54         beq     $18,.Lend2      # jump if size was == 2
55
56         .align  3
57 .Loop:  mulq    $2,$19,$3       # $3 = prod_low
58         ldq     $5,0($16)       # $5 = *res_ptr
59         addq    $4,$0,$0        # cy_limb = cy_limb + 'cy'
60         subq    $18,1,$18       # size--
61         umulh   $2,$19,$4       # $4 = cy_limb
62         ldq     $2,0($17)       # $2 = s1_limb
63         addq    $17,8,$17       # s1_ptr++
64         addq    $3,$0,$3        # $3 = cy_limb + prod_low
65         cmpult  $3,$0,$0        # $0 = carry from (cy_limb + prod_low)
66         addq    $5,$3,$3
67         cmpult  $3,$5,$5
68         stq     $3,0($16)
69         addq    $16,8,$16       # res_ptr++
70         addq    $5,$0,$0        # combine carries
71         bne     $18,.Loop
72
73 .Lend2: mulq    $2,$19,$3       # $3 = prod_low
74         ldq     $5,0($16)       # $5 = *res_ptr
75         addq    $4,$0,$0        # cy_limb = cy_limb + 'cy'
76         umulh   $2,$19,$4       # $4 = cy_limb
77         addq    $3,$0,$3        # $3 = cy_limb + prod_low
78         cmpult  $3,$0,$0        # $0 = carry from (cy_limb + prod_low)
79         addq    $5,$3,$3
80         cmpult  $3,$5,$5
81         stq     $3,0($16)
82         addq    $5,$0,$0        # combine carries
83         addq    $4,$0,$0        # cy_limb = prod_high + cy
84         ret     $31,($26),1
85 .Lend1: addq    $5,$3,$3
86         cmpult  $3,$5,$5
87         stq     $3,0($16)
88         addq    $0,$5,$0
89         ret     $31,($26),1
90
91         .end    __mpn_addmul_1