Additional configuration for IA-64/ELF.
[kopensolaris-gnu/glibc.git] / sysdeps / arm / strlen.S
1 /* Copyright (C) 1998 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Code contributed by Matthew Wilcox <willy@odie.barnet.ac.uk>
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21
22 /* size_t strlen(const char *S)
23  * entry: r0 -> string
24  * exit: r0 = len
25  */
26
27 ENTRY(strlen)
28         bic     r1, r0, $3              @ addr of word containing first byte
29         ldr     r2, [r1], $4            @ get the first word
30         ands    r3, r0, $3              @ how many bytes are duff?
31         rsb     r0, r3, $0              @ get - that number into counter.
32         beq     Laligned                @ skip into main check routine if no
33                                         @ more
34 #ifdef __ARMEB__
35         orr     r2, r2, $0xff000000     @ set this byte to non-zero
36         subs    r3, r3, $1              @ any more to do?
37         orrgt   r2, r2, $0x00ff0000     @ if so, set this byte
38         subs    r3, r3, $1              @ more?
39         orrgt   r2, r2, $0x0000ff00     @ then set.
40 #else
41         orr     r2, r2, $0x000000ff     @ set this byte to non-zero
42         subs    r3, r3, $1              @ any more to do?
43         orrgt   r2, r2, $0x0000ff00     @ if so, set this byte
44         subs    r3, r3, $1              @ more?
45         orrgt   r2, r2, $0x00ff0000     @ then set.
46 #endif
47 Laligned:                               @ here, we have a word in r2.  Does it
48         tst     r2, $0x000000ff         @ contain any zeroes?
49         tstne   r2, $0x0000ff00         @
50         tstne   r2, $0x00ff0000         @
51         tstne   r2, $0xff000000         @
52         addne   r0, r0, $4              @ if not, the string is 4 bytes longer
53         ldrne   r2, [r1], $4            @ and we continue to the next word
54         bne     Laligned                @
55 Llastword:                              @ drop through to here once we find a
56         tst     r2, $0x000000ff         @ word that has a zero byte in it
57         addne   r0, r0, $1              @
58         tstne   r2, $0x0000ff00         @ and add up to 3 bytes on to it
59         addne   r0, r0, $1              @
60         tstne   r2, $0x00ff0000         @ (if first three all non-zero, 4th
61         addne   r0, r0, $1              @  must be zero)
62         RETINSTR(mov,pc,lr)
63 END(strlen)