Cleanup swapoff.c and swapon.c
[kopensolaris-gnu/glibc.git] / sysdeps / alpha / lshift.s
1  # Alpha 21064 __mpn_lshift --
2
3  # Copyright (C) 1994, 1995 Free Software Foundation, Inc.
4
5  # This file is part of the GNU MP Library.
6
7  # The GNU MP Library is free software; you can redistribute it and/or modify
8  # it under the terms of the GNU Lesser General Public License as published by
9  # the Free Software Foundation; either version 2.1 of the License, or (at your
10  # option) any later version.
11
12  # The GNU MP Library is distributed in the hope that it will be useful, but
13  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
15  # License for more details.
16
17  # You should have received a copy of the GNU Lesser General Public License
18  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
19  # the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
20  # MA 02111-1307, USA.
21
22
23  # INPUT PARAMETERS
24  # res_ptr      r16
25  # s1_ptr       r17
26  # size         r18
27  # cnt          r19
28
29  # This code runs at 4.8 cycles/limb on the 21064.  With infinite unrolling,
30  # it would take 4 cycles/limb.  It should be possible to get down to 3
31  # cycles/limb since both ldq and stq can be paired with the other used
32  # instructions.  But there are many restrictions in the 21064 pipeline that
33  # makes it hard, if not impossible, to get down to 3 cycles/limb:
34
35  # 1. ldq has a 3 cycle delay, srl and sll have a 2 cycle delay.
36  # 2. Only aligned instruction pairs can be paired.
37  # 3. The store buffer or silo might not be able to deal with the bandwidth.
38
39         .set    noreorder
40         .set    noat
41 .text
42         .align  3
43         .globl  __mpn_lshift
44         .ent    __mpn_lshift
45 __mpn_lshift:
46         .frame  $30,0,$26,0
47
48         s8addq  $18,$17,$17     # make r17 point at end of s1
49         ldq     $4,-8($17)      # load first limb
50         subq    $17,8,$17
51         subq    $31,$19,$7
52         s8addq  $18,$16,$16     # make r16 point at end of RES
53         subq    $18,1,$18
54         and     $18,4-1,$20     # number of limbs in first loop
55         srl     $4,$7,$0        # compute function result
56
57         beq     $20,.L0
58         subq    $18,$20,$18
59
60         .align  3
61 .Loop0:
62         ldq     $3,-8($17)
63         subq    $16,8,$16
64         subq    $17,8,$17
65         subq    $20,1,$20
66         sll     $4,$19,$5
67         srl     $3,$7,$6
68         bis     $3,$3,$4
69         bis     $5,$6,$8
70         stq     $8,0($16)
71         bne     $20,.Loop0
72
73 .L0:    beq     $18,.Lend
74
75         .align  3
76 .Loop:  ldq     $3,-8($17)
77         subq    $16,32,$16
78         subq    $18,4,$18
79         sll     $4,$19,$5
80         srl     $3,$7,$6
81
82         ldq     $4,-16($17)
83         sll     $3,$19,$1
84         bis     $5,$6,$8
85         stq     $8,24($16)
86         srl     $4,$7,$2
87
88         ldq     $3,-24($17)
89         sll     $4,$19,$5
90         bis     $1,$2,$8
91         stq     $8,16($16)
92         srl     $3,$7,$6
93
94         ldq     $4,-32($17)
95         sll     $3,$19,$1
96         bis     $5,$6,$8
97         stq     $8,8($16)
98         srl     $4,$7,$2
99
100         subq    $17,32,$17
101         bis     $1,$2,$8
102         stq     $8,0($16)
103
104         bgt     $18,.Loop
105
106 .Lend:  sll     $4,$19,$8
107         stq     $8,-8($16)
108         ret     $31,($26),1
109         .end    __mpn_lshift