update from main archive 961105
[kopensolaris-gnu/glibc.git] / sysdeps / alpha / strcat.S
1 /* Copyright (C) 1996 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Richard Henderson (rth@tamu.edu)
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 /* Append a null-terminated string from SRC to DST.  */
21
22 #include <sysdep.h>
23
24         .text
25
26 ENTRY(strcat)
27         ldgp    gp, 0(pv)
28 #ifdef PROF
29         lda     AT, _mcount
30         jsr     AT, (AT), _mcount
31 #endif
32         .prologue 1
33
34         mov     a0, v0          # set up return value
35
36         /* Find the end of the string.  */
37
38         ldq_u   t0, 0(a0)       # load first quadword (a0 may be misaligned)
39         lda     t1, -1(zero)
40         insqh   t1, a0, t1
41         andnot  a0, 7, a0
42         or      t1, t0, t0
43         cmpbge  zero, t0, t1    # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
44         bne     t1, $found
45
46 $loop:  ldq     t0, 8(a0)
47         addq    a0, 8, a0       # addr += 8
48         cmpbge  zero, t0, t1
49         beq     t1, $loop
50
51 $found: negq    t1, t2          # clear all but least set bit
52         and     t1, t2, t1
53
54         and     t1, 0xf0, t2    # binary search for that set bit
55         and     t1, 0xcc, t3
56         and     t1, 0xaa, t4
57         cmovne  t2, 4, t2
58         cmovne  t3, 2, t3
59         cmovne  t4, 1, t4
60         addq    t2, t3, t2
61         addq    a0, t4, a0
62         addq    a0, t2, a0
63
64         /* Now do the append.  */
65
66         jsr     t9, __stxcpy
67         ret
68
69         END(strcat)