Updated from ../=mpn/gmp-1.906.7
[kopensolaris-gnu/glibc.git] / sysdeps / hppa / hppa1.1 / submul_1.s
1 ; HP-PA-1.1 __mpn_submul_1 -- Multiply a limb vector with a limb and
2 ; subtract the result from a second limb vector.
3
4 ; Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
5
6 ; This file is part of the GNU MP Library.
7
8 ; The GNU MP Library is free software; you can redistribute it and/or modify
9 ; it under the terms of the GNU Library General Public License as published by
10 ; the Free Software Foundation; either version 2 of the License, or (at your
11 ; option) any later version.
12
13 ; The GNU MP Library is distributed in the hope that it will be useful, but
14 ; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 ; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
16 ; License for more details.
17
18 ; You should have received a copy of the GNU Library General Public License
19 ; along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20 ; the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21
22
23 ; INPUT PARAMETERS
24 ; res_ptr       r26
25 ; s1_ptr        r25
26 ; size          r24
27 ; s2_limb       r23
28
29 ; This runs at 12 cycles/limb on a PA7000.  With the used instructions, it
30 ; can not become faster due to data cache contention after a store.  On the
31 ; PA7100 it runs at 11 cycles/limb, and that can not be improved either,
32 ; since only the xmpyu does not need the integer pipeline, so the only
33 ; dual-issue we will get are addc+xmpyu.  Unrolling could gain a cycle/limb
34 ; on the PA7100.
35
36 ; There are some ideas described in mul_1.s that applies to this code too.
37
38 ; It seems possible to make this run as fast as __mpn_addmul_1, if we use
39 ;       sub,>>= %r29,%r19,%r22
40 ;       addi    1,%r28,%r28
41 ; but that requires reworking the hairy software pipeline...
42
43         .code
44         .export         __mpn_submul_1
45 __mpn_submul_1
46         .proc
47         .callinfo       frame=64,no_calls
48         .entry
49
50         ldo             64(%r30),%r30
51         fldws,ma        4(%r25),%fr5
52         stw             %r23,-16(%r30)          ; move s2_limb ...
53         addib,=         -1,%r24,L$just_one_limb
54          fldws          -16(%r30),%fr4          ; ... into fr4
55         add             %r0,%r0,%r0             ; clear carry
56         xmpyu           %fr4,%fr5,%fr6
57         fldws,ma        4(%r25),%fr7
58         fstds           %fr6,-16(%r30)
59         xmpyu           %fr4,%fr7,%fr8
60         ldw             -12(%r30),%r19          ; least significant limb in product
61         ldw             -16(%r30),%r28
62
63         fstds           %fr8,-16(%r30)
64         addib,=         -1,%r24,L$end
65          ldw            -12(%r30),%r1
66
67 ; Main loop
68 L$loop  ldws            0(%r26),%r29
69         fldws,ma        4(%r25),%fr5
70         sub             %r29,%r19,%r22
71         add             %r22,%r19,%r0
72         stws,ma         %r22,4(%r26)
73         addc            %r28,%r1,%r19
74         xmpyu           %fr4,%fr5,%fr6
75         ldw             -16(%r30),%r28
76         fstds           %fr6,-16(%r30)
77         addc            %r0,%r28,%r28
78         addib,<>        -1,%r24,L$loop
79          ldw            -12(%r30),%r1
80
81 L$end   ldw             0(%r26),%r29
82         sub             %r29,%r19,%r22
83         add             %r22,%r19,%r0
84         stws,ma         %r22,4(%r26)
85         addc            %r28,%r1,%r19
86         ldw             -16(%r30),%r28
87         ldws            0(%r26),%r29
88         addc            %r0,%r28,%r28
89         sub             %r29,%r19,%r22
90         add             %r22,%r19,%r0
91         stws,ma         %r22,4(%r26)
92         addc            %r0,%r28,%r28
93         bv              0(%r2)
94          ldo            -64(%r30),%r30
95
96 L$just_one_limb
97         xmpyu           %fr4,%fr5,%fr6
98         ldw             0(%r26),%r29
99         fstds           %fr6,-16(%r30)
100         ldw             -12(%r30),%r1
101         ldw             -16(%r30),%r28
102         sub             %r29,%r1,%r22
103         add             %r22,%r1,%r0
104         stw             %r22,0(%r26)
105         addc            %r0,%r28,%r28
106         bv              0(%r2)
107          ldo            -64(%r30),%r30
108
109         .exit
110         .procend