* elf/elf.h (DT_ALPHA_PLTRO, DT_ALPHA_NUM): New.
[kopensolaris-gnu/glibc.git] / sysdeps / alpha / divl.S
1 /* Copyright (C) 2004 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3
4    The GNU C Library is free software; you can redistribute it and/or
5    modify it under the terms of the GNU Lesser General Public
6    License as published by the Free Software Foundation; either
7    version 2.1 of the License, or (at your option) any later version.
8
9    The GNU C Library is distributed in the hope that it will be useful,
10    but WITHOUT ANY WARRANTY; without even the implied warranty of
11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12    Lesser General Public License for more details.
13
14    You should have received a copy of the GNU Lesser General Public
15    License along with the GNU C Library; if not, write to the Free
16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
17    02111-1307 USA.  */
18
19 #include "div_libc.h"
20
21 /* 32-bit signed int divide.  This is not a normal C function.  Argument
22    registers are t10 and t11, the result goes in t12.  Only t12 and AT may
23    be clobbered.
24
25    The FPU can handle all input values except zero.  Whee!
26
27    The FPCR save/restore is due to the fact that the EV6 _will_ set FPCR_INE
28    for cvttq/c even without /sui being set.  It will not, however, properly
29    raise the exception, so we don't have to worry about FPCR_INED being clear
30    and so dying by SIGFPE.  */
31
32 #ifndef EXTEND
33 #define EXTEND(S,D)     sextl S, D
34 #endif
35
36         .text
37         .align  4
38         .globl  __divl
39         .type   __divl, @funcnoplt
40         .usepv  __divl, no
41
42         cfi_startproc
43         cfi_return_column (RA)
44 __divl:
45         lda     sp, -FRAME(sp)
46         cfi_def_cfa_offset (FRAME)
47         CALL_MCOUNT
48         stt     $f0, 0(sp)
49         excb
50         beq     Y, DIVBYZERO
51
52         stt     $f1, 8(sp)
53         stt     $f2, 16(sp)
54         cfi_rel_offset ($f0, 0)
55         cfi_rel_offset ($f1, 8)
56         cfi_rel_offset ($f2, 16)
57         mf_fpcr $f2
58
59         EXTEND  (X, RV)
60         EXTEND  (Y, AT)
61         _ITOFT2 RV, $f0, 24, AT, $f1, 32
62         cvtqt   $f0, $f0
63         cvtqt   $f1, $f1
64         divt/c  $f0, $f1, $f0
65         cvttq/c $f0, $f0
66         excb
67         mt_fpcr $f2
68         _FTOIT  $f0, RV, 24
69
70         ldt     $f0, 0(sp)
71         ldt     $f1, 8(sp)
72         ldt     $f2, 16(sp)
73         lda     sp, FRAME(sp)
74         cfi_restore ($f0)
75         cfi_restore ($f1)
76         cfi_restore ($f2)
77         cfi_def_cfa_offset (0)
78         sextl   RV, RV
79         ret     $31, (RA), 1
80
81         cfi_endproc
82         .size   __divl, .-__divl
83
84         DO_DIVBYZERO