Updated from ../=mpn/gmp-1.906.7
[kopensolaris-gnu/glibc.git] / sysdeps / alpha / rshift.s
1  # Alpha 21064 __mpn_rshift --
2
3  # Copyright (C) 1994, 1995 Free Software Foundation, Inc.
4
5  # This file is part of the GNU MP Library.
6
7  # The GNU MP Library is free software; you can redistribute it and/or modify
8  # it under the terms of the GNU Library General Public License as published by
9  # the Free Software Foundation; either version 2 of the License, or (at your
10  # option) any later version.
11
12  # The GNU MP Library is distributed in the hope that it will be useful, but
13  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
15  # License for more details.
16
17  # You should have received a copy of the GNU Library General Public License
18  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
19  # the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20
21
22  # INPUT PARAMETERS
23  # res_ptr      r16
24  # s1_ptr       r17
25  # size         r18
26  # cnt          r19
27
28  # This code runs at 4.8 cycles/limb on the 21064.  With infinite unrolling,
29  # it would take 4 cycles/limb.  It should be possible to get down to 3
30  # cycles/limb since both ldq and stq can be paired with the other used
31  # instructions.  But there are many restrictions in the 21064 pipeline that
32  # makes it hard, if not impossible, to get down to 3 cycles/limb:
33
34  # 1. ldq has a 3 cycle delay, srl and sll have a 2 cycle delay.
35  # 2. Only aligned instruction pairs can be paired.
36  # 3. The store buffer or silo might not be able to deal with the bandwidth.
37       
38         .set    noreorder
39         .set    noat
40 .text
41         .align  3
42         .globl  __mpn_rshift
43         .ent    __mpn_rshift
44 __mpn_rshift:
45         .frame  $30,0,$26,0
46
47         ldq     $4,0($17)       # load first limb
48         addq    $17,8,$17
49         subq    $31,$19,$7
50         subq    $18,1,$18
51         and     $18,4-1,$20     # number of limbs in first loop
52         sll     $4,$7,$0        # compute function result
53
54         beq     $20,L0
55         subq    $18,$20,$18
56
57         .align  3
58 Loop0:
59         ldq     $3,0($17)
60         addq    $16,8,$16
61         addq    $17,8,$17
62         subq    $20,1,$20
63         srl     $4,$19,$5
64         sll     $3,$7,$6
65         bis     $3,$3,$4
66         bis     $5,$6,$8
67         stq     $8,-8($16)
68         bne     $20,Loop0
69
70 L0:     beq     $18,Lend
71
72         .align  3
73 Loop:   ldq     $3,0($17)
74         addq    $16,32,$16
75         subq    $18,4,$18
76         srl     $4,$19,$5
77         sll     $3,$7,$6
78
79         ldq     $4,8($17)
80         srl     $3,$19,$1
81         bis     $5,$6,$8
82         stq     $8,-32($16)
83         sll     $4,$7,$2
84
85         ldq     $3,16($17)
86         srl     $4,$19,$5
87         bis     $1,$2,$8
88         stq     $8,-24($16)
89         sll     $3,$7,$6
90
91         ldq     $4,24($17)
92         srl     $3,$19,$1
93         bis     $5,$6,$8
94         stq     $8,-16($16)
95         sll     $4,$7,$2
96
97         addq    $17,32,$17
98         bis     $1,$2,$8
99         stq     $8,-8($16)
100
101         bgt     $18,Loop
102
103 Lend:   srl     $4,$19,$8
104         stq     $8,0($16)
105         ret     $31,($26),1
106         .end    __mpn_rshift