Updated from ../=mpn/gmp-1.906.7
[kopensolaris-gnu/glibc.git] / sysdeps / hppa / hppa1.1 / addmul_1.s
1 ; HP-PA-1.1 __mpn_addmul_1 -- Multiply a limb vector with a limb and
2 ; add the result to a second limb vector.
3
4 ; Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
5
6 ; This file is part of the GNU MP Library.
7
8 ; The GNU MP Library is free software; you can redistribute it and/or modify
9 ; it under the terms of the GNU Library General Public License as published by
10 ; the Free Software Foundation; either version 2 of the License, or (at your
11 ; option) any later version.
12
13 ; The GNU MP Library is distributed in the hope that it will be useful, but
14 ; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 ; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
16 ; License for more details.
17
18 ; You should have received a copy of the GNU Library General Public License
19 ; along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20 ; the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21
22
23 ; INPUT PARAMETERS
24 ; res_ptr       r26
25 ; s1_ptr        r25
26 ; size          r24
27 ; s2_limb       r23
28
29 ; This runs at 11 cycles/limb on a PA7000.  With the used instructions, it
30 ; can not become faster due to data cache contention after a store.  On the
31 ; PA7100 it runs at 10 cycles/limb, and that can not be improved either,
32 ; since only the xmpyu does not need the integer pipeline, so the only
33 ; dual-issue we will get are addc+xmpyu.  Unrolling could gain a cycle/limb
34 ; on the PA7100.
35
36 ; There are some ideas described in mul_1.s that applies to this code too.
37
38         .code
39         .export         __mpn_addmul_1
40 __mpn_addmul_1
41         .proc
42         .callinfo       frame=64,no_calls
43         .entry
44
45         ldo             64(%r30),%r30
46         fldws,ma        4(%r25),%fr5
47         stw             %r23,-16(%r30)          ; move s2_limb ...
48         addib,=         -1,%r24,L$just_one_limb
49          fldws          -16(%r30),%fr4          ; ... into fr4
50         add             %r0,%r0,%r0             ; clear carry
51         xmpyu           %fr4,%fr5,%fr6
52         fldws,ma        4(%r25),%fr7
53         fstds           %fr6,-16(%r30)
54         xmpyu           %fr4,%fr7,%fr8
55         ldw             -12(%r30),%r19          ; least significant limb in product
56         ldw             -16(%r30),%r28
57
58         fstds           %fr8,-16(%r30)
59         addib,=         -1,%r24,L$end
60          ldw            -12(%r30),%r1
61
62 ; Main loop
63 L$loop  ldws            0(%r26),%r29
64         fldws,ma        4(%r25),%fr5
65         add             %r29,%r19,%r19
66         stws,ma         %r19,4(%r26)
67         addc            %r28,%r1,%r19
68         xmpyu           %fr4,%fr5,%fr6
69         ldw             -16(%r30),%r28
70         fstds           %fr6,-16(%r30)
71         addc            %r0,%r28,%r28
72         addib,<>        -1,%r24,L$loop
73          ldw            -12(%r30),%r1
74
75 L$end   ldw             0(%r26),%r29
76         add             %r29,%r19,%r19
77         stws,ma         %r19,4(%r26)
78         addc            %r28,%r1,%r19
79         ldw             -16(%r30),%r28
80         ldws            0(%r26),%r29
81         addc            %r0,%r28,%r28
82         add             %r29,%r19,%r19
83         stws,ma         %r19,4(%r26)
84         addc            %r0,%r28,%r28
85         bv              0(%r2)
86          ldo            -64(%r30),%r30
87
88 L$just_one_limb
89         xmpyu           %fr4,%fr5,%fr6
90         ldw             0(%r26),%r29
91         fstds           %fr6,-16(%r30)
92         ldw             -12(%r30),%r1
93         ldw             -16(%r30),%r28
94         add             %r29,%r1,%r19
95         stw             %r19,0(%r26)
96         addc            %r0,%r28,%r28
97         bv              0(%r2)
98          ldo            -64(%r30),%r30
99
100         .exit
101         .procend