Document new tristate __libc_missing_32bit_uids.
[kopensolaris-gnu/glibc.git] / sysdeps / arm / memset.S
1 /* Copyright (C) 1998 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Philip Blundell <philb@gnu.org>
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21
22 /* void *memset (dstpp, c, len) */
23
24 ENTRY(memset)
25         mov     a4, a1
26         cmp     a3, $8          @ at least 8 bytes to do?
27         blt     2f
28         orr     a2, a2, a2, lsl $8
29         orr     a2, a2, a2, lsl $16
30 1:
31         tst     a4, $3          @ aligned yet?
32         strneb  a2, [a4], $1
33         subne   a3, a3, $1
34         bne     1b
35         mov     ip, a2
36 1:
37         cmp     a3, $8          @ 8 bytes still to do?
38         blt     2f
39         stmia   a4!, {a2, ip}
40         sub     a3, a3, $8
41         cmp     a3, $8          @ 8 bytes still to do?
42         blt     2f
43         stmia   a4!, {a2, ip}
44         sub     a3, a3, $8
45         cmp     a3, $8          @ 8 bytes still to do?
46         blt     2f
47         stmia   a4!, {a2, ip}
48         sub     a3, a3, $8
49         cmp     a3, $8          @ 8 bytes still to do?
50         stmgeia a4!, {a2, ip}
51         subge   a3, a3, $8
52         bge     1b
53 2:
54         movs    a3, a3          @ anything left?
55         RETINSTR(moveq,pc,lr)   @ nope
56         rsb     a3, a3, $7
57         add     pc, pc, a3, lsl $2
58         mov     r0, r0
59         strb    a2, [a4], $1
60         strb    a2, [a4], $1
61         strb    a2, [a4], $1
62         strb    a2, [a4], $1
63         strb    a2, [a4], $1
64         strb    a2, [a4], $1
65         strb    a2, [a4], $1
66         RETINSTR(mov,pc,lr)
67 END(memset)