Updated from /src/gmp-1.937
[kopensolaris-gnu/glibc.git] / sysdeps / alpha / mul_1.s
1  # Alpha 21064 __mpn_mul_1 -- Multiply a limb vector with a limb and store
2  # the result in a second limb vector.
3
4  # Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
5
6  # This file is part of the GNU MP Library.
7
8  # The GNU MP Library is free software; you can redistribute it and/or modify
9  # it under the terms of the GNU Library General Public License as published by
10  # the Free Software Foundation; either version 2 of the License, or (at your
11  # option) any later version.
12
13  # The GNU MP Library is distributed in the hope that it will be useful, but
14  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
16  # License for more details.
17
18  # You should have received a copy of the GNU Library General Public License
19  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20  # the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21
22
23  # INPUT PARAMETERS
24  # res_ptr      r16
25  # s1_ptr       r17
26  # size         r18
27  # s2_limb      r19
28
29  # This code runs at 42 cycles/limb on the EV4 and 18 cycles/limb on the EV5.
30
31  # To improve performance for long multiplications, we would use
32  # 'fetch' for S1 and 'fetch_m' for RES.  It's not obvious how to use
33  # these instructions without slowing down the general code: 1. We can
34  # only have two prefetches in operation at any time in the Alpha
35  # architecture.  2. There will seldom be any special alignment
36  # between RES_PTR and S1_PTR.  Maybe we can simply divide the current
37  # loop into an inner and outer loop, having the inner loop handle
38  # exactly one prefetch block?
39
40         .set    noreorder
41         .set    noat
42 .text
43         .align  3
44         .globl  __mpn_mul_1
45         .ent    __mpn_mul_1 2
46 __mpn_mul_1:
47         .frame  $30,0,$26
48
49         ldq     $2,0($17)       # $2 = s1_limb
50         subq    $18,1,$18       # size--
51         mulq    $2,$19,$3       # $3 = prod_low
52         bic     $31,$31,$4      # clear cy_limb
53         umulh   $2,$19,$0       # $0 = prod_high
54         beq     $18,Lend1       # jump if size was == 1
55         ldq     $2,8($17)       # $2 = s1_limb
56         subq    $18,1,$18       # size--
57         stq     $3,0($16)
58         beq     $18,Lend2       # jump if size was == 2
59
60         .align  3
61 Loop:   mulq    $2,$19,$3       # $3 = prod_low
62         addq    $4,$0,$0        # cy_limb = cy_limb + 'cy'
63         subq    $18,1,$18       # size--
64         umulh   $2,$19,$4       # $4 = cy_limb
65         ldq     $2,16($17)      # $2 = s1_limb
66         addq    $17,8,$17       # s1_ptr++
67         addq    $3,$0,$3        # $3 = cy_limb + prod_low
68         stq     $3,8($16)
69         cmpult  $3,$0,$0        # $0 = carry from (cy_limb + prod_low)
70         addq    $16,8,$16       # res_ptr++
71         bne     $18,Loop
72
73 Lend2:  mulq    $2,$19,$3       # $3 = prod_low
74         addq    $4,$0,$0        # cy_limb = cy_limb + 'cy'
75         umulh   $2,$19,$4       # $4 = cy_limb
76         addq    $3,$0,$3        # $3 = cy_limb + prod_low
77         cmpult  $3,$0,$0        # $0 = carry from (cy_limb + prod_low)
78         stq     $3,8($16)
79         addq    $4,$0,$0        # cy_limb = prod_high + cy
80         ret     $31,($26),1
81 Lend1:  stq     $3,0($16)
82         ret     $31,($26),1
83
84         .end    __mpn_mul_1